(main) [DJGPP v2]: Don't change to binary for a tty.

[bpt/emacs.git] / config.bat

@echo off\r
rem   ----------------------------------------------------------------------\r
rem   Configuration script for MSDOS\r
rem   Copyright (C) 1994 Free Software Foundation, Inc.\r
\r
rem   This file is part of GNU Emacs.\r
\r
rem   GNU Emacs is free software; you can redistribute it and/or modify\r
rem   it under the terms of the GNU General Public License as published by\r
rem   the Free Software Foundation; either version 2, or (at your option)\r
rem   any later version.\r
\r
rem   GNU Emacs is distributed in the hope that it will be useful,\r
rem   but WITHOUT ANY WARRANTY; without even the implied warranty of\r
rem   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the\r
rem   GNU General Public License for more details.\r
\r
rem   You should have received a copy of the GNU General Public License\r
rem   along with GNU Emacs; see the file COPYING.  If not, write to\r
rem   the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.\r
rem   ----------------------------------------------------------------------\r
rem   YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:\r
rem\r
rem   + msdos version 3 or better.\r
rem   + djgpp version 1.12maint1 or later (version 2.0 or later recommended).\r
rem   + make utility that allows breaking of the 128 chars limit on\r
rem     command lines.  ndmake (as of version 4.5) won't work due to a\r
rem     line length limit.  The make that comes with djgpp does work.\r
rem   + rm and mv (from GNU file utilities).\r
rem   + sed (you can use the port that comes with DJGPP).\r
rem\r
rem   You should be able to get all the above utilities from any SimTel\r
rem   repository, e.g. ftp.coast.net, in the directories\r
rem   "SimTel/vendors/djgpp" and "SimTel/vendors/gnu/gnuish/dos_only".  As\r
rem   usual, please use your local mirroring site to reduce trans-Atlantic\r
rem   traffic.\r
rem   ----------------------------------------------------------------------\r
set X11=\r
set nodebug=\r
set djgpp_ver=\r
:again\r
if "%1" == "" goto usage\r
if "%1" == "--with-x" goto withx\r
if "%1" == "--no-debug" goto nodebug\r
if "%1" == "msdos" goto msdos\r
:usage\r
echo Usage: config [--with-x] [--no-debug] msdos\r
echo [Read the script before you run it.]\r
goto end\r
rem   ----------------------------------------------------------------------\r
:withx\r
set X11=Y\r
shift\r
goto again\r
rem   ----------------------------------------------------------------------\r
:nodebug\r
set nodebug=Y\r
shift\r
goto again\r
rem   ----------------------------------------------------------------------\r
:msdos\r
Echo Checking whether 'sed' is available...\r
sed -e "w junk.$$$" <Nul\r
If Exist junk.$$$ Goto sedOk\r
Echo To configure 'Emacs' you need to have 'sed'!\r
Goto End\r
:sedOk\r
Echo Checking whether 'rm' is available...\r
rm -f junk.$$$\r
If Not Exist junk.$$$ Goto rmOk\r
Echo To configure 'Emacs' you need to have 'rm'!\r
Goto End\r
:rmOk\r
Echo Checking whether 'mv' is available...\r
rm -f junk.1 junk.2\r
echo foo >junk.1\r
mv junk.1 junk.2\r
If Exist junk.2 Goto mvOk\r
Echo To configure 'Emacs' you need to have 'mv'!\r
rm -f junk.1\r
Goto End\r
:mvOk\r
rm -f junk.2\r
Echo Checking whether 'gcc' is available...\r
echo main(){} >junk.c\r
gcc -c junk.c\r
if exist junk.o goto gccOk\r
Echo To configure 'Emacs' you need to have 'gcc'!\r
rm -f junk.c\r
Goto End\r
:gccOk\r
rm -f junk.c junk.o\r
Echo Checking what version of DJGPP is installed...\r
If Not "%DJGPP%" == "" goto djgppOk\r
Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!\r
Goto End\r
:djgppOk\r
echo int main()           >junk.c\r
echo #ifdef __DJGPP__    >>junk.c\r
echo {return (__DJGPP__)*10;} >>junk.c\r
echo #else               >>junk.c\r
echo #ifdef __GO32__     >>junk.c\r
echo {return 10;}         >>junk.c\r
echo #else               >>junk.c\r
echo {return 0;}         >>junk.c\r
echo #endif              >>junk.c\r
echo #endif              >>junk.c\r
gcc -o junk.exe junk.c\r
junk\r
If ErrorLevel 10 Goto go32Ok\r
rm -f junk.c junk junk.exe\r
Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!\r
Goto End\r
:go32Ok\r
set djgpp_ver=1\r
If ErrorLevel 20 set djgpp_ver=2\r
rm -f junk.c junk junk.exe\r
Echo Configuring for DJGPP Version %DJGPP_VER% ...\r
Rem   ----------------------------------------------------------------------\r
Echo Configuring the source directory...\r
cd src\r
\r
rem   Create "paths.h"\r
sed -f ../msdos/sed4.inp <paths.in >paths.tmp\r
update paths.tmp paths.h >nul\r
rm -f paths.tmp\r
\r
rem   Create "config.h"\r
rm -f config.h2 config.tmp\r
cp config.in config.tmp\r
if "%X11%" == "" goto src4\r
sed -f ../msdos/sed2x.inp <config.in >config.tmp\r
:src4\r
sed -f ../msdos/sed2.inp <config.tmp >config.h2\r
update config.h2 config.h >nul\r
rm -f config.tmp config.h2\r
\r
rem   On my system dir.h gets in the way.  It's a VMS file so who cares.\r
if exist dir.h ren dir.h vmsdir.h\r
\r
rem   Create "makefile" from "makefile.in".\r
rm -f makefile junk.c\r
sed -e "1,/cpp stuff/s@^# .*$@@" <makefile.in >junk.c\r
If "%DJGPP_VER%" == "1" Goto mfV1\r
gcc -E junk.c | sed -f ../msdos/sed1v2.inp >makefile\r
goto mfDone\r
:mfV1\r
gcc -E junk.c | sed -f ../msdos/sed1.inp >makefile\r
:mfDone\r
rm -f junk.c\r
\r
if "%X11%" == "" goto src5\r
mv makefile makefile.tmp\r
sed -f ../msdos/sed1x.inp <makefile.tmp >makefile\r
rm -f makefile.tmp\r
:src5\r
\r
if "%nodebug%" == "" goto src6\r
sed -e "/^CFLAGS *=/s/ *-g//" <makefile >makefile.tmp\r
sed -e "/^LDFLAGS *=/s/=/=-s/" <makefile.tmp >makefile\r
rm -f makefile.tmp\r
:src6\r
cd ..\r
rem   ----------------------------------------------------------------------\r
Echo Configuring the library source directory...\r
cd lib-src\r
rem   Create "makefile" from "makefile.in".\r
sed -e "1,/cpp stuff/s@^# .*$@@" <makefile.in >junk.c\r
gcc -E -I. -I../src junk.c | sed -e "s/^ /	/" -e "/^#/d" -e "/^[ 	\f]*$/d" >makefile.new\r
If "%DJGPP_VER%" == "2" goto libsrc-v2\r
sed -f ../msdos/sed3.inp <makefile.new >makefile\r
Goto libsrc2\r
:libsrc-v2\r
sed -f ../msdos/sed3v2.inp <makefile.new >makefile\r
:libsrc2\r
rm -f makefile.new junk.c\r
if "%nodebug%" == "" goto libsrc3\r
sed -e "/^CFLAGS *=/s/ *-g//" <makefile >makefile.tmp\r
sed -e "/^ALL_CFLAGS *=/s/=/= -s/" <makefile.tmp >makefile\r
rm -f makefile.tmp\r
:libsrc3\r
cd ..\r
rem   ----------------------------------------------------------------------\r
if "%X11%" == "" goto oldx1\r
Echo Configuring the oldxmenu directory...\r
cd oldxmenu\r
sed -f ../msdos/sed5x.inp <makefile.in >makefile\r
if "%nodebug%" == "" goto oldx2\r
sed -e "/^CFLAGS *=/s/ *-g//" <makefile >makefile.tmp\r
mv -f makefile.tmp makefile\r
:oldx2\r
cd ..\r
:oldx1\r
rem   ----------------------------------------------------------------------\r
Echo Configuring the main directory...\r
If "%DJGPP_VER%" == "2" copy msdos\mainmake.v2 makefile >nul\r
If "%DJGPP_VER%" == "1" copy msdos\mainmake makefile >nul\r
rem   ----------------------------------------------------------------------\r
:end\r
set X11=\r
set nodebug=\r
set djgpp_ver=\r