configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ(2.68)
   5 AC_INIT([GNU Guix],
   6   [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
   7   [bug-guix@gnu.org], [guix],
   8   [https://www.gnu.org/software/guix/])
   9 AC_CONFIG_AUX_DIR([build-aux])
  10
  11 AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  12  color-tests parallel-tests -Woverride -Wno-portability])
  13
  14 # Enable silent rules by default.
  15 AM_SILENT_RULES([yes])
  16
  17 AC_CONFIG_SRCDIR([guix.scm])
  18 AC_CONFIG_MACRO_DIR([m4])
  19
  20 dnl For the C++ code.  This must be used early.
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_GNU_GETTEXT([external])
  24 AM_GNU_GETTEXT_VERSION([0.18.1])
  25
  26 GUIX_SYSTEM_TYPE
  27 GUIX_ASSERT_SUPPORTED_SYSTEM
  28
  29 AM_CONDITIONAL([CROSS_COMPILING], [test "x$cross_compiling" = "xyes"])
  30
  31 AC_ARG_WITH(store-dir,
  32   AC_HELP_STRING([--with-store-dir=PATH],
  33     [file name of the store (defaults to /gnu/store)]),
  34   [storedir="$withval"],
  35   [storedir="/gnu/store"])
  36 AC_SUBST(storedir)
  37
  38 AC_ARG_WITH([bash-completion-dir],
  39   AC_HELP_STRING([--with-bash-completion-dir=DIR],
  40     [name of the Bash completion directory]),
  41   [bashcompletiondir="$withval"],
  42   [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  43 AC_SUBST([bashcompletiondir])
  44
  45 AC_ARG_WITH([zsh-completion-dir],
  46   AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  47     [name of the Zsh completion directory]),
  48   [zshcompletiondir="$withval"],
  49   [zshcompletiondir='${datadir}/zsh/site-functions'])
  50 AC_SUBST([zshcompletiondir])
  51
  52 AC_ARG_WITH([fish-completion-dir],
  53   AC_HELP_STRING([--with-fish-completion-dir=DIR],
  54     [name of the Fish completion directory]),
  55   [fishcompletiondir="$withval"],
  56   [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  57 AC_SUBST([fishcompletiondir])
  58
  59 AC_ARG_WITH([selinux-policy-dir],
  60   AC_HELP_STRING([--with-selinux-policy-dir=DIR],
  61     [name of the SELinux policy directory]),
  62   [selinux_policydir="$withval"],
  63   [selinux_policydir='${datadir}/selinux/'])
  64 AC_SUBST([selinux_policydir])
  65
  66 dnl Better be verbose.
  67 AC_MSG_CHECKING([for the store directory])
  68 AC_MSG_RESULT([$storedir])
  69
  70 AC_ARG_ENABLE([daemon],
  71   [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  72   [guix_build_daemon="$enableval"],
  73   [guix_build_daemon="yes"])
  74
  75 # Prepare a version of $localstatedir & co. that does not contain references
  76 # to shell variables.
  77 guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  78 guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  79 guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  80 guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  81 AC_SUBST([guix_localstatedir])
  82 AC_SUBST([guix_sysconfdir])
  83 AC_SUBST([guix_sbindir])
  84
  85 GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  86 AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  87
  88 dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  89 dnl Make sure they are available.
  90 m4_pattern_forbid([PKG_CHECK_MODULES])
  91 m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  92 m4_pattern_forbid([^GUILE_P])
  93 m4_pattern_allow([^GUILE_PKG_ERRORS])
  94 m4_pattern_forbid([^GUIX_])
  95
  96 dnl Search for 'guile' and 'guild'.  This macro defines
  97 dnl 'GUILE_EFFECTIVE_VERSION'.
  98 GUILE_PKG([3.0 2.2])
  99 GUILE_PROGS
 100 if test "x$GUILD" = "x"; then
 101    AC_MSG_ERROR(['guild' binary not found; please check your Guile installation.])
 102 fi
 103
 104 if test "x$GUILE_EFFECTIVE_VERSION" = "x2.2"; then
 105   PKG_CHECK_MODULES([GUILE], [guile-2.2 >= 2.2.3])
 106 fi
 107
 108 dnl Installation directories for .scm and .go files.
 109 guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
 110 guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
 111 AC_SUBST([guilemoduledir])
 112 AC_SUBST([guileobjectdir])
 113
 114 dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
 115 dnl pull', among other things.
 116 GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
 117 if test "x$have_gnutls" != "xyes"; then
 118   AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
 119 fi
 120
 121 dnl Check for Guile-Git.
 122 GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
 123 if test "x$have_guile_git" != "xyes"; then
 124   AC_MSG_ERROR([Guile-Git is missing; please install it.])
 125 fi
 126
 127 dnl Check for Guile-JSON.
 128 GUIX_CHECK_GUILE_JSON
 129 if test "x$guix_cv_have_recent_guile_json" != "xyes"; then
 130   AC_MSG_ERROR([Guile-JSON is missing; please install it.])
 131 fi
 132
 133 dnl Guile-Sqlite3 is used by the (guix store ...) modules.
 134 GUIX_CHECK_GUILE_SQLITE3
 135 if test "x$guix_cv_have_recent_guile_sqlite3" != "xyes"; then
 136   AC_MSG_ERROR([A recent Guile-SQLite3 could not be found; please install it.])
 137 fi
 138
 139 GUIX_CHECK_GUILE_GCRYPT
 140 if test "x$guix_cv_have_recent_guile_gcrypt" != "xyes"; then
 141   AC_MSG_ERROR([A recent Guile-Gcrypt could not be found; please install it.])
 142 fi
 143
 144 dnl Check for Guile-zlib.
 145 GUILE_MODULE_AVAILABLE([have_guile_zlib], [(zlib)])
 146 if test "x$have_guile_zlib" != "xyes"; then
 147   AC_MSG_ERROR([Guile-zlib is missing; please install it.])
 148 fi
 149
 150 dnl Check for Guile-lzlib.
 151 GUILE_MODULE_AVAILABLE([have_guile_lzlib], [(lzlib)])
 152 if test "x$have_guile_lzlib" != "xyes"; then
 153   AC_MSG_ERROR([Guile-lzlib is missing; please install it.])
 154 fi
 155
 156 dnl Guile-newt is used by the graphical installer.
 157 GUILE_MODULE_AVAILABLE([have_guile_newt], [(newt)])
 158
 159 AC_ARG_ENABLE([installer],
 160     AS_HELP_STRING([--enable-installer], [Build the graphical installer sources.]))
 161
 162 AS_IF([test "x$enable_installer" = "xyes"], [
 163 if test "x$have_guile_newt" != "xyes"; then
 164   AC_MSG_ERROR([Guile-newt could not be found; please install it.])
 165 fi
 166 ])
 167
 168 AM_CONDITIONAL([ENABLE_INSTALLER],
 169   [test "x$enable_installer" = "xyes"])
 170
 171 dnl Make sure we have a full-fledged Guile.
 172 GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
 173
 174 AC_PROG_SED
 175
 176 dnl Decompressors, for use by the substituter and other modules.
 177 AC_PATH_PROG([GZIP], [gzip])
 178 AC_PATH_PROG([BZIP2], [bzip2])
 179 AC_PATH_PROG([XZ], [xz])
 180 AC_SUBST([GZIP])
 181 AC_SUBST([BZIP2])
 182 AC_SUBST([XZ])
 183
 184 AC_ARG_WITH([nix-prefix],
 185   [AS_HELP_STRING([--with-nix-prefix=DIR],
 186     [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
 187   [case "$withval" in
 188     yes|no) ;;
 189     *)
 190       NIX_PREFIX="$withval"
 191       PATH="$NIX_PREFIX/bin:$PATH"; export PATH
 192       AC_SUBST([NIX_PREFIX])
 193       ;;
 194    esac],
 195   [])
 196
 197 AC_ARG_WITH([nixpkgs],
 198   [AS_HELP_STRING([--with-nixpkgs=DIR],
 199     [search for Nixpkgs in DIR (for testing purposes only)])],
 200   [case "$withval" in
 201     yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
 202     *)      NIXPKGS="$withval";;
 203    esac],
 204   [])
 205
 206 AC_MSG_CHECKING([for Nixpkgs source tree])
 207 if test -f "$NIXPKGS/default.nix"; then
 208    AC_MSG_RESULT([$NIXPKGS])
 209    AC_SUBST([NIXPKGS])
 210 else
 211    AC_MSG_RESULT([not found])
 212 fi
 213
 214 LIBGCRYPT_LIBDIR="no"
 215 LIBGCRYPT_PREFIX="no"
 216
 217 AC_ARG_WITH([libgcrypt-prefix],
 218   [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
 219   [case "$withval" in
 220     yes|no)
 221       ;;
 222     *)
 223       LIBGCRYPT_PREFIX="$withval"
 224       LIBGCRYPT_LIBDIR="$withval/lib"
 225       ;;
 226    esac])
 227
 228 AC_ARG_WITH([libgcrypt-libdir],
 229   [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
 230      [search for GNU libgcrypt's shared library in DIR])],
 231   [case "$withval" in
 232     yes|no)
 233       LIBGCRYPT_LIBDIR="no"
 234       ;;
 235     *)
 236       LIBGCRYPT_LIBDIR="$withval"
 237       ;;
 238    esac])
 239
 240 dnl If none of the --with-libgcrypt-* options was used, try to determine the
 241 dnl the library directory.
 242 case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
 243   xnono)
 244     GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
 245     ;;
 246 esac
 247
 248 AC_SUBST([LIBGCRYPT_PREFIX])
 249 AC_SUBST([LIBGCRYPT_LIBDIR])
 250
 251 dnl Check for Guile-SSH, for the (guix ssh) module.
 252 GUIX_CHECK_GUILE_SSH
 253 AM_CONDITIONAL([HAVE_GUILE_SSH],
 254   [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
 255
 256 AC_CACHE_SAVE
 257
 258 m4_include([config-daemon.ac])
 259
 260 dnl `dot' (from the Graphviz package) is only needed for maintainers.
 261 dnl See `Building from Git' in the manual for more info.
 262 AM_MISSING_PROG([DOT], [dot])
 263
 264 dnl Manual pages.
 265 AM_MISSING_PROG([HELP2MAN], [help2man])
 266
 267 dnl Documentation translation.
 268 AM_MISSING_PROG([PO4A_TRANSLATE], [po4a-translate])
 269 AM_MISSING_PROG([PO4A_UPDATEPO], [po4a-updatepo])
 270
 271 case "$storedir" in
 272   /gnu/store)
 273     ;;
 274   *)
 275     AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
 276     AC_MSG_WARN([from downloading substitutes from gnu.org.])
 277     ;;
 278 esac
 279
 280 AC_CONFIG_FILES([Makefile
 281                  po/guix/Makefile.in
 282                  po/packages/Makefile.in
 283                  etc/guix-daemon.cil
 284                  guix/config.scm])
 285
 286 AC_CONFIG_FILES([etc/committer.scm], [chmod +x etc/committer.scm])
 287 AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
 288 AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
 289   [chmod +x pre-inst-env])
 290
 291 AC_OUTPUT