Move declarations to header files.

[bpt/emacs.git] / config.bat

@echo off\r
rem   ----------------------------------------------------------------------\r
rem   Configuration script for MSDOS\r
rem   Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2001, 2002, 2003\r
rem   2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.\r
\r
rem   This file is part of GNU Emacs.\r
\r
rem   GNU Emacs is free software: you can redistribute it and/or modify\r
rem   it under the terms of the GNU General Public License as published by\r
rem   the Free Software Foundation, either version 3 of the License, or\r
rem   (at your option) any later version.\r
\r
rem   GNU Emacs is distributed in the hope that it will be useful,\r
rem   but WITHOUT ANY WARRANTY; without even the implied warranty of\r
rem   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the\r
rem   GNU General Public License for more details.\r
\r
rem   You should have received a copy of the GNU General Public License\r
rem   along with GNU Emacs.  If not, see http://www.gnu.org/licenses/.\r
\r
rem   ----------------------------------------------------------------------\r
rem   YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:\r
rem\r
rem   + msdos version 3 or better.\r
rem   + DJGPP version 2.0 or later (version 2.03 or later recommended).\r
rem   + make utility that allows breaking of the 128 chars limit on\r
rem     command lines.  ndmake (as of version 4.5) won't work due to a\r
rem     line length limit.  The make that comes with DJGPP does work (and is\r
rem     recommended).\r
rem   + rm, mv, and cp (from GNU file utilities).\r
rem   + sed (you can use the port that comes with DJGPP).\r
rem\r
rem   You should be able to get all the above utilities from the DJGPP FTP\r
rem   site, ftp.delorie.com, in the directory "pub/djgpp/current/v2gnu".\r
rem   ----------------------------------------------------------------------\r
set X11=\r
set nodebug=\r
set djgpp_ver=\r
set sys_malloc=\r
if "%1" == "" goto usage\r
rem   ----------------------------------------------------------------------\r
rem   See if their environment is large enough.  We need 28 bytes.\r
set $foo$=789012345678901234567\r
if not "%$foo$%" == "789012345678901234567" goto SmallEnv\r
set $foo$=\r
:again\r
if "%1" == "" goto usage\r
if "%1" == "--with-x" goto withx\r
if "%1" == "--no-debug" goto nodebug\r
if "%1" == "msdos" goto msdos\r
if "%1" == "--with-system-malloc" goto sysmalloc\r
:usage\r
echo Usage: config [--no-debug] [--with-system-malloc] [--with-x] msdos\r
echo [Read the script before you run it.]\r
goto end\r
rem   ----------------------------------------------------------------------\r
:withx\r
set X11=Y\r
shift\r
goto again\r
rem   ----------------------------------------------------------------------\r
:nodebug\r
set nodebug=Y\r
shift\r
goto again\r
rem   ----------------------------------------------------------------------\r
:sysmalloc\r
set sys_malloc=Y\r
shift\r
goto again\r
rem   ----------------------------------------------------------------------\r
:msdos\r
Echo Checking whether 'sed' is available...\r
sed -e "w junk.$$$" <Nul\r
If Exist junk.$$$ Goto sedOk\r
Echo To configure 'Emacs' you need to have 'sed'!\r
Goto End\r
:sedOk\r
Echo Checking whether 'rm' is available...\r
rm -f junk.$$$\r
If Not Exist junk.$$$ Goto rmOk\r
Echo To configure 'Emacs' you need to have 'rm'!\r
Goto End\r
:rmOk\r
Echo Checking whether 'mv' is available...\r
rm -f junk.1 junk.2\r
echo foo >junk.1\r
mv junk.1 ./junk.2\r
If Exist junk.2 Goto mvOk\r
Echo To configure 'Emacs' you need to have 'mv'!\r
rm -f junk.1\r
Goto End\r
:mvOk\r
rm -f junk.2\r
Echo Checking whether 'gcc' is available...\r
echo main(){} >junk.c\r
gcc -c junk.c\r
if exist junk.o goto gccOk\r
Echo To configure 'Emacs' you need to have 'gcc'!\r
rm -f junk.c\r
Goto End\r
:gccOk\r
rm -f junk.c junk.o junk junk.exe\r
Echo Checking what version of DJGPP is installed...\r
If Not "%DJGPP%" == "" goto djgppOk\r
Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!\r
Goto End\r
:djgppOk\r
echo int main()           >junk.c\r
echo #ifdef __DJGPP__    >>junk.c\r
echo {return (__DJGPP__)*10;} >>junk.c\r
echo #else               >>junk.c\r
echo #ifdef __GO32__     >>junk.c\r
echo {return 10;}         >>junk.c\r
echo #else               >>junk.c\r
echo {return 0;}         >>junk.c\r
echo #endif              >>junk.c\r
echo #endif              >>junk.c\r
gcc -o junk junk.c\r
if not exist junk.exe coff2exe junk\r
junk\r
If ErrorLevel 10 Goto go32Ok\r
rm -f junk.c junk junk.exe\r
Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!\r
Goto End\r
:go32Ok\r
set djgpp_ver=2\r
If Not ErrorLevel 20 Echo To build 'Emacs' you need DJGPP v2.0 or later!\r
If Not ErrorLevel 20 Goto End\r
rm -f junk.c junk junk.exe\r
rem DJECHO is used by the top-level Makefile in the v2.x build\r
Echo Checking whether 'djecho' is available...\r
redir -o Nul -eo djecho -o junk.$$$ foo\r
If Exist junk.$$$ Goto djechoOk\r
Echo To build 'Emacs' you need the 'djecho.exe' program!\r
Echo 'djecho.exe' is part of 'djdevNNN.zip' basic DJGPP development kit.\r
Echo Versions of DJGPP before 2.02 called this program 'echo.exe'.\r
Echo Either unpack 'djecho.exe' from the 'djdevNNN.zip' archive,\r
Echo or, if you have 'echo.exe', copy it to 'djecho.exe'.\r
Echo Then run CONFIG.BAT again with the same arguments you did now.\r
Goto End\r
:djechoOk\r
rm -f junk.$$$\r
Echo Configuring for DJGPP Version %DJGPP_VER% ...\r
Rem   ----------------------------------------------------------------------\r
Echo Configuring the source directory...\r
cd src\r
\r
rem   Create "epaths.h"\r
sed -f ../msdos/sed4.inp <epaths.in >epaths.tmp\r
update epaths.tmp epaths.h >nul\r
rm -f epaths.tmp\r
\r
rem   Create "config.h"\r
rm -f config.h2 config.tmp\r
sed -e '' config.in > config.tmp\r
if "%X11%" == "" goto src4\r
sed -f ../msdos/sed2x.inp <config.in >config.tmp\r
:src4\r
sed -f ../msdos/sed2v2.inp <config.tmp >config.h2\r
Rem See if DECL_ALIGN can be supported with this GCC\r
rm -f junk.c junk.o junk junk.exe\r
echo struct { int i; char *p; } __attribute__((__aligned__(8))) foo;  >junk.c\r
rem Two percent signs because it is a special character for COMMAND.COM/CMD\r
rem Filter thru Sed because "&" is special for CMD.EXE\r
echo int main(void) { return (unsigned long)"&"foo %% 8; } | sed "s/.&./\&/"         >>junk.c\r
gcc -o junk junk.c\r
if not exist junk.exe coff2exe junk\r
junk\r
If Not ErrorLevel 1 Goto alignOk\r
Echo WARNING: Your GCC does not support 8-byte aligned variables.\r
Echo WARNING: Therefore Emacs cannot support buffers larger than 128MB.\r
rem The following line disables DECL_ALIGN which in turn disables USE_LSB_TAG\r
rem For details see lisp.h where it defines USE_LSB_TAG\r
echo #define NO_DECL_ALIGN >>config.h2\r
:alignOk\r
Rem See if they requested a SYSTEM_MALLOC build\r
if "%sys_malloc%" == "" Goto cfgDone\r
rm -f config.tmp\r
ren config.h2 config.tmp\r
sed -f ../msdos/sedalloc.inp <config.tmp >config.h2\r
\r
:cfgDone\r
rm -f junk.c junk junk.exe\r
update config.h2 config.h >nul\r
rm -f config.tmp config.h2\r
\r
rem   On my system dir.h gets in the way.  It's a VMS file so who cares.\r
if exist dir.h ren dir.h vmsdir.h\r
\r
rem   Create "makefile" from "makefile.in".\r
rm -f Makefile makefile.tmp\r
copy Makefile.in+deps.mk makefile.tmp\r
sed -f ../msdos/sed1v2.inp <makefile.tmp >Makefile\r
rm -f makefile.tmp\r
\r
if "%X11%" == "" goto src5\r
mv Makefile makefile.tmp\r
sed -f ../msdos/sed1x.inp <makefile.tmp >Makefile\r
rm -f makefile.tmp\r
:src5\r
\r
if "%sys_malloc%" == "" goto src5a\r
sed -e "/^GMALLOC_OBJ *=/s/gmalloc.o//" <Makefile >makefile.tmp\r
sed -e "/^VMLIMIT_OBJ *=/s/vm-limit.o//" <makefile.tmp >makefile.tmp2\r
sed -e "/^RALLOC_OBJ *=/s/ralloc.o//" <makefile.tmp2 >Makefile\r
rm -f makefile.tmp makefile.tmp2\r
:src5a\r
\r
if "%nodebug%" == "" goto src6\r
sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp\r
sed -e "/^LDFLAGS *=/s/=/=-s/" <makefile.tmp >Makefile\r
rm -f makefile.tmp\r
:src6\r
cd ..\r
rem   ----------------------------------------------------------------------\r
Echo Configuring the library source directory...\r
cd lib-src\r
sed -f ../msdos/sed3v2.inp <Makefile.in >Makefile\r
if "%X11%" == "" goto libsrc2a\r
mv Makefile makefile.tmp\r
sed -f ../msdos/sed3x.inp <makefile.tmp >Makefile\r
rm -f makefile.tmp\r
:libsrc2a\r
if "%nodebug%" == "" goto libsrc3\r
sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp\r
sed -e "/^ALL_CFLAGS *=/s/=/= -s/" <makefile.tmp >Makefile\r
rm -f makefile.tmp\r
:libsrc3\r
cd ..\r
rem   ----------------------------------------------------------------------\r
if "%X11%" == "" goto oldx1\r
Echo Configuring the oldxmenu directory...\r
cd oldxmenu\r
sed -f ../msdos/sed5x.inp <Makefile.in >Makefile\r
if "%nodebug%" == "" goto oldx2\r
sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp\r
mv -f makefile.tmp Makefile\r
:oldx2\r
cd ..\r
:oldx1\r
rem   ----------------------------------------------------------------------\r
Echo Configuring the doc directory, expect one "File not found" message...\r
cd doc\r
Rem The two variants for lispintro below is for when the shell\r
Rem supports long file names but DJGPP does not\r
for %%d in (emacs lispref lispintro lispintr misc) do sed -f ../msdos/sed6.inp < %%d\Makefile.in > %%d\Makefile\r
cd ..\r
rem   ----------------------------------------------------------------------\r
Echo Configuring the lisp directory...\r
cd lisp\r
sed -f ../msdos/sedlisp.inp < Makefile.in > Makefile\r
cd ..\r
rem   ----------------------------------------------------------------------\r
If not Exist leim\quail\latin-pre.el goto maindir\r
Echo Configuring the leim directory...\r
cd leim\r
sed -f ../msdos/sedleim.inp < Makefile.in > Makefile\r
cd ..\r
rem   ----------------------------------------------------------------------\r
:maindir\r
Echo Configuring the main directory...\r
If Exist .dir-locals.el update .dir-locals.el _dir-locals.el\r
If Exist src\.dbxinit update src/.dbxinit src/_dbxinit\r
Echo Looking for the GDB init file...\r
If Exist src\.gdbinit update src/.gdbinit src/_gdbinit\r
If Exist src\_gdbinit goto gdbinitOk\r
Echo ERROR:\r
Echo I cannot find the GDB init file.  It was called ".gdbinit" in\r
Echo the Emacs distribution, but was probably renamed to some other\r
Echo name without the leading dot when you untarred the archive.\r
Echo It should be in the "src/" subdirectory.  Please make sure this\r
Echo file exists and is called "_gdbinit" with a leading underscore.\r
Echo Then run CONFIG.BAT again with the same arguments you did now.\r
goto End\r
:gdbinitOk\r
Echo Looking for the GDB init file...found\r
copy msdos\mainmake.v2 Makefile >nul\r
rem   ----------------------------------------------------------------------\r
goto End\r
:SmallEnv\r
echo Your environment size is too small.  Please enlarge it and run me again.\r
echo For example, type "command.com /e:2048" to have 2048 bytes available.\r
set $foo$=\r
:end\r
set X11=\r
set nodebug=\r
set djgpp_ver=\r
set sys_malloc=\r
\r
goto skipArchTag\r
   arch-tag: 2d2fed23-4dc6-4006-a2e4-49daf0031f33\r
:skipArchTag\r