meta/guile.m4

   1 ## Autoconf macros for working with Guile.
   2 ##
   3 ##   Copyright (C) 1998,2001, 2006, 2010, 2012 Free Software Foundation, Inc.
   4 ##
   5 ## This library is free software; you can redistribute it and/or
   6 ## modify it under the terms of the GNU Lesser General Public License
   7 ## as published by the Free Software Foundation; either version 3 of
   8 ## the License, or (at your option) any later version.
   9 ##
  10 ## This library is distributed in the hope that it will be useful,
  11 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 ## Lesser General Public License for more details.
  14 ##
  15 ## You should have received a copy of the GNU Lesser General Public
  16 ## License along with this library; if not, write to the Free Software
  17 ## Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  18 ## 02110-1301 USA
  19
  20 # serial 10
  21
  22 ## Index
  23 ## -----
  24 ##
  25 ## GUILE_PKG -- find Guile development files
  26 ## GUILE_PROGS -- set paths to Guile interpreter, config and tool programs
  27 ## GUILE_FLAGS -- set flags for compiling and linking with Guile
  28 ## GUILE_SITE_DIR -- find path to Guile "site" directory
  29 ## GUILE_CHECK -- evaluate Guile Scheme code and capture the return value
  30 ## GUILE_MODULE_CHECK -- check feature of a Guile Scheme module
  31 ## GUILE_MODULE_AVAILABLE -- check availability of a Guile Scheme module
  32 ## GUILE_MODULE_REQUIRED -- fail if a Guile Scheme module is unavailable
  33 ## GUILE_MODULE_EXPORTS -- check if a module exports a variable
  34 ## GUILE_MODULE_REQUIRED_EXPORT -- fail if a module doesn't export a variable
  35
  36 ## Code
  37 ## ----
  38
  39 ## NOTE: Comments preceding an AC_DEFUN (starting from "Usage:") are massaged
  40 ## into doc/ref/autoconf-macros.texi (see Makefile.am in that directory).
  41
  42 # GUILE_PKG -- find Guile development files
  43 #
  44 # Usage: GUILE_PKG([VERSIONS])
  45 #
  46 # This macro runs the @code{pkg-config} tool to find development files
  47 # for an available version of Guile.
  48 #
  49 # By default, this macro will search for the latest stable version of
  50 # Guile (e.g. 2.0), falling back to the previous stable version
  51 # (e.g. 1.8) if it is available.  If no guile-@var{VERSION}.pc file is
  52 # found, an error is signalled.  The found version is stored in
  53 # @var{GUILE_EFFECTIVE_VERSION}.
  54 #
  55 # If @code{GUILE_PROGS} was already invoked, this macro ensures that the
  56 # development files have the same effective version as the Guile
  57 # program.
  58 #
  59 # @var{GUILE_EFFECTIVE_VERSION} is marked for substitution, as by
  60 # @code{AC_SUBST}.
  61 #
  62 AC_DEFUN([GUILE_PKG],
  63  [PKG_PROG_PKG_CONFIG
  64   _guile_versions_to_search="m4_default([$1], [2.0 1.8])"
  65   if test -n "$GUILE_EFFECTIVE_VERSION"; then
  66     _guile_tmp=""
  67     for v in $_guile_versions_to_search; do
  68       if test "$v" = "$GUILE_EFFECTIVE_VERSION"; then
  69         _guile_tmp=$v
  70       fi
  71     done
  72     if test -z "$_guile_tmp"; then
  73       AC_MSG_FAILURE([searching for guile development files for versions $_guile_versions_to_search, but previously found $GUILE version $GUILE_EFFECTIVE_VERSION])
  74     fi
  75     _guile_versions_to_search=$GUILE_EFFECTIVE_VERSION
  76   fi
  77   GUILE_EFFECTIVE_VERSION=""
  78   _guile_errors=""
  79   for v in $_guile_versions_to_search; do
  80     AC_MSG_NOTICE([checking for guile $v])
  81     if test -z "$GUILE_EFFECTIVE_VERSION"; then
  82       PKG_CHECK_EXISTS([guile-$v], [GUILE_EFFECTIVE_VERSION=$v], [])
  83     fi
  84   done
  85
  86   if test -z "$GUILE_EFFECTIVE_VERSION"; then
  87     AC_MSG_ERROR([
  88 No Guile development packages were found.
  89
  90 Please verify that you have Guile installed.  If you installed Guile
  91 from a binary distribution, please verify that you have also installed
  92 the development packages.  If you installed it yourself, you might need
  93 to adjust your PKG_CONFIG_PATH; see the pkg-config man page for more.
  94 ])
  95   fi
  96   AC_MSG_NOTICE([found guile $v])
  97   AC_SUBST([GUILE_EFFECTIVE_VERSION])
  98  ])
  99
 100 # GUILE_FLAGS -- set flags for compiling and linking with Guile
 101 #
 102 # Usage: GUILE_FLAGS
 103 #
 104 # This macro runs the @code{pkg-config} tool to find out how to compile
 105 # and link programs against Guile.  It sets four variables:
 106 # @var{GUILE_CFLAGS}, @var{GUILE_LDFLAGS}, @var{GUILE_LIBS}, and
 107 # @var{GUILE_LTLIBS}.
 108 #
 109 # @var{GUILE_CFLAGS}: flags to pass to a C or C++ compiler to build code that
 110 # uses Guile header files.  This is almost always just one or more @code{-I}
 111 # flags.
 112 #
 113 # @var{GUILE_LDFLAGS}: flags to pass to the compiler to link a program
 114 # against Guile.  This includes @code{-lguile-@var{VERSION}} for the
 115 # Guile library itself, and may also include one or more @code{-L} flag
 116 # to tell the compiler where to find the libraries.  But it does not
 117 # include flags that influence the program's runtime search path for
 118 # libraries, and will therefore lead to a program that fails to start,
 119 # unless all necessary libraries are installed in a standard location
 120 # such as @file{/usr/lib}.
 121 #
 122 # @var{GUILE_LIBS} and @var{GUILE_LTLIBS}: flags to pass to the compiler or to
 123 # libtool, respectively, to link a program against Guile.  It includes flags
 124 # that augment the program's runtime search path for libraries, so that shared
 125 # libraries will be found at the location where they were during linking, even
 126 # in non-standard locations.  @var{GUILE_LIBS} is to be used when linking the
 127 # program directly with the compiler, whereas @var{GUILE_LTLIBS} is to be used
 128 # when linking the program is done through libtool.
 129 #
 130 # The variables are marked for substitution, as by @code{AC_SUBST}.
 131 #
 132 AC_DEFUN([GUILE_FLAGS],
 133  [AC_REQUIRE([GUILE_PKG])
 134   PKG_CHECK_MODULES(GUILE, [guile-$GUILE_EFFECTIVE_VERSION])
 135
 136   dnl GUILE_CFLAGS and GUILE_LIBS are already defined and AC_SUBST'd by
 137   dnl PKG_CHECK_MODULES.  But GUILE_LIBS to pkg-config is GUILE_LDFLAGS
 138   dnl to us.
 139
 140   GUILE_LDFLAGS=$GUILE_LIBS
 141
 142   dnl Determine the platform dependent parameters needed to use rpath.
 143   dnl AC_LIB_LINKFLAGS_FROM_LIBS is defined in gnulib/m4/lib-link.m4 and needs
 144   dnl the file gnulib/build-aux/config.rpath.
 145   AC_LIB_LINKFLAGS_FROM_LIBS([GUILE_LIBS], [$GUILE_LDFLAGS], [])
 146   GUILE_LIBS="$GUILE_LDFLAGS $GUILE_LIBS"
 147   AC_LIB_LINKFLAGS_FROM_LIBS([GUILE_LTLIBS], [$GUILE_LDFLAGS], [yes])
 148   GUILE_LTLIBS="$GUILE_LDFLAGS $GUILE_LTLIBS"
 149
 150   AC_SUBST([GUILE_EFFECTIVE_VERSION])
 151   AC_SUBST([GUILE_CFLAGS])
 152   AC_SUBST([GUILE_LDFLAGS])
 153   AC_SUBST([GUILE_LIBS])
 154   AC_SUBST([GUILE_LTLIBS])
 155  ])
 156
 157 # GUILE_SITE_DIR -- find path to Guile "site" directory
 158 #
 159 # Usage: GUILE_SITE_DIR
 160 #
 161 # This looks for Guile's "site" directory, usually something like
 162 # PREFIX/share/guile/site, and sets var @var{GUILE_SITE} to the path.
 163 # Note that the var name is different from the macro name.
 164 #
 165 # The variable is marked for substitution, as by @code{AC_SUBST}.
 166 #
 167 AC_DEFUN([GUILE_SITE_DIR],
 168  [AC_REQUIRE([GUILE_PKG])
 169   AC_MSG_CHECKING(for Guile site directory)
 170   GUILE_SITE=`$PKG_CONFIG --print-errors --variable=sitedir guile-$GUILE_EFFECTIVE_VERSION`
 171   AC_MSG_RESULT($GUILE_SITE)
 172   if test "$GUILE_SITE" = ""; then
 173      AC_MSG_FAILURE(sitedir not found)
 174   fi
 175   AC_SUBST(GUILE_SITE)
 176  ])
 177
 178 # GUILE_PROGS -- set paths to Guile interpreter, config and tool programs
 179 #
 180 # Usage: GUILE_PROGS
 181 #
 182 # This macro looks for programs @code{guile} and @code{guild}, setting
 183 # variables @var{GUILE} and @var{GUILD} to their paths, respectively.
 184 # If @code{guile} is not found, signal an error.
 185 #
 186 # The effective version of the found @code{guile} is set to
 187 # @var{GUILE_EFFECTIVE_VERSION}.  This macro ensures that the effective
 188 # version is compatible with the result of a previous invocation of
 189 # @code{GUILE_FLAGS}, if any.
 190 #
 191 # As a legacy interface, it also looks for @code{guile-config} and
 192 # @code{guile-tools}, setting @var{GUILE_CONFIG} and @var{GUILE_TOOLS}.
 193 #
 194 # The variables are marked for substitution, as by @code{AC_SUBST}.
 195 #
 196 AC_DEFUN([GUILE_PROGS],
 197  [AC_PATH_PROG(GUILE,guile)
 198   if test "$GUILE" = "" ; then
 199       AC_MSG_ERROR([guile required but not found])
 200   fi
 201   AC_SUBST(GUILE)
 202
 203   _guile_prog_version=`$GUILE -c "(display (effective-version))"`
 204   if test -z "$GUILE_EFFECTIVE_VERSION"; then
 205     GUILE_EFFECTIVE_VERSION=$_guile_prog_version
 206   elif test "$GUILE_EFFECTIVE_VERSION" != "$_guile_prog_version"; then
 207     AC_MSG_ERROR([found development files for Guile $GUILE_EFFECTIVE_VERSION, but $GUILE has effective version $_guile_prog_version])
 208   fi
 209
 210   AC_PATH_PROG(GUILD,guild)
 211   AC_SUBST(GUILD)
 212
 213   AC_PATH_PROG(GUILE_CONFIG,guile-config)
 214   AC_SUBST(GUILE_CONFIG)
 215   if test -n "$GUILD"; then
 216     GUILE_TOOLS=$GUILD
 217   else
 218     AC_PATH_PROG(GUILE_TOOLS,guile-tools)
 219   fi
 220   AC_SUBST(GUILE_TOOLS)
 221  ])
 222
 223 # GUILE_CHECK -- evaluate Guile Scheme code and capture the return value
 224 #
 225 # Usage: GUILE_CHECK_RETVAL(var,check)
 226 #
 227 # @var{var} is a shell variable name to be set to the return value.
 228 # @var{check} is a Guile Scheme expression, evaluated with "$GUILE -c", and
 229 #    returning either 0 or non-#f to indicate the check passed.
 230 #    Non-0 number or #f indicates failure.
 231 #    Avoid using the character "#" since that confuses autoconf.
 232 #
 233 AC_DEFUN([GUILE_CHECK],
 234  [AC_REQUIRE([GUILE_PROGS])
 235   $GUILE -c "$2" > /dev/null 2>&1
 236   $1=$?
 237  ])
 238
 239 # GUILE_MODULE_CHECK -- check feature of a Guile Scheme module
 240 #
 241 # Usage: GUILE_MODULE_CHECK(var,module,featuretest,description)
 242 #
 243 # @var{var} is a shell variable name to be set to "yes" or "no".
 244 # @var{module} is a list of symbols, like: (ice-9 common-list).
 245 # @var{featuretest} is an expression acceptable to GUILE_CHECK, q.v.
 246 # @var{description} is a present-tense verb phrase (passed to AC_MSG_CHECKING).
 247 #
 248 AC_DEFUN([GUILE_MODULE_CHECK],
 249          [AC_MSG_CHECKING([if $2 $4])
 250           GUILE_CHECK($1,(use-modules $2) (exit ((lambda () $3))))
 251           if test "$$1" = "0" ; then $1=yes ; else $1=no ; fi
 252           AC_MSG_RESULT($$1)
 253          ])
 254
 255 # GUILE_MODULE_AVAILABLE -- check availability of a Guile Scheme module
 256 #
 257 # Usage: GUILE_MODULE_AVAILABLE(var,module)
 258 #
 259 # @var{var} is a shell variable name to be set to "yes" or "no".
 260 # @var{module} is a list of symbols, like: (ice-9 common-list).
 261 #
 262 AC_DEFUN([GUILE_MODULE_AVAILABLE],
 263          [GUILE_MODULE_CHECK($1,$2,0,is available)
 264          ])
 265
 266 # GUILE_MODULE_REQUIRED -- fail if a Guile Scheme module is unavailable
 267 #
 268 # Usage: GUILE_MODULE_REQUIRED(symlist)
 269 #
 270 # @var{symlist} is a list of symbols, WITHOUT surrounding parens,
 271 # like: ice-9 common-list.
 272 #
 273 AC_DEFUN([GUILE_MODULE_REQUIRED],
 274          [GUILE_MODULE_AVAILABLE(ac_guile_module_required, ($1))
 275           if test "$ac_guile_module_required" = "no" ; then
 276               AC_MSG_ERROR([required guile module not found: ($1)])
 277           fi
 278          ])
 279
 280 # GUILE_MODULE_EXPORTS -- check if a module exports a variable
 281 #
 282 # Usage: GUILE_MODULE_EXPORTS(var,module,modvar)
 283 #
 284 # @var{var} is a shell variable to be set to "yes" or "no".
 285 # @var{module} is a list of symbols, like: (ice-9 common-list).
 286 # @var{modvar} is the Guile Scheme variable to check.
 287 #
 288 AC_DEFUN([GUILE_MODULE_EXPORTS],
 289  [GUILE_MODULE_CHECK($1,$2,$3,exports `$3')
 290  ])
 291
 292 # GUILE_MODULE_REQUIRED_EXPORT -- fail if a module doesn't export a variable
 293 #
 294 # Usage: GUILE_MODULE_REQUIRED_EXPORT(module,modvar)
 295 #
 296 # @var{module} is a list of symbols, like: (ice-9 common-list).
 297 # @var{modvar} is the Guile Scheme variable to check.
 298 #
 299 AC_DEFUN([GUILE_MODULE_REQUIRED_EXPORT],
 300  [GUILE_MODULE_EXPORTS(guile_module_required_export,$1,$2)
 301   if test "$guile_module_required_export" = "no" ; then
 302       AC_MSG_ERROR([module $1 does not export $2; required])
 303   fi
 304  ])
 305
 306 ## guile.m4 ends here