module/language/cps.scm

   1 ;;; Continuation-passing style (CPS) intermediate language (IL)
   2
   3 ;; Copyright (C) 2013, 2014, 2015 Free Software Foundation, Inc.
   4
   5 ;;;; This library is free software; you can redistribute it and/or
   6 ;;;; modify it under the terms of the GNU Lesser General Public
   7 ;;;; License as published by the Free Software Foundation; either
   8 ;;;; version 3 of the License, or (at your option) any later version.
   9 ;;;;
  10 ;;;; This library is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 ;;;; Lesser General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU Lesser General Public
  16 ;;;; License along with this library; if not, write to the Free Software
  17 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  18
  19 ;;; Commentary:
  20 ;;;
  21 ;;; This is the continuation-passing style (CPS) intermediate language
  22 ;;; (IL) for Guile.
  23 ;;;
  24 ;;; There are two kinds of terms in CPS: terms that bind continuations,
  25 ;;; and terms that call continuations.
  26 ;;;
  27 ;;; $letk binds a set of mutually recursive continuations, each one an
  28 ;;; instance of $cont.  A $cont declares the name of a continuation, and
  29 ;;; then contains as a subterm the particular continuation instance:
  30 ;;; $kargs for continuations that bind values, $ktail for the tail
  31 ;;; continuation, etc.
  32 ;;;
  33 ;;; $continue nodes call continuations.  The expression contained in the
  34 ;;; $continue node determines the value or values that are passed to the
  35 ;;; target continuation: $const to pass a constant value, $values to
  36 ;;; pass multiple named values, etc.  $continue nodes also record the source at which
  37 ;;;
  38 ;;; Additionally there is $letrec, a term that binds mutually recursive
  39 ;;; functions.  The contification pass will turn $letrec into $letk if
  40 ;;; it can do so.  Otherwise, the closure conversion pass will desugar
  41 ;;; $letrec into an equivalent sequence of make-closure primcalls and
  42 ;;; subsequent initializations of the captured variables of the
  43 ;;; closures.  You can think of $letrec as pertaining to "high CPS",
  44 ;;; whereas later passes will only see "low CPS", which does not have
  45 ;;; $letrec.
  46 ;;;
  47 ;;; This particular formulation of CPS was inspired by Andrew Kennedy's
  48 ;;; 2007 paper, "Compiling with Continuations, Continued".  All Guile
  49 ;;; hackers should read that excellent paper!  As in Kennedy's paper,
  50 ;;; continuations are second-class, and may be thought of as basic block
  51 ;;; labels.  All values are bound to variables using continuation calls:
  52 ;;; even constants!
  53 ;;;
  54 ;;; There are some Guile-specific quirks as well:
  55 ;;;
  56 ;;;   - $kreceive represents a continuation that receives multiple values,
  57 ;;;     but which truncates them to some number of required values,
  58 ;;;     possibly with a rest list.
  59 ;;;
  60 ;;;   - $kfun labels an entry point for a $fun (a function), and
  61 ;;;     contains a $ktail representing the formal argument which is the
  62 ;;;     function's continuation.
  63 ;;;
  64 ;;;   - $kfun also contain a $kclause continuation, corresponding to
  65 ;;;     the first case-lambda clause of the function.  $kclause actually
  66 ;;;     contains the clause body, and the subsequent clause (if any).
  67 ;;;     This is because the $kclause logically matches or doesn't match
  68 ;;;     a given set of actual arguments against a formal arity, then
  69 ;;;     proceeds to a "body" continuation (which is a $kargs).
  70 ;;;
  71 ;;;     That's to say that a $fun can be matched like this:
  72 ;;;
  73 ;;;     (match f
  74 ;;;       (($ $fun
  75 ;;;           ($ $cont kfun
  76 ;;;              ($ $kfun src meta self ($ $cont ktail ($ $ktail))
  77 ;;;                 ($ $kclause arity
  78 ;;;                    ($ $cont kbody ($ $kargs names syms body))
  79 ;;;                    alternate))))
  80 ;;;         #t))
  81 ;;;
  82 ;;;     A $continue to ktail is in tail position.  $kfun, $kclause,
  83 ;;;     and $ktail will never be seen elsewhere in a CPS term.
  84 ;;;
  85 ;;;   - $prompt continues to the body of the prompt, having pushed on a
  86 ;;;     prompt whose handler will continue at its "handler"
  87 ;;;     continuation.  The continuation of the prompt is responsible for
  88 ;;;     popping the prompt.
  89 ;;;
  90 ;;; In summary:
  91 ;;;
  92 ;;;   - $letk, $letrec, and $continue are terms.
  93 ;;;
  94 ;;;   - $cont is a continuation, containing a continuation body ($kargs,
  95 ;;;     $ktail, etc).
  96 ;;;
  97 ;;;   - $continue terms contain an expression ($call, $const, $fun,
  98 ;;;     etc).
  99 ;;;
 100 ;;; See (language tree-il compile-cps) for details on how Tree-IL
 101 ;;; converts to CPS.
 102 ;;;
 103 ;;; Code:
 104
 105 (define-module (language cps)
 106   #:use-module (ice-9 match)
 107   #:use-module ((srfi srfi-1) #:select (fold))
 108   #:use-module (srfi srfi-9)
 109   #:use-module (srfi srfi-9 gnu)
 110   #:use-module (srfi srfi-11)
 111   #:export (;; Helper.
 112             $arity
 113             make-$arity
 114
 115             ;; Terms.
 116             $letk $continue
 117
 118             ;; Continuations.
 119             $cont
 120
 121             ;; Continuation bodies.
 122             $kreceive $kargs $kfun $ktail $kclause
 123
 124             ;; Expressions.
 125             $const $prim $fun $rec $closure $branch
 126             $call $callk $primcall $values $prompt
 127
 128             ;; First-order CPS root.
 129             $program
 130
 131             ;; Fresh names.
 132             label-counter var-counter
 133             fresh-label fresh-var
 134             with-fresh-name-state compute-max-label-and-var
 135             let-fresh
 136
 137             ;; Building macros.
 138             build-cps-term build-cps-cont build-cps-exp
 139             rewrite-cps-term rewrite-cps-cont rewrite-cps-exp
 140
 141             ;; Misc.
 142             parse-cps unparse-cps
 143             make-global-cont-folder make-local-cont-folder
 144             fold-conts fold-local-conts
 145             visit-cont-successors))
 146
 147 ;; FIXME: Use SRFI-99, when Guile adds it.
 148 (define-syntax define-record-type*
 149   (lambda (x)
 150     (define (id-append ctx . syms)
 151       (datum->syntax ctx (apply symbol-append (map syntax->datum syms))))
 152     (syntax-case x ()
 153       ((_ name field ...)
 154        (and (identifier? #'name) (and-map identifier? #'(field ...)))
 155        (with-syntax ((cons (id-append #'name #'make- #'name))
 156                      (pred (id-append #'name #'name #'?))
 157                      ((getter ...) (map (lambda (f)
 158                                           (id-append f #'name #'- f))
 159                                         #'(field ...))))
 160          #'(define-record-type name
 161              (cons field ...)
 162              pred
 163              (field getter)
 164              ...))))))
 165
 166 (define-syntax-rule (define-cps-type name field ...)
 167   (begin
 168     (define-record-type* name field ...)
 169     (set-record-type-printer! name print-cps)))
 170
 171 (define (print-cps exp port)
 172   (format port "#<cps ~S>" (unparse-cps exp)))
 173
 174 ;; Helper.
 175 (define-record-type* $arity req opt rest kw allow-other-keys?)
 176
 177 ;; Terms.
 178 (define-cps-type $letk conts body)
 179 (define-cps-type $continue k src exp)
 180
 181 ;; Continuations
 182 (define-cps-type $cont k cont)
 183 (define-cps-type $kreceive arity k)
 184 (define-cps-type $kargs names syms body)
 185 (define-cps-type $kfun src meta self tail clause)
 186 (define-cps-type $ktail)
 187 (define-cps-type $kclause arity cont alternate)
 188
 189 ;; Expressions.
 190 (define-cps-type $const val)
 191 (define-cps-type $prim name)
 192 (define-cps-type $fun body) ; Higher-order.
 193 (define-cps-type $rec names syms funs) ; Higher-order.
 194 (define-cps-type $closure label nfree) ; First-order.
 195 (define-cps-type $branch k exp)
 196 (define-cps-type $call proc args)
 197 (define-cps-type $callk k proc args) ; First-order.
 198 (define-cps-type $primcall name args)
 199 (define-cps-type $values args)
 200 (define-cps-type $prompt escape? tag handler)
 201
 202 ;; The root of a higher-order CPS term is $cont containing a $kfun.  The
 203 ;; root of a first-order CPS term is a $program.
 204 (define-cps-type $program funs)
 205
 206 (define label-counter (make-parameter #f))
 207 (define var-counter (make-parameter #f))
 208
 209 (define (fresh-label)
 210   (let ((count (or (label-counter)
 211                    (error "fresh-label outside with-fresh-name-state"))))
 212     (label-counter (1+ count))
 213     count))
 214
 215 (define (fresh-var)
 216   (let ((count (or (var-counter)
 217                    (error "fresh-var outside with-fresh-name-state"))))
 218     (var-counter (1+ count))
 219     count))
 220
 221 (define-syntax-rule (let-fresh (label ...) (var ...) body ...)
 222   (let ((label (fresh-label)) ...
 223         (var (fresh-var)) ...)
 224     body ...))
 225
 226 (define-syntax-rule (with-fresh-name-state fun body ...)
 227   (call-with-values (lambda () (compute-max-label-and-var fun))
 228     (lambda (max-label max-var)
 229       (parameterize ((label-counter (1+ max-label))
 230                      (var-counter (1+ max-var)))
 231         body ...))))
 232
 233 (define-syntax build-arity
 234   (syntax-rules (unquote)
 235     ((_ (unquote exp)) exp)
 236     ((_ (req opt rest kw allow-other-keys?))
 237      (make-$arity req opt rest kw allow-other-keys?))))
 238
 239 (define-syntax build-cont-body
 240   (syntax-rules (unquote $kreceive $kargs $kfun $ktail $kclause)
 241     ((_ (unquote exp))
 242      exp)
 243     ((_ ($kreceive req rest kargs))
 244      (make-$kreceive (make-$arity req '() rest '() #f) kargs))
 245     ((_ ($kargs (name ...) (unquote syms) body))
 246      (make-$kargs (list name ...) syms (build-cps-term body)))
 247     ((_ ($kargs (name ...) (sym ...) body))
 248      (make-$kargs (list name ...) (list sym ...) (build-cps-term body)))
 249     ((_ ($kargs names syms body))
 250      (make-$kargs names syms (build-cps-term body)))
 251     ((_ ($kfun src meta self tail clause))
 252      (make-$kfun src meta self (build-cps-cont tail) (build-cps-cont clause)))
 253     ((_ ($ktail))
 254      (make-$ktail))
 255     ((_ ($kclause arity cont alternate))
 256      (make-$kclause (build-arity arity) (build-cps-cont cont)
 257                     (build-cps-cont alternate)))))
 258
 259 (define-syntax build-cps-cont
 260   (syntax-rules (unquote)
 261     ((_ (unquote exp)) exp)
 262     ((_ (k cont)) (make-$cont k (build-cont-body cont)))))
 263
 264 (define-syntax build-cps-exp
 265   (syntax-rules (unquote
 266                  $const $prim $fun $rec $closure $branch
 267                  $call $callk $primcall $values $prompt)
 268     ((_ (unquote exp)) exp)
 269     ((_ ($const val)) (make-$const val))
 270     ((_ ($prim name)) (make-$prim name))
 271     ((_ ($fun body)) (make-$fun (build-cps-cont body)))
 272     ((_ ($rec names gensyms funs)) (make-$rec names gensyms funs))
 273     ((_ ($closure k nfree)) (make-$closure k nfree))
 274     ((_ ($call proc (unquote args))) (make-$call proc args))
 275     ((_ ($call proc (arg ...))) (make-$call proc (list arg ...)))
 276     ((_ ($call proc args)) (make-$call proc args))
 277     ((_ ($callk k proc (unquote args))) (make-$callk k proc args))
 278     ((_ ($callk k proc (arg ...))) (make-$callk k proc (list arg ...)))
 279     ((_ ($callk k proc args)) (make-$callk k proc args))
 280     ((_ ($primcall name (unquote args))) (make-$primcall name args))
 281     ((_ ($primcall name (arg ...))) (make-$primcall name (list arg ...)))
 282     ((_ ($primcall name args)) (make-$primcall name args))
 283     ((_ ($values (unquote args))) (make-$values args))
 284     ((_ ($values (arg ...))) (make-$values (list arg ...)))
 285     ((_ ($values args)) (make-$values args))
 286     ((_ ($branch k exp)) (make-$branch k (build-cps-exp exp)))
 287     ((_ ($prompt escape? tag handler))
 288      (make-$prompt escape? tag handler))))
 289
 290 (define-syntax build-cps-term
 291   (syntax-rules (unquote $letk $letk* $letconst $program $continue)
 292     ((_ (unquote exp))
 293      exp)
 294     ((_ ($letk (unquote conts) body))
 295      (make-$letk conts (build-cps-term body)))
 296     ((_ ($letk (cont ...) body))
 297      (make-$letk (list (build-cps-cont cont) ...)
 298                  (build-cps-term body)))
 299     ((_ ($letk* () body))
 300      (build-cps-term body))
 301     ((_ ($letk* (cont conts ...) body))
 302      (build-cps-term ($letk (cont) ($letk* (conts ...) body))))
 303     ((_ ($letconst () body))
 304      (build-cps-term body))
 305     ((_ ($letconst ((name sym val) tail ...) body))
 306      (let-fresh (kconst) ()
 307        (build-cps-term
 308          ($letk ((kconst ($kargs (name) (sym) ($letconst (tail ...) body))))
 309            ($continue kconst (let ((props (source-properties val)))
 310                                (and (pair? props) props))
 311              ($const val))))))
 312     ((_ ($program (unquote conts)))
 313      (make-$program conts))
 314     ((_ ($program (cont ...)))
 315      (make-$program (list (build-cps-cont cont) ...)))
 316     ((_ ($program conts))
 317      (make-$program conts))
 318     ((_ ($continue k src exp))
 319      (make-$continue k src (build-cps-exp exp)))))
 320
 321 (define-syntax-rule (rewrite-cps-term x (pat body) ...)
 322   (match x
 323     (pat (build-cps-term body)) ...))
 324 (define-syntax-rule (rewrite-cps-cont x (pat body) ...)
 325   (match x
 326     (pat (build-cps-cont body)) ...))
 327 (define-syntax-rule (rewrite-cps-exp x (pat body) ...)
 328   (match x
 329     (pat (build-cps-exp body)) ...))
 330
 331 (define (parse-cps exp)
 332   (define (src exp)
 333     (let ((props (source-properties exp)))
 334       (and (pair? props) props)))
 335   (match exp
 336     ;; Continuations.
 337     (('letconst k (name sym c) body)
 338      (build-cps-term
 339        ($letk ((k ($kargs (name) (sym)
 340                     ,(parse-cps body))))
 341          ($continue k (src exp) ($const c)))))
 342     (('let k (name sym val) body)
 343      (build-cps-term
 344       ($letk ((k ($kargs (name) (sym)
 345                    ,(parse-cps body))))
 346         ,(parse-cps val))))
 347     (('letk (cont ...) body)
 348      (build-cps-term
 349        ($letk ,(map parse-cps cont) ,(parse-cps body))))
 350     (('k sym body)
 351      (build-cps-cont
 352        (sym ,(parse-cps body))))
 353     (('kreceive req rest k)
 354      (build-cont-body ($kreceive req rest k)))
 355     (('kargs names syms body)
 356      (build-cont-body ($kargs names syms ,(parse-cps body))))
 357     (('kfun src meta self tail clause)
 358      (build-cont-body
 359       ($kfun (src exp) meta self ,(parse-cps tail)
 360         ,(and=> clause parse-cps))))
 361     (('ktail)
 362      (build-cont-body
 363       ($ktail)))
 364     (('kclause (req opt rest kw allow-other-keys?) body)
 365      (build-cont-body
 366       ($kclause (req opt rest kw allow-other-keys?)
 367         ,(parse-cps body)
 368         ,#f)))
 369     (('kclause (req opt rest kw allow-other-keys?) body alternate)
 370      (build-cont-body
 371       ($kclause (req opt rest kw allow-other-keys?)
 372         ,(parse-cps body)
 373         ,(parse-cps alternate))))
 374     (('kseq body)
 375      (build-cont-body ($kargs () () ,(parse-cps body))))
 376
 377     ;; Calls.
 378     (('continue k exp)
 379      (build-cps-term ($continue k (src exp) ,(parse-cps exp))))
 380     (('const exp)
 381      (build-cps-exp ($const exp)))
 382     (('prim name)
 383      (build-cps-exp ($prim name)))
 384     (('fun body)
 385      (build-cps-exp ($fun ,(parse-cps body))))
 386     (('closure k nfree)
 387      (build-cps-exp ($closure k nfree)))
 388     (('rec (name sym fun) ...)
 389      (build-cps-exp ($rec name sym (map parse-cps fun))))
 390     (('program (cont ...))
 391      (build-cps-term ($program ,(map parse-cps cont))))
 392     (('call proc arg ...)
 393      (build-cps-exp ($call proc arg)))
 394     (('callk k proc arg ...)
 395      (build-cps-exp ($callk k proc arg)))
 396     (('primcall name arg ...)
 397      (build-cps-exp ($primcall name arg)))
 398     (('branch k exp)
 399      (build-cps-exp ($branch k ,(parse-cps exp))))
 400     (('values arg ...)
 401      (build-cps-exp ($values arg)))
 402     (('prompt escape? tag handler)
 403      (build-cps-exp ($prompt escape? tag handler)))
 404     (_
 405      (error "unexpected cps" exp))))
 406
 407 (define (unparse-cps exp)
 408   (match exp
 409     ;; Continuations.
 410     (($ $letk (($ $cont k ($ $kargs (name) (sym) body)))
 411         ($ $continue k src ($ $const c)))
 412      `(letconst ,k (,name ,sym ,c)
 413                 ,(unparse-cps body)))
 414     (($ $letk (($ $cont k ($ $kargs (name) (sym) body))) val)
 415      `(let ,k (,name ,sym ,(unparse-cps val))
 416            ,(unparse-cps body)))
 417     (($ $letk conts body)
 418      `(letk ,(map unparse-cps conts) ,(unparse-cps body)))
 419     (($ $cont sym body)
 420      `(k ,sym ,(unparse-cps body)))
 421     (($ $kreceive ($ $arity req () rest '() #f) k)
 422      `(kreceive ,req ,rest ,k))
 423     (($ $kargs () () body)
 424      `(kseq ,(unparse-cps body)))
 425     (($ $kargs names syms body)
 426      `(kargs ,names ,syms ,(unparse-cps body)))
 427     (($ $kfun src meta self tail clause)
 428      `(kfun ,meta ,self ,(unparse-cps tail) ,(unparse-cps clause)))
 429     (($ $ktail)
 430      `(ktail))
 431     (($ $kclause ($ $arity req opt rest kw allow-other-keys?) body alternate)
 432      `(kclause (,req ,opt ,rest ,kw ,allow-other-keys?) ,(unparse-cps body)
 433                . ,(if alternate (list (unparse-cps alternate)) '())))
 434
 435     ;; Calls.
 436     (($ $continue k src exp)
 437      `(continue ,k ,(unparse-cps exp)))
 438     (($ $const val)
 439      `(const ,val))
 440     (($ $prim name)
 441      `(prim ,name))
 442     (($ $fun body)
 443      `(fun ,(unparse-cps body)))
 444     (($ $closure k nfree)
 445      `(closure ,k ,nfree))
 446     (($ $rec names syms funs)
 447      `(rec ,@(map (lambda (name sym fun)
 448                     (list name sym (unparse-cps fun)))
 449                   names syms funs)))
 450     (($ $program conts)
 451      `(program ,(map unparse-cps conts)))
 452     (($ $call proc args)
 453      `(call ,proc ,@args))
 454     (($ $callk k proc args)
 455      `(callk ,k ,proc ,@args))
 456     (($ $primcall name args)
 457      `(primcall ,name ,@args))
 458     (($ $branch k exp)
 459      `(branch ,k ,(unparse-cps exp)))
 460     (($ $values args)
 461      `(values ,@args))
 462     (($ $prompt escape? tag handler)
 463      `(prompt ,escape? ,tag ,handler))
 464     (_
 465      (error "unexpected cps" exp))))
 466
 467 (define-syntax-rule (make-global-cont-folder seed ...)
 468   (lambda (proc cont seed ...)
 469     (define (cont-folder cont seed ...)
 470       (match cont
 471         (($ $cont k cont)
 472          (let-values (((seed ...) (proc k cont seed ...)))
 473            (match cont
 474              (($ $kargs names syms body)
 475               (term-folder body seed ...))
 476
 477              (($ $kfun src meta self tail clause)
 478               (let-values (((seed ...) (cont-folder tail seed ...)))
 479                 (if clause
 480                     (cont-folder clause seed ...)
 481                     (values seed ...))))
 482
 483              (($ $kclause arity body alternate)
 484               (let-values (((seed ...) (cont-folder body seed ...)))
 485                 (if alternate
 486                     (cont-folder alternate seed ...)
 487                     (values seed ...))))
 488
 489              (_ (values seed ...)))))))
 490
 491     (define (fun-folder fun seed ...)
 492       (match fun
 493         (($ $fun body)
 494          (cont-folder body seed ...))))
 495
 496     (define (term-folder term seed ...)
 497       (match term
 498         (($ $letk conts body)
 499          (let-values (((seed ...) (term-folder body seed ...)))
 500            (let lp ((conts conts) (seed seed) ...)
 501              (if (null? conts)
 502                  (values seed ...)
 503                  (let-values (((seed ...) (cont-folder (car conts) seed ...)))
 504                    (lp (cdr conts) seed ...))))))
 505
 506         (($ $continue k src exp)
 507          (match exp
 508            (($ $fun) (fun-folder exp seed ...))
 509            (($ $rec names syms funs)
 510             (let lp ((funs funs) (seed seed) ...)
 511               (if (null? funs)
 512                   (values seed ...)
 513                   (let-values (((seed ...) (fun-folder (car funs) seed ...)))
 514                     (lp (cdr funs) seed ...)))))
 515            (_ (values seed ...))))))
 516
 517     (cont-folder cont seed ...)))
 518
 519 (define-syntax-rule (make-local-cont-folder seed ...)
 520   (lambda (proc cont seed ...)
 521     (define (cont-folder cont seed ...)
 522       (match cont
 523         (($ $cont k (and cont ($ $kargs names syms body)))
 524          (let-values (((seed ...) (proc k cont seed ...)))
 525            (term-folder body seed ...)))
 526         (($ $cont k cont)
 527          (proc k cont seed ...))))
 528     (define (term-folder term seed ...)
 529       (match term
 530         (($ $letk conts body)
 531          (let-values (((seed ...) (term-folder body seed ...)))
 532            (let lp ((conts conts) (seed seed) ...)
 533              (match conts
 534                (() (values seed ...))
 535                ((cont) (cont-folder cont seed ...))
 536                ((cont . conts)
 537                 (let-values (((seed ...) (cont-folder cont seed ...)))
 538                   (lp conts seed ...)))))))
 539         (_ (values seed ...))))
 540     (define (clause-folder clause seed ...)
 541       (match clause
 542         (($ $cont k (and cont ($ $kclause arity body alternate)))
 543          (let-values (((seed ...) (proc k cont seed ...)))
 544            (if alternate
 545                (let-values (((seed ...) (cont-folder body seed ...)))
 546                  (clause-folder alternate seed ...))
 547                (cont-folder body seed ...))))))
 548     (match cont
 549       (($ $cont k (and cont ($ $kfun src meta self tail clause)))
 550        (let*-values (((seed ...) (proc k cont seed ...))
 551                      ((seed ...) (if clause
 552                                      (clause-folder clause seed ...)
 553                                      (values seed ...))))
 554          (cont-folder tail seed ...))))))
 555
 556 (define (compute-max-label-and-var fun)
 557   (match fun
 558     (($ $cont)
 559      ((make-global-cont-folder max-label max-var)
 560       (lambda (label cont max-label max-var)
 561         (values (max label max-label)
 562                 (match cont
 563                   (($ $kargs names vars body)
 564                    (fold max max-var vars))
 565                   (($ $kfun src meta self)
 566                    (max self max-var))
 567                   (_ max-var))))
 568       fun -1 -1))
 569     (($ $program conts)
 570      (define (fold/2 proc in s0 s1)
 571       (if (null? in)
 572           (values s0 s1)
 573           (let-values (((s0 s1) (proc (car in) s0 s1)))
 574             (fold/2 proc (cdr in) s0 s1))))
 575      (let lp ((conts conts) (max-label -1) (max-var -1))
 576        (if (null? conts)
 577            (values max-label max-var)
 578            (call-with-values (lambda ()
 579                                ((make-local-cont-folder max-label max-var)
 580                                 (lambda (label cont max-label max-var)
 581                                   (values (max label max-label)
 582                                           (match cont
 583                                             (($ $kargs names vars body)
 584                                              (fold max max-var vars))
 585                                             (($ $kfun src meta self)
 586                                              (max self max-var))
 587                                             (_ max-var))))
 588                                 (car conts) max-label max-var))
 589              (lambda (max-label max-var)
 590                (lp (cdr conts) max-label max-var))))))))
 591
 592 (define (fold-conts proc seed fun)
 593   ((make-global-cont-folder seed) proc fun seed))
 594
 595 (define (fold-local-conts proc seed fun)
 596   ((make-local-cont-folder seed) proc fun seed))
 597
 598 (define (visit-cont-successors proc cont)
 599   (match cont
 600     (($ $kargs names syms body)
 601      (let lp ((body body))
 602        (match body
 603          (($ $letk conts body) (lp body))
 604          (($ $continue k src exp)
 605           (match exp
 606             (($ $prompt escape? tag handler) (proc k handler))
 607             (($ $branch kt) (proc k kt))
 608             (_ (proc k)))))))
 609
 610     (($ $kreceive arity k) (proc k))
 611
 612     (($ $kclause arity ($ $cont kbody) #f) (proc kbody))
 613
 614     (($ $kclause arity ($ $cont kbody) ($ $cont kalt)) (proc kbody kalt))
 615
 616     (($ $kfun src meta self tail ($ $cont clause)) (proc clause))
 617
 618     (($ $kfun src meta self tail #f) (proc))
 619
 620     (($ $ktail) (proc))))