bushing.scad

   1 // PRUSA iteration3
   2 // Bushing/bearing housings
   3 // GNU GPL v3
   4 // Josef Průša <josefprusa@me.com>
   5 // Václav 'ax' Hůla <axtheb@gmail.com>
   6 // http://www.reprap.org/wiki/Prusa_Mendel
   7 // http://github.com/prusajr/PrusaMendel
   8
   9 include <configuration.scad>
  10
  11 /**
  12  * @id bushing
  13  * @name Bushing
  14  * @category Printed
  15  * @id bushing
  16  */
  17
  18 // Linear bearing options
  19 lm8uu_diameter=(bearing_type==1) ? 16 : 15;
  20 lm8uu_length=(bearing_type==1) ? 25 : 24;
  21 lm8uu_radius = lm8uu_diameter / 2;
  22 block_height = 2*lm8uu_length+17;
  23
  24 // basic building blocks, housings for 1 bushing/bearing
  25 // at [0,0] there is center of the smooth rod, pointing in Z
  26
  27 module linear_bushing_square(h=11) {
  28     translate([0,0,h/2]) {
  29         difference(){
  30             union(){
  31                 translate([-10.5/2,0,0]) cube([10.5,13.8,h], center = true);
  32                 cube([13.8,13.8,h], center = true);
  33             }
  34             cube([9,9,h+0.02], center = true);
  35         }
  36     }
  37 }
  38
  39 module linear_bushing_round(h=11) {
  40     difference(){
  41         union(){
  42             translate([-10.5/2,0,h/2]) cube([10.5,13.8,h], center = true);
  43             cylinder(r=7.5, h=h);
  44         }
  45         translate([0,0,-0.01])  cylinder(r=5.1, h=h+0.02);
  46     }
  47 }
  48
  49 module linear_bushing_bronze(h=11) {
  50     difference(){
  51         union(){
  52             translate([-10.5/2,0,h/2]) cube([10.5,13.8,h], center = true);
  53             cylinder(r=10.7, h=h);
  54         }
  55         translate([0,0,-0.01])  cylinder(r=8.1, h=h+0.02);
  56     }
  57 }
  58
  59 // select right bushing and cut it at angle, so it can be printed upside down
  60 module linear_bushing_long(h=30){
  61     intersection(){
  62         if (bushing_type == 0) {
  63             linear_bushing_square(h);
  64         }
  65         if (bushing_type == 1) {
  66             linear_bushing_round(h);
  67         }
  68         if (bushing_type == 2) {
  69             linear_bushing_bronze(h);
  70         }
  71         if (bushing_type == 2) {
  72             translate([0, 0, 0]) rotate([0,-55,0]) cube([30, 40, 80], center=true);
  73         } else {
  74             translate([0, 0, -4]) rotate([0,-45,0]) cube([30, 40, 80], center=true);
  75         }
  76     }
  77 }
  78
  79 module linear_bushing(h=65){
  80     translate([-9.5,0,h/2]) cube([2,13.8,h], center=true);
  81     linear_bushing_long(h);
  82     if (h>30) {
  83         translate([0,0,h]) mirror([0,0,1]) linear_bushing_long(30);
  84     }
  85 }
  86
  87 //this is for Z axis
  88 module bushing_negative(h=lm8uu_length+4){
  89     if (bearing_choice == 1) {
  90         if (bushing_type == 0) {
  91             translate([0,0,h/2]) cube([9,9,h+0.02], center = true);
  92         }
  93         if (bushing_type == 1) {
  94             translate([0,0,-0.01])  cylinder(r=5.1, h=h+0.02);
  95         }
  96         if (bushing_type == 2) {
  97             translate([0,0,-0.01])  cylinder(r=8.1, h=h+0.02);
  98         }
  99     } else {
 100         translate([0,0,-0.01])  cylinder(r=lm8uu_radius+0.4, h=h+0.02);
 101     }
 102
 103 }
 104
 105 module firm_foot(){
 106     difference(){
 107         union() {
 108             translate([0,13,0]) cube_fillet([3,18,20], top=[11,0,0,0], center=true);
 109         }
 110         translate([1.5,14,0]) rotate([0,-90,0]) screw();
 111     }
 112 }
 113
 114 module spring_foot(){
 115
 116     difference(){
 117         union() {
 118             translate([0.5,23.5,0]) cube_fillet([3,14,20], top=[11,0,0,0], center=true);
 119             translate([5,17,0]) rotate([0,0,-15]) cube_fillet([12,3,20], center=true);
 120             translate([5,13,0]) rotate([0,0,25]) cube_fillet([13,3,20], center=true);
 121             translate([0,9,0]) cube_fillet([3,6,20], vertical=[0,2,0,0], center=true);
 122         }
 123         translate([2,24,0]) rotate([0,-90,0]) screw();
 124     }
 125 }
 126
 127 module y_bearing(float=false){
 128     if (bearing_choice == 2) {
 129         linear_bearing(lm8uu_length+4);
 130     } else {
 131         linear_bushing_long(20);
 132     }
 133     translate([-9,0,10]) {
 134         if (float) {
 135             spring_foot();
 136             mirror([0,1,0]) spring_foot();
 137         } else {
 138             firm_foot();
 139             mirror([0,1,0]) firm_foot();
 140         }
 141     }
 142 }
 143
 144
 145 module linear_bearing(h=0, fillet=false){
 146     linear_holder_base((h > lm8uu_length+4)? h : lm8uu_length+4, fillet);
 147     translate([-(3)/2-lm8uu_radius+2,0,1]) cube([3,18,2], center = true);
 148     translate([-(3)/2-lm8uu_radius+2,0,((h > lm8uu_length+4)? h : lm8uu_length+4)-1]) cube([3,18,2], center = true);
 149     if ( (h-4)/2 > lm8uu_length){
 150         translate([-(3)/2-lm8uu_radius+2,0,h/2]) cube([3,18, (h-4)-2*lm8uu_length], center = true);
 151     }
 152 }
 153
 154 module linear_holder_base(length, fillet=false){
 155
 156     difference(){
 157         union(){
 158             //main block
 159             translate([-10.5/2,0,length/2]) cube([10.5,lm8uu_diameter+5,length], center = true);
 160             translate([0,0,0]) cylinder(h = length, r=lm8uu_radius+2.5, $fn=60);
 161         }
 162         //main axis
 163         translate([0,0,-2]) cylinder(h = length+4, r=(lm8uu_diameter+0.4)/2, $fn=50);
 164         // not needed for zip tie
 165         //main cut
 166         translate([10,0,length/2]) cube([20,14,length+4], center = true);
 167         //smooth entry cut
 168         translate([12,0,length/2]) rotate([0,0,45]) cube([20,20,length+4], center = true);
 169         if (fillet) {
 170             translate([0,0,length/2 ]) cube_negative_fillet([21,lm8uu_diameter+5,length], vertical=[0,3,3,0]);
 171         }
 172     }
 173 }
 174
 175
 176 %cylinder(r=4, h=90);
 177 y_bearing();
 178 translate([0,46,0]) y_bearing();
 179 if (bearing_choice == 2) {
 180     translate([-22, 23, 0]) y_bearing();
 181 } else {
 182     translate ([-26,23,0]) mirror([1,0,0]) y_bearing(true);
 183 }