configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # Independent Subdirectories
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_CONFIG_SUBDIRS(guile-readline)
  36
  37 #--------------------------------------------------------------------
  38 #
  39 # User options
  40 #
  41 #--------------------------------------------------------------------
  42
  43 AC_ARG_ENABLE(dynamic-linking,
  44   [  --enable-dynamic-linking  include support for dynamic linking],,
  45   enable_dynamic_linking=yes)
  46
  47 AC_ARG_ENABLE(guile-debug,
  48   [  --enable-guile-debug    include internal debugging functions],
  49   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  50     AC_DEFINE(GUILE_DEBUG)
  51   fi)
  52
  53 AC_ARG_ENABLE(debug-freelist,
  54   [  --enable-debug-freelist    Include garbage collector freelist debugging code],
  55   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  56     AC_DEFINE(GUILE_DEBUG_FREELIST)
  57   fi)
  58
  59 AC_ARG_ENABLE(posix,
  60   [  --disable-posix         omit posix interfaces],,
  61   enable_posix=yes)
  62
  63 AC_ARG_ENABLE(networking,
  64   [  --disable-net           omit networking interfaces],,
  65   enable_networking=yes)
  66
  67 AC_ARG_ENABLE(regex,
  68   [  --disable-regex         omit regular expression interfaces],,
  69   enable_regex=yes)
  70
  71 dnl The --disable-debug used to control these two.  But now they are
  72 dnl a required part of the distribution.
  73 AC_DEFINE(DEBUG_EXTENSIONS)
  74 AC_DEFINE(READER_EXTENSIONS)
  75
  76 dnl files which are destined for separate modules.
  77
  78 if test "$enable_posix" = yes; then
  79    LIBOBJS="$LIBOBJS filesys.o posix.o"
  80    AC_DEFINE(HAVE_POSIX)
  81 fi
  82
  83 if test "$enable_networking" = yes; then
  84    LIBOBJS="$LIBOBJS net_db.o socket.o"
  85    AC_DEFINE(HAVE_NETWORKING)
  86 fi
  87
  88 #--------------------------------------------------------------------
  89
  90 AC_PROG_CC
  91 AC_PROG_CPP
  92
  93 AC_AIX
  94 AC_ISC_POSIX
  95 AC_MINIX
  96
  97 AM_PROG_CC_STDC
  98 AM_PROG_LIBTOOL
  99
 100 AC_C_CONST
 101 AC_C_INLINE
 102 AC_CHECK_SIZEOF(int)
 103 AC_CHECK_SIZEOF(long)
 104 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 105                AC_TRY_COMPILE(,
 106                               [long long a],
 107                               scm_cv_long_longs=yes,
 108                               scm_cv_long_longs=no))
 109 if test "$scm_cv_long_longs" = yes; then
 110   AC_DEFINE(HAVE_LONG_LONGS)
 111 fi
 112
 113 AC_HEADER_STDC
 114 AC_HEADER_DIRENT
 115 AC_HEADER_TIME
 116 AC_HEADER_SYS_WAIT
 117 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
 118 GUILE_HEADER_LIBC_WITH_UNISTD
 119
 120 AC_TYPE_GETGROUPS
 121 AC_TYPE_SIGNAL
 122 AC_TYPE_MODE_T
 123
 124 AC_CHECK_LIB(m, main)
 125 AC_CHECK_FUNCS(gethostbyname)
 126 if test $ac_cv_func_gethostbyname = no; then
 127     AC_CHECK_LIB(nsl, gethostbyname)
 128 fi
 129 AC_CHECK_FUNCS(connect)
 130 if test $ac_cv_func_connect = no; then
 131     AC_CHECK_LIB(socket, connect)
 132 fi
 133
 134 # Checks for dynamic linking
 135
 136 if test "$enable_dynamic_linking" = "yes"; then
 137
 138 AC_CHECK_LIB(dl,dlopen)
 139 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 140   AC_CHECK_FUNCS(dlopen)
 141   AC_DEFINE(DYNAMIC_LINKING)
 142 else
 143 AC_CHECK_LIB(dld,dld_link)
 144 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
 145   AC_DEFINE(DYNAMIC_LINKING)
 146 else
 147 AC_CHECK_FUNCS(shl_load)
 148 if test "$ac_cv_func_shl_load" = "yes"; then
 149   AC_DEFINE(DYNAMIC_LINKING)
 150 else
 151 AC_CHECK_FUNCS(dlopen)
 152 if test "$ac_cv_func_dlopen" = "yes"; then
 153   AC_DEFINE(DYNAMIC_LINKING)
 154 fi
 155 fi
 156 fi
 157 fi
 158
 159 fi
 160
 161 GUILE_DLSYM_USCORE
 162
 163 AC_CHECK_FUNCS(ctermid ftime getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep atexit on_exit)
 164
 165 ### Some systems don't declare some functions.  On such systems, we
 166 ### need to at least provide our own K&R-style declarations.
 167
 168 ### GUILE_FUNC_DECLARED(function, headerfile)
 169
 170 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 171 ### not there, #define MISSING_FUNCTION_DECL.
 172 AC_DEFUN(GUILE_FUNC_DECLARED, [
 173   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 174     AC_EGREP_HEADER($1, $2,
 175                     guile_cv_func_$1_declared=yes,
 176                     guile_cv_func_$1_declared=no))
 177   if test [x$guile_cv_func_]$1[_declared] = xno; then
 178     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 179   fi
 180 ])
 181
 182 GUILE_FUNC_DECLARED(strptime, time.h)
 183 GUILE_FUNC_DECLARED(bzero, string.h)
 184 GUILE_FUNC_DECLARED(sleep, unistd.h)
 185 GUILE_FUNC_DECLARED(usleep, unistd.h)
 186
 187 ### On some systems usleep has no return value.  If it does have one,
 188 ### we'd like to return it; otherwise, we'll fake it.
 189 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 190   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 191                    /usr/include/unistd.h,
 192                    [guile_cv_func_usleep_return_type=void],
 193                    [guile_cv_func_usleep_return_type=int])])
 194 case "$guile_cv_func_usleep_return_type" in
 195   "void" )
 196     AC_DEFINE(USLEEP_RETURNS_VOID)
 197   ;;
 198 esac
 199
 200 dnl <GNU-WIN32 hacks>
 201
 202 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 203 if test -n "$have_sys_un_h" ; then
 204 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 205 fi
 206
 207 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 208
 209 dnl I don't know what this prefixing of cygwin32_ is for.
 210 dnl scmconfig.h wasn't updated with the test results.
 211 dnl so use AC_CHECK_FUNCS for now.
 212
 213 dnl how about:
 214 dnl save confdefs.h
 215 dnl if test $ac_cv_cigwin = yes; then
 216 dnl   modify confdefs.h
 217 dnl fi
 218 dnl AC_CHECK_FUNCS...
 219 dnl restore confdefs.h
 220
 221 dnl cp confdefs.h confdefs.h.bak
 222 dnl for func in gethostent sethostent endhostent getnetent setnetent endnetent getprotoent setprotoent endprotoent getservent setservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof ; do
 223 dnl cp confdefs.h.bak confdefs.h
 224 dnl cat >> confdefs.h << EOF
 225 dnl #ifdef __CYGWIN32__
 226 dnl #define $func cygwin32_$func
 227 dnl #endif
 228 dnl EOF
 229 dnl AC_CHECK_FUNC($func)
 230 dnl done
 231 dnl cp confdefs.h.bak confdefs.h
 232
 233 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 234                setnetent    getnetent    endnetent    dnl
 235                setprotoent  getprotoent  endprotoent  dnl
 236                setservent   getservent   endservent   dnl
 237                getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof)
 238
 239 dnl </GNU-WIN32 hacks>
 240
 241 dnl Test whether system calls are restartable by default on the
 242 dnl current system.  If they are not, we put a loop around every system
 243 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 244 dnl change from the default behaviour.  On the other hand, if signals
 245 dnl are restartable then the loop is not installed and when libguile
 246 dnl initialises it also resets the behaviour of each signal to cause a
 247 dnl restart (in case a different runtime had a different default
 248 dnl behaviour for some reason: e.g., different versions of linux seem
 249 dnl to behave differently.)
 250
 251 AC_SYS_RESTARTABLE_SYSCALLS
 252
 253 if test "$enable_regex" = yes; then
 254    if test "$ac_cv_header_regex_h" = yes ||
 255       test "$ac_cv_header_rxposix_h" = yes ||
 256       test "$ac_cv_header_rx_rxposix_h" = yes; then
 257      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 258      [AC_CHECK_LIB(rx, main)
 259       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 260      )
 261      dnl The following should not be necessary, but for some reason
 262      dnl autoheader misses it if we don't include it!
 263      if test "$ac_cv_func_regcomp_norx" = yes ||
 264         test "$ac_cv_func_regcomp_rx" = yes; then
 265        AC_DEFINE(HAVE_REGCOMP)
 266      fi
 267    fi
 268 fi
 269
 270 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
 271
 272 # When testing for the presence of alloca, we need to add alloca.o
 273 # explicitly to LIBOBJS to make sure that it is translated to
 274 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 275 AC_FUNC_ALLOCA
 276 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 277
 278 AC_STRUCT_ST_RDEV
 279 AC_STRUCT_ST_BLKSIZE
 280
 281 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 282 # LIBOBJS, which we don't need.  This seems more direct.
 283 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 284 [AC_TRY_COMPILE([#include <sys/types.h>
 285 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 286 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 287 if test $ac_cv_struct_st_blocks = yes; then
 288   AC_DEFINE(HAVE_ST_BLOCKS)
 289 fi
 290
 291 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 292   [AC_TRY_CPP([#include <sys/stat.h>
 293                #ifndef S_ISLNK
 294                #error no S_ISLNK
 295                #endif],
 296                ac_cv_macro_S_ISLNK=yes,
 297                ac_cv_macro_S_ISLNK=no)])
 298 if test $ac_cv_macro_S_ISLNK = yes; then
 299   AC_DEFINE(HAVE_S_ISLNK)
 300 fi
 301
 302 AC_STRUCT_TIMEZONE
 303 GUILE_STRUCT_UTIMBUF
 304
 305 #--------------------------------------------------------------------
 306 #
 307 # Which way does the stack grow?
 308 #
 309 #--------------------------------------------------------------------
 310
 311 AC_TRY_RUN(aux (l) unsigned long l;
 312              { int x; exit (l >= ((unsigned long)&x)); }
 313            main () { int q; aux((unsigned long)&q); },
 314            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 315
 316 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 317     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 318                 [guile_cv_type_float_fits_long=yes],
 319                 [guile_cv_type_float_fits_long=no],
 320                 [guile_cv_type_float_fits_long=guess-yes])])
 321 case $guile_cv_type_float_fits_long in
 322   "yes" )
 323     AC_DEFINE(SCM_SINGLES)
 324   ;;
 325   "guess-yes" )
 326     AC_DEFINE(SCM_SINGLES)
 327     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 328     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 329   ;;
 330 esac
 331
 332
 333 AC_MSG_CHECKING(for struct linger)
 334 AC_CACHE_VAL(scm_cv_struct_linger,
 335         AC_TRY_COMPILE([
 336 #include <sys/types.h>
 337 #include <sys/socket.h>],
 338                         [struct linger lgr;  lgr.l_linger = 100],
 339                         scm_cv_struct_linger="yes",
 340                         scm_cv_struct_linger="no"))
 341 AC_MSG_RESULT($scm_cv_struct_linger)
 342 if test $scm_cv_struct_linger = yes; then
 343         AC_DEFINE(HAVE_STRUCT_LINGER)
 344 fi
 345
 346 #--------------------------------------------------------------------
 347 #
 348 # Flags for thread support
 349 #
 350 #--------------------------------------------------------------------
 351
 352 ### What thread package has the user asked for?
 353 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 354             , with_threads=no)
 355
 356 ### Turn $with_threads into either the name of a threads package, like
 357 ### `qt', or `no', meaning that threads should not be supported.
 358 AC_MSG_CHECKING(whether to support threads)
 359 case "$with_threads" in
 360   "yes" | "qt" | "coop" | "")
 361     with_threads=qt
 362   ;;
 363   "no" )
 364   ;;
 365   * )
 366     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 367   ;;
 368 esac
 369 AC_MSG_RESULT($with_threads)
 370
 371 ## Make sure the threads package we've chosen is actually supported on
 372 ## the present platform.
 373 case "${with_threads}" in
 374   "qt" )
 375     ## This configures the QuickThreads package, and sets or clears
 376     ## the THREAD_PACKAGE variable if qthreads don't configure
 377     ## correctly.
 378     QTHREADS_CONFIGURE
 379    ;;
 380 esac
 381
 382 ## If we're using threads, bring in some other parts of Guile which
 383 ## work with them.
 384 if test "${THREAD_PACKAGE}" != "" ; then
 385   AC_DEFINE(USE_THREADS, 1)
 386
 387   ## Include the Guile thread interface in the library...
 388   LIBOBJS="$LIBOBJS threads.o"
 389
 390   ## ... and tell it which package to talk to.
 391   case "${THREAD_PACKAGE}" in
 392     "QT" )
 393       AC_DEFINE(USE_COOP_THREADS, 1)
 394     ;;
 395     * )
 396       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 397     ;;
 398   esac
 399
 400   ## Bring in scm_internal_select, if appropriate.
 401   if test $ac_cv_func_gettimeofday = yes &&
 402      test $ac_cv_func_select = yes; then
 403     LIBOBJS="$LIBOBJS iselect.o"
 404     AC_DEFINE(GUILE_ISELECT, 1)
 405   fi
 406 fi
 407
 408 ## If we're using GCC, ask for aggressive warnings.
 409 case "$GCC" in
 410   yes )
 411     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 412     ## much stuff with generic function pointers for that to really be
 413     ## less than exasperating.
 414     CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wmissing-prototypes" ;;
 415 esac
 416
 417 AC_PROG_AWK
 418
 419 ## If we're creating a shared library (using libtool!), then we'll
 420 ## need to generate a list of .lo files corresponding to the .o files
 421 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 422 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 423
 424 AC_SUBST(GUILE_MAJOR_VERSION)
 425 AC_SUBST(GUILE_MINOR_VERSION)
 426 AC_SUBST(GUILE_VERSION)
 427
 428 dnl Tell guile-config what flags guile users should link against.
 429 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 430 AC_SUBST(GUILE_LIBS)
 431
 432 AC_SUBST(AWK)
 433 AC_SUBST(LIBLOBJS)
 434
 435 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/versiondat.h ice-9/Makefile qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf])
 436
 437 dnl Local Variables:
 438 dnl comment-start: "dnl "
 439 dnl comment-end: ""
 440 dnl comment-start-skip: "\\bdnl\\b\\s *"
 441 dnl End: