configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 Boston, MA 02111-1307, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT
  31 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  32 AC_CONFIG_SRCDIR([GUILE-VERSION])
  33 . $srcdir/GUILE-VERSION
  34 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  35 AM_MAINTAINER_MODE
  36 AM_CONFIG_HEADER([config.h])
  37 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  38
  39 #--------------------------------------------------------------------
  40 #
  41 # Independent Subdirectories
  42 #
  43 #--------------------------------------------------------------------
  44
  45 AC_CONFIG_SUBDIRS(guile-readline)
  46
  47 #--------------------------------------------------------------------
  48
  49 dnl Some more checks for Win32
  50 AC_CYGWIN
  51 AC_MINGW32
  52 AC_LIBTOOL_WIN32_DLL
  53
  54 AC_PROG_INSTALL
  55 AC_PROG_CC
  56 AC_PROG_CPP
  57 AC_PROG_AWK
  58
  59 AC_AIX
  60 AC_ISC_POSIX
  61 AC_MINIX
  62
  63 AM_PROG_CC_STDC
  64
  65 AC_LIBTOOL_DLOPEN
  66 AC_PROG_LIBTOOL
  67 AC_LIB_LTDL
  68
  69 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  70 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  71
  72 AM_PATH_LISPDIR
  73
  74 #--------------------------------------------------------------------
  75 #
  76 # User options (after above tests that may set default CFLAGS etc.)
  77 #
  78 #--------------------------------------------------------------------
  79
  80 GUILE_ERROR_ON_WARNING="yes"
  81
  82 AC_ARG_ENABLE(error-on-warning,
  83   [  --enable-error-on-warning    treat compile warnings as errors],
  84   [case "${enableval}" in
  85      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  86      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  87      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  88    esac])
  89
  90 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
  91 AC_ARG_ENABLE(debug-freelist,
  92   [  --enable-debug-freelist include garbage collector freelist debugging code],
  93   if test "$enable_debug_freelist" = y \
  94      || test "$enable_debug_freelist" = yes; then
  95     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
  96   fi)
  97
  98 AC_ARG_ENABLE(debug-malloc,
  99   [  --enable-debug-malloc   include malloc debugging code],
 100   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 101     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 102       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 103   fi)
 104
 105 SCM_I_GSC_GUILE_DEBUG=0
 106 AC_ARG_ENABLE(guile-debug,
 107   [AC_HELP_STRING([--enable-guile-debug],
 108                   [include internal debugging functions])],
 109   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 110     SCM_I_GSC_GUILE_DEBUG=1
 111   fi)
 112
 113 AC_ARG_ENABLE(arrays,
 114   [AC_HELP_STRING([--disable-arrays],[omit array and uniform array support])],
 115   ,
 116   enable_arrays=yes)
 117
 118 AC_ARG_ENABLE(posix,
 119   [  --disable-posix         omit posix interfaces],,
 120   enable_posix=yes)
 121
 122 AC_ARG_ENABLE(networking,
 123   [  --disable-networking    omit networking interfaces],,
 124   enable_networking=yes)
 125
 126 AC_ARG_ENABLE(regex,
 127   [  --disable-regex         omit regular expression interfaces],,
 128   enable_regex=yes)
 129
 130 AC_ARG_ENABLE(htmldoc,
 131   [  --enable-htmldoc        build HTML documentation as well as Info],
 132   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
 133      htmldoc_enabled=yes
 134      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
 135      if test "$TEXI2HTML" = "not found"; then
 136        echo
 137        echo Building HTML documentation requires the \`texi2html\' program,
 138        echo which appears not to be present on your machine.
 139        echo
 140        echo \`texi2html\' is available from
 141        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
 142        echo
 143        echo In the meantime, to build the guile-doc distribution
 144        echo without HTML enabled, please rerun \`./configure\' without
 145        echo the \`--enable-htmldoc\' option.
 146        exit -1
 147      fi
 148    fi])
 149
 150 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
 151
 152 AC_ARG_ENABLE([deprecated],
 153   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 154
 155 if test "$enable_deprecated" = no; then
 156   SCM_I_GSC_ENABLE_DEPRECATED=0
 157 else
 158   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 159     warn_default=summary
 160   elif test "$enable_deprecated" = shutup; then
 161     warn_default=no
 162   else
 163     warn_default=$enable_deprecated
 164   fi
 165   SCM_I_GSC_ENABLE_DEPRECATED=1
 166   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 167   [Define this to control the default warning level for deprecated features.])
 168 fi
 169
 170 AC_ARG_ENABLE(elisp,
 171   [  --disable-elisp         omit Emacs Lisp support],,
 172   enable_elisp=yes)
 173
 174 #--------------------------------------------------------------------
 175
 176 dnl Check for dynamic linking
 177
 178 use_modules=yes
 179 AC_ARG_WITH(modules,
 180 [  --with-modules[=FILES]  Add support for dynamic modules],
 181 use_modules="$withval")
 182 test -z "$use_modules" && use_modules=yes
 183 DLPREOPEN=
 184 if test "$use_modules" != no; then
 185   if test "$use_modules" = yes; then
 186     DLPREOPEN="-dlpreopen force"
 187   else
 188     DLPREOPEN="-export-dynamic"
 189     for module in $use_modules; do
 190       DLPREOPEN="$DLPREOPEN -dlopen $module"
 191     done
 192   fi
 193 fi
 194
 195 dnl files which are destined for separate modules.
 196
 197 if test "$use_modules" != no; then
 198    AC_LIBOBJ([dynl])
 199 fi
 200
 201 SCM_I_GSC_HAVE_ARRAYS=0
 202 if test "$enable_arrays" = yes; then
 203    AC_LIBOBJ([ramap])
 204    AC_LIBOBJ([unif])
 205    SCM_I_GSC_HAVE_ARRAYS=1
 206 fi
 207
 208 if test "$enable_posix" = yes; then
 209    AC_LIBOBJ([filesys])
 210    AC_LIBOBJ([posix])
 211    AC_DEFINE(HAVE_POSIX, 1,
 212      [Define this if you want support for POSIX system calls in Guile.])
 213 fi
 214
 215 if test "$enable_networking" = yes; then
 216    AC_LIBOBJ([net_db])
 217    AC_LIBOBJ([socket])
 218    AC_DEFINE(HAVE_NETWORKING, 1,
 219      [Define this if you want support for networking in Guile.])
 220 fi
 221
 222 if test "$enable_debug_malloc" = yes; then
 223    AC_LIBOBJ([debug-malloc])
 224 fi
 225
 226 if test "$enable_elisp" = yes; then
 227   SCM_I_GSC_ENABLE_ELISP=1
 228 else
 229   SCM_I_GSC_ENABLE_ELISP=0
 230 fi
 231
 232 AC_C_CONST
 233
 234 AC_C_INLINE
 235 if test "$ac_cv_c_inline" != no; then
 236   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 237 else
 238   SCM_I_GSC_C_INLINE=NULL
 239 fi
 240
 241 AC_C_BIGENDIAN
 242
 243 AC_CHECK_SIZEOF(char)
 244 AC_CHECK_SIZEOF(unsigned char)
 245 AC_CHECK_SIZEOF(short)
 246 AC_CHECK_SIZEOF(unsigned short)
 247 AC_CHECK_SIZEOF(int)
 248 AC_CHECK_SIZEOF(unsigned int)
 249 AC_CHECK_SIZEOF(long)
 250 AC_CHECK_SIZEOF(unsigned long)
 251 AC_CHECK_SIZEOF(size_t)
 252 AC_CHECK_SIZEOF(long long)
 253 AC_CHECK_SIZEOF(unsigned long long)
 254 AC_CHECK_SIZEOF(__int64)
 255 AC_CHECK_SIZEOF(unsigned __int64)
 256 AC_CHECK_SIZEOF(void *)
 257 AC_CHECK_SIZEOF(intptr_t)
 258 AC_CHECK_SIZEOF(uintptr_t)
 259 AC_CHECK_SIZEOF(ptrdiff_t)
 260
 261 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 262   AC_MSG_ERROR(sizes of long and void* are not identical)
 263 fi
 264
 265 if test "$ac_cv_sizeof_ptrdiff_t" -eq 0; then
 266   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 267 else
 268   SCM_I_GSC_T_PTRDIFF='"long"'
 269 fi
 270 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 271
 272 AC_CHECK_HEADERS([stdint.h])
 273 AC_CHECK_HEADERS([inttypes.h])
 274
 275 SCM_I_GSC_NEEDS_STDINT_H=0
 276 SCM_I_GSC_NEEDS_INTTYPES_H=0
 277
 278 ### intptr and uintptr (try not to use inttypes if we don't have to)
 279 if test "$ac_cv_header_inttypes_h" = yes; then
 280   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 281     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 282 #include <stdio.h>])
 283     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 284       SCM_I_GSC_NEEDS_INTTYPES_H=1
 285     fi
 286   fi
 287   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 288     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 289 #include <stdio.h>])
 290     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 291       SCM_I_GSC_NEEDS_INTTYPES_H=1
 292     fi
 293   fi
 294 fi
 295
 296 ### See what's provided by stdint.h
 297 if test "$ac_cv_header_stdint_h" = yes; then
 298    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 299    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 300    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 301    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 302    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 303    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 304    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 305    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 306    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 307    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 308 fi
 309
 310 # so we don't get confused by the cache (wish there was a better way
 311 # to check particular headers for the same type...)
 312
 313 unset ac_cv_type_int8_t
 314 unset ac_cv_type_uint8_t
 315 unset ac_cv_type_int16_t
 316 unset ac_cv_type_uint16_t
 317 unset ac_cv_type_int32_t
 318 unset ac_cv_type_uint32_t
 319 unset ac_cv_type_int64_t
 320 unset ac_cv_type_uint64_t
 321 unset ac_cv_type_intmax_t
 322 unset ac_cv_type_uintmax_t
 323
 324 ### See what's provided by inttypes.h
 325 if test "$ac_cv_header_inttypes_h" = yes; then
 326   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 327   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 328   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 329   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 330   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 331   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 332   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 333   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 334   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 335   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 336 fi
 337
 338 # Try hard to find definitions for some required scm_t_*int* types.
 339
 340 ### Required type scm_t_int8
 341 if test "$ac_cv_sizeof_char" -eq 1; then
 342   SCM_I_GSC_T_INT8='"char"'
 343 elif test "$scm_stdint_has_int8"; then
 344   SCM_I_GSC_T_INT8='"int8_t"'
 345   SCM_I_GSC_NEEDS_STDINT_H=1
 346 elif test "$scm_inttypes_has_int8"; then
 347   SCM_I_GSC_T_INT8='"int8_t"'
 348   SCM_I_GSC_NEEDS_INTTYPES_H=1
 349 else
 350   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 351 fi
 352 AC_SUBST([SCM_I_GSC_T_INT8])
 353
 354 ### Required type scm_t_uint8
 355 if test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 356   SCM_I_GSC_T_UINT8='"unsigned char"'
 357 elif test "$scm_stdint_has_uint8"; then
 358   SCM_I_GSC_T_UINT8='"uint8_t"'
 359   SCM_I_GSC_NEEDS_STDINT_H=1
 360 elif test "$scm_inttypes_has_uint8"; then
 361   SCM_I_GSC_T_UINT8='"uint8_t"'
 362   SCM_I_GSC_NEEDS_INTTYPES_H=1
 363 else
 364   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 365 fi
 366 AC_SUBST([SCM_I_GSC_T_UINT8])
 367
 368
 369 ### Required type scm_t_int16 (ANSI C says int or short might work)
 370 if test "$ac_cv_sizeof_int" -eq 2; then
 371   SCM_I_GSC_T_INT16='"int"'
 372 elif test "$ac_cv_sizeof_short" -eq 2; then
 373   SCM_I_GSC_T_INT16='"short"'
 374 elif test "$scm_stdint_has_int16"; then
 375   SCM_I_GSC_T_INT16='"int16_t"'
 376   SCM_I_GSC_NEEDS_STDINT_H=1
 377 elif test "$scm_inttypes_has_int16"; then
 378   SCM_I_GSC_T_INT16='"int16_t"'
 379   SCM_I_GSC_NEEDS_INTTYPES_H=1
 380 else
 381   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 382 fi
 383 AC_SUBST([SCM_I_GSC_T_INT16])
 384
 385 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 386 if test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 387   SCM_I_GSC_T_UINT16='"unsigned int"'
 388 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 389   SCM_I_GSC_T_UINT16='"unsigned short"'
 390 elif test "$scm_stdint_has_uint16"; then
 391   SCM_I_GSC_T_UINT16='"uint16_t"'
 392   SCM_I_GSC_NEEDS_STDINT_H=1
 393 elif test "$scm_inttypes_has_uint16"; then
 394   SCM_I_GSC_T_UINT16='"uint16_t"'
 395   SCM_I_GSC_NEEDS_INTTYPES_H=1
 396 else
 397   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 398 fi
 399 AC_SUBST([SCM_I_GSC_T_UINT16])
 400
 401
 402 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 403 if test "$ac_cv_sizeof_int" -eq 4; then
 404   SCM_I_GSC_T_INT32='"int"'
 405 elif test "$ac_cv_sizeof_long" -eq 4; then
 406   SCM_I_GSC_T_INT32='"long"'
 407 elif test "$ac_cv_sizeof_short" -eq 4; then
 408   SCM_I_GSC_T_INT32='"short"'
 409 elif test "$scm_stdint_has_int32"; then
 410   SCM_I_GSC_T_INT32='"int32_t"'
 411   SCM_I_GSC_NEEDS_STDINT_H=1
 412 elif test "$scm_inttypes_has_int32"; then
 413   SCM_I_GSC_T_INT32='"int32_t"'
 414   SCM_I_GSC_NEEDS_INTTYPES_H=1
 415 else
 416   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 417 fi
 418 AC_SUBST([SCM_I_GSC_T_INT32])
 419
 420 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 421 if test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 422   SCM_I_GSC_T_UINT32='"unsigned int"'
 423 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 424   SCM_I_GSC_T_UINT32='"unsigned long"'
 425 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 426   SCM_I_GSC_T_UINT32='"unsigned short"'
 427 elif test "$scm_stdint_has_uint32"; then
 428   SCM_I_GSC_T_UINT32='"uint32_t"'
 429   SCM_I_GSC_NEEDS_STDINT_H=1
 430 elif test "$scm_inttypes_has_uint32"; then
 431   SCM_I_GSC_T_UINT32='"uint32_t"'
 432   SCM_I_GSC_NEEDS_INTTYPES_H=1
 433 else
 434   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 435 fi
 436 AC_SUBST([SCM_I_GSC_T_UINT32])
 437
 438 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 439 ### Also try 'long long' and '__int64' if we have it.
 440 SCM_I_GSC_T_INT64=0
 441 if test "$ac_cv_sizeof_int" -eq 8; then
 442   SCM_I_GSC_T_INT64='"int"'
 443 elif test "$ac_cv_sizeof_long" -eq 8; then
 444   SCM_I_GSC_T_INT64='"long"'
 445 elif test "$ac_cv_sizeof_short" -eq 8; then
 446   SCM_I_GSC_T_INT64='"short"'
 447 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 448   SCM_I_GSC_T_INT64='"long long"'
 449 elif test "$ac_cv_sizeof___int64" -eq 8; then
 450   SCM_I_GSC_T_INT64='"__int64"'
 451 elif test "$scm_stdint_has_int64"; then
 452   SCM_I_GSC_T_INT64='"int64_t"'
 453   SCM_I_GSC_NEEDS_STDINT_H=1
 454 elif test "$scm_inttypes_has_int64"; then
 455   SCM_I_GSC_T_INT64='"int64_t"'
 456   SCM_I_GSC_NEEDS_INTTYPES_H=1
 457 else
 458   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 459 fi
 460 AC_SUBST([SCM_I_GSC_T_INT64])
 461
 462 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 463 ### Also try 'long long' and '__int64' if we have it.
 464 SCM_I_GSC_T_UINT64=0
 465 if test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 466   SCM_I_GSC_T_UINT64='"unsigned int"'
 467 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 468   SCM_I_GSC_T_UINT64='"unsigned long"'
 469 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 470   SCM_I_GSC_T_UINT64='"unsigned short"'
 471 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 472   SCM_I_GSC_T_UINT64='"unsigned long long"'
 473 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 474   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 475 elif test "$scm_stdint_has_uint64"; then
 476   SCM_I_GSC_T_UINT64='"uint64_t"'
 477   SCM_I_GSC_NEEDS_STDINT_H=1
 478 elif test "$scm_inttypes_has_uint64"; then
 479   SCM_I_GSC_T_UINT64='"uint64_t"'
 480   SCM_I_GSC_NEEDS_INTTYPES_H=1
 481 else
 482   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 483 fi
 484 AC_SUBST([SCM_I_GSC_T_UINT64])
 485
 486 ### Required type scm_t_intmax
 487 ###
 488 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 489 ### none of them is available, we use 'long'.
 490 ###
 491 SCM_I_GSC_T_INTMAX=0
 492 if test "$scm_stdint_has_intmax"; then
 493   SCM_I_GSC_T_INTMAX='"intmax_t"'
 494   SCM_I_GSC_NEEDS_STDINT_H=1
 495 elif test "$scm_inttypes_has_intmax"; then
 496   SCM_I_GSC_T_INTMAX='"intmax_t"'
 497   SCM_I_GSC_NEEDS_INTTYPES_H=1
 498 elif test "$ac_cv_sizeof___int64" -ne 0; then
 499   SCM_I_GSC_T_INTMAX='"__int64"'
 500 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 501   SCM_I_GSC_T_INTMAX='"long long"'
 502 else
 503   SCM_I_GSC_T_INTMAX='"long"'
 504 fi
 505 AC_SUBST([SCM_I_GSC_T_INTMAX])
 506
 507 ### Required type scm_t_uintmax
 508 ###
 509 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 510 ### this order.  When none of them is available, we use 'unsigned long'.
 511 ###
 512 SCM_I_GSC_T_UINTMAX=0
 513 if test "$scm_stdint_has_uintmax"; then
 514   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 515   SCM_I_GSC_NEEDS_STDINT_H=1
 516 elif test "$scm_inttypes_has_uintmax"; then
 517   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 518   SCM_I_GSC_NEEDS_INTTYPES_H=1
 519 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 520   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 521 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 522   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 523 else
 524   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 525 fi
 526 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 527
 528
 529 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 530 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 531
 532 AC_HEADER_STDC
 533 AC_HEADER_DIRENT
 534 AC_HEADER_TIME
 535 AC_HEADER_SYS_WAIT
 536
 537 # Reasons for testing:
 538 #   fenv.h - available in C99, but not older systems
 539 #
 540 AC_CHECK_HEADERS([fenv.h io.h libc.h limits.h malloc.h memory.h string.h \
 541 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 542 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 543 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 544 direct.h])
 545
 546 GUILE_HEADER_LIBC_WITH_UNISTD
 547
 548 AC_TYPE_GETGROUPS
 549 AC_TYPE_SIGNAL
 550 AC_TYPE_MODE_T
 551
 552 if test $MINGW32 = no; then
 553         AC_CHECK_LIB(m, main)
 554 fi
 555 AC_CHECK_FUNCS(gethostbyname)
 556 if test $ac_cv_func_gethostbyname = no; then
 557     AC_CHECK_LIB(nsl, gethostbyname)
 558 fi
 559
 560 AC_CHECK_FUNCS(connect)
 561 if test $ac_cv_func_connect = no; then
 562     AC_CHECK_LIB(socket, connect)
 563 fi
 564
 565 dnl
 566 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 567 dnl
 568 EXTRA_DEFS=""
 569 if test "$MINGW32" = "yes" ; then
 570     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 571       [Define if you have the <winsock2.h> header file.])])
 572     AC_CHECK_LIB(ws2_32, main)
 573     AC_LIBOBJ([win32-uname])
 574     AC_LIBOBJ([win32-dirent])
 575     if test "$enable_networking" = yes ; then
 576       AC_LIBOBJ([win32-socket])
 577     fi
 578     if test "$enable_shared" = yes ; then
 579       EXTRA_DEFS="-DSCM_IMPORT"
 580       AC_DEFINE(USE_DLL_IMPORT, 1,
 581         [Define if you need additional CPP macros on Win32 platforms.])
 582     fi
 583     if test x"$enable_ltdl_install" = x"yes" ; then
 584       INCLTDL="-DLIBLTDL_DLL_IMPORT $INCLTDL"
 585     fi
 586 fi
 587 AC_SUBST(EXTRA_DEFS)
 588
 589 # FIXME: check to see if we still need these.
 590 #AC_SUBST(INCLTDL)
 591 #AC_SUBST(LIBLTDL)
 592
 593 AC_SUBST(DLPREOPEN)
 594
 595 # Reasons for testing:
 596 #   crt_externs.h - Darwin specific
 597 #
 598 AC_CHECK_HEADERS([assert.h crt_externs.h])
 599
 600 # Reasons for testing:
 601 #   DINFINITY - OSF specific
 602 #   DQNAN - OSF specific
 603 #       (DINFINITY and DQNAN are actually global variables, not functions)
 604 #   fesetround - available in C99, but not older systems
 605 #   gmtime_r - recent posix, not on old systems
 606 #   readdir_r - recent posix, not on old systems
 607 #   sysconf - not on old systems
 608 #   _NSGetEnviron - Darwin specific
 609 #
 610 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid fesetround ftime fchown getcwd geteuid gettimeofday gmtime_r lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv _NSGetEnviron])
 611
 612 # Reasons for testing:
 613 #   netdb.h - not in mingw
 614 #   sys/param.h - not in mingw
 615 #
 616 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 617 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 618
 619 # crypt() may or may not be available, for instance in some countries there
 620 # are restrictions on cryptography.
 621 #
 622 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 623 # -lcrypt library (eg. Debian GNU/Linux).
 624 #
 625 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 626 # be careful to avoid -lcrypt in this case, since libtool will see there's
 627 # only a static libcrypt and decide to build only a static libguile.
 628 #
 629 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 630 # libraries already in that list.
 631 #
 632 AC_SEARCH_LIBS(crypt, crypt,
 633   [AC_DEFINE(HAVE_CRYPT,1,
 634              [Define to 1 if you have the `crypt' function.])])
 635
 636 dnl GMP tests
 637 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 638   [AC_MSG_ERROR([GNU MP not found, see http://swox.com/gmp])])
 639
 640 # mpz_import is a macro so we need to include <gmp.h>
 641 AC_TRY_LINK([#include <gmp.h>],
 642             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 643   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see http://swox.com/gmp])])
 644
 645 ### Some systems don't declare some functions.  On such systems, we
 646 ### need to at least provide our own K&R-style declarations.
 647
 648 ### GUILE_FUNC_DECLARED(function, headerfile)
 649
 650 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 651 ### not there, #define MISSING_FUNCTION_DECL.
 652 AC_DEFUN([GUILE_FUNC_DECLARED], [
 653   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 654     AC_EGREP_HEADER($1, $2,
 655                     guile_cv_func_$1_declared=yes,
 656                     guile_cv_func_$1_declared=no))
 657   if test [x$guile_cv_func_]$1[_declared] = xno; then
 658     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 659       [Define if the operating system supplies $1 without declaring it.])
 660   fi
 661 ])
 662
 663 GUILE_FUNC_DECLARED(sleep, unistd.h)
 664 GUILE_FUNC_DECLARED(usleep, unistd.h)
 665
 666 AC_CHECK_DECLS([strptime],,,
 667 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 668 #include <time.h>])
 669
 670 ### On some systems usleep has no return value.  If it does have one,
 671 ### we'd like to return it; otherwise, we'll fake it.
 672 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 673   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 674                    unistd.h,
 675                    [guile_cv_func_usleep_return_type=void],
 676                    [guile_cv_func_usleep_return_type=int])])
 677 case "$guile_cv_func_usleep_return_type" in
 678   "void" )
 679     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 680       [Define if the system headers declare usleep to return void.])
 681   ;;
 682 esac
 683
 684 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 685 if test -n "$have_sys_un_h" ; then
 686   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 687     [Define if the system supports Unix-domain (file-domain) sockets.])
 688 fi
 689
 690 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 691
 692 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 693                setnetent    getnetent    endnetent    dnl
 694                setprotoent  getprotoent  endprotoent  dnl
 695                setservent   getservent   endservent   dnl
 696                getnetbyaddr getnetbyname dnl
 697                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 698                inet_pton inet_ntop)
 699
 700 AC_MSG_CHECKING(for __libc_stack_end)
 701 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 702 [AC_TRY_LINK([#include <stdio.h>
 703 extern char *__libc_stack_end;],
 704              [printf("%p", (char*) __libc_stack_end);],
 705              guile_cv_have_libc_stack_end=yes,
 706              guile_cv_have_libc_stack_end=no)])
 707 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 708
 709 if test $guile_cv_have_libc_stack_end = yes; then
 710   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 711            [Define if you have the __libc_stack_end variable.])
 712 fi
 713
 714 dnl Some systems do not declare this.  Some systems do declare it, as a
 715 dnl macro.  With cygwin it may be in a DLL.
 716
 717 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 718 AC_CACHE_VAL(guile_cv_have_h_errno,
 719 [AC_TRY_COMPILE([#include <netdb.h>],
 720 [int a = h_errno;],
 721 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 722 AC_MSG_RESULT($guile_cv_have_h_errno)
 723 if test $guile_cv_have_h_errno = yes; then
 724   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 725 fi
 726
 727 AC_MSG_CHECKING(whether uint32_t is defined)
 728 AC_CACHE_VAL(guile_cv_have_uint32_t,
 729   [AC_TRY_COMPILE([#include <sys/types.h>
 730                    #if HAVE_STDINT_H
 731                    #include <stdint.h>
 732                    #endif
 733                    #ifndef __MINGW32__
 734                    #include <netdb.h>
 735                    #endif],
 736                   [uint32_t a;],
 737                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 738 AC_MSG_RESULT($guile_cv_have_uint32_t)
 739 if test $guile_cv_have_uint32_t = yes; then
 740   AC_DEFINE(HAVE_UINT32_T, 1,
 741     [Define if uint32_t typedef is defined when netdb.h is include.])
 742 fi
 743
 744 AC_MSG_CHECKING(for working IPv6 support)
 745 AC_CACHE_VAL(guile_cv_have_ipv6,
 746 [AC_TRY_COMPILE([
 747 #ifdef HAVE_SYS_TYPES_H
 748 #include <sys/types.h>
 749 #endif
 750 #include <netinet/in.h>
 751 #include <sys/socket.h>],
 752 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 753 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 754 AC_MSG_RESULT($guile_cv_have_ipv6)
 755 if test $guile_cv_have_ipv6 = yes; then
 756   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 757 fi
 758
 759 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 760 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 761 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 762 [AC_TRY_COMPILE([
 763 #ifdef HAVE_SYS_TYPES_H
 764 #include <sys/types.h>
 765 #endif
 766 #include <netinet/in.h>],
 767 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 768 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 769 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 770 if test $guile_cv_have_sin6_scope_id = yes; then
 771   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 772     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 773 fi
 774
 775 AC_MSG_CHECKING(whether localtime caches TZ)
 776 AC_CACHE_VAL(guile_cv_localtime_cache,
 777 [if test x$ac_cv_func_tzset = xyes; then
 778 AC_TRY_RUN([#include <time.h>
 779 #if STDC_HEADERS
 780 # include <stdlib.h>
 781 #endif
 782 extern char **environ;
 783 unset_TZ ()
 784 {
 785   char **from, **to;
 786   for (to = from = environ; (*to = *from); from++)
 787     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 788       to++;
 789 }
 790 char TZ_GMT0[] = "TZ=GMT0";
 791 char TZ_PST8[] = "TZ=PST8";
 792 main()
 793 {
 794   time_t now = time ((time_t *) 0);
 795   int hour_GMT0, hour_unset;
 796   if (putenv (TZ_GMT0) != 0)
 797     exit (1);
 798   hour_GMT0 = localtime (&now)->tm_hour;
 799   unset_TZ ();
 800   hour_unset = localtime (&now)->tm_hour;
 801   if (putenv (TZ_PST8) != 0)
 802     exit (1);
 803   if (localtime (&now)->tm_hour == hour_GMT0)
 804     exit (1);
 805   unset_TZ ();
 806   if (localtime (&now)->tm_hour != hour_unset)
 807     exit (1);
 808   exit (0);
 809 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 810 [# If we have tzset, assume the worst when cross-compiling.
 811 guile_cv_localtime_cache=yes])
 812 else
 813         # If we lack tzset, report that localtime does not cache TZ,
 814         # since we can't invalidate the cache if we don't have tzset.
 815         guile_cv_localtime_cache=no
 816 fi])dnl
 817 AC_MSG_RESULT($guile_cv_localtime_cache)
 818 if test $guile_cv_localtime_cache = yes; then
 819   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 820 fi
 821
 822 dnl Test whether system calls are restartable by default on the
 823 dnl current system.  If they are not, we put a loop around every system
 824 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 825 dnl change from the default behaviour.  On the other hand, if signals
 826 dnl are restartable then the loop is not installed and when libguile
 827 dnl initialises it also resets the behaviour of each signal to cause a
 828 dnl restart (in case a different runtime had a different default
 829 dnl behaviour for some reason: e.g., different versions of linux seem
 830 dnl to behave differently.)
 831
 832 AC_SYS_RESTARTABLE_SYSCALLS
 833
 834 if test "$enable_regex" = yes; then
 835    if test "$ac_cv_header_regex_h" = yes ||
 836       test "$ac_cv_header_rxposix_h" = yes ||
 837       test "$ac_cv_header_rx_rxposix_h" = yes; then
 838      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 839      [AC_CHECK_LIB(rx, main)
 840       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 841      [AC_CHECK_LIB(regex, main)
 842       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 843      )
 844      dnl The following should not be necessary, but for some reason
 845      dnl autoheader misses it if we don't include it!
 846      if test "$ac_cv_func_regcomp_norx" = yes ||
 847         test "$ac_cv_func_regcomp_regex" = yes ||
 848         test "$ac_cv_func_regcomp_rx" = yes; then
 849        AC_DEFINE(HAVE_REGCOMP, 1,
 850          [This is included as part of a workaround for a autoheader bug.])
 851      fi
 852    fi
 853 fi
 854
 855 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 856
 857 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 858
 859 # Reasons for testing:
 860 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 861 #                                older systems
 862 #   sincos - GLIBC extension
 863 #
 864 AC_CHECK_FUNCS(asinh acosh atanh copysign finite isinf isnan sincos trunc)
 865
 866 # When testing for the presence of alloca, we need to add alloca.o
 867 # explicitly to LIBOBJS to make sure that it is translated to
 868 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 869 AC_FUNC_ALLOCA
 870 if test "$ALLOCA" = "alloca.o"
 871 then
 872   AC_LIBOBJ([alloca])
 873 fi
 874
 875 AC_CHECK_MEMBERS([struct stat.st_rdev])
 876 AC_CHECK_MEMBERS([struct stat.st_blksize])
 877
 878 AC_STRUCT_ST_BLOCKS
 879
 880 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 881   [AC_TRY_CPP([#include <sys/stat.h>
 882                #ifndef S_ISLNK
 883                #error no S_ISLNK
 884                #endif],
 885                ac_cv_macro_S_ISLNK=yes,
 886                ac_cv_macro_S_ISLNK=no)])
 887 if test $ac_cv_macro_S_ISLNK = yes; then
 888   AC_DEFINE(HAVE_S_ISLNK, 1,
 889     [Define this if your system defines S_ISLNK in sys/stat.h.])
 890 fi
 891
 892 AC_STRUCT_TIMEZONE
 893 GUILE_STRUCT_UTIMBUF
 894
 895 #--------------------------------------------------------------------
 896 #
 897 # Which way does the stack grow?
 898 #
 899 #--------------------------------------------------------------------
 900
 901 SCM_I_GSC_STACK_GROWS_UP=0
 902 AC_TRY_RUN(aux (l) unsigned long l;
 903              { int x; exit (l >= ((unsigned long)&x)); }
 904            main () { int q; aux((unsigned long)&q); },
 905            [SCM_I_GSC_STACK_GROWS_UP=1],
 906            [],
 907            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
 908
 909 AC_CHECK_SIZEOF(float)
 910 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
 911     AC_DEFINE(SCM_SINGLES, 1,
 912               [Define this if floats are the same size as longs.])
 913 fi
 914
 915 AC_MSG_CHECKING(for struct linger)
 916 AC_CACHE_VAL(scm_cv_struct_linger,
 917         AC_TRY_COMPILE([
 918 #include <sys/types.h>
 919 #include <sys/socket.h>],
 920                         [struct linger lgr;  lgr.l_linger = 100],
 921                         scm_cv_struct_linger="yes",
 922                         scm_cv_struct_linger="no"))
 923 AC_MSG_RESULT($scm_cv_struct_linger)
 924 if test $scm_cv_struct_linger = yes; then
 925         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 926           [Define this if your system defines struct linger, for use with the
 927            getsockopt and setsockopt system calls.])
 928 fi
 929
 930
 931 AC_MSG_CHECKING(for struct timespec)
 932 AC_CACHE_VAL(scm_cv_struct_timespec,
 933         AC_TRY_COMPILE([
 934 #include <time.h>],
 935                         [struct timespec t;  t.tv_nsec = 100],
 936                         scm_cv_struct_timespec="yes",
 937                         scm_cv_struct_timespec="no"))
 938 AC_MSG_RESULT($scm_cv_struct_timespec)
 939 if test $scm_cv_struct_timespec = yes; then
 940   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 941     [Define this if your system defines struct timespec via <time.h>.])
 942 fi
 943
 944 #--------------------------------------------------------------------
 945 #
 946 # Flags for thread support
 947 #
 948 #--------------------------------------------------------------------
 949
 950 SCM_I_GSC_USE_PTHREAD_THREADS=0
 951 SCM_I_GSC_USE_NULL_THREADS=0
 952 SCM_I_GSC_USE_COOP_THREADS=0
 953 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
 954 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
 955 AC_SUBST([SCM_I_GSC_USE_COOP_THREADS])
 956
 957 ### What thread package has the user asked for?
 958 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 959             , with_threads=yes)
 960
 961 case "$with_threads" in
 962   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
 963     AC_CHECK_LIB(pthread, main,
 964       LIBS="-lpthread $LIBS"
 965       SCM_I_GSC_USE_PTHREAD_THREADS=1
 966       with_threads="pthreads",
 967       with_threads="null")
 968
 969     if test $GCC = yes; then
 970     AC_DEFINE(_THREAD_SAFE, 1,
 971       [Use thread safe versions of GNU Libc functions.])
 972     fi
 973
 974     AC_MSG_CHECKING(if pthread_mutexattr_settype is declared)
 975     AC_CACHE_VAL(guile_cv_mutexattr_settype_declared,
 976       [AC_TRY_COMPILE([#include <pthread.h>],
 977           [int pthread_mutexattr_settype (int, int);],
 978           guile_cv_mutexattr_settype_declared=no,
 979           guile_cv_mutexattr_settype_declared=yes)])
 980     AC_MSG_RESULT($guile_cv_mutexattr_settype_declared)
 981     if test $guile_cv_mutexattr_settype_declared = yes; then
 982       AC_DEFINE(SCM_MUTEXATTR_SETTYPE_DECLARED, 1,
 983           [Define if pthread.h declares pthread_mutexattr_settype.])
 984     fi
 985
 986     AC_MSG_CHECKING(how to get a fast mutex)
 987     AC_CACHE_VAL(guile_cv_have_mutex_fast,
 988       [AC_TRY_COMPILE([#include <pthread.h>],
 989           [int a = PTHREAD_MUTEX_ADAPTIVE_NP;],
 990           guile_cv_have_mutex_fast=PTHREAD_MUTEX_ADAPTIVE_NP,
 991           guile_cv_have_mutex_fast=none)])
 992     AC_MSG_RESULT($guile_cv_have_mutex_fast)
 993     if test ! $guile_cv_have_mutex_fast = none; then
 994       AC_DEFINE_UNQUOTED(SCM_MUTEX_FAST, $guile_cv_have_mutex_fast,
 995           [The mutex kind enum for fast mutexes.])
 996     fi
 997
 998     AC_MSG_CHECKING(how to get a recursive mutex)
 999     AC_CACHE_VAL(guile_cv_have_mutex_recursive,
1000       [AC_TRY_COMPILE([#include <pthread.h>],
1001         [int a = PTHREAD_MUTEX_RECURSIVE_NP;],
1002          guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE_NP)
1003       if test -z "$guile_cv_have_mutex_recursive"; then
1004           AC_TRY_COMPILE([#include <pthread.h>],
1005             [int a = PTHREAD_MUTEX_RECURSIVE;],
1006             guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE,
1007             guile_cv_have_mutex_recursive=none)
1008         fi])
1009     AC_MSG_RESULT($guile_cv_have_mutex_recursive)
1010     if test ! $guile_cv_have_mutex_recursive = none; then
1011       AC_DEFINE_UNQUOTED(SCM_MUTEX_RECURSIVE, $guile_cv_have_mutex_recursive,
1012          [The mutex kind enum for recursive mutexes.])
1013     fi
1014
1015     # On Solaris, sched_yield lives in -lrt.
1016     AC_SEARCH_LIBS(sched_yield, rt)
1017
1018   ;;
1019 esac
1020
1021 case "$with_threads" in
1022   "pthreads")
1023   ;;
1024   "no" | "null")
1025     SCM_I_GSC_USE_NULL_THREADS=1
1026     with_threads="null-threads"
1027   ;;
1028   * )
1029     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1030   ;;
1031 esac
1032
1033 AC_MSG_CHECKING(what kind of threads to support)
1034 AC_MSG_RESULT($with_threads)
1035
1036 ## Cross building
1037 if test "$cross_compiling" = "yes"; then
1038   AC_MSG_CHECKING(cc for build)
1039   ## /usr/bin/cc still uses wrong assembler
1040   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1041   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1042 else
1043   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1044 fi
1045
1046 ## AC_MSG_CHECKING("if we are cross compiling")
1047 ## AC_MSG_RESULT($cross_compiling)
1048 if test "$cross_compiling" = "yes"; then
1049    AC_MSG_RESULT($CC_FOR_BUILD)
1050 fi
1051
1052 ## No need as yet to be more elaborate
1053 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1054
1055 AC_SUBST(cross_compiling)
1056 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1057 AC_SUBST(CCLD_FOR_BUILD)
1058
1059 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1060 ## --HOST is the platform that PACKAGE is compiled for.
1061 HOST_CC="$CC_FOR_BUILD"
1062 AC_SUBST(HOST_CC)
1063
1064 if test "$cross_compiling" = "yes"; then
1065   AC_MSG_CHECKING(guile for build)
1066   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1067 else
1068   GUILE_FOR_BUILD='$(preinstguile)'
1069 fi
1070
1071 ## AC_MSG_CHECKING("if we are cross compiling")
1072 ## AC_MSG_RESULT($cross_compiling)
1073 if test "$cross_compiling" = "yes"; then
1074    AC_MSG_RESULT($GUILE_FOR_BUILD)
1075 fi
1076 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1077 AC_SUBST(GUILE_FOR_BUILD)
1078
1079 ## If we're using GCC, ask for aggressive warnings.
1080 case "$GCC" in
1081   yes )
1082     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1083     ## much stuff with generic function pointers for that to really be
1084     ## less than exasperating.
1085     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1086     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1087     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1088     # Do this here so we don't screw up any of the tests above that might
1089     # not be "warning free"
1090     if test "${GUILE_ERROR_ON_WARNING}" = yes
1091     then
1092         CFLAGS="${CFLAGS} -Werror"
1093         enable_compile_warnings=no
1094     fi
1095     ;;
1096 esac
1097
1098 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
1099 ## -- I'm disabling it for now in the hopes that the newer autoconf
1100 ## will DTRT -- if not, we need to fix up the sed command to match the
1101 ## others...
1102 ##
1103 ## Remove fileblocks.o from the object list.  This file gets added by
1104 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
1105 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
1106
1107 ## If we're creating a shared library (using libtool!), then we'll
1108 ## need to generate a list of .lo files corresponding to the .o files
1109 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1110 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1111
1112 ## We also need to create corresponding .doc and .x files
1113 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1114 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1115
1116 AC_SUBST(GUILE_MAJOR_VERSION)
1117 AC_SUBST(GUILE_MINOR_VERSION)
1118 AC_SUBST(GUILE_MICRO_VERSION)
1119 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1120 AC_SUBST(GUILE_VERSION)
1121
1122 #######################################################################
1123 # library versioning
1124
1125 AC_SUBST(LIBQTHREADS_INTERFACE_CURRENT)
1126 AC_SUBST(LIBQTHREADS_INTERFACE_REVISION)
1127 AC_SUBST(LIBQTHREADS_INTERFACE_AGE)
1128 AC_SUBST(LIBQTHREADS_INTERFACE)
1129
1130 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1131 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1132 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1133 AC_SUBST(LIBGUILE_INTERFACE)
1134
1135 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1136 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1137 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1138 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1139
1140 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1141 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1142 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1143 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1144
1145 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1146 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1147 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1148 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1149
1150 #######################################################################
1151
1152 dnl Tell guile-config what flags guile users should link against.
1153 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
1154 AC_SUBST(GUILE_LIBS)
1155
1156 AC_SUBST(AWK)
1157 AC_SUBST(LIBLOBJS)
1158 AC_SUBST(EXTRA_DOT_DOC_FILES)
1159 AC_SUBST(EXTRA_DOT_X_FILES)
1160
1161 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1162 top_builddir_absolute=`pwd`
1163 AC_SUBST(top_builddir_absolute)
1164 top_srcdir_absolute=`(cd $srcdir && pwd)`
1165 AC_SUBST(top_srcdir_absolute)
1166
1167 # Additional SCM_I_GSC definitions are above.
1168 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1169 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1170 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1171 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1172 AC_SUBST([SCM_I_GSC_HAVE_ARRAYS])
1173 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1174 AC_SUBST([SCM_I_GSC_C_INLINE])
1175 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1176
1177 AC_CONFIG_FILES([
1178   Makefile
1179   am/Makefile
1180   benchmark-suite/Makefile
1181   doc/Makefile
1182   doc/goops/Makefile
1183   doc/r5rs/Makefile
1184   doc/ref/Makefile
1185   doc/tutorial/Makefile
1186   emacs/Makefile
1187   examples/Makefile
1188   examples/box-dynamic-module/Makefile
1189   examples/box-dynamic/Makefile
1190   examples/box-module/Makefile
1191   examples/box/Makefile
1192   examples/modules/Makefile
1193   examples/safe/Makefile
1194   examples/scripts/Makefile
1195   guile-config/Makefile
1196   ice-9/Makefile
1197   ice-9/debugger/Makefile
1198   ice-9/debugger/breakpoints/Makefile
1199   lang/Makefile
1200   lang/elisp/Makefile
1201   lang/elisp/internals/Makefile
1202   lang/elisp/primitives/Makefile
1203   libguile-ltdl/Makefile
1204   libguile-ltdl/upstream/Makefile
1205   libguile/Makefile
1206   oop/Makefile
1207   oop/goops/Makefile
1208   scripts/Makefile
1209   srfi/Makefile
1210   test-suite/Makefile
1211   test-suite/standalone/Makefile
1212 ])
1213
1214 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1215 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1216 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1217 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1218 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1219 AC_CONFIG_FILES([libguile/guile-snarf],
1220                 [chmod +x libguile/guile-snarf])
1221 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1222                 [chmod +x libguile/guile-doc-snarf])
1223 AC_CONFIG_FILES([libguile/guile-func-name-check],
1224                 [chmod +x libguile/guile-func-name-check])
1225 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1226                 [chmod +x libguile/guile-snarf-docs])
1227
1228 AC_OUTPUT
1229
1230 dnl Local Variables:
1231 dnl comment-start: "dnl "
1232 dnl comment-end: ""
1233 dnl comment-start-skip: "\\bdnl\\b\\s *"
1234 dnl End: