Initial revision

[bpt/emacs.git] / config.bat

@echo off\r
rem   ----------------------------------------------------------------------\r
rem   Configuration script for MSDOS\r
rem   This file is part of GNU Emacs.\r
\r
rem   GNU Emacs is free software; you can redistribute it and/or modify\r
rem   it under the terms of the GNU General Public License as published by\r
rem   the Free Software Foundation; either version 2, or (at your option)\r
rem   any later version.\r
\r
rem   GNU Emacs is distributed in the hope that it will be useful,\r
rem   but WITHOUT ANY WARRANTY; without even the implied warranty of\r
rem   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the\r
rem   GNU General Public License for more details.\r
\r
rem   You should have received a copy of the GNU General Public License\r
rem   along with GNU Emacs; see the file COPYING.  If not, write to\r
rem   the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.\r
rem   ----------------------------------------------------------------------\r
rem   YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:\r
rem\r
rem   + djgpp.\r
rem   + make utility that allows breaking of 128 chars limit of commands.\r
rem     ndmake (as of version 4.5) won't work due to a line length limit.\r
rem   + rm, mv, chmod (From GNU file utilities).\r
rem   + sed.\r
rem   + patch (Larry Wall's for instance.  I think it's supplied with djgpp).\r
rem   ----------------------------------------------------------------------\r
if not "%2" == "" goto usage\r
if "%1" == "msdos" goto msdos\r
:usage\r
echo Usage: config msdos\r
echo [Read the script before you run it; also check that you have all the\r
echo necessary utilities.]\r
goto end\r
rem   ----------------------------------------------------------------------\r
:msdos\r
rem   Change to the Emacs root\r
cd c:\emacs\r
rem   ----------------------------------------------------------------------\r
Echo Configuring the source directory...\r
cd src\r
set PATHSH=paths-h.in\r
if exist %PATHSH% goto src1\r
set PATHSH=paths.h-in\r
if exist %PATHSH% goto src1\r
echo config: *** The file originally called "src/paths.h.in" cannot be found.\r
cd ..\r
goto end\r
:src1\r
set CONFIGH=config-h.in\r
if exist %CONFIGH% goto src2\r
set CONFIGH=config.h-in\r
if exist %CONFIGH% goto src2\r
echo config: *** The file originally called "src/config.h.in" cannot be found.\r
cd ..\r
goto end\r
:src2\r
set MAKEFILEIN=makefile.in-in\r
if exist %MAKEFILEIN% goto src3\r
set MAKEFILEIN=makefile-in.in\r
if exist %MAKEFILEIN% goto src3\r
echo makefile: *** The file originally called "src/makefile.in.in" cannot be found.\r
cd ..\r
goto end\r
:src3\r
\r
rem   Create "paths.h"\r
rm -f paths.h\r
sed -e "s!/lib/emacs!!" -e "s!/usr/local!c:/emacs!" -e "s!/data!/etc!" <%PATHSH% >paths.h\r
\r
rem   Create "config.h"\r
rm -f config.h\r
sed -f ../msdos/sed2.inp <%CONFIGH% >config.h\r
\r
rem   On my system dir.h gets in the way.  It's a VMS file so who cares.\r
if exist dir.h ren dir.h vmsdir.h\r
\r
rem   Create "makefile" from "makefile.in.in" using a context patch.\r
rm -f makefile\r
cp %MAKEFILEIN% makefile\r
patch -p1 -B ! -r patch.rjt makefile ../msdos/patch1\r
echo All hunks above should have passed!  If they didn't, you'll have to\r
echo update manually.  That should be easy though.\r
mv makefile junk.c\r
gcc -E junk.c | sed -f ../msdos/sed1.inp >makefile\r
del !makefile\r
del junk.c\r
cd ..\r
rem   ----------------------------------------------------------------------\r
Echo Configuring the library source directory...\r
cd lib-src\r
rem   Create "makefile" from "makefile.in".\r
copy makefile makefile.bak >nul\r
sed -f ../msdos/sed3.inp <makefile.in >makefile\r
cd ..\r
rem   ----------------------------------------------------------------------\r
Echo Configuring the main directory...\r
copy msdos\mainmake makefile >nul\r
rem   ----------------------------------------------------------------------\r
:end\r