configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   8   2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   9
  10 This file is part of GUILE
  11
  12 GUILE is free software; you can redistribute it and/or modify it under
  13 the terms of the GNU Lesser General Public License as published by the
  14 Free Software Foundation; either version 3, or (at your option) any
  15 later version.
  16
  17 GUILE is distributed in the hope that it will be useful, but WITHOUT
  18 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  19 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  20 License for more details.
  21
  22 You should have received a copy of the GNU Lesser General Public
  23 License along with GUILE; see the file COPYING.LESSER.  If not, write
  24 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  25 Floor, Boston, MA 02110-1301, USA.
  26
  27 ]])
  28
  29 AC_PREREQ(2.61)
  30
  31 AC_INIT([GNU Guile],
  32         m4_esyscmd([build-aux/git-version-gen                                   \
  33           .tarball-version                                                      \
  34           's/^release_\([0-9][0-9]*\)-\([0-9][0-9]*\)-\([0-9][0-9]*\)/v\1.\2\.\3/g']),
  35         [bug-guile@gnu.org])
  36 AC_CONFIG_AUX_DIR([build-aux])
  37 AC_CONFIG_MACRO_DIR([m4])
  38 AC_CONFIG_SRCDIR(GUILE-VERSION)
  39
  40 AM_INIT_AUTOMAKE([gnu no-define -Wall -Wno-override])
  41 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  42
  43 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  44 AC_CONFIG_SRCDIR([GUILE-VERSION])
  45
  46 . $srcdir/GUILE-VERSION
  47 GUILE_VERSION="$PACKAGE_VERSION"
  48
  49 AC_CONFIG_HEADERS([config.h])
  50 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  51
  52 #--------------------------------------------------------------------
  53
  54 AC_LANG([C])
  55
  56 dnl Some more checks for Win32
  57 AC_CANONICAL_HOST
  58
  59 AC_LIBTOOL_WIN32_DLL
  60
  61 AC_PROG_INSTALL
  62 AC_PROG_CC
  63 gl_EARLY
  64 AC_PROG_CPP
  65 AC_PROG_SED
  66 AC_PROG_AWK
  67
  68 dnl Gnulib.
  69 gl_INIT
  70
  71 AC_PROG_CC_C89
  72
  73 # for per-target cflags in the libguile subdir
  74 AM_PROG_CC_C_O
  75
  76 AC_LIBTOOL_DLOPEN
  77 AC_PROG_LIBTOOL
  78
  79 AM_CONDITIONAL([HAVE_SHARED_LIBRARIES], [test "x$enable_shared" = "xyes"])
  80
  81 AC_DEFINE_UNQUOTED([SHARED_LIBRARY_PATH_VARIABLE], ["$shlibpath_var"],
  82   [Name of the environment variable that tells the dynamic linker where
  83 to find shared libraries.])
  84
  85 dnl Check for libltdl.
  86 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  87   [lt_dlopenext ("foo");])
  88 if test "x$HAVE_LIBLTDL" != "xyes"; then
  89   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
  90 fi
  91
  92 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  93 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  94
  95 AM_PATH_LISPDIR
  96
  97 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
  98   [Define to the host's GNU triplet.])
  99
 100 #--------------------------------------------------------------------
 101 #
 102 # User options (after above tests that may set default CFLAGS etc.)
 103 #
 104 #--------------------------------------------------------------------
 105
 106 GUILE_ERROR_ON_WARNING="no"
 107
 108 AC_ARG_ENABLE(error-on-warning,
 109   [  --enable-error-on-warning    treat compile warnings as errors],
 110   [case "${enableval}" in
 111      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 112      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 113      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 114    esac])
 115
 116 AC_ARG_ENABLE(debug-malloc,
 117   [  --enable-debug-malloc   include malloc debugging code],
 118   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 119     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 120       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 121   fi)
 122
 123 SCM_I_GSC_GUILE_DEBUG=0
 124 AC_ARG_ENABLE(guile-debug,
 125   [AS_HELP_STRING([--enable-guile-debug],
 126                   [include internal debugging functions])],
 127   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 128     SCM_I_GSC_GUILE_DEBUG=1
 129   fi)
 130
 131 AC_ARG_ENABLE(posix,
 132   [  --disable-posix         omit posix interfaces],,
 133   enable_posix=yes)
 134
 135 AC_ARG_ENABLE(networking,
 136   [  --disable-networking    omit networking interfaces],,
 137   enable_networking=yes)
 138
 139 AC_ARG_ENABLE(regex,
 140   [  --disable-regex         omit regular expression interfaces],,
 141   enable_regex=yes)
 142
 143 AC_ARG_ENABLE([deprecated],
 144   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 145
 146 if test "$enable_deprecated" = no; then
 147   SCM_I_GSC_ENABLE_DEPRECATED=0
 148   warn_default=no
 149 else
 150   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 151     warn_default=summary
 152   elif test "$enable_deprecated" = shutup; then
 153     warn_default=no
 154   else
 155     warn_default=$enable_deprecated
 156   fi
 157   SCM_I_GSC_ENABLE_DEPRECATED=1
 158 fi
 159 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 160 [Define this to control the default warning level for deprecated features.])
 161
 162 dnl  Added the following configure option in January 2008 following
 163 dnl  investigation of problems with "64" system and library calls on
 164 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 165 dnl  system has stat64, it will have all the other 64 APIs too; but on
 166 dnl  Darwin, stat64 is there but other APIs are missing.
 167 dnl
 168 dnl  It also appears, from the Darwin docs, that most system call APIs
 169 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 170 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 171 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 172 dnl
 173 dnl  A similar problem has been reported for HP-UX:
 174 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 175 dnl
 176 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 177 dnl  better than no Guile at all, we provide this option to suppress
 178 dnl  trying to use "64" calls.
 179 dnl
 180 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 181 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 182 dnl  missing out on that.  If so, someone can work on that in the future.
 183 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 184 dnl  wasn't building before.
 185 AC_MSG_CHECKING([whether to use system and library "64" calls])
 186 AC_ARG_WITH([64-calls],
 187   AS_HELP_STRING([--without-64-calls],
 188                  [don't attempt to use system and library calls with "64" in their names]),
 189   [use_64_calls=$withval],
 190   [use_64_calls=yes
 191    case $host in
 192      *-apple-darwin* )
 193        use_64_calls=no
 194        ;;
 195      powerpc-ibm-aix* )
 196        use_64_calls=no
 197        ;;
 198    esac])
 199 AC_MSG_RESULT($use_64_calls)
 200 case "$use_64_calls" in
 201   y* )
 202     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 203       [Define to 1 in order to try to use "64" versions of system and library calls.])
 204     ;;
 205 esac
 206
 207 #--------------------------------------------------------------------
 208
 209 dnl Check for dynamic linking
 210
 211 use_modules=yes
 212 AC_ARG_WITH(modules,
 213 [  --with-modules[=FILES]  Add support for dynamic modules],
 214 use_modules="$withval")
 215 test -z "$use_modules" && use_modules=yes
 216 DLPREOPEN=
 217 if test "$use_modules" != no; then
 218   if test "$use_modules" = yes; then
 219     DLPREOPEN="-dlpreopen force"
 220   else
 221     DLPREOPEN="-export-dynamic"
 222     for module in $use_modules; do
 223       DLPREOPEN="$DLPREOPEN -dlopen $module"
 224     done
 225   fi
 226 fi
 227
 228 dnl files which are destined for separate modules.
 229
 230 if test "$use_modules" != no; then
 231    AC_LIBOBJ([dynl])
 232 fi
 233
 234 if test "$enable_posix" = yes; then
 235    AC_LIBOBJ([filesys])
 236    AC_LIBOBJ([posix])
 237    AC_DEFINE([HAVE_POSIX], 1,
 238      [Define this if you want support for POSIX system calls in Guile.])
 239 fi
 240
 241 if test "$enable_networking" = yes; then
 242    AC_LIBOBJ([net_db])
 243    AC_LIBOBJ([socket])
 244    AC_DEFINE([HAVE_NETWORKING], 1,
 245      [Define this if you want support for networking in Guile.])
 246 fi
 247
 248 if test "$enable_debug_malloc" = yes; then
 249    AC_LIBOBJ([debug-malloc])
 250 fi
 251
 252 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 253
 254 AC_C_CONST
 255
 256 # "volatile" is used in a couple of tests below.
 257 AC_C_VOLATILE
 258
 259 AC_C_INLINE
 260 if test "$ac_cv_c_inline" != no; then
 261   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 262 else
 263   SCM_I_GSC_C_INLINE=NULL
 264 fi
 265 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 266
 267 AC_C_BIGENDIAN
 268
 269 AC_C_LABELS_AS_VALUES
 270
 271 AC_CHECK_SIZEOF(char)
 272 AC_CHECK_SIZEOF(unsigned char)
 273 AC_CHECK_SIZEOF(short)
 274 AC_CHECK_SIZEOF(unsigned short)
 275 AC_CHECK_SIZEOF(int)
 276 AC_CHECK_SIZEOF(unsigned int)
 277 AC_CHECK_SIZEOF(long)
 278 AC_CHECK_SIZEOF(unsigned long)
 279 AC_CHECK_SIZEOF(size_t)
 280 AC_CHECK_SIZEOF(long long)
 281 AC_CHECK_SIZEOF(unsigned long long)
 282 AC_CHECK_SIZEOF(__int64)
 283 AC_CHECK_SIZEOF(unsigned __int64)
 284 AC_CHECK_SIZEOF(void *)
 285 AC_CHECK_SIZEOF(intptr_t)
 286 AC_CHECK_SIZEOF(uintptr_t)
 287 AC_CHECK_SIZEOF(ptrdiff_t)
 288 AC_CHECK_SIZEOF(size_t)
 289 AC_CHECK_SIZEOF(off_t)
 290
 291 if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then
 292   AC_MSG_ERROR(long does not fit into a void*)
 293 fi
 294
 295 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 296   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 297 else
 298   SCM_I_GSC_T_PTRDIFF='"long"'
 299 fi
 300 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 301
 302 AC_CHECK_HEADERS([stdint.h])
 303 AC_CHECK_HEADERS([inttypes.h])
 304
 305 AC_CHECK_SIZEOF(intmax_t)
 306
 307 SCM_I_GSC_NEEDS_STDINT_H=0
 308 SCM_I_GSC_NEEDS_INTTYPES_H=0
 309
 310 ### intptr and uintptr (try not to use inttypes if we don't have to)
 311 if test "$ac_cv_header_inttypes_h" = yes; then
 312   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 313     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 314 #include <stdio.h>])
 315     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 316       SCM_I_GSC_NEEDS_INTTYPES_H=1
 317     fi
 318   fi
 319   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 320     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 321 #include <stdio.h>])
 322     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 323       SCM_I_GSC_NEEDS_INTTYPES_H=1
 324     fi
 325   fi
 326 fi
 327
 328 ### See what's provided by stdint.h
 329 if test "$ac_cv_header_stdint_h" = yes; then
 330    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 331    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 332    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 333    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 334    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 335    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 336    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 337    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 338    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 339    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 340    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 341    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 342 fi
 343
 344 # so we don't get confused by the cache (wish there was a better way
 345 # to check particular headers for the same type...)
 346
 347 unset ac_cv_type_int8_t
 348 unset ac_cv_type_uint8_t
 349 unset ac_cv_type_int16_t
 350 unset ac_cv_type_uint16_t
 351 unset ac_cv_type_int32_t
 352 unset ac_cv_type_uint32_t
 353 unset ac_cv_type_int64_t
 354 unset ac_cv_type_uint64_t
 355 unset ac_cv_type_intmax_t
 356 unset ac_cv_type_uintmax_t
 357
 358 ### See what's provided by inttypes.h
 359 if test "$ac_cv_header_inttypes_h" = yes; then
 360   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 361   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 362   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 363   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 364   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 365   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 366   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 367   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 368   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 369   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 370   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 371   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 372 fi
 373
 374 # Try hard to find definitions for some required scm_t_*int* types.
 375
 376 ### Required type scm_t_int8
 377 if test "$scm_stdint_has_int8"; then
 378   SCM_I_GSC_T_INT8='"int8_t"'
 379   SCM_I_GSC_NEEDS_STDINT_H=1
 380 elif test "$scm_inttypes_has_int8"; then
 381   SCM_I_GSC_T_INT8='"int8_t"'
 382   SCM_I_GSC_NEEDS_INTTYPES_H=1
 383 elif test "$ac_cv_sizeof_char" -eq 1; then
 384   SCM_I_GSC_T_INT8='"signed char"'
 385 else
 386   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 387 fi
 388 AC_SUBST([SCM_I_GSC_T_INT8])
 389
 390 ### Required type scm_t_uint8
 391 if test "$scm_stdint_has_uint8"; then
 392   SCM_I_GSC_T_UINT8='"uint8_t"'
 393   SCM_I_GSC_NEEDS_STDINT_H=1
 394 elif test "$scm_inttypes_has_uint8"; then
 395   SCM_I_GSC_T_UINT8='"uint8_t"'
 396   SCM_I_GSC_NEEDS_INTTYPES_H=1
 397 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 398   SCM_I_GSC_T_UINT8='"unsigned char"'
 399 else
 400   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 401 fi
 402 AC_SUBST([SCM_I_GSC_T_UINT8])
 403
 404 ### Required type scm_t_int16 (ANSI C says int or short might work)
 405 if test "$scm_stdint_has_int16"; then
 406   SCM_I_GSC_T_INT16='"int16_t"'
 407   SCM_I_GSC_NEEDS_STDINT_H=1
 408 elif test "$scm_inttypes_has_int16"; then
 409   SCM_I_GSC_T_INT16='"int16_t"'
 410   SCM_I_GSC_NEEDS_INTTYPES_H=1
 411 elif test "$ac_cv_sizeof_int" -eq 2; then
 412   SCM_I_GSC_T_INT16='"int"'
 413 elif test "$ac_cv_sizeof_short" -eq 2; then
 414   SCM_I_GSC_T_INT16='"short"'
 415 else
 416   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 417 fi
 418 AC_SUBST([SCM_I_GSC_T_INT16])
 419
 420 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 421 if test "$scm_stdint_has_uint16"; then
 422   SCM_I_GSC_T_UINT16='"uint16_t"'
 423   SCM_I_GSC_NEEDS_STDINT_H=1
 424 elif test "$scm_inttypes_has_uint16"; then
 425   SCM_I_GSC_T_UINT16='"uint16_t"'
 426   SCM_I_GSC_NEEDS_INTTYPES_H=1
 427 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 428   SCM_I_GSC_T_UINT16='"unsigned int"'
 429 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 430   SCM_I_GSC_T_UINT16='"unsigned short"'
 431 else
 432   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 433 fi
 434 AC_SUBST([SCM_I_GSC_T_UINT16])
 435
 436
 437 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 438 if test "$scm_stdint_has_int32"; then
 439   SCM_I_GSC_T_INT32='"int32_t"'
 440   SCM_I_GSC_NEEDS_STDINT_H=1
 441 elif test "$scm_inttypes_has_int32"; then
 442   SCM_I_GSC_T_INT32='"int32_t"'
 443   SCM_I_GSC_NEEDS_INTTYPES_H=1
 444 elif test "$ac_cv_sizeof_int" -eq 4; then
 445   SCM_I_GSC_T_INT32='"int"'
 446 elif test "$ac_cv_sizeof_long" -eq 4; then
 447   SCM_I_GSC_T_INT32='"long"'
 448 elif test "$ac_cv_sizeof_short" -eq 4; then
 449   SCM_I_GSC_T_INT32='"short"'
 450 else
 451   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 452 fi
 453 AC_SUBST([SCM_I_GSC_T_INT32])
 454
 455 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 456 if test "$scm_stdint_has_uint32"; then
 457   SCM_I_GSC_T_UINT32='"uint32_t"'
 458   SCM_I_GSC_NEEDS_STDINT_H=1
 459 elif test "$scm_inttypes_has_uint32"; then
 460   SCM_I_GSC_T_UINT32='"uint32_t"'
 461   SCM_I_GSC_NEEDS_INTTYPES_H=1
 462 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 463   SCM_I_GSC_T_UINT32='"unsigned int"'
 464 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 465   SCM_I_GSC_T_UINT32='"unsigned long"'
 466 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 467   SCM_I_GSC_T_UINT32='"unsigned short"'
 468 else
 469   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 470 fi
 471 AC_SUBST([SCM_I_GSC_T_UINT32])
 472
 473 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 474 ### Also try 'long long' and '__int64' if we have it.
 475 SCM_I_GSC_T_INT64=0
 476 if test "$scm_stdint_has_int64"; then
 477   SCM_I_GSC_T_INT64='"int64_t"'
 478   SCM_I_GSC_NEEDS_STDINT_H=1
 479 elif test "$scm_inttypes_has_int64"; then
 480   SCM_I_GSC_T_INT64='"int64_t"'
 481   SCM_I_GSC_NEEDS_INTTYPES_H=1
 482 elif test "$ac_cv_sizeof_int" -eq 8; then
 483   SCM_I_GSC_T_INT64='"int"'
 484 elif test "$ac_cv_sizeof_long" -eq 8; then
 485   SCM_I_GSC_T_INT64='"long"'
 486 elif test "$ac_cv_sizeof_short" -eq 8; then
 487   SCM_I_GSC_T_INT64='"short"'
 488 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 489   SCM_I_GSC_T_INT64='"long long"'
 490 elif test "$ac_cv_sizeof___int64" -eq 8; then
 491   SCM_I_GSC_T_INT64='"__int64"'
 492 else
 493   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 494 fi
 495 AC_SUBST([SCM_I_GSC_T_INT64])
 496
 497
 498 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 499 ### Also try 'long long' and '__int64' if we have it.
 500 SCM_I_GSC_T_UINT64=0
 501 if test "$scm_stdint_has_uint64"; then
 502   SCM_I_GSC_T_UINT64='"uint64_t"'
 503   SCM_I_GSC_NEEDS_STDINT_H=1
 504 elif test "$scm_inttypes_has_uint64"; then
 505   SCM_I_GSC_T_UINT64='"uint64_t"'
 506   SCM_I_GSC_NEEDS_INTTYPES_H=1
 507 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 508   SCM_I_GSC_T_UINT64='"unsigned int"'
 509 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 510   SCM_I_GSC_T_UINT64='"unsigned long"'
 511 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 512   SCM_I_GSC_T_UINT64='"unsigned short"'
 513 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 514   SCM_I_GSC_T_UINT64='"unsigned long long"'
 515 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 516   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 517 else
 518   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 519 fi
 520 AC_SUBST([SCM_I_GSC_T_UINT64])
 521
 522 ### Required type scm_t_intmax
 523 ###
 524 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 525 ### none of them is available, we use 'long'.
 526 ###
 527 SCM_I_GSC_T_INTMAX=0
 528 if test "$scm_stdint_has_intmax"; then
 529   SCM_I_GSC_T_INTMAX='"intmax_t"'
 530   SCM_I_GSC_NEEDS_STDINT_H=1
 531 elif test "$scm_inttypes_has_intmax"; then
 532   SCM_I_GSC_T_INTMAX='"intmax_t"'
 533   SCM_I_GSC_NEEDS_INTTYPES_H=1
 534 elif test "$ac_cv_sizeof___int64" -ne 0; then
 535   SCM_I_GSC_T_INTMAX='"__int64"'
 536 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 537   SCM_I_GSC_T_INTMAX='"long long"'
 538 else
 539   SCM_I_GSC_T_INTMAX='"long"'
 540 fi
 541 AC_SUBST([SCM_I_GSC_T_INTMAX])
 542
 543 ### Required type scm_t_uintmax
 544 ###
 545 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 546 ### this order.  When none of them is available, we use 'unsigned long'.
 547 ###
 548 SCM_I_GSC_T_UINTMAX=0
 549 if test "$scm_stdint_has_uintmax"; then
 550   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 551   SCM_I_GSC_NEEDS_STDINT_H=1
 552 elif test "$scm_inttypes_has_uintmax"; then
 553   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 554   SCM_I_GSC_NEEDS_INTTYPES_H=1
 555 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 556   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 557 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 558   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 559 else
 560   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 561 fi
 562 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 563
 564 ### Required type scm_t_intptr
 565 ###
 566 SCM_I_GSC_T_INTPTR=0
 567 if test "$scm_stdint_has_intptr"; then
 568   SCM_I_GSC_T_INTPTR='"intptr_t"'
 569   SCM_I_GSC_NEEDS_STDINT_H=1
 570 elif test "$scm_inttypes_has_intptr"; then
 571   SCM_I_GSC_T_INTPTR='"intptr_t"'
 572   SCM_I_GSC_NEEDS_INTTYPES_H=1
 573 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 574   SCM_I_GSC_T_INTPTR='"int"'
 575 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 576   SCM_I_GSC_T_INTPTR='"long"'
 577 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 578   SCM_I_GSC_T_INTPTR='"long long"'
 579 else
 580   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 581 fi
 582 AC_SUBST([SCM_I_GSC_T_INTPTR])
 583
 584 ### Required type scm_t_uintptr
 585 ###
 586 SCM_I_GSC_T_UINTPTR=0
 587 if test "$scm_stdint_has_uintptr"; then
 588   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 589   SCM_I_GSC_NEEDS_STDINT_H=1
 590 elif test "$scm_inttypes_has_uintptr"; then
 591   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 592   SCM_I_GSC_NEEDS_INTTYPES_H=1
 593 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 594   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 595 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 596   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 597 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 598   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 599 else
 600   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 601 fi
 602 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 603
 604
 605 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 606 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 607
 608 AC_HEADER_STDC
 609 AC_HEADER_TIME
 610 AC_HEADER_SYS_WAIT
 611 AC_HEADER_DIRENT
 612
 613 # Reason for checking:
 614 #
 615 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 616 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 617 #
 618 AC_CHECK_MEMBER([struct dirent64.d_name],
 619   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 620   [ #ifndef _LARGEFILE64_SOURCE
 621     # define _LARGEFILE64_SOURCE
 622     #endif
 623
 624     /* Per Autoconf manual.  */
 625     #include <sys/types.h>
 626     #ifdef HAVE_DIRENT_H
 627     # include <dirent.h>
 628     #else
 629     # define dirent direct
 630     # ifdef HAVE_SYS_NDIR_H
 631     #  include <sys/ndir.h>
 632     # endif
 633     # ifdef HAVE_SYS_DIR_H
 634     #  include <sys/dir.h>
 635     # endif
 636     # ifdef HAVE_NDIR_H
 637     #  include <ndir.h>
 638     # endif
 639     #endif ])
 640 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 641
 642 # Reasons for testing:
 643 #   complex.h - new in C99
 644 #   fenv.h - available in C99, but not older systems
 645 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 646 #     this file instead of <fenv.h>
 647 #   process.h - mingw specific
 648 #   langinfo.h, nl_types.h - SuS v2
 649 #
 650 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 651 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 652 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 653 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 654 direct.h langinfo.h nl_types.h machine/fpu.h poll.h])
 655
 656 # Reasons for testing:
 657 #   nl_item - lacking on Cygwin
 658 AC_CHECK_TYPES([nl_item], [], [],
 659   [[#ifdef HAVE_LANGINFO_H
 660     # include <langinfo.h>
 661     #endif
 662     #ifdef HAVE_NL_TYPES_H
 663     # include <nl_types.h>
 664     #endif]])
 665
 666 # "complex double" is new in C99, and "complex" is only a keyword if
 667 # <complex.h> is included
 668 AC_CHECK_TYPES(complex double,,,
 669 [#if HAVE_COMPLEX_H
 670 #include <complex.h>
 671 #endif])
 672
 673 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 674 # when testing.
 675 AC_CHECK_TYPE(socklen_t, ,
 676   [AC_DEFINE_UNQUOTED([socklen_t], int,
 677                       [Define to `int' if <sys/socket.h> does not define.])],
 678   [#if HAVE_SYS_TYPES_H
 679 #include <sys/types.h>
 680 #endif
 681 #include <sys/socket.h>
 682 ])
 683
 684 AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>])
 685
 686 GUILE_HEADER_LIBC_WITH_UNISTD
 687
 688 AC_TYPE_GETGROUPS
 689 AC_TYPE_SIGNAL
 690 AC_TYPE_MODE_T
 691
 692 # On mingw -lm is empty, so this test is unnecessary, but it's
 693 # harmless so we don't hard-code to suppress it.
 694 #
 695 AC_CHECK_LIB(m, cos)
 696
 697 AC_CHECK_FUNCS(gethostbyname)
 698 if test $ac_cv_func_gethostbyname = no; then
 699     AC_CHECK_LIB(nsl, gethostbyname)
 700 fi
 701
 702 AC_CHECK_FUNCS(connect)
 703 if test $ac_cv_func_connect = no; then
 704     AC_CHECK_LIB(socket, connect)
 705 fi
 706
 707 dnl
 708 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 709 dnl
 710 EXTRA_DEFS=""
 711 case $host in
 712   *-*-mingw*)
 713     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 714       [Define if you have the <winsock2.h> header file.])])
 715     AC_CHECK_LIB(ws2_32, main)
 716     AC_LIBOBJ([win32-uname])
 717     AC_LIBOBJ([win32-dirent])
 718     if test "$enable_networking" = yes ; then
 719       AC_LIBOBJ([win32-socket])
 720     fi
 721     if test "$enable_shared" = yes ; then
 722       EXTRA_DEFS="-DSCM_IMPORT"
 723       AC_DEFINE([USE_DLL_IMPORT], 1,
 724         [Define if you need additional CPP macros on Win32 platforms.])
 725     fi
 726     ;;
 727 esac
 728 AC_SUBST(EXTRA_DEFS)
 729
 730 # Reasons for testing:
 731 #   crt_externs.h - Darwin specific
 732 #
 733 AC_CHECK_HEADERS([assert.h crt_externs.h])
 734
 735 # Reasons for testing:
 736 #   DINFINITY - OSF specific
 737 #   DQNAN - OSF specific
 738 #       (DINFINITY and DQNAN are actually global variables, not functions)
 739 #   chsize - an MS-DOS-ism, found in mingw
 740 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 741 #       for gcc to provide the "complex double" type but the system to not
 742 #       have functions like cexp and clog
 743 #   clog10 - not in mingw (though others like clog and csqrt are)
 744 #   fesetround - available in C99, but not older systems
 745 #   ftruncate - posix, but probably not older systems (current mingw
 746 #               has it as an inline for chsize)
 747 #   ioctl - not in mingw.
 748 #   gmtime_r - recent posix, not on old systems
 749 #   pipe - not in mingw
 750 #   _pipe - specific to mingw, taking 3 args
 751 #   poll - since posix 2001
 752 #   readdir_r - recent posix, not on old systems
 753 #   readdir64_r - not available on HP-UX 11.11
 754 #   stat64 - SuS largefile stuff, not on old systems
 755 #   sysconf - not on old systems
 756 #   truncate - not in mingw
 757 #   isblank - available as a GNU extension or in C99
 758 #   _NSGetEnviron - Darwin specific
 759 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 760 #   nl_langinfo - X/Open, not available on Windows.
 761 #   utimensat: posix.1-2008
 762 #   sched_getaffinity, sched_setaffinity: GNU extensions (glibc)
 763 #
 764 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe poll readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat sched_getaffinity sched_setaffinity])
 765
 766 # Reasons for testing:
 767 #   netdb.h - not in mingw
 768 #   sys/param.h - not in mingw
 769 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 770 #       check this specifically, we need it for the timespec test below.
 771 #   sethostname - the function itself check because it's not in mingw,
 772 #       the DECL is checked because Solaris 10 doens't have in any header
 773 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 774 #       declaration isn't anywhere.
 775 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 776 #       only with `_XOPEN_SOURCE' or some such.
 777 #
 778 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h])
 779 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 780 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 781
 782 # crypt() may or may not be available, for instance in some countries there
 783 # are restrictions on cryptography.
 784 #
 785 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 786 # -lcrypt library (eg. Debian GNU/Linux).
 787 #
 788 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 789 # be careful to avoid -lcrypt in this case, since libtool will see there's
 790 # only a static libcrypt and decide to build only a static libguile.
 791 #
 792 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 793 # libraries already in that list.
 794 #
 795 AC_SEARCH_LIBS(crypt, crypt,
 796   [AC_DEFINE([HAVE_CRYPT],1,
 797              [Define to 1 if you have the `crypt' function.])])
 798
 799 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 800 # work; in the reported cases so far, 1.0fi works well instead.  According
 801 # to the C99 spec, the complex.h header must provide a working definition
 802 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 803 # is a workaround for the failure of some systems to conform to C99.
 804 if test "$ac_cv_type_complex_double" = yes; then
 805   AC_MSG_CHECKING([for i])
 806   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 807 #if HAVE_COMPLEX_H
 808 #include <complex.h>
 809 #endif
 810 complex double z;
 811 ]], [[
 812 z = _Complex_I;
 813 ]])],
 814     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 815      AC_MSG_RESULT([_Complex_I])],
 816     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 817 #if HAVE_COMPLEX_H
 818 #include <complex.h>
 819 #endif
 820 complex double z;
 821 ]],[[
 822 z = 1.0fi;
 823 ]])],
 824   [AC_DEFINE([GUILE_I],1.0fi)
 825    AC_MSG_RESULT([1.0fi])],
 826   [ac_cv_type_complex_double=no
 827    AC_MSG_RESULT([not available])])])
 828 fi
 829
 830 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 831 # csqrt(-i) returned a negative real part, when it should be positive
 832 # for the principal root.
 833 #
 834 if test "$ac_cv_type_complex_double" = yes; then
 835
 836   AC_CACHE_CHECK([whether csqrt is usable],
 837     guile_cv_use_csqrt,
 838     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 839 #include <complex.h>
 840 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 841    constant, we want to test libc. */
 842 volatile complex double z = - _Complex_I;
 843 int
 844 main (void)
 845 {
 846   z = csqrt (z);
 847   if (creal (z) > 0.0)
 848     return 0;  /* good */
 849   else
 850     return 1;  /* bad */
 851 }]])],
 852     [guile_cv_use_csqrt=yes],
 853     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 854     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 855   case $guile_cv_use_csqrt in
 856     yes*)
 857       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 858       ;;
 859   esac
 860 fi
 861
 862 AC_CACHE_SAVE
 863
 864 dnl GMP tests
 865 AC_LIB_HAVE_LINKFLAGS([gmp],
 866   [],
 867   [#include <gmp.h>],
 868   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 869
 870 if test "x$HAVE_LIBGMP" != "xyes"; then
 871   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 872 fi
 873
 874 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 875 if test "x$LTLIBUNISTRING" = "x"; then
 876   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 877 fi
 878
 879 dnl Libffi is needed to compile Guile's foreign function interface, but its
 880 dnl interface isn't exposed in Guile's API.
 881 PKG_CHECK_MODULES(LIBFFI, libffi)
 882 AC_SUBST(LIBFFI_CFLAGS)
 883 AC_SUBST(LIBFFI_LIBS)
 884
 885 dnl figure out approriate ffi type for size_t
 886 AC_CHECK_SIZEOF(size_t)
 887 AC_CHECK_SIZEOF(ssize_t)
 888 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 889 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 890 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 891                    [ffi type for size_t])
 892 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 893                    [ffi type for ssize_t])
 894
 895 dnl i18n tests
 896 #AC_CHECK_HEADERS([libintl.h])
 897 #AC_CHECK_FUNCS(gettext)
 898 #if test $ac_cv_func_gettext = no; then
 899 #   AC_CHECK_LIB(intl, gettext)
 900 #fi
 901 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 902 AM_GNU_GETTEXT([external], [need-ngettext])
 903
 904 ### Some systems don't declare some functions.  On such systems, we
 905 ### need to at least provide our own K&R-style declarations.
 906
 907 ### GUILE_FUNC_DECLARED(function, headerfile)
 908
 909 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 910 ### not there, #define MISSING_FUNCTION_DECL.
 911 AC_DEFUN([GUILE_FUNC_DECLARED], [
 912   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 913     AC_EGREP_HEADER($1, $2,
 914                     guile_cv_func_$1_declared=yes,
 915                     guile_cv_func_$1_declared=no))
 916   if test [x$guile_cv_func_]$1[_declared] = xno; then
 917     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 918       [Define if the operating system supplies $1 without declaring it.])
 919   fi
 920 ])
 921
 922 GUILE_FUNC_DECLARED(sleep, unistd.h)
 923 GUILE_FUNC_DECLARED(usleep, unistd.h)
 924
 925 AC_CHECK_DECLS([strptime],,,
 926 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 927 #include <time.h>])
 928
 929 ### On some systems usleep has no return value.  If it does have one,
 930 ### we'd like to return it; otherwise, we'll fake it.
 931 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 932   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 933                    unistd.h,
 934                    [guile_cv_func_usleep_return_type=void],
 935                    [guile_cv_func_usleep_return_type=int])])
 936 case "$guile_cv_func_usleep_return_type" in
 937   "void" )
 938     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 939       [Define if the system headers declare usleep to return void.])
 940   ;;
 941 esac
 942
 943 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 944 if test -n "$have_sys_un_h" ; then
 945   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 946     [Define if the system supports Unix-domain (file-domain) sockets.])
 947 fi
 948
 949 AC_CHECK_FUNCS(getrlimit setrlimit)
 950
 951 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 952
 953 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 954                setnetent    getnetent    endnetent    dnl
 955                setprotoent  getprotoent  endprotoent  dnl
 956                setservent   getservent   endservent   dnl
 957                getnetbyaddr getnetbyname dnl
 958                inet_lnaof inet_makeaddr inet_netof hstrerror)
 959
 960 AC_CHECK_MEMBERS([struct sockaddr_in.sin_len],,,
 961 [#ifdef HAVE_SYS_TYPES_H
 962 #include <sys/types.h>
 963 #endif
 964 #include <netinet/in.h>])
 965
 966 AC_MSG_CHECKING(for __libc_stack_end)
 967 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 968 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 969 extern char *__libc_stack_end;]],
 970    [[printf("%p", (char*) __libc_stack_end);]])],
 971    [guile_cv_have_libc_stack_end=yes],
 972    [guile_cv_have_libc_stack_end=no])])
 973 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 974
 975 if test $guile_cv_have_libc_stack_end = yes; then
 976   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 977            [Define if you have the __libc_stack_end variable.])
 978 fi
 979
 980 dnl Some systems do not declare this.  Some systems do declare it, as a
 981 dnl macro.  With cygwin it may be in a DLL.
 982
 983 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 984 AC_CACHE_VAL(guile_cv_have_h_errno,
 985   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 986                                       [[int a = h_errno;]])],
 987   [guile_cv_have_h_errno=yes],
 988   [guile_cv_have_h_errno=no])])
 989 AC_MSG_RESULT($guile_cv_have_h_errno)
 990 if test $guile_cv_have_h_errno = yes; then
 991   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
 992 fi
 993
 994 AC_MSG_CHECKING(whether uint32_t is defined)
 995 AC_CACHE_VAL(guile_cv_have_uint32_t,
 996   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 997                    #if HAVE_STDINT_H
 998                    #include <stdint.h>
 999                    #endif
1000                    #ifndef HAVE_NETDB_H
1001                    #include <netdb.h>
1002                    #endif]],
1003                    [[uint32_t a;]])],
1004                    [guile_cv_have_uint32_t=yes],
1005                    [guile_cv_have_uint32_t=no])])
1006 AC_MSG_RESULT($guile_cv_have_uint32_t)
1007 if test $guile_cv_have_uint32_t = yes; then
1008   AC_DEFINE([HAVE_UINT32_T], 1,
1009     [Define if uint32_t typedef is defined when netdb.h is include.])
1010 fi
1011
1012 AC_MSG_CHECKING(for working IPv6 support)
1013 AC_CACHE_VAL(guile_cv_have_ipv6,
1014 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1015 #ifdef HAVE_SYS_TYPES_H
1016 #include <sys/types.h>
1017 #endif
1018 #include <netinet/in.h>
1019 #include <sys/socket.h>]],
1020 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1021 [guile_cv_have_ipv6=yes],
1022 [guile_cv_have_ipv6=no])])
1023 AC_MSG_RESULT($guile_cv_have_ipv6)
1024 if test $guile_cv_have_ipv6 = yes; then
1025   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1026 fi
1027
1028 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1029 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1030 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1031 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1032 #ifdef HAVE_SYS_TYPES_H
1033 #include <sys/types.h>
1034 #endif
1035 #include <netinet/in.h>]],
1036 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1037 [guile_cv_have_sin6_scope_id=yes],
1038 [guile_cv_have_sin6_scope_id=no])])
1039 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1040 if test $guile_cv_have_sin6_scope_id = yes; then
1041   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1042     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1043 fi
1044
1045 # struct sockaddr_in6 field sin_len is only present on BSD systems
1046 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1047 [#ifdef HAVE_SYS_TYPES_H
1048 #include <sys/types.h>
1049 #endif
1050 #include <netinet/in.h>])
1051
1052 AC_MSG_CHECKING(whether localtime caches TZ)
1053 AC_CACHE_VAL(guile_cv_localtime_cache,
1054 [if test x$ac_cv_func_tzset = xyes; then
1055 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1056 #if STDC_HEADERS
1057 # include <stdlib.h>
1058 #endif
1059 extern char **environ;
1060 unset_TZ ()
1061 {
1062   char **from, **to;
1063   for (to = from = environ; (*to = *from); from++)
1064     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1065       to++;
1066 }
1067 char TZ_GMT0[] = "TZ=GMT0";
1068 char TZ_PST8[] = "TZ=PST8";
1069 main()
1070 {
1071   time_t now = time ((time_t *) 0);
1072   int hour_GMT0, hour_unset;
1073   if (putenv (TZ_GMT0) != 0)
1074     exit (1);
1075   hour_GMT0 = localtime (&now)->tm_hour;
1076   unset_TZ ();
1077   hour_unset = localtime (&now)->tm_hour;
1078   if (putenv (TZ_PST8) != 0)
1079     exit (1);
1080   if (localtime (&now)->tm_hour == hour_GMT0)
1081     exit (1);
1082   unset_TZ ();
1083   if (localtime (&now)->tm_hour != hour_unset)
1084     exit (1);
1085   exit (0);
1086 }]])],
1087 [guile_cv_localtime_cache=no],
1088 [guile_cv_localtime_cache=yes],
1089 [# If we have tzset, assume the worst when cross-compiling.
1090 guile_cv_localtime_cache=yes])
1091 else
1092         # If we lack tzset, report that localtime does not cache TZ,
1093         # since we can't invalidate the cache if we don't have tzset.
1094         guile_cv_localtime_cache=no
1095 fi])dnl
1096 AC_MSG_RESULT($guile_cv_localtime_cache)
1097 if test $guile_cv_localtime_cache = yes; then
1098   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1099 fi
1100
1101 if test "$enable_regex" = yes; then
1102    if test "$ac_cv_header_regex_h" = yes ||
1103       test "$ac_cv_header_rxposix_h" = yes ||
1104       test "$ac_cv_header_rx_rxposix_h" = yes; then
1105      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1106      [AC_CHECK_LIB(rx, main)
1107       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1108      [AC_CHECK_LIB(regex, main)
1109       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1110      )
1111      dnl The following should not be necessary, but for some reason
1112      dnl autoheader misses it if we don't include it!
1113      if test "$ac_cv_func_regcomp_norx" = yes ||
1114         test "$ac_cv_func_regcomp_regex" = yes ||
1115         test "$ac_cv_func_regcomp_rx" = yes; then
1116        AC_DEFINE([HAVE_REGCOMP], 1,
1117          [This is included as part of a workaround for a autoheader bug.])
1118      fi
1119    fi
1120 fi
1121
1122 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1123
1124 # Reasons for testing:
1125 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1126 #                                older systems
1127 #   sincos - GLIBC extension
1128 #
1129 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1130
1131 # C99 specifies isinf and isnan as macros.
1132 # HP-UX provides only macros, no functions.
1133 # glibc 2.3.2 provides both macros and functions.
1134 # IRIX 6.5 and Solaris 8 only provide functions.
1135 #
1136 # The following tests detect isinf and isnan either as functions or as
1137 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1138 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1139 #
1140 AC_MSG_CHECKING([for isinf])
1141 AC_LINK_IFELSE(AC_LANG_SOURCE(
1142 [[#include <math.h>
1143 volatile double x = 0.0;
1144 int main () { return (isinf(x) != 0); }]]),
1145   [AC_MSG_RESULT([yes])
1146    AC_DEFINE([HAVE_ISINF], 1,
1147              [Define to 1 if you have the `isinf' macro or function.])],
1148   [AC_MSG_RESULT([no])])
1149 AC_MSG_CHECKING([for isnan])
1150 AC_LINK_IFELSE(AC_LANG_SOURCE(
1151 [[#include <math.h>
1152 volatile double x = 0.0;
1153 int main () { return (isnan(x) != 0); }]]),
1154   [AC_MSG_RESULT([yes])
1155    AC_DEFINE([HAVE_ISNAN], 1,
1156              [Define to 1 if you have the `isnan' macro or function.])],
1157   [AC_MSG_RESULT([no])])
1158
1159 # Reasons for checking:
1160 #
1161 #     st_rdev
1162 #     st_blksize
1163 #     st_blocks   not in mingw
1164 #     tm_gmtoff   BSD+GNU, not in C99
1165 #
1166 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1167 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1168 #
1169 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1170                  [#define _GNU_SOURCE
1171 AC_INCLUDES_DEFAULT
1172 ])
1173
1174 AC_STRUCT_TIMEZONE
1175 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1176 [#include <time.h>
1177 #ifdef TIME_WITH_SYS_TIME
1178 # include <sys/time.h>
1179 # include <time.h>
1180 #else
1181 # if HAVE_SYS_TIME_H
1182 #  include <sys/time.h>
1183 # else
1184 #  include <time.h>
1185 # endif
1186 #endif
1187 ])
1188 GUILE_STRUCT_UTIMBUF
1189
1190
1191 #--------------------------------------------------------------------
1192 #
1193 # Which way does the stack grow?
1194 #
1195 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1196 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1197 # very similar code, so in future we could look at using that.
1198 #
1199 # An important detail is that the code involves find_stack_direction
1200 # calling _itself_ - which means that find_stack_direction (or at
1201 # least the second find_stack_direction() call) cannot be inlined.
1202 # If the code could be inlined, that might cause the test to give
1203 # an incorrect answer.
1204 #--------------------------------------------------------------------
1205
1206 SCM_I_GSC_STACK_GROWS_UP=0
1207 AC_RUN_IFELSE([AC_LANG_SOURCE(
1208 [AC_INCLUDES_DEFAULT
1209 int
1210 find_stack_direction ()
1211 {
1212   static char *addr = 0;
1213   auto char dummy;
1214   if (addr == 0)
1215     {
1216       addr = &dummy;
1217       return find_stack_direction ();
1218     }
1219   else
1220     return (&dummy > addr) ? 1 : -1;
1221 }
1222
1223 int
1224 main ()
1225 {
1226   return find_stack_direction () < 0;
1227 }])],
1228                [SCM_I_GSC_STACK_GROWS_UP=1],
1229                [],
1230                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1231
1232 #--------------------------------------------------------------------
1233 #
1234 # Boehm's GC library
1235 #
1236 #--------------------------------------------------------------------
1237 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1238
1239 save_LIBS="$LIBS"
1240 LIBS="$BDW_GC_LIBS $LIBS"
1241 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1242
1243 AC_CHECK_FUNCS([GC_do_blocking GC_call_with_gc_active])
1244
1245 # Though the `GC_do_blocking ()' symbol is present in GC 7.1, it is not
1246 # declared, and has a different type (returning void instead of
1247 # void*).
1248 AC_CHECK_DECL([GC_do_blocking],
1249   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1250     [Define this if the `GC_do_blocking ()' function is declared])],
1251   [],
1252   [#include <gc/gc.h>])
1253
1254 # `GC_fn_type' is not available in GC 7.1 and earlier.
1255 AC_CHECK_TYPE([GC_fn_type],
1256   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1257     [Define this if the `GC_fn_type' type is available.])],
1258   [],
1259   [#include <gc/gc.h>])
1260
1261 LIBS="$save_LIBS"
1262
1263
1264 AC_CHECK_SIZEOF(float)
1265 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1266     AC_DEFINE([SCM_SINGLES], 1,
1267               [Define this if floats are the same size as longs.])
1268 fi
1269
1270 AC_MSG_CHECKING(for struct linger)
1271 AC_CACHE_VAL(scm_cv_struct_linger,
1272         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1273 #include <sys/types.h>
1274 #include <sys/socket.h>]],
1275                           [[struct linger lgr;  lgr.l_linger = 100]])],
1276                           [scm_cv_struct_linger="yes"],
1277                           [scm_cv_struct_linger="no"]))
1278 AC_MSG_RESULT($scm_cv_struct_linger)
1279 if test $scm_cv_struct_linger = yes; then
1280         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1281           [Define this if your system defines struct linger, for use with the
1282            getsockopt and setsockopt system calls.])
1283 fi
1284
1285
1286 # On mingw, struct timespec is in <pthread.h>.
1287 #
1288 AC_MSG_CHECKING(for struct timespec)
1289 AC_CACHE_VAL(scm_cv_struct_timespec,
1290         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1291 #include <time.h>
1292 #if HAVE_PTHREAD_H
1293 #include <pthread.h>
1294 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1295           [scm_cv_struct_timespec="yes"],
1296           [scm_cv_struct_timespec="no"]))
1297 AC_MSG_RESULT($scm_cv_struct_timespec)
1298 if test $scm_cv_struct_timespec = yes; then
1299   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1300     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1301 fi
1302
1303 #--------------------------------------------------------------------
1304 #
1305 # Flags for thread support
1306 #
1307 #--------------------------------------------------------------------
1308
1309 SCM_I_GSC_USE_PTHREAD_THREADS=0
1310 SCM_I_GSC_USE_NULL_THREADS=0
1311 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1312 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1313
1314 ### What thread package has the user asked for?
1315 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1316             , with_threads=yes)
1317
1318 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1319 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1320
1321 case "$with_threads" in
1322   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1323
1324     build_pthread_support="yes"
1325
1326     ACX_PTHREAD([CC="$PTHREAD_CC"
1327        LIBS="$PTHREAD_LIBS $LIBS"
1328        SCM_I_GSC_USE_PTHREAD_THREADS=1
1329        with_threads="pthreads"],
1330       [with_threads="null"
1331        build_pthread_support="no"])
1332
1333     old_CFLAGS="$CFLAGS"
1334     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1335
1336     # Reasons for testing:
1337     #     pthread_getattr_np - "np" meaning "non portable" says it
1338     #         all; not present on MacOS X or Solaris 10
1339     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1340     #         all; specific to MacOS X
1341     #     pthread_sigmask - not available on mingw
1342     #
1343     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1344
1345     # On past versions of Solaris, believe 8 through 10 at least, you
1346     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1347     # This is contrary to POSIX:
1348     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1349     # Check here if this style is required.
1350     #
1351     # glibc (2.3.6 at least) works both with or without braces, so the
1352     # test checks whether it works without.
1353     #
1354
1355     if test "$GCC" = "yes"; then
1356       # Since GCC only issues a warning for missing braces, so we need
1357       # `-Werror' to catch it.
1358       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1359     fi
1360
1361     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1362       guile_cv_need_braces_on_pthread_once_init,
1363       [AC_COMPILE_IFELSE([#include <pthread.h>
1364          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1365         [guile_cv_need_braces_on_pthread_once_init=no],
1366         [guile_cv_need_braces_on_pthread_once_init=yes])])
1367     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1368       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1369     fi
1370
1371     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1372     # 6.5.30m with GCC 3.3.
1373     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1374       guile_cv_need_braces_on_pthread_mutex_initializer,
1375       [AC_COMPILE_IFELSE([#include <pthread.h>
1376          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1377         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1378         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1379     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1380       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1381     fi
1382
1383     CFLAGS="$old_CFLAGS"
1384
1385     # On Solaris, sched_yield lives in -lrt.
1386     AC_SEARCH_LIBS(sched_yield, rt)
1387
1388   ;;
1389 esac
1390
1391 case "$with_threads" in
1392   "pthreads")
1393   ;;
1394   "no" | "null")
1395     SCM_I_GSC_USE_NULL_THREADS=1
1396     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1397     with_threads="null-threads"
1398   ;;
1399   * )
1400     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1401   ;;
1402 esac
1403
1404 AC_MSG_CHECKING(what kind of threads to support)
1405 AC_MSG_RESULT($with_threads)
1406
1407 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1408   [test "x$build_pthread_support" = "xyes"])
1409
1410
1411 ## Check whether pthread_attr_getstack works for the main thread
1412
1413 if test "$with_threads" = pthreads; then
1414
1415 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1416 old_CFLAGS="$CFLAGS"
1417 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1418 if test "$cross_compiling" = "no"; then
1419   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1420   #if HAVE_PTHREAD_ATTR_GETSTACK
1421   #include <pthread.h>
1422
1423   int main ()
1424   {
1425     pthread_attr_t attr;
1426     void *start, *end;
1427     size_t size;
1428
1429     pthread_getattr_np (pthread_self (), &attr);
1430     pthread_attr_getstack (&attr, &start, &size);
1431     end = (char *)start + size;
1432
1433     if ((void *)&attr < start || (void *)&attr >= end)
1434       return 1;
1435     else
1436       return 0;
1437   }
1438   #else
1439   int main ()
1440   {
1441     return 1;
1442   }
1443   #endif
1444   ]])],
1445   [works=yes
1446    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1447   [works=no],
1448   [])
1449 else
1450   works="assuming it doesn't"
1451 fi
1452 CFLAGS="$old_CFLAGS"
1453 AC_MSG_RESULT($works)
1454
1455 GUILE_THREAD_LOCAL_STORAGE
1456
1457 fi # with_threads=pthreads
1458
1459
1460 ## Cross building
1461 if test "$cross_compiling" = "yes"; then
1462   AC_MSG_CHECKING(cc for build)
1463   ## /usr/bin/cc still uses wrong assembler
1464   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1465   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1466 else
1467   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1468 fi
1469
1470 ## AC_MSG_CHECKING("if we are cross compiling")
1471 ## AC_MSG_RESULT($cross_compiling)
1472 if test "$cross_compiling" = "yes"; then
1473    AC_MSG_RESULT($CC_FOR_BUILD)
1474 fi
1475
1476 ## No need as yet to be more elaborate
1477 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1478
1479 AC_SUBST(cross_compiling)
1480 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1481 AC_SUBST(CCLD_FOR_BUILD)
1482
1483 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1484 ## --HOST is the platform that PACKAGE is compiled for.
1485 HOST_CC="$CC_FOR_BUILD"
1486 AC_SUBST(HOST_CC)
1487
1488 if test "$cross_compiling" = "yes"; then
1489   AC_MSG_CHECKING(guile for build)
1490   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1491 else
1492   GUILE_FOR_BUILD='$(preinstguile)'
1493 fi
1494
1495 ## AC_MSG_CHECKING("if we are cross compiling")
1496 ## AC_MSG_RESULT($cross_compiling)
1497 if test "$cross_compiling" = "yes"; then
1498    AC_MSG_RESULT($GUILE_FOR_BUILD)
1499 fi
1500 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1501 AC_SUBST(GUILE_FOR_BUILD)
1502
1503 ## If we're using GCC, ask for aggressive warnings.
1504 GCC_CFLAGS=""
1505 case "$GCC" in
1506   yes )
1507     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1508     ## much stuff with generic function pointers for that to really be
1509     ## less than exasperating.
1510     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1511     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1512     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1513       -Wdeclaration-after-statement -Wundef \
1514       -Wswitch-enum"
1515     # Do this here so we don't screw up any of the tests above that might
1516     # not be "warning free"
1517     if test "${GUILE_ERROR_ON_WARNING}" = yes
1518     then
1519         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1520         enable_compile_warnings=no
1521     fi
1522
1523     for flag in $POTENTIAL_GCC_CFLAGS
1524     do
1525         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1526     done
1527     ;;
1528 esac
1529
1530 AC_SUBST(GCC_CFLAGS)
1531
1532 # Check for GNU ld's "-z relro".
1533 GUILE_GNU_LD_RELRO
1534
1535
1536 ## If we're creating a shared library (using libtool!), then we'll
1537 ## need to generate a list of .lo files corresponding to the .o files
1538 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1539 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1540
1541 ## We also need to create corresponding .doc and .x files
1542 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1543 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1544
1545 # GNU Readline bindings.
1546 GUILE_READLINE
1547
1548 AC_SUBST(GUILE_MAJOR_VERSION)
1549 AC_SUBST(GUILE_MINOR_VERSION)
1550 AC_SUBST(GUILE_MICRO_VERSION)
1551 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1552 AC_SUBST(GUILE_VERSION)
1553
1554 #######################################################################
1555 # library versioning
1556
1557 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1558 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1559 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1560 AC_SUBST(LIBGUILE_INTERFACE)
1561
1562 AC_SUBST(LIBGUILE_I18N_MAJOR)
1563 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1564 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1565 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1566 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1567
1568
1569 #######################################################################
1570
1571 dnl Tell guile-config what flags guile users should compile and link with.
1572 GUILE_LIBS="$LDFLAGS $LIBS"
1573 GUILE_CFLAGS="$CPPFLAGS $PTHREAD_CFLAGS"
1574 AC_SUBST(GUILE_LIBS)
1575 AC_SUBST(GUILE_CFLAGS)
1576
1577 AC_SUBST(AWK)
1578 AC_SUBST(LIBLOBJS)
1579 AC_SUBST(EXTRA_DOT_DOC_FILES)
1580 AC_SUBST(EXTRA_DOT_X_FILES)
1581
1582 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1583 top_builddir_absolute=`pwd`
1584 AC_SUBST(top_builddir_absolute)
1585 top_srcdir_absolute=`(cd $srcdir && pwd)`
1586 AC_SUBST(top_srcdir_absolute)
1587
1588 dnl `sitedir' goes into libpath.h and the pkg-config file.
1589 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1590 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1591 AC_SUBST([sitedir])
1592
1593 # Additional SCM_I_GSC definitions are above.
1594 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1595 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1596 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1597 AC_SUBST([SCM_I_GSC_C_INLINE])
1598 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1599
1600 AC_CONFIG_FILES([
1601   Makefile
1602   am/Makefile
1603   lib/Makefile
1604   benchmark-suite/Makefile
1605   doc/Makefile
1606   doc/r5rs/Makefile
1607   doc/ref/Makefile
1608   emacs/Makefile
1609   examples/Makefile
1610   libguile/Makefile
1611   libguile/version.h
1612   guile-readline/Makefile
1613   test-suite/Makefile
1614   test-suite/standalone/Makefile
1615   test-suite/vm/Makefile
1616   meta/Makefile
1617   module/Makefile
1618 ])
1619
1620 AC_CONFIG_FILES([meta/guile-2.0.pc])
1621 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1622 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1623
1624 GUILE_CONFIG_SCRIPT([check-guile])
1625 GUILE_CONFIG_SCRIPT([benchmark-guile])
1626 GUILE_CONFIG_SCRIPT([meta/guile])
1627 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1628 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1629 GUILE_CONFIG_SCRIPT([meta/guile-tools])
1630 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1631 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1632 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1633 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1634
1635 AC_OUTPUT
1636
1637 dnl Local Variables:
1638 dnl comment-start: "dnl "
1639 dnl comment-end: ""
1640 dnl comment-start-skip: "\\bdnl\\b\\s *"
1641 dnl End: