module/language/tree-il/primitives.scm

   1 ;;; open-coding primitive procedures
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012, 2013 Free Software Foundation, Inc.
   4
   5 ;;;; This library is free software; you can redistribute it and/or
   6 ;;;; modify it under the terms of the GNU Lesser General Public
   7 ;;;; License as published by the Free Software Foundation; either
   8 ;;;; version 3 of the License, or (at your option) any later version.
   9 ;;;;
  10 ;;;; This library is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 ;;;; Lesser General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU Lesser General Public
  16 ;;;; License along with this library; if not, write to the Free Software
  17 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  18
  19 ;;; Code:
  20
  21 (define-module (language tree-il primitives)
  22   #:use-module (system base pmatch)
  23   #:use-module (ice-9 match)
  24   #:use-module (rnrs bytevectors)
  25   #:use-module (system base syntax)
  26   #:use-module (language tree-il)
  27   #:use-module (srfi srfi-4)
  28   #:use-module (srfi srfi-16)
  29   #:export (resolve-primitives add-interesting-primitive!
  30             expand-primitives
  31             effect-free-primitive? effect+exception-free-primitive?
  32             constructor-primitive? accessor-primitive?
  33             singly-valued-primitive? equality-primitive?
  34             bailout-primitive?
  35             negate-primitive))
  36
  37 ;; When adding to this, be sure to update *multiply-valued-primitives*
  38 ;; if appropriate.
  39 (define *interesting-primitive-names*
  40   '(apply
  41     call-with-values
  42     call-with-current-continuation
  43     call/cc
  44     dynamic-wind
  45     values
  46     eq? eqv? equal?
  47     memq memv
  48     = < > <= >= zero?
  49     + * - / 1- 1+ quotient remainder modulo
  50     ash logand logior logxor lognot
  51     not
  52     pair? null? list? symbol? vector? string? struct? number? char? nil?
  53
  54     procedure? thunk?
  55
  56     complex? real? rational? inf? nan? integer? exact? inexact? even? odd?
  57
  58     char<? char<=? char>=? char>?
  59
  60     integer->char char->integer number->string string->number
  61
  62     acons cons cons*
  63
  64     list vector
  65
  66     car cdr
  67     set-car! set-cdr!
  68
  69     caar cadr cdar cddr
  70
  71     caaar caadr cadar caddr cdaar cdadr cddar cdddr
  72
  73     caaaar caaadr caadar caaddr cadaar cadadr caddar cadddr
  74     cdaaar cdaadr cdadar cdaddr cddaar cddadr cdddar cddddr
  75
  76     vector-length vector-ref vector-set!
  77     variable-ref variable-set!
  78     variable-bound?
  79
  80     fluid-ref fluid-set! with-fluid*
  81
  82     call-with-prompt
  83     abort-to-prompt* abort-to-prompt
  84     make-prompt-tag
  85
  86     throw error scm-error
  87
  88     string-length string-ref string-set!
  89
  90     struct-vtable make-struct struct-ref struct-set!
  91
  92     bytevector-u8-ref bytevector-u8-set!
  93     bytevector-s8-ref bytevector-s8-set!
  94     u8vector-ref u8vector-set! s8vector-ref s8vector-set!
  95
  96     bytevector-u16-ref bytevector-u16-set!
  97     bytevector-u16-native-ref bytevector-u16-native-set!
  98     bytevector-s16-ref bytevector-s16-set!
  99     bytevector-s16-native-ref bytevector-s16-native-set!
 100     u16vector-ref u16vector-set! s16vector-ref s16vector-set!
 101
 102     bytevector-u32-ref bytevector-u32-set!
 103     bytevector-u32-native-ref bytevector-u32-native-set!
 104     bytevector-s32-ref bytevector-s32-set!
 105     bytevector-s32-native-ref bytevector-s32-native-set!
 106     u32vector-ref u32vector-set! s32vector-ref s32vector-set!
 107
 108     bytevector-u64-ref bytevector-u64-set!
 109     bytevector-u64-native-ref bytevector-u64-native-set!
 110     bytevector-s64-ref bytevector-s64-set!
 111     bytevector-s64-native-ref bytevector-s64-native-set!
 112     u64vector-ref u64vector-set! s64vector-ref s64vector-set!
 113
 114     bytevector-ieee-single-ref bytevector-ieee-single-set!
 115     bytevector-ieee-single-native-ref bytevector-ieee-single-native-set!
 116     bytevector-ieee-double-ref bytevector-ieee-double-set!
 117     bytevector-ieee-double-native-ref bytevector-ieee-double-native-set!
 118     f32vector-ref f32vector-set! f64vector-ref f64vector-set!))
 119
 120 (define (add-interesting-primitive! name)
 121   (hashq-set! *interesting-primitive-vars*
 122               (or (module-variable (current-module) name)
 123                   (error "unbound interesting primitive" name))
 124               name))
 125
 126 (define *interesting-primitive-vars* (make-hash-table))
 127
 128 (for-each add-interesting-primitive! *interesting-primitive-names*)
 129
 130 (define *primitive-constructors*
 131   ;; Primitives that return a fresh object.
 132   '(acons cons cons* list vector make-struct make-struct/no-tail
 133     make-prompt-tag))
 134
 135 (define *primitive-accessors*
 136   ;; Primitives that are pure, but whose result depends on the mutable
 137   ;; memory pointed to by their operands.
 138   '(vector-ref
 139     car cdr
 140     memq memv
 141     struct-ref
 142     string-ref
 143     bytevector-u8-ref bytevector-s8-ref
 144     bytevector-u16-ref bytevector-u16-native-ref
 145     bytevector-s16-ref bytevector-s16-native-ref
 146     bytevector-u32-ref bytevector-u32-native-ref
 147     bytevector-s32-ref bytevector-s32-native-ref
 148     bytevector-u64-ref bytevector-u64-native-ref
 149     bytevector-s64-ref bytevector-s64-native-ref
 150     bytevector-ieee-single-ref bytevector-ieee-single-native-ref
 151     bytevector-ieee-double-ref bytevector-ieee-double-native-ref))
 152
 153 (define *effect-free-primitives*
 154   `(values
 155     eq? eqv? equal?
 156     = < > <= >= zero?
 157     ash logand logior logxor lognot
 158     + * - / 1- 1+ quotient remainder modulo
 159     not
 160     pair? null? list? symbol? vector? struct? string? number? char? nil
 161     complex? real? rational? inf? nan? integer? exact? inexact? even? odd?
 162     char<? char<=? char>=? char>?
 163     integer->char char->integer number->string string->number
 164     struct-vtable
 165     string-length vector-length
 166     ;; These all should get expanded out by expand-primitives.
 167     caar cadr cdar cddr
 168     caaar caadr cadar caddr cdaar cdadr cddar cdddr
 169     caaaar caaadr caadar caaddr cadaar cadadr caddar cadddr
 170     cdaaar cdaadr cdadar cdaddr cddaar cddadr cdddar cddddr
 171     ,@*primitive-constructors*
 172     ,@*primitive-accessors*))
 173
 174 ;; Like *effect-free-primitives* above, but further restricted in that they
 175 ;; cannot raise exceptions.
 176 (define *effect+exception-free-primitives*
 177   '(values
 178     eq? eqv? equal?
 179     not
 180     pair? null? list? symbol? vector? struct? string? number? char?
 181     procedure? thunk?
 182     acons cons cons* list vector))
 183
 184 ;; Primitives that don't always return one value.
 185 (define *multiply-valued-primitives*
 186   '(apply
 187     call-with-values
 188     call-with-current-continuation
 189     call/cc
 190     dynamic-wind
 191     values
 192     call-with-prompt
 193     @abort abort-to-prompt))
 194
 195 ;; Procedures that cause a nonlocal, non-resumable abort.
 196 (define *bailout-primitives*
 197   '(throw error scm-error))
 198
 199 ;; Negatable predicates.
 200 (define *negatable-primitives*
 201   '((even? . odd?)
 202     (exact? . inexact?)
 203     ;; (< <= > >=) are not negatable because of NaNs.
 204     (char<? . char>=?)
 205     (char>? . char<=?)))
 206
 207 (define *equality-primitives*
 208   '(eq? eqv? equal?))
 209
 210 (define *effect-free-primitive-table* (make-hash-table))
 211 (define *effect+exceptions-free-primitive-table* (make-hash-table))
 212 (define *equality-primitive-table* (make-hash-table))
 213 (define *multiply-valued-primitive-table* (make-hash-table))
 214 (define *bailout-primitive-table* (make-hash-table))
 215 (define *negatable-primitive-table* (make-hash-table))
 216
 217 (for-each (lambda (x)
 218             (hashq-set! *effect-free-primitive-table* x #t))
 219           *effect-free-primitives*)
 220 (for-each (lambda (x)
 221             (hashq-set! *effect+exceptions-free-primitive-table* x #t))
 222           *effect+exception-free-primitives*)
 223 (for-each (lambda (x)
 224             (hashq-set! *equality-primitive-table* x #t))
 225           *equality-primitives*)
 226 (for-each (lambda (x)
 227             (hashq-set! *multiply-valued-primitive-table* x #t))
 228           *multiply-valued-primitives*)
 229 (for-each (lambda (x)
 230             (hashq-set! *bailout-primitive-table* x #t))
 231           *bailout-primitives*)
 232 (for-each (lambda (x)
 233             (hashq-set! *negatable-primitive-table* (car x) (cdr x))
 234             (hashq-set! *negatable-primitive-table* (cdr x) (car x)))
 235           *negatable-primitives*)
 236
 237 (define (constructor-primitive? prim)
 238   (memq prim *primitive-constructors*))
 239 (define (accessor-primitive? prim)
 240   (memq prim *primitive-accessors*))
 241 (define (effect-free-primitive? prim)
 242   (hashq-ref *effect-free-primitive-table* prim))
 243 (define (effect+exception-free-primitive? prim)
 244   (hashq-ref *effect+exceptions-free-primitive-table* prim))
 245 (define (equality-primitive? prim)
 246   (hashq-ref *equality-primitive-table* prim))
 247 (define (singly-valued-primitive? prim)
 248   (not (hashq-ref *multiply-valued-primitive-table* prim)))
 249 (define (bailout-primitive? prim)
 250   (hashq-ref *bailout-primitive-table* prim))
 251 (define (negate-primitive prim)
 252   (hashq-ref *negatable-primitive-table* prim))
 253
 254 (define (resolve-primitives x mod)
 255   (define local-definitions
 256     (make-hash-table))
 257
 258   (let collect-local-definitions ((x x))
 259     (record-case x
 260       ((<toplevel-define> name)
 261        (hashq-set! local-definitions name #t))
 262       ((<seq> head tail)
 263        (collect-local-definitions head)
 264        (collect-local-definitions tail))
 265       (else #f)))
 266
 267   (post-order
 268    (lambda (x)
 269      (or
 270       (record-case x
 271         ((<toplevel-ref> src name)
 272          (and=> (and (not (hashq-ref local-definitions name))
 273                      (hashq-ref *interesting-primitive-vars*
 274                                 (module-variable mod name)))
 275                 (lambda (name) (make-primitive-ref src name))))
 276         ((<module-ref> src mod name public?)
 277          ;; for the moment, we're disabling primitive resolution for
 278          ;; public refs because resolve-interface can raise errors.
 279          (and=> (and=> (resolve-module mod)
 280                        (if public?
 281                            module-public-interface
 282                            identity))
 283                 (lambda (m)
 284                   (and=> (hashq-ref *interesting-primitive-vars*
 285                                     (module-variable m name))
 286                          (lambda (name)
 287                            (make-primitive-ref src name))))))
 288         ((<call> src proc args)
 289          (and (primitive-ref? proc)
 290               (make-primcall src (primitive-ref-name proc) args)))
 291         (else #f))
 292       x))
 293    x))
 294
 295 \f
 296
 297 (define *primitive-expand-table* (make-hash-table))
 298
 299 (define (expand-primitives x)
 300   (pre-order
 301    (lambda (x)
 302      (record-case x
 303        ((<primcall> src name args)
 304         (let ((expand (hashq-ref *primitive-expand-table* name)))
 305           (or (and expand (apply expand src args))
 306               x)))
 307        (else x)))
 308    x))
 309
 310 ;;; I actually did spend about 10 minutes trying to redo this with
 311 ;;; syntax-rules. Patches appreciated.
 312 ;;;
 313 (define-macro (define-primitive-expander sym . clauses)
 314   (define (inline-args args)
 315     (let lp ((in args) (out '()))
 316       (cond ((null? in) `(list ,@(reverse out)))
 317             ((symbol? in) `(cons* ,@(reverse out) ,in))
 318             ((pair? (car in))
 319              (lp (cdr in)
 320                  (cons (if (eq? (caar in) 'quote)
 321                            `(make-const src ,@(cdar in))
 322                            `(make-primcall src ',(caar in)
 323                                            ,(inline-args (cdar in))))
 324                        out)))
 325             ((symbol? (car in))
 326              ;; assume it's locally bound
 327              (lp (cdr in) (cons (car in) out)))
 328             ((self-evaluating? (car in))
 329              (lp (cdr in) (cons `(make-const src ,(car in)) out)))
 330             (else
 331              (error "what what" (car in))))))
 332   (define (consequent exp)
 333     (cond
 334      ((pair? exp)
 335       (pmatch exp
 336         ((if ,test ,then ,else)
 337          `(if ,test
 338               ,(consequent then)
 339               ,(consequent else)))
 340         (else
 341          `(make-primcall src ',(car exp)
 342                          ,(inline-args (cdr exp))))))
 343      ((symbol? exp)
 344       ;; assume locally bound
 345       exp)
 346      ((number? exp)
 347       `(make-const src ,exp))
 348      ((not exp)
 349       ;; failed match
 350       #f)
 351      (else (error "bad consequent yall" exp))))
 352   `(hashq-set! *primitive-expand-table*
 353                ',sym
 354                (match-lambda*
 355                 ,@(let lp ((in clauses) (out '()))
 356                     (if (null? in)
 357                         (reverse (cons '(_ #f) out))
 358                         (lp (cddr in)
 359                             (cons `((src . ,(car in))
 360                                     ,(consequent (cadr in)))
 361                                   out)))))))
 362
 363 (define-primitive-expander zero? (x)
 364   (= x 0))
 365
 366 ;; FIXME: All the code that uses `const?' is redundant with `peval'.
 367
 368 (define-primitive-expander +
 369   () 0
 370   (x) (values x)
 371   (x y) (if (and (const? y) (eqv? (const-exp y) 1))
 372             (1+ x)
 373             (if (and (const? y) (eqv? (const-exp y) -1))
 374                 (1- x)
 375                 (if (and (const? x) (eqv? (const-exp x) 1))
 376                     (1+ y)
 377                     (if (and (const? x) (eqv? (const-exp x) -1))
 378                         (1- y)
 379                         (+ x y)))))
 380   (x y z ... last) (+ (+ x y . z) last))
 381
 382 (define-primitive-expander *
 383   () 1
 384   (x) (values x)
 385   (x y z ... last) (* (* x y . z) last))
 386
 387 (define-primitive-expander -
 388   (x) (- 0 x)
 389   (x y) (if (and (const? y) (eqv? (const-exp y) 1))
 390             (1- x)
 391             (- x y))
 392   (x y z ... last) (- (- x y . z) last))
 393
 394 (define-primitive-expander /
 395   (x) (/ 1 x)
 396   (x y z ... last) (/ (/ x y . z) last))
 397
 398 (define-primitive-expander logior
 399   () 0
 400   (x) (logior x 0)
 401   (x y) (logior x y)
 402   (x y z ... last) (logior (logior x y . z) last))
 403
 404 (define-primitive-expander logand
 405   () -1
 406   (x) (logand x -1)
 407   (x y) (logand x y)
 408   (x y z ... last) (logand (logand x y . z) last))
 409
 410 (define-primitive-expander caar (x) (car (car x)))
 411 (define-primitive-expander cadr (x) (car (cdr x)))
 412 (define-primitive-expander cdar (x) (cdr (car x)))
 413 (define-primitive-expander cddr (x) (cdr (cdr x)))
 414 (define-primitive-expander caaar (x) (car (car (car x))))
 415 (define-primitive-expander caadr (x) (car (car (cdr x))))
 416 (define-primitive-expander cadar (x) (car (cdr (car x))))
 417 (define-primitive-expander caddr (x) (car (cdr (cdr x))))
 418 (define-primitive-expander cdaar (x) (cdr (car (car x))))
 419 (define-primitive-expander cdadr (x) (cdr (car (cdr x))))
 420 (define-primitive-expander cddar (x) (cdr (cdr (car x))))
 421 (define-primitive-expander cdddr (x) (cdr (cdr (cdr x))))
 422 (define-primitive-expander caaaar (x) (car (car (car (car x)))))
 423 (define-primitive-expander caaadr (x) (car (car (car (cdr x)))))
 424 (define-primitive-expander caadar (x) (car (car (cdr (car x)))))
 425 (define-primitive-expander caaddr (x) (car (car (cdr (cdr x)))))
 426 (define-primitive-expander cadaar (x) (car (cdr (car (car x)))))
 427 (define-primitive-expander cadadr (x) (car (cdr (car (cdr x)))))
 428 (define-primitive-expander caddar (x) (car (cdr (cdr (car x)))))
 429 (define-primitive-expander cadddr (x) (car (cdr (cdr (cdr x)))))
 430 (define-primitive-expander cdaaar (x) (cdr (car (car (car x)))))
 431 (define-primitive-expander cdaadr (x) (cdr (car (car (cdr x)))))
 432 (define-primitive-expander cdadar (x) (cdr (car (cdr (car x)))))
 433 (define-primitive-expander cdaddr (x) (cdr (car (cdr (cdr x)))))
 434 (define-primitive-expander cddaar (x) (cdr (cdr (car (car x)))))
 435 (define-primitive-expander cddadr (x) (cdr (cdr (car (cdr x)))))
 436 (define-primitive-expander cdddar (x) (cdr (cdr (cdr (car x)))))
 437 (define-primitive-expander cddddr (x) (cdr (cdr (cdr (cdr x)))))
 438
 439 (define-primitive-expander cons*
 440   (x) (values x)
 441   (x y) (cons x y)
 442   (x y . rest) (cons x (cons* y . rest)))
 443
 444 (define-primitive-expander acons (x y z)
 445   (cons (cons x y) z))
 446
 447 (define-primitive-expander call/cc (proc)
 448   (call-with-current-continuation proc))
 449
 450 (define-primitive-expander make-struct (vtable tail-size . args)
 451   (if (and (const? tail-size)
 452            (let ((n (const-exp tail-size)))
 453              (and (number? n) (exact? n) (zero? n))))
 454       (make-struct/no-tail vtable . args)
 455       #f))
 456
 457 (define-primitive-expander u8vector-ref (vec i)
 458   (bytevector-u8-ref vec i))
 459 (define-primitive-expander u8vector-set! (vec i x)
 460   (bytevector-u8-set! vec i x))
 461 (define-primitive-expander s8vector-ref (vec i)
 462   (bytevector-s8-ref vec i))
 463 (define-primitive-expander s8vector-set! (vec i x)
 464   (bytevector-s8-set! vec i x))
 465
 466 (define-primitive-expander u16vector-ref (vec i)
 467   (bytevector-u16-native-ref vec (* i 2)))
 468 (define-primitive-expander u16vector-set! (vec i x)
 469   (bytevector-u16-native-set! vec (* i 2) x))
 470 (define-primitive-expander s16vector-ref (vec i)
 471   (bytevector-s16-native-ref vec (* i 2)))
 472 (define-primitive-expander s16vector-set! (vec i x)
 473   (bytevector-s16-native-set! vec (* i 2) x))
 474
 475 (define-primitive-expander u32vector-ref (vec i)
 476   (bytevector-u32-native-ref vec (* i 4)))
 477 (define-primitive-expander u32vector-set! (vec i x)
 478   (bytevector-u32-native-set! vec (* i 4) x))
 479 (define-primitive-expander s32vector-ref (vec i)
 480   (bytevector-s32-native-ref vec (* i 4)))
 481 (define-primitive-expander s32vector-set! (vec i x)
 482   (bytevector-s32-native-set! vec (* i 4) x))
 483
 484 (define-primitive-expander u64vector-ref (vec i)
 485   (bytevector-u64-native-ref vec (* i 8)))
 486 (define-primitive-expander u64vector-set! (vec i x)
 487   (bytevector-u64-native-set! vec (* i 8) x))
 488 (define-primitive-expander s64vector-ref (vec i)
 489   (bytevector-s64-native-ref vec (* i 8)))
 490 (define-primitive-expander s64vector-set! (vec i x)
 491   (bytevector-s64-native-set! vec (* i 8) x))
 492
 493 (define-primitive-expander f32vector-ref (vec i)
 494   (bytevector-ieee-single-native-ref vec (* i 4)))
 495 (define-primitive-expander f32vector-set! (vec i x)
 496   (bytevector-ieee-single-native-set! vec (* i 4) x))
 497 (define-primitive-expander f32vector-ref (vec i)
 498   (bytevector-ieee-single-native-ref vec (* i 4)))
 499 (define-primitive-expander f32vector-set! (vec i x)
 500   (bytevector-ieee-single-native-set! vec (* i 4) x))
 501
 502 (define-primitive-expander f64vector-ref (vec i)
 503   (bytevector-ieee-double-native-ref vec (* i 8)))
 504 (define-primitive-expander f64vector-set! (vec i x)
 505   (bytevector-ieee-double-native-set! vec (* i 8) x))
 506 (define-primitive-expander f64vector-ref (vec i)
 507   (bytevector-ieee-double-native-ref vec (* i 8)))
 508 (define-primitive-expander f64vector-set! (vec i x)
 509   (bytevector-ieee-double-native-set! vec (* i 8) x))
 510
 511 ;; Appropriate for use with either 'eqv?' or 'equal?'.
 512 (define (maybe-simplify-to-eq prim)
 513   (case-lambda
 514     ((src) (make-const src #t))
 515     ((src a) (make-const src #t))
 516     ((src a b)
 517      ;; Simplify cases where either A or B is constant.
 518      (define (maybe-simplify a b)
 519        (and (const? a)
 520             (let ((v (const-exp a)))
 521               (and (or (memq v '(#f #t () #nil))
 522                        (symbol? v)
 523                        (and (integer? v)
 524                             (exact? v)
 525                             (<= v most-positive-fixnum)
 526                             (>= v most-negative-fixnum)))
 527                    (make-primcall src 'eq? (list a b))))))
 528      (or (maybe-simplify a b) (maybe-simplify b a)))
 529     ((src a b . rest)
 530      (make-conditional src (make-primcall src prim (list a b))
 531                        (make-primcall src prim (cons b rest))
 532                        (make-const src #f)))
 533     (else #f)))
 534
 535 (hashq-set! *primitive-expand-table* 'eqv?   (maybe-simplify-to-eq 'eqv?))
 536 (hashq-set! *primitive-expand-table* 'equal? (maybe-simplify-to-eq 'equal?))
 537
 538 (define (expand-chained-comparisons prim)
 539   (case-lambda
 540     ((src) (make-const src #t))
 541     ((src a) (make-const src #t))
 542     ((src a b) #f)
 543     ((src a b . rest)
 544      (make-conditional src (make-primcall src prim (list a b))
 545                        (make-primcall src prim (cons b rest))
 546                        (make-const src #f)))
 547     (else #f)))
 548
 549 (for-each (lambda (prim)
 550             (hashq-set! *primitive-expand-table* prim
 551                         (expand-chained-comparisons prim)))
 552  '(< <= = >= > eq?))
 553
 554 (hashq-set! *primitive-expand-table*
 555             'call-with-prompt
 556             (case-lambda
 557               ((src tag thunk handler)
 558                (make-prompt src #f tag thunk handler))
 559               (else #f)))
 560
 561 (hashq-set! *primitive-expand-table*
 562             'abort-to-prompt*
 563             (case-lambda
 564               ((src tag tail-args)
 565                (make-abort src tag '() tail-args))
 566               (else #f)))
 567 (hashq-set! *primitive-expand-table*
 568             'abort-to-prompt
 569             (case-lambda
 570               ((src tag . args)
 571                (make-abort src tag args (make-const #f '())))
 572               (else #f)))