configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # Independent Subdirectories
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_CONFIG_SUBDIRS(guile-readline)
  36
  37 #--------------------------------------------------------------------
  38 #
  39 # User options
  40 #
  41 #--------------------------------------------------------------------
  42
  43 AC_ARG_ENABLE(debug-freelist,
  44   [  --enable-debug-freelist  include garbage collector freelist debugging code],
  45   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  46     AC_DEFINE(GUILE_DEBUG_FREELIST)
  47   fi)
  48
  49 AC_ARG_ENABLE(debug-malloc,
  50   [  --enable-debug-malloc    include malloc debugging code],
  51   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  52     AC_DEFINE(GUILE_DEBUG_MALLOC)
  53   fi)
  54
  55 AC_ARG_ENABLE(guile-debug,
  56   [  --enable-guile-debug    include internal debugging functions],
  57   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  58     AC_DEFINE(GUILE_DEBUG)
  59   fi)
  60
  61 AC_ARG_ENABLE(arrays,
  62   [  --disable-arrays        omit array and uniform array support],,
  63   enable_arrays=yes)
  64
  65 AC_ARG_ENABLE(posix,
  66   [  --disable-posix         omit posix interfaces],,
  67   enable_posix=yes)
  68
  69 AC_ARG_ENABLE(networking,
  70   [  --disable-networking    omit networking interfaces],,
  71   enable_networking=yes)
  72
  73 AC_ARG_ENABLE(regex,
  74   [  --disable-regex         omit regular expression interfaces],,
  75   enable_regex=yes)
  76
  77 AC_ARG_ENABLE(htmldoc,
  78   [  --enable-htmldoc        build HTML documentation as well as Info],
  79   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  80      htmldoc_enabled=yes
  81      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  82      if test "$TEXI2HTML" = "not found"; then
  83        echo
  84        echo Building HTML documentation requires the \`texi2html\' program,
  85        echo which appears not to be present on your machine.
  86        echo
  87        echo \`texi2html\' is available from
  88        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
  89        echo
  90        echo In the meantime, to build the guile-doc distribution
  91        echo without HTML enabled, please rerun \`./configure\' without
  92        echo the \`--enable-htmldoc\' option.
  93        exit -1
  94      fi
  95    fi])
  96
  97 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
  98
  99 dnl The --disable-debug used to control these two.  But now they are
 100 dnl a required part of the distribution.
 101 AC_DEFINE(DEBUG_EXTENSIONS)
 102 AC_DEFINE(READER_EXTENSIONS)
 103
 104 dnl files which are destined for separate modules.
 105
 106 if test "$enable_arrays" = yes; then
 107    LIBOBJS="$LIBOBJS ramap.o unif.o"
 108    AC_DEFINE(HAVE_ARRAYS)
 109 fi
 110
 111 if test "$enable_posix" = yes; then
 112    LIBOBJS="$LIBOBJS filesys.o posix.o"
 113    AC_DEFINE(HAVE_POSIX)
 114 fi
 115
 116 if test "$enable_networking" = yes; then
 117    LIBOBJS="$LIBOBJS net_db.o socket.o"
 118    AC_DEFINE(HAVE_NETWORKING)
 119 fi
 120
 121 if test "$enable_debug_malloc" = yes; then
 122    LIBOBJS="$LIBOBJS debug-malloc.o"
 123 fi
 124
 125 #--------------------------------------------------------------------
 126
 127 AC_LIBLTDL_CONVENIENCE
 128 AC_CONFIG_SUBDIRS(libltdl)
 129
 130 AC_PROG_CC
 131 AC_PROG_CPP
 132 AC_LIBTOOL_DLOPEN
 133
 134 AC_AIX
 135 AC_ISC_POSIX
 136 AC_MINIX
 137
 138 AM_PROG_CC_STDC
 139 AM_PROG_LIBTOOL
 140
 141 AC_C_CONST
 142 AC_C_INLINE
 143 AC_CHECK_SIZEOF(int)
 144 AC_CHECK_SIZEOF(long)
 145 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 146                AC_TRY_COMPILE(,
 147                               [long long a],
 148                               scm_cv_long_longs=yes,
 149                               scm_cv_long_longs=no))
 150 if test "$scm_cv_long_longs" = yes; then
 151   AC_DEFINE(HAVE_LONG_LONGS)
 152 fi
 153
 154 AC_HEADER_STDC
 155 AC_HEADER_DIRENT
 156 AC_HEADER_TIME
 157 AC_HEADER_SYS_WAIT
 158 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
 159 GUILE_HEADER_LIBC_WITH_UNISTD
 160
 161 AC_TYPE_GETGROUPS
 162 AC_TYPE_SIGNAL
 163 AC_TYPE_MODE_T
 164
 165 AC_CHECK_LIB(m, main)
 166 AC_CHECK_FUNCS(gethostbyname)
 167 if test $ac_cv_func_gethostbyname = no; then
 168     AC_CHECK_LIB(nsl, gethostbyname)
 169 fi
 170 AC_CHECK_FUNCS(connect)
 171 if test $ac_cv_func_connect = no; then
 172     AC_CHECK_LIB(socket, connect)
 173 fi
 174
 175 # Check for dynamic linking
 176
 177 use_modules=yes
 178 AC_ARG_WITH(modules,
 179 [  --with-modules[=FILES]  Add support for dynamic modules],
 180 use_modules="$withval")
 181 test -z "$use_modules" && use_modules=yes
 182 DLPREOPEN=
 183 if test "$use_modules" != no; then
 184   AC_DEFINE(DYNAMIC_LINKING)
 185   if test "$use_modules" = yes; then
 186     DLPREOPEN="-dlpreopen force"
 187   else
 188     DLPREOPEN="-export-dynamic"
 189     for module in $use_modules; do
 190       DLPREOPEN="$DLPREOPEN -dlopen $module"
 191     done
 192   fi
 193 fi
 194 AC_SUBST(INCLTDL)
 195 AC_SUBST(LIBLTDL)
 196 AC_SUBST(DLPREOPEN)
 197
 198 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep atexit on_exit)
 199
 200 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 201 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 202 AC_CHECK_LIB(crypt, crypt)
 203
 204 ### Some systems don't declare some functions.  On such systems, we
 205 ### need to at least provide our own K&R-style declarations.
 206
 207 ### GUILE_FUNC_DECLARED(function, headerfile)
 208
 209 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 210 ### not there, #define MISSING_FUNCTION_DECL.
 211 AC_DEFUN(GUILE_FUNC_DECLARED, [
 212   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 213     AC_EGREP_HEADER($1, $2,
 214                     guile_cv_func_$1_declared=yes,
 215                     guile_cv_func_$1_declared=no))
 216   if test [x$guile_cv_func_]$1[_declared] = xno; then
 217     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 218   fi
 219 ])
 220
 221 GUILE_FUNC_DECLARED(strptime, time.h)
 222 GUILE_FUNC_DECLARED(bzero, string.h)
 223 GUILE_FUNC_DECLARED(sleep, unistd.h)
 224 GUILE_FUNC_DECLARED(usleep, unistd.h)
 225
 226 ### On some systems usleep has no return value.  If it does have one,
 227 ### we'd like to return it; otherwise, we'll fake it.
 228 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 229   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 230                    /usr/include/unistd.h,
 231                    [guile_cv_func_usleep_return_type=void],
 232                    [guile_cv_func_usleep_return_type=int])])
 233 case "$guile_cv_func_usleep_return_type" in
 234   "void" )
 235     AC_DEFINE(USLEEP_RETURNS_VOID)
 236   ;;
 237 esac
 238
 239 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 240 if test -n "$have_sys_un_h" ; then
 241 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 242 fi
 243
 244 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 245
 246 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 247                setnetent    getnetent    endnetent    dnl
 248                setprotoent  getprotoent  endprotoent  dnl
 249                setservent   getservent   endservent   dnl
 250                getnetbyaddr getnetbyname dnl
 251                inet_lnaof inet_makeaddr inet_netof hstrerror)
 252
 253 dnl Some systems do not declare this.  Some systems do declare it, as a
 254 dnl macro.  With cygwin it may be in a DLL.
 255
 256 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 257 AC_CACHE_VAL(guile_cv_have_h_errno,
 258 [AC_TRY_COMPILE([#include <netdb.h>],
 259 [int a = h_errno;],
 260 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 261 AC_MSG_RESULT($guile_cv_have_h_errno)
 262 if test $guile_cv_have_h_errno = yes; then
 263   AC_DEFINE(HAVE_H_ERRNO)
 264 fi
 265
 266 AC_MSG_CHECKING(whether localtime caches TZ)
 267 AC_CACHE_VAL(guile_cv_localtime_cache,
 268 [if test x$ac_cv_func_tzset = xyes; then
 269 AC_TRY_RUN([#include <time.h>
 270 #if STDC_HEADERS
 271 # include <stdlib.h>
 272 #endif
 273 extern char **environ;
 274 unset_TZ ()
 275 {
 276   char **from, **to;
 277   for (to = from = environ; (*to = *from); from++)
 278     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 279       to++;
 280 }
 281 char TZ_GMT0[] = "TZ=GMT0";
 282 char TZ_PST8[] = "TZ=PST8";
 283 main()
 284 {
 285   time_t now = time ((time_t *) 0);
 286   int hour_GMT0, hour_unset;
 287   if (putenv (TZ_GMT0) != 0)
 288     exit (1);
 289   hour_GMT0 = localtime (&now)->tm_hour;
 290   unset_TZ ();
 291   hour_unset = localtime (&now)->tm_hour;
 292   if (putenv (TZ_PST8) != 0)
 293     exit (1);
 294   if (localtime (&now)->tm_hour == hour_GMT0)
 295     exit (1);
 296   unset_TZ ();
 297   if (localtime (&now)->tm_hour != hour_unset)
 298     exit (1);
 299   exit (0);
 300 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 301 [# If we have tzset, assume the worst when cross-compiling.
 302 guile_cv_localtime_cache=yes])
 303 else
 304         # If we lack tzset, report that localtime does not cache TZ,
 305         # since we can't invalidate the cache if we don't have tzset.
 306         guile_cv_localtime_cache=no
 307 fi])dnl
 308 AC_MSG_RESULT($guile_cv_localtime_cache)
 309 if test $guile_cv_localtime_cache = yes; then
 310   AC_DEFINE(LOCALTIME_CACHE)
 311 fi
 312
 313 dnl Test whether system calls are restartable by default on the
 314 dnl current system.  If they are not, we put a loop around every system
 315 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 316 dnl change from the default behaviour.  On the other hand, if signals
 317 dnl are restartable then the loop is not installed and when libguile
 318 dnl initialises it also resets the behaviour of each signal to cause a
 319 dnl restart (in case a different runtime had a different default
 320 dnl behaviour for some reason: e.g., different versions of linux seem
 321 dnl to behave differently.)
 322
 323 AC_SYS_RESTARTABLE_SYSCALLS
 324
 325 if test "$enable_regex" = yes; then
 326    if test "$ac_cv_header_regex_h" = yes ||
 327       test "$ac_cv_header_rxposix_h" = yes ||
 328       test "$ac_cv_header_rx_rxposix_h" = yes; then
 329      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 330      [AC_CHECK_LIB(rx, main)
 331       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 332      )
 333      dnl The following should not be necessary, but for some reason
 334      dnl autoheader misses it if we don't include it!
 335      if test "$ac_cv_func_regcomp_norx" = yes ||
 336         test "$ac_cv_func_regcomp_rx" = yes; then
 337        AC_DEFINE(HAVE_REGCOMP)
 338      fi
 339    fi
 340 fi
 341
 342 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
 343
 344 # When testing for the presence of alloca, we need to add alloca.o
 345 # explicitly to LIBOBJS to make sure that it is translated to
 346 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 347 AC_FUNC_ALLOCA
 348 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 349
 350 AC_STRUCT_ST_RDEV
 351 AC_STRUCT_ST_BLKSIZE
 352
 353 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 354 # LIBOBJS, which we don't need.  This seems more direct.
 355 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 356 [AC_TRY_COMPILE([#include <sys/types.h>
 357 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 358 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 359 if test $ac_cv_struct_st_blocks = yes; then
 360   AC_DEFINE(HAVE_ST_BLOCKS)
 361 fi
 362
 363 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 364   [AC_TRY_CPP([#include <sys/stat.h>
 365                #ifndef S_ISLNK
 366                #error no S_ISLNK
 367                #endif],
 368                ac_cv_macro_S_ISLNK=yes,
 369                ac_cv_macro_S_ISLNK=no)])
 370 if test $ac_cv_macro_S_ISLNK = yes; then
 371   AC_DEFINE(HAVE_S_ISLNK)
 372 fi
 373
 374 AC_STRUCT_TIMEZONE
 375 GUILE_STRUCT_UTIMBUF
 376
 377 #--------------------------------------------------------------------
 378 #
 379 # Which way does the stack grow?
 380 #
 381 #--------------------------------------------------------------------
 382
 383 AC_TRY_RUN(aux (l) unsigned long l;
 384              { int x; exit (l >= ((unsigned long)&x)); }
 385            main () { int q; aux((unsigned long)&q); },
 386            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 387
 388 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 389     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 390                 [guile_cv_type_float_fits_long=yes],
 391                 [guile_cv_type_float_fits_long=no],
 392                 [guile_cv_type_float_fits_long=guess-yes])])
 393 case $guile_cv_type_float_fits_long in
 394   "yes" )
 395     AC_DEFINE(SCM_SINGLES)
 396   ;;
 397   "guess-yes" )
 398     AC_DEFINE(SCM_SINGLES)
 399     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 400     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 401   ;;
 402 esac
 403
 404
 405 AC_MSG_CHECKING(for struct linger)
 406 AC_CACHE_VAL(scm_cv_struct_linger,
 407         AC_TRY_COMPILE([
 408 #include <sys/types.h>
 409 #include <sys/socket.h>],
 410                         [struct linger lgr;  lgr.l_linger = 100],
 411                         scm_cv_struct_linger="yes",
 412                         scm_cv_struct_linger="no"))
 413 AC_MSG_RESULT($scm_cv_struct_linger)
 414 if test $scm_cv_struct_linger = yes; then
 415         AC_DEFINE(HAVE_STRUCT_LINGER)
 416 fi
 417
 418
 419 AC_MSG_CHECKING(for struct timespec)
 420 AC_CACHE_VAL(scm_cv_struct_timespec,
 421         AC_TRY_COMPILE([
 422 #include <time.h>],
 423                         [struct timespec t;  t.tv_nsec = 100],
 424                         scm_cv_struct_timespec="yes",
 425                         scm_cv_struct_timespec="no"))
 426 AC_MSG_RESULT($scm_cv_struct_timespec)
 427 if test $scm_cv_struct_timespec = yes; then
 428         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 429 fi
 430
 431 #--------------------------------------------------------------------
 432 #
 433 # Flags for thread support
 434 #
 435 #--------------------------------------------------------------------
 436
 437 ### What thread package has the user asked for?
 438 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 439             , with_threads=no)
 440
 441 ### Turn $with_threads into either the name of a threads package, like
 442 ### `qt', or `no', meaning that threads should not be supported.
 443 AC_MSG_CHECKING(whether to support threads)
 444 case "$with_threads" in
 445   "yes" | "qt" | "coop" | "")
 446     with_threads=qt
 447   ;;
 448   "no" )
 449   ;;
 450   * )
 451     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 452   ;;
 453 esac
 454 AC_MSG_RESULT($with_threads)
 455
 456 ## Make sure the threads package we've chosen is actually supported on
 457 ## the present platform.
 458 case "${with_threads}" in
 459   "qt" )
 460     ## This configures the QuickThreads package, and sets or clears
 461     ## the THREAD_PACKAGE variable if qthreads don't configure
 462     ## correctly.
 463     QTHREADS_CONFIGURE
 464    ;;
 465 esac
 466
 467 ## If we're using threads, bring in some other parts of Guile which
 468 ## work with them.
 469 if test "${THREAD_PACKAGE}" != "" ; then
 470   AC_DEFINE(USE_THREADS, 1)
 471
 472   ## Include the Guile thread interface in the library...
 473   LIBOBJS="$LIBOBJS threads.o"
 474
 475   ## ... and tell it which package to talk to.
 476   case "${THREAD_PACKAGE}" in
 477     "QT" )
 478       AC_DEFINE(USE_COOP_THREADS, 1)
 479     ;;
 480     * )
 481       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 482     ;;
 483   esac
 484
 485   ## Bring in scm_internal_select, if appropriate.
 486   if test $ac_cv_func_gettimeofday = yes &&
 487      test $ac_cv_func_select = yes; then
 488     AC_DEFINE(GUILE_ISELECT, 1)
 489   fi
 490
 491   ## Workaround for linuxthreads (currently disabled)
 492   if test $host_os = linux-gnu; then
 493     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 494     AC_CHECK_LIB(pthread, main)
 495   fi
 496 fi
 497
 498 ## If we're using GCC, ask for aggressive warnings.
 499 case "$GCC" in
 500   yes )
 501     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 502     ## much stuff with generic function pointers for that to really be
 503     ## less than exasperating.
 504     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 505     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 506     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 507 esac
 508
 509 AC_PROG_AWK
 510
 511 ## If we're creating a shared library (using libtool!), then we'll
 512 ## need to generate a list of .lo files corresponding to the .o files
 513 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 514 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 515
 516 ## We also need to create corresponding .doc and .x files
 517 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 518 EXTRA_DOT_X_FILES="`echo ${LIBOBJS} | sed 's/\.o/.x/g'`"
 519
 520 AC_SUBST(GUILE_MAJOR_VERSION)
 521 AC_SUBST(GUILE_MINOR_VERSION)
 522 AC_SUBST(GUILE_VERSION)
 523 AC_SUBST(LIBGUILE_MAJOR_VERSION)
 524 AC_SUBST(LIBGUILE_MINOR_VERSION)
 525 AC_SUBST(LIBGUILE_REVISION_VERSION)
 526 AC_SUBST(LIBGUILE_VERSION)
 527
 528 dnl Tell guile-config what flags guile users should link against.
 529 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 530 AC_SUBST(GUILE_LIBS)
 531
 532 AC_SUBST(AWK)
 533 AC_SUBST(LIBLOBJS)
 534 AC_SUBST(EXTRA_DOT_DOC_FILES)
 535 AC_SUBST(EXTRA_DOT_X_FILES)
 536
 537 # Support for "make check"
 538 test_suite_dir="`(cd $srcdir ; pwd)`/test-suite"
 539 AC_SUBST(test_suite_dir)
 540
 541 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check libguile/guile-snarf.awk libguile/versiondat.h ice-9/Makefile oop/Makefile oop/goops/Makefile qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile check-guile], [chmod +x libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check check-guile])
 542
 543 dnl Local Variables:
 544 dnl comment-start: "dnl "
 545 dnl comment-end: ""
 546 dnl comment-start-skip: "\\bdnl\\b\\s *"
 547 dnl End: