configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_PREREQ(2.53)
  24
  25 AC_INIT
  26 AC_CONFIG_SRCDIR([Makefile.in])
  27 . $srcdir/GUILE-VERSION
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  29 AM_MAINTAINER_MODE
  30 AM_CONFIG_HEADER(libguile/scmconfig.h)
  31
  32 #--------------------------------------------------------------------
  33 #
  34 # Independent Subdirectories
  35 #
  36 #--------------------------------------------------------------------
  37
  38 AC_CONFIG_SUBDIRS(guile-readline)
  39
  40 #--------------------------------------------------------------------
  41 #
  42 # User options
  43 #
  44 #--------------------------------------------------------------------
  45
  46 AC_ARG_ENABLE(error-on-warning,
  47   [  --enable-error-on-warning    treat compile warnings as errors],
  48   [case "${enableval}" in
  49      yes | y) CFLAGS="${CFLAGS} -Werror"; enable_compile_warnings=no ;;
  50      no | n)  ;;
  51      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  52    esac])
  53
  54
  55 AC_ARG_ENABLE(debug-freelist,
  56   [  --enable-debug-freelist include garbage collector freelist debugging code],
  57   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  58     AC_DEFINE(GUILE_DEBUG_FREELIST, 1,
  59       [Define this if you want to debug the free list (helps w/ GC bugs).])
  60   fi)
  61
  62 AC_ARG_ENABLE(debug-malloc,
  63   [  --enable-debug-malloc   include malloc debugging code],
  64   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  65     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
  66       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
  67   fi)
  68
  69 AC_ARG_ENABLE(guile-debug,
  70   [  --enable-guile-debug    include internal debugging functions],
  71   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  72     AC_DEFINE(GUILE_DEBUG, 1,
  73       [Define this to include various undocumented functions used to debug.])
  74   fi)
  75
  76 AC_ARG_ENABLE(arrays,
  77   [  --disable-arrays        omit array and uniform array support],,
  78   enable_arrays=yes)
  79
  80 AC_ARG_ENABLE(posix,
  81   [  --disable-posix         omit posix interfaces],,
  82   enable_posix=yes)
  83
  84 AC_ARG_ENABLE(networking,
  85   [  --disable-networking    omit networking interfaces],,
  86   enable_networking=yes)
  87
  88 AC_ARG_ENABLE(regex,
  89   [  --disable-regex         omit regular expression interfaces],,
  90   enable_regex=yes)
  91
  92 AC_ARG_ENABLE(htmldoc,
  93   [  --enable-htmldoc        build HTML documentation as well as Info],
  94   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  95      htmldoc_enabled=yes
  96      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  97      if test "$TEXI2HTML" = "not found"; then
  98        echo
  99        echo Building HTML documentation requires the \`texi2html\' program,
 100        echo which appears not to be present on your machine.
 101        echo
 102        echo \`texi2html\' is available from
 103        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
 104        echo
 105        echo In the meantime, to build the guile-doc distribution
 106        echo without HTML enabled, please rerun \`./configure\' without
 107        echo the \`--enable-htmldoc\' option.
 108        exit -1
 109      fi
 110    fi])
 111
 112 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
 113
 114 AC_ARG_ENABLE(deprecated,
 115   [  --disable-deprecated    omit deprecated features [no]])
 116
 117 AH_TEMPLATE([SCM_ENABLE_DEPRECATED],
 118   [Define this to 1 if you want to include deprecated features.])
 119
 120 if test "$enable_deprecated" = no; then
 121   AC_DEFINE(SCM_ENABLE_DEPRECATED, 0)
 122 else
 123   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 124     warn_default=summary
 125   elif test "$enable_deprecated" = shutup; then
 126     warn_default=no
 127   else
 128     warn_default=$enable_deprecated
 129   fi
 130   AC_DEFINE(SCM_ENABLE_DEPRECATED, 1)
 131   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 132   [Define this to control the default warning level for deprecated features.])
 133 fi
 134
 135 dnl The --disable-debug used to control these two.  But now they are
 136 dnl a required part of the distribution.
 137 AC_DEFINE(DEBUG_EXTENSIONS, 1,
 138   [Define if you want support for debugging Scheme programs.])
 139 AC_DEFINE(READER_EXTENSIONS, 1,
 140   [Define if you want support for debugging Scheme programs.])
 141
 142 AC_ARG_ENABLE(elisp,
 143   [  --disable-elisp         omit Emacs Lisp support],,
 144   enable_elisp=yes)
 145
 146 #--------------------------------------------------------------------
 147
 148 dnl Some more checks for Win32
 149 AC_CYGWIN
 150 AC_MINGW32
 151 AC_LIBTOOL_WIN32_DLL
 152
 153 AC_LIBLTDL_INSTALLABLE
 154 AC_CONFIG_SUBDIRS(libltdl)
 155
 156 AC_PROG_INSTALL
 157 AC_PROG_CC
 158 AC_PROG_CPP
 159 AC_LIBTOOL_DLOPEN
 160
 161 AC_AIX
 162 AC_ISC_POSIX
 163 AC_MINIX
 164
 165 AM_PROG_CC_STDC
 166 AM_PROG_LIBTOOL
 167
 168 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
 169 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
 170
 171 dnl files which are destined for separate modules.
 172
 173 if test "$enable_arrays" = yes; then
 174    AC_LIBOBJ([ramap])
 175    AC_LIBOBJ([unif])
 176    AC_DEFINE(HAVE_ARRAYS, 1,
 177      [Define this if you want support for arrays and uniform arrays.])
 178 fi
 179
 180 if test "$enable_posix" = yes; then
 181    AC_LIBOBJ([filesys])
 182    AC_LIBOBJ([posix])
 183    AC_DEFINE(HAVE_POSIX, 1,
 184      [Define this if you want support for POSIX system calls in Guile.])
 185 fi
 186
 187 if test "$enable_networking" = yes; then
 188    AC_LIBOBJ([net_db])
 189    AC_LIBOBJ([socket])
 190    AC_DEFINE(HAVE_NETWORKING, 1,
 191      [Define this if you want support for networking in Guile.])
 192 fi
 193
 194 if test "$enable_debug_malloc" = yes; then
 195    AC_LIBOBJ([debug-malloc])
 196 fi
 197
 198 if test "$enable_elisp" = yes; then
 199    AC_DEFINE(SCM_ENABLE_ELISP, 1,
 200      [Define this if you want Elisp support (in addition to Scheme).])
 201 fi
 202
 203
 204 AC_C_CONST
 205 AC_C_INLINE
 206 AC_C_BIGENDIAN
 207
 208 if test "$ac_cv_c_inline" != no; then
 209   AC_DEFINE(HAVE_INLINE, 1,
 210     [Define if the compiler supports inline functions.])
 211 fi
 212
 213 AC_CHECK_SIZEOF(short)
 214 AC_CHECK_SIZEOF(int)
 215 AC_CHECK_SIZEOF(long)
 216 AC_CHECK_SIZEOF(size_t)
 217
 218 dnl Check for integral types that can represent the range of pointers.
 219 dnl If these types don't exist on this platform, they are replaced by
 220 dnl "unsigned long" and "long", respectively.
 221
 222 AC_CHECK_HEADERS(stdint.h)
 223 AC_CHECK_HEADERS(inttypes.h)
 224 AC_CHECK_SIZEOF(uintptr_t)
 225 AC_CHECK_SIZEOF(ptrdiff_t)
 226
 227 AC_CHECK_SIZEOF(long long)
 228
 229 AC_CHECK_SIZEOF(void *)
 230
 231 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 232   AC_MSG_ERROR(sizes of long and void* are not identical)
 233 fi
 234
 235 AC_HEADER_STDC
 236 AC_HEADER_DIRENT
 237 AC_HEADER_TIME
 238 AC_HEADER_SYS_WAIT
 239 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h direct.h)
 240 GUILE_HEADER_LIBC_WITH_UNISTD
 241
 242 AC_TYPE_GETGROUPS
 243 AC_TYPE_SIGNAL
 244 AC_TYPE_MODE_T
 245
 246 AC_CHECK_LIB(m, main)
 247 AC_CHECK_FUNCS(gethostbyname)
 248 if test $ac_cv_func_gethostbyname = no; then
 249     AC_CHECK_LIB(nsl, gethostbyname)
 250 fi
 251 AC_CHECK_FUNCS(connect)
 252 if test $ac_cv_func_connect = no; then
 253     AC_CHECK_LIB(socket, connect)
 254 fi
 255
 256 dnl
 257 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 258 dnl
 259 EXTRA_DEFS=""
 260 if test "$MINGW32" = "yes" ; then
 261     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 262       [Define if you have the <winsock2.h> header file.])])
 263     AC_CHECK_LIB(ws2_32, main)
 264     AC_LIBOBJ([win32-uname])
 265     AC_LIBOBJ([win32-dirent])
 266     if test "$enable_networking" = yes ; then
 267       AC_LIBOBJ([win32-socket])
 268     fi
 269     if test "$enable_shared" = yes ; then
 270       EXTRA_DEFS="-DSCM_IMPORT"
 271       AC_DEFINE(USE_DLL_IMPORT, 1,
 272         [Define if you need additional CPP macros on Win32 platforms.])
 273     fi
 274     if test x"$enable_ltdl_install" = x"yes" ; then
 275       INCLTDL="-DLIBLTDL_DLL_IMPORT $INCLTDL"
 276     fi
 277 fi
 278 AC_SUBST(EXTRA_DEFS)
 279
 280 dnl Check for dynamic linking
 281
 282 use_modules=yes
 283 AC_ARG_WITH(modules,
 284 [  --with-modules[=FILES]  Add support for dynamic modules],
 285 use_modules="$withval")
 286 test -z "$use_modules" && use_modules=yes
 287 DLPREOPEN=
 288 if test "$use_modules" != no; then
 289   AC_DEFINE(DYNAMIC_LINKING, 1,
 290     [Define if you want support for dynamic linking.])
 291   if test "$use_modules" = yes; then
 292     DLPREOPEN="-dlpreopen force"
 293   else
 294     DLPREOPEN="-export-dynamic"
 295     for module in $use_modules; do
 296       DLPREOPEN="$DLPREOPEN -dlopen $module"
 297     done
 298   fi
 299 fi
 300
 301 AC_SUBST(INCLTDL)
 302 AC_SUBST(LIBLTDL)
 303 AC_SUBST(DLPREOPEN)
 304
 305 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer)
 306
 307 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 308 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 309 AC_CHECK_LIB(crypt, crypt)
 310
 311 ### Some systems don't declare some functions.  On such systems, we
 312 ### need to at least provide our own K&R-style declarations.
 313
 314 ### GUILE_FUNC_DECLARED(function, headerfile)
 315
 316 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 317 ### not there, #define MISSING_FUNCTION_DECL.
 318 AC_DEFUN(GUILE_FUNC_DECLARED, [
 319   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 320     AC_EGREP_HEADER($1, $2,
 321                     guile_cv_func_$1_declared=yes,
 322                     guile_cv_func_$1_declared=no))
 323   if test [x$guile_cv_func_]$1[_declared] = xno; then
 324     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 325       [Define if the operating system supplies $1 without declaring it.])
 326   fi
 327 ])
 328
 329 GUILE_FUNC_DECLARED(strptime, time.h)
 330 GUILE_FUNC_DECLARED(sleep, unistd.h)
 331 GUILE_FUNC_DECLARED(usleep, unistd.h)
 332
 333 ### On some systems usleep has no return value.  If it does have one,
 334 ### we'd like to return it; otherwise, we'll fake it.
 335 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 336   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 337                    unistd.h,
 338                    [guile_cv_func_usleep_return_type=void],
 339                    [guile_cv_func_usleep_return_type=int])])
 340 case "$guile_cv_func_usleep_return_type" in
 341   "void" )
 342     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 343       [Define if the system headers declare usleep to return void.])
 344   ;;
 345 esac
 346
 347 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 348 if test -n "$have_sys_un_h" ; then
 349   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 350     [Define if the system supports Unix-domain (file-domain) sockets.])
 351 fi
 352
 353 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 354
 355 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 356                setnetent    getnetent    endnetent    dnl
 357                setprotoent  getprotoent  endprotoent  dnl
 358                setservent   getservent   endservent   dnl
 359                getnetbyaddr getnetbyname dnl
 360                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 361                inet_pton inet_ntop)
 362
 363 dnl Some systems do not declare this.  Some systems do declare it, as a
 364 dnl macro.  With cygwin it may be in a DLL.
 365
 366 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 367 AC_CACHE_VAL(guile_cv_have_h_errno,
 368 [AC_TRY_COMPILE([#include <netdb.h>],
 369 [int a = h_errno;],
 370 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 371 AC_MSG_RESULT($guile_cv_have_h_errno)
 372 if test $guile_cv_have_h_errno = yes; then
 373   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 374 fi
 375
 376 AC_MSG_CHECKING(whether uint32_t is defined)
 377 AC_CACHE_VAL(guile_cv_have_uint32_t,
 378   [AC_TRY_COMPILE([#include <sys/types.h>
 379                    #if HAVE_STDINT_H
 380                    #include <stdint.h>
 381                    #endif
 382                    #ifndef __MINGW32__
 383                    #include <netdb.h>
 384                    #endif],
 385                   [uint32_t a;],
 386                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 387 AC_MSG_RESULT($guile_cv_have_uint32_t)
 388 if test $guile_cv_have_uint32_t = yes; then
 389   AC_DEFINE(HAVE_UINT32_T, 1,
 390     [Define if uint32_t typedef is defined when netdb.h is include.])
 391 fi
 392
 393 AC_MSG_CHECKING(for working IPv6 support)
 394 AC_CACHE_VAL(guile_cv_have_ipv6,
 395 [AC_TRY_COMPILE([
 396 #ifdef HAVE_SYS_TYPES_H
 397 #include <sys/types.h>
 398 #endif
 399 #include <netinet/in.h>
 400 #include <sys/socket.h>],
 401 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 402 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 403 AC_MSG_RESULT($guile_cv_have_ipv6)
 404 if test $guile_cv_have_ipv6 = yes; then
 405   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 406 fi
 407
 408 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 409 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 410 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 411 [AC_TRY_COMPILE([
 412 #ifdef HAVE_SYS_TYPES_H
 413 #include <sys/types.h>
 414 #endif
 415 #include <netinet/in.h>],
 416 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 417 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 418 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 419 if test $guile_cv_have_sin6_scope_id = yes; then
 420   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 421     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 422 fi
 423
 424 AC_MSG_CHECKING(whether localtime caches TZ)
 425 AC_CACHE_VAL(guile_cv_localtime_cache,
 426 [if test x$ac_cv_func_tzset = xyes; then
 427 AC_TRY_RUN([#include <time.h>
 428 #if STDC_HEADERS
 429 # include <stdlib.h>
 430 #endif
 431 extern char **environ;
 432 unset_TZ ()
 433 {
 434   char **from, **to;
 435   for (to = from = environ; (*to = *from); from++)
 436     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 437       to++;
 438 }
 439 char TZ_GMT0[] = "TZ=GMT0";
 440 char TZ_PST8[] = "TZ=PST8";
 441 main()
 442 {
 443   time_t now = time ((time_t *) 0);
 444   int hour_GMT0, hour_unset;
 445   if (putenv (TZ_GMT0) != 0)
 446     exit (1);
 447   hour_GMT0 = localtime (&now)->tm_hour;
 448   unset_TZ ();
 449   hour_unset = localtime (&now)->tm_hour;
 450   if (putenv (TZ_PST8) != 0)
 451     exit (1);
 452   if (localtime (&now)->tm_hour == hour_GMT0)
 453     exit (1);
 454   unset_TZ ();
 455   if (localtime (&now)->tm_hour != hour_unset)
 456     exit (1);
 457   exit (0);
 458 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 459 [# If we have tzset, assume the worst when cross-compiling.
 460 guile_cv_localtime_cache=yes])
 461 else
 462         # If we lack tzset, report that localtime does not cache TZ,
 463         # since we can't invalidate the cache if we don't have tzset.
 464         guile_cv_localtime_cache=no
 465 fi])dnl
 466 AC_MSG_RESULT($guile_cv_localtime_cache)
 467 if test $guile_cv_localtime_cache = yes; then
 468   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 469 fi
 470
 471 dnl Test whether system calls are restartable by default on the
 472 dnl current system.  If they are not, we put a loop around every system
 473 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 474 dnl change from the default behaviour.  On the other hand, if signals
 475 dnl are restartable then the loop is not installed and when libguile
 476 dnl initialises it also resets the behaviour of each signal to cause a
 477 dnl restart (in case a different runtime had a different default
 478 dnl behaviour for some reason: e.g., different versions of linux seem
 479 dnl to behave differently.)
 480
 481 AC_SYS_RESTARTABLE_SYSCALLS
 482
 483 if test "$enable_regex" = yes; then
 484    if test "$ac_cv_header_regex_h" = yes ||
 485       test "$ac_cv_header_rxposix_h" = yes ||
 486       test "$ac_cv_header_rx_rxposix_h" = yes; then
 487      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 488      [AC_CHECK_LIB(rx, main)
 489       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 490      [AC_CHECK_LIB(regex, main)
 491       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 492      )
 493      dnl The following should not be necessary, but for some reason
 494      dnl autoheader misses it if we don't include it!
 495      if test "$ac_cv_func_regcomp_norx" = yes ||
 496         test "$ac_cv_func_regcomp_regex" = yes ||
 497         test "$ac_cv_func_regcomp_rx" = yes; then
 498        AC_DEFINE(HAVE_REGCOMP, 1,
 499          [This is included as part of a workaround for a autoheader bug.])
 500      fi
 501    fi
 502 fi
 503
 504 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 505
 506 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 507
 508 AC_CHECK_FUNCS(finite isinf isnan)
 509
 510 # When testing for the presence of alloca, we need to add alloca.o
 511 # explicitly to LIBOBJS to make sure that it is translated to
 512 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 513 AC_FUNC_ALLOCA
 514 if test "$ALLOCA" = "alloca.o"; then AC_LIBOBJ([alloca]); fi
 515
 516 AC_CHECK_MEMBERS([struct stat.st_rdev])
 517 AC_CHECK_MEMBERS([struct stat.st_blksize])
 518
 519 AC_STRUCT_ST_BLOCKS
 520
 521 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 522   [AC_TRY_CPP([#include <sys/stat.h>
 523                #ifndef S_ISLNK
 524                #error no S_ISLNK
 525                #endif],
 526                ac_cv_macro_S_ISLNK=yes,
 527                ac_cv_macro_S_ISLNK=no)])
 528 if test $ac_cv_macro_S_ISLNK = yes; then
 529   AC_DEFINE(HAVE_S_ISLNK, 1,
 530     [Define this if your system defines S_ISLNK in sys/stat.h.])
 531 fi
 532
 533 AC_STRUCT_TIMEZONE
 534 GUILE_STRUCT_UTIMBUF
 535
 536 #--------------------------------------------------------------------
 537 #
 538 # Which way does the stack grow?
 539 #
 540 #--------------------------------------------------------------------
 541
 542 AC_TRY_RUN(aux (l) unsigned long l;
 543              { int x; exit (l >= ((unsigned long)&x)); }
 544            main () { int q; aux((unsigned long)&q); },
 545            [AC_DEFINE([SCM_STACK_GROWS_UP], 1,
 546               [Define this if a callee's stack frame has a higher address
 547                than the caller's stack frame.  On most machines, this is
 548                not the case.])],
 549            [],
 550            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in)])
 551
 552 AH_TEMPLATE([SCM_SINGLES],
 553   [Define this if floats are the same size as longs.])
 554
 555 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 556     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 557                 [guile_cv_type_float_fits_long=yes],
 558                 [guile_cv_type_float_fits_long=no],
 559                 [guile_cv_type_float_fits_long=guess-yes])])
 560 case $guile_cv_type_float_fits_long in
 561   "yes" )
 562     AC_DEFINE(SCM_SINGLES)
 563   ;;
 564   "guess-yes" )
 565     AC_DEFINE(SCM_SINGLES)
 566     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 567     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 568   ;;
 569 esac
 570
 571
 572 AC_MSG_CHECKING(for struct linger)
 573 AC_CACHE_VAL(scm_cv_struct_linger,
 574         AC_TRY_COMPILE([
 575 #include <sys/types.h>
 576 #include <sys/socket.h>],
 577                         [struct linger lgr;  lgr.l_linger = 100],
 578                         scm_cv_struct_linger="yes",
 579                         scm_cv_struct_linger="no"))
 580 AC_MSG_RESULT($scm_cv_struct_linger)
 581 if test $scm_cv_struct_linger = yes; then
 582         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 583           [Define this if your system defines struct linger, for use with the
 584            getsockopt and setsockopt system calls.])
 585 fi
 586
 587
 588 AC_MSG_CHECKING(for struct timespec)
 589 AC_CACHE_VAL(scm_cv_struct_timespec,
 590         AC_TRY_COMPILE([
 591 #include <time.h>],
 592                         [struct timespec t;  t.tv_nsec = 100],
 593                         scm_cv_struct_timespec="yes",
 594                         scm_cv_struct_timespec="no"))
 595 AC_MSG_RESULT($scm_cv_struct_timespec)
 596 if test $scm_cv_struct_timespec = yes; then
 597   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 598     [Define this if your system defines struct timespec via <time.h>.])
 599 fi
 600
 601 #--------------------------------------------------------------------
 602 #
 603 # Flags for thread support
 604 #
 605 #--------------------------------------------------------------------
 606
 607 ### What thread package has the user asked for?
 608 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 609             , with_threads=no)
 610
 611 ### Turn $with_threads into either the name of a threads package, like
 612 ### `qt', or `no', meaning that threads should not be supported.
 613 AC_MSG_CHECKING(whether to support threads)
 614 case "$with_threads" in
 615   "yes" | "qt" | "coop" | "")
 616     with_threads=qt
 617   ;;
 618   "no" )
 619   ;;
 620   * )
 621     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 622   ;;
 623 esac
 624 AC_MSG_RESULT($with_threads)
 625
 626 ## Make sure the threads package we've chosen is actually supported on
 627 ## the present platform.
 628 case "${with_threads}" in
 629   "qt" )
 630     ## This configures the QuickThreads package, and sets or clears
 631     ## the THREAD_PACKAGE variable if qthreads don't configure
 632     ## correctly.
 633     QTHREADS_CONFIGURE
 634    ;;
 635 esac
 636
 637 ## If we're using threads, bring in some other parts of Guile which
 638 ## work with them.
 639 if test "${THREAD_PACKAGE}" != "" ; then
 640   AC_DEFINE(USE_THREADS, 1, [Define if using any sort of threads.])
 641
 642   ## Include the Guile thread interface in the library...
 643   AC_LIBOBJ([threads])
 644
 645   ## ... and tell it which package to talk to.
 646   case "${THREAD_PACKAGE}" in
 647     "QT" )
 648       AC_DEFINE(USE_COOP_THREADS, 1,
 649         [Define if using cooperative multithreading.])
 650     ;;
 651     * )
 652       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 653     ;;
 654   esac
 655
 656   ## Bring in scm_internal_select, if appropriate.
 657   if test $ac_cv_func_gettimeofday = yes &&
 658      test $ac_cv_func_select = yes; then
 659     AC_DEFINE(GUILE_ISELECT, 1, [Define to implement scm_internal_select.])
 660   fi
 661
 662   AC_ARG_ENABLE(linuxthreads,
 663   [  --disable-linuxthreads  disable linuxthreads workaround],,
 664   enable_linuxthreads=yes)
 665
 666   ## Workaround for linuxthreads (optionally disabled)
 667   if test $host_os = linux-gnu -a "$enable_linuxthreads" = yes; then
 668     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1,
 669       [Define to enable workaround for COOP-linuxthreads compatibility.])
 670     AC_CHECK_LIB(pthread, main)
 671   fi
 672 fi
 673
 674 ## If we're using GCC, ask for aggressive warnings.
 675 case "$GCC" in
 676   yes )
 677     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 678     ## much stuff with generic function pointers for that to really be
 679     ## less than exasperating.
 680     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 681     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 682     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 683 esac
 684
 685 AC_PROG_AWK
 686
 687 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
 688 ## -- I'm disabling it for now in the hopes that the newer autoconf
 689 ## will DTRT -- if not, we need to fix up the sed command to match the
 690 ## others...
 691 ##
 692 ## Remove fileblocks.o from the object list.  This file gets added by
 693 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
 694 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
 695
 696 ## If we're creating a shared library (using libtool!), then we'll
 697 ## need to generate a list of .lo files corresponding to the .o files
 698 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 699 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
 700
 701 ## We also need to create corresponding .doc and .x files
 702 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
 703 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
 704
 705 AC_SUBST(GUILE_MAJOR_VERSION)
 706 AC_SUBST(GUILE_MINOR_VERSION)
 707 AC_SUBST(GUILE_MICRO_VERSION)
 708 AC_SUBST(GUILE_VERSION)
 709
 710 #######################################################################
 711 # library versioning
 712
 713 AC_SUBST(LIBQTHREADS_INTERFACE_CURRENT)
 714 AC_SUBST(LIBQTHREADS_INTERFACE_REVISION)
 715 AC_SUBST(LIBQTHREADS_INTERFACE_AGE)
 716 AC_SUBST(LIBQTHREADS_INTERFACE)
 717
 718 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
 719 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
 720 AC_SUBST(LIBGUILE_INTERFACE_AGE)
 721 AC_SUBST(LIBGUILE_INTERFACE)
 722
 723 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
 724 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
 725 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
 726 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
 727
 728 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
 729 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
 730 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
 731 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
 732
 733 #######################################################################
 734
 735 dnl Tell guile-config what flags guile users should link against.
 736 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 737 AC_SUBST(GUILE_LIBS)
 738
 739 AC_SUBST(AWK)
 740 AC_SUBST(LIBLOBJS)
 741 AC_SUBST(EXTRA_DOT_DOC_FILES)
 742 AC_SUBST(EXTRA_DOT_X_FILES)
 743
 744 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
 745 top_builddir_absolute=`pwd`
 746 AC_SUBST(top_builddir_absolute)
 747 top_srcdir_absolute=`(cd $srcdir ; pwd)`
 748 AC_SUBST(top_srcdir_absolute)
 749
 750 AC_CONFIG_FILES([
 751   Makefile
 752   am/Makefile
 753   libguile/Makefile
 754   libguile/guile-snarf
 755   libguile/guile-doc-snarf
 756   libguile/guile-func-name-check
 757   libguile/guile-snarf-docs
 758   libguile/version.h
 759   ice-9/Makefile
 760   lang/Makefile
 761   lang/elisp/Makefile
 762   lang/elisp/internals/Makefile
 763   lang/elisp/primitives/Makefile
 764   oop/Makefile
 765   oop/goops/Makefile
 766   scripts/Makefile
 767   srfi/Makefile
 768   qt/Makefile
 769   qt/qt.h
 770   qt/md/Makefile
 771   qt/time/Makefile
 772   guile-config/Makefile
 773   doc/Makefile
 774   doc/ref/Makefile
 775   doc/tutorial/Makefile
 776   doc/goops/Makefile
 777   doc/r5rs/Makefile
 778   examples/Makefile
 779   examples/scripts/Makefile
 780   examples/box/Makefile
 781   examples/box-module/Makefile
 782   examples/box-dynamic/Makefile
 783   examples/box-dynamic-module/Makefile
 784   examples/modules/Makefile
 785   examples/safe/Makefile
 786   test-suite/Makefile
 787   check-guile
 788   guile-tools
 789   pre-inst-guile])
 790
 791 AC_CONFIG_COMMANDS(default,
 792   [ chmod +x libguile/guile-snarf \
 793              libguile/guile-doc-snarf \
 794              libguile/guile-func-name-check \
 795              libguile/guile-snarf-docs \
 796              check-guile \
 797              guile-tools \
 798              pre-inst-guile])
 799
 800 AC_OUTPUT
 801
 802 dnl Local Variables:
 803 dnl comment-start: "dnl "
 804 dnl comment-end: ""
 805 dnl comment-start-skip: "\\bdnl\\b\\s *"
 806 dnl End: