configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_PREREQ(2.50)
  24
  25 AC_INIT
  26 AC_CONFIG_SRCDIR([Makefile.in])
  27 . $srcdir/GUILE-VERSION
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  29 AM_MAINTAINER_MODE
  30 AM_CONFIG_HEADER(libguile/scmconfig.h)
  31
  32 #--------------------------------------------------------------------
  33 #
  34 # Independent Subdirectories
  35 #
  36 #--------------------------------------------------------------------
  37
  38 AC_CONFIG_SUBDIRS(guile-readline)
  39
  40 #--------------------------------------------------------------------
  41 #
  42 # User options
  43 #
  44 #--------------------------------------------------------------------
  45
  46 AC_ARG_ENABLE(error-on-warning,
  47   [  --enable-error-on-warning    treat compile warnings as errors],
  48   [case "${enableval}" in
  49      yes | y) CFLAGS="${CFLAGS} -Werror"; enable_compile_warnings=no ;;
  50      no | n)  ;;
  51      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  52    esac])
  53
  54 AC_ARG_ENABLE(debug-freelist,
  55   [  --enable-debug-freelist include garbage collector freelist debugging code],
  56   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  57     AC_DEFINE(GUILE_DEBUG_FREELIST)
  58   fi)
  59
  60 AC_ARG_ENABLE(debug-malloc,
  61   [  --enable-debug-malloc   include malloc debugging code],
  62   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  63     AC_DEFINE(GUILE_DEBUG_MALLOC)
  64   fi)
  65
  66 AC_ARG_ENABLE(guile-debug,
  67   [  --enable-guile-debug    include internal debugging functions],
  68   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  69     AC_DEFINE(GUILE_DEBUG)
  70   fi)
  71
  72 AC_ARG_ENABLE(arrays,
  73   [  --disable-arrays        omit array and uniform array support],,
  74   enable_arrays=yes)
  75
  76 AC_ARG_ENABLE(posix,
  77   [  --disable-posix         omit posix interfaces],,
  78   enable_posix=yes)
  79
  80 AC_ARG_ENABLE(networking,
  81   [  --disable-networking    omit networking interfaces],,
  82   enable_networking=yes)
  83
  84 AC_ARG_ENABLE(regex,
  85   [  --disable-regex         omit regular expression interfaces],,
  86   enable_regex=yes)
  87
  88 AC_ARG_ENABLE(htmldoc,
  89   [  --enable-htmldoc        build HTML documentation as well as Info],
  90   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  91      htmldoc_enabled=yes
  92      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  93      if test "$TEXI2HTML" = "not found"; then
  94        echo
  95        echo Building HTML documentation requires the \`texi2html\' program,
  96        echo which appears not to be present on your machine.
  97        echo
  98        echo \`texi2html\' is available from
  99        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
 100        echo
 101        echo In the meantime, to build the guile-doc distribution
 102        echo without HTML enabled, please rerun \`./configure\' without
 103        echo the \`--enable-htmldoc\' option.
 104        exit -1
 105      fi
 106    fi])
 107
 108 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
 109
 110 AC_ARG_ENABLE(deprecated,
 111   [  --disable-deprecated    omit deprecated features [no]])
 112
 113 if test "$enable_deprecated" = no; then
 114   AC_DEFINE(SCM_DEBUG_DEPRECATED, 1)
 115 else
 116   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 117     warn_default=summary
 118   elif test "$enable_deprecated" = shutup; then
 119     warn_default=no
 120   else
 121     warn_default=$enable_deprecated
 122   fi
 123   AC_DEFINE(SCM_DEBUG_DEPRECATED, 0)
 124   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default")
 125 fi
 126
 127 dnl The --disable-debug used to control these two.  But now they are
 128 dnl a required part of the distribution.
 129 AC_DEFINE(DEBUG_EXTENSIONS)
 130 AC_DEFINE(READER_EXTENSIONS)
 131
 132 dnl files which are destined for separate modules.
 133
 134 if test "$enable_arrays" = yes; then
 135    LIBOBJS="$LIBOBJS ramap.o unif.o"
 136    AC_DEFINE(HAVE_ARRAYS)
 137 fi
 138
 139 if test "$enable_posix" = yes; then
 140    LIBOBJS="$LIBOBJS filesys.o posix.o"
 141    AC_DEFINE(HAVE_POSIX)
 142 fi
 143
 144 if test "$enable_networking" = yes; then
 145    LIBOBJS="$LIBOBJS net_db.o socket.o"
 146    AC_DEFINE(HAVE_NETWORKING)
 147 fi
 148
 149 if test "$enable_debug_malloc" = yes; then
 150    LIBOBJS="$LIBOBJS debug-malloc.o"
 151 fi
 152
 153 #--------------------------------------------------------------------
 154
 155 AC_LIBLTDL_CONVENIENCE
 156 AC_CONFIG_SUBDIRS(libltdl)
 157
 158 AC_PROG_CC
 159 AC_PROG_CPP
 160 AC_LIBTOOL_DLOPEN
 161
 162 AC_AIX
 163 AC_ISC_POSIX
 164 AC_MINIX
 165
 166 AM_PROG_CC_STDC
 167 AM_PROG_LIBTOOL
 168
 169 AC_C_CONST
 170 AC_C_INLINE
 171 AC_C_BIGENDIAN
 172
 173 AC_CHECK_SIZEOF(int)
 174 AC_CHECK_SIZEOF(long)
 175
 176 dnl Check for integral types that can represent the range of pointers.
 177 dnl If these types don't exist on this platform, they are replaced by
 178 dnl "unsigned long" and "long", respectively.
 179
 180 AC_CHECK_HEADERS(stdint.h)
 181 AC_CHECK_HEADERS(inttypes.h)
 182 AC_CHECK_TYPES([uintptr_t, ptrdiff_t])
 183
 184 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 185                AC_TRY_COMPILE(,
 186                               [long long a],
 187                               scm_cv_long_longs=yes,
 188                               scm_cv_long_longs=no))
 189 if test "$scm_cv_long_longs" = yes; then
 190   AC_DEFINE(HAVE_LONG_LONGS)
 191   AC_CHECK_SIZEOF(long long)
 192 fi
 193
 194 AC_CHECK_SIZEOF(void *)
 195
 196 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 197   AC_MSG_ERROR(sizes of long and void* are not identical)
 198 fi
 199
 200 AC_HEADER_STDC
 201 AC_HEADER_DIRENT
 202 AC_HEADER_TIME
 203 AC_HEADER_SYS_WAIT
 204 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h sys/utime.h time.h unistd.h utime.h pwd.h winsock2.h grp.h sys/utsname.h)
 205 GUILE_HEADER_LIBC_WITH_UNISTD
 206
 207 AC_TYPE_GETGROUPS
 208 AC_TYPE_SIGNAL
 209 AC_TYPE_MODE_T
 210
 211 AC_CHECK_LIB(m, main)
 212 AC_CHECK_FUNCS(gethostbyname)
 213 if test $ac_cv_func_gethostbyname = no; then
 214     AC_CHECK_LIB(nsl, gethostbyname)
 215 fi
 216 AC_CHECK_FUNCS(connect)
 217 if test $ac_cv_func_connect = no; then
 218     AC_CHECK_LIB(socket, connect)
 219 fi
 220
 221 # Check for dynamic linking
 222
 223 use_modules=yes
 224 AC_ARG_WITH(modules,
 225 [  --with-modules[=FILES]  Add support for dynamic modules],
 226 use_modules="$withval")
 227 test -z "$use_modules" && use_modules=yes
 228 DLPREOPEN=
 229 if test "$use_modules" != no; then
 230   AC_DEFINE(DYNAMIC_LINKING)
 231   if test "$use_modules" = yes; then
 232     DLPREOPEN="-dlpreopen force"
 233   else
 234     DLPREOPEN="-export-dynamic"
 235     for module in $use_modules; do
 236       DLPREOPEN="$DLPREOPEN -dlopen $module"
 237     done
 238   fi
 239 fi
 240 AC_SUBST(INCLTDL)
 241 AC_SUBST(LIBLTDL)
 242 AC_SUBST(DLPREOPEN)
 243
 244 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer)
 245
 246 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 247 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 248 AC_CHECK_LIB(crypt, crypt)
 249
 250 ### Some systems don't declare some functions.  On such systems, we
 251 ### need to at least provide our own K&R-style declarations.
 252
 253 ### GUILE_FUNC_DECLARED(function, headerfile)
 254
 255 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 256 ### not there, #define MISSING_FUNCTION_DECL.
 257 AC_DEFUN(GUILE_FUNC_DECLARED, [
 258   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 259     AC_EGREP_HEADER($1, $2,
 260                     guile_cv_func_$1_declared=yes,
 261                     guile_cv_func_$1_declared=no))
 262   if test [x$guile_cv_func_]$1[_declared] = xno; then
 263     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 264   fi
 265 ])
 266
 267 GUILE_FUNC_DECLARED(strptime, time.h)
 268 GUILE_FUNC_DECLARED(sleep, unistd.h)
 269 GUILE_FUNC_DECLARED(usleep, unistd.h)
 270
 271 ### On some systems usleep has no return value.  If it does have one,
 272 ### we'd like to return it; otherwise, we'll fake it.
 273 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 274   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 275                    /usr/include/unistd.h,
 276                    [guile_cv_func_usleep_return_type=void],
 277                    [guile_cv_func_usleep_return_type=int])])
 278 case "$guile_cv_func_usleep_return_type" in
 279   "void" )
 280     AC_DEFINE(USLEEP_RETURNS_VOID)
 281   ;;
 282 esac
 283
 284 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 285 if test -n "$have_sys_un_h" ; then
 286 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 287 fi
 288
 289 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 290
 291 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 292                setnetent    getnetent    endnetent    dnl
 293                setprotoent  getprotoent  endprotoent  dnl
 294                setservent   getservent   endservent   dnl
 295                getnetbyaddr getnetbyname dnl
 296                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 297                inet_pton inet_ntop)
 298
 299 dnl Some systems do not declare this.  Some systems do declare it, as a
 300 dnl macro.  With cygwin it may be in a DLL.
 301
 302 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 303 AC_CACHE_VAL(guile_cv_have_h_errno,
 304 [AC_TRY_COMPILE([#include <netdb.h>],
 305 [int a = h_errno;],
 306 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 307 AC_MSG_RESULT($guile_cv_have_h_errno)
 308 if test $guile_cv_have_h_errno = yes; then
 309   AC_DEFINE(HAVE_H_ERRNO)
 310 fi
 311
 312 AC_MSG_CHECKING(whether netdb.h defines uint32_t)
 313 AC_CACHE_VAL(guile_cv_have_uint32_t,
 314 [AC_TRY_COMPILE([#include <netdb.h>],
 315 [uint32_t a;],
 316 guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 317 AC_MSG_RESULT($guile_cv_have_uint32_t)
 318 if test $guile_cv_have_uint32_t = yes; then
 319   AC_DEFINE(HAVE_UINT32_T)
 320 fi
 321
 322 AC_MSG_CHECKING(for working IPv6 support)
 323 AC_CACHE_VAL(guile_cv_have_ipv6,
 324 [AC_TRY_COMPILE([#include <netinet/in.h>
 325 #include <sys/socket.h>],
 326 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 327 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 328 AC_MSG_RESULT($guile_cv_have_ipv6)
 329 if test $guile_cv_have_ipv6 = yes; then
 330   AC_DEFINE(HAVE_IPV6)
 331 fi
 332
 333 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 334 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 335 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 336 [AC_TRY_COMPILE([#include <netinet/in.h>],
 337 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 338 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 339 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 340 if test $guile_cv_have_sin6_scope_id = yes; then
 341   AC_DEFINE(HAVE_SIN6_SCOPE_ID)
 342 fi
 343
 344 AC_MSG_CHECKING(whether localtime caches TZ)
 345 AC_CACHE_VAL(guile_cv_localtime_cache,
 346 [if test x$ac_cv_func_tzset = xyes; then
 347 AC_TRY_RUN([#include <time.h>
 348 #if STDC_HEADERS
 349 # include <stdlib.h>
 350 #endif
 351 extern char **environ;
 352 unset_TZ ()
 353 {
 354   char **from, **to;
 355   for (to = from = environ; (*to = *from); from++)
 356     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 357       to++;
 358 }
 359 char TZ_GMT0[] = "TZ=GMT0";
 360 char TZ_PST8[] = "TZ=PST8";
 361 main()
 362 {
 363   time_t now = time ((time_t *) 0);
 364   int hour_GMT0, hour_unset;
 365   if (putenv (TZ_GMT0) != 0)
 366     exit (1);
 367   hour_GMT0 = localtime (&now)->tm_hour;
 368   unset_TZ ();
 369   hour_unset = localtime (&now)->tm_hour;
 370   if (putenv (TZ_PST8) != 0)
 371     exit (1);
 372   if (localtime (&now)->tm_hour == hour_GMT0)
 373     exit (1);
 374   unset_TZ ();
 375   if (localtime (&now)->tm_hour != hour_unset)
 376     exit (1);
 377   exit (0);
 378 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 379 [# If we have tzset, assume the worst when cross-compiling.
 380 guile_cv_localtime_cache=yes])
 381 else
 382         # If we lack tzset, report that localtime does not cache TZ,
 383         # since we can't invalidate the cache if we don't have tzset.
 384         guile_cv_localtime_cache=no
 385 fi])dnl
 386 AC_MSG_RESULT($guile_cv_localtime_cache)
 387 if test $guile_cv_localtime_cache = yes; then
 388   AC_DEFINE(LOCALTIME_CACHE)
 389 fi
 390
 391 dnl Test whether system calls are restartable by default on the
 392 dnl current system.  If they are not, we put a loop around every system
 393 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 394 dnl change from the default behaviour.  On the other hand, if signals
 395 dnl are restartable then the loop is not installed and when libguile
 396 dnl initialises it also resets the behaviour of each signal to cause a
 397 dnl restart (in case a different runtime had a different default
 398 dnl behaviour for some reason: e.g., different versions of linux seem
 399 dnl to behave differently.)
 400
 401 AC_SYS_RESTARTABLE_SYSCALLS
 402
 403 if test "$enable_regex" = yes; then
 404    if test "$ac_cv_header_regex_h" = yes ||
 405       test "$ac_cv_header_rxposix_h" = yes ||
 406       test "$ac_cv_header_rx_rxposix_h" = yes; then
 407      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 408      [AC_CHECK_LIB(rx, main)
 409       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 410      )
 411      dnl The following should not be necessary, but for some reason
 412      dnl autoheader misses it if we don't include it!
 413      if test "$ac_cv_func_regcomp_norx" = yes ||
 414         test "$ac_cv_func_regcomp_rx" = yes; then
 415        AC_DEFINE(HAVE_REGCOMP)
 416      fi
 417    fi
 418 fi
 419
 420 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 421
 422 # When testing for the presence of alloca, we need to add alloca.o
 423 # explicitly to LIBOBJS to make sure that it is translated to
 424 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 425 AC_FUNC_ALLOCA
 426 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 427
 428 AC_CHECK_MEMBERS([struct stat.st_rdev])
 429 AC_CHECK_MEMBERS([struct stat.st_blksize])
 430
 431 AC_STRUCT_ST_BLOCKS
 432
 433 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 434   [AC_TRY_CPP([#include <sys/stat.h>
 435                #ifndef S_ISLNK
 436                #error no S_ISLNK
 437                #endif],
 438                ac_cv_macro_S_ISLNK=yes,
 439                ac_cv_macro_S_ISLNK=no)])
 440 if test $ac_cv_macro_S_ISLNK = yes; then
 441   AC_DEFINE(HAVE_S_ISLNK)
 442 fi
 443
 444 AC_STRUCT_TIMEZONE
 445 GUILE_STRUCT_UTIMBUF
 446
 447 #--------------------------------------------------------------------
 448 #
 449 # Which way does the stack grow?
 450 #
 451 #--------------------------------------------------------------------
 452
 453 AC_TRY_RUN(aux (l) unsigned long l;
 454              { int x; exit (l >= ((unsigned long)&x)); }
 455            main () { int q; aux((unsigned long)&q); },
 456            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 457
 458 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 459     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 460                 [guile_cv_type_float_fits_long=yes],
 461                 [guile_cv_type_float_fits_long=no],
 462                 [guile_cv_type_float_fits_long=guess-yes])])
 463 case $guile_cv_type_float_fits_long in
 464   "yes" )
 465     AC_DEFINE(SCM_SINGLES)
 466   ;;
 467   "guess-yes" )
 468     AC_DEFINE(SCM_SINGLES)
 469     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 470     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 471   ;;
 472 esac
 473
 474
 475 AC_MSG_CHECKING(for struct linger)
 476 AC_CACHE_VAL(scm_cv_struct_linger,
 477         AC_TRY_COMPILE([
 478 #include <sys/types.h>
 479 #include <sys/socket.h>],
 480                         [struct linger lgr;  lgr.l_linger = 100],
 481                         scm_cv_struct_linger="yes",
 482                         scm_cv_struct_linger="no"))
 483 AC_MSG_RESULT($scm_cv_struct_linger)
 484 if test $scm_cv_struct_linger = yes; then
 485         AC_DEFINE(HAVE_STRUCT_LINGER)
 486 fi
 487
 488
 489 AC_MSG_CHECKING(for struct timespec)
 490 AC_CACHE_VAL(scm_cv_struct_timespec,
 491         AC_TRY_COMPILE([
 492 #include <time.h>],
 493                         [struct timespec t;  t.tv_nsec = 100],
 494                         scm_cv_struct_timespec="yes",
 495                         scm_cv_struct_timespec="no"))
 496 AC_MSG_RESULT($scm_cv_struct_timespec)
 497 if test $scm_cv_struct_timespec = yes; then
 498         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 499 fi
 500
 501 #--------------------------------------------------------------------
 502 #
 503 # Flags for thread support
 504 #
 505 #--------------------------------------------------------------------
 506
 507 ### What thread package has the user asked for?
 508 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 509             , with_threads=no)
 510
 511 ### Turn $with_threads into either the name of a threads package, like
 512 ### `qt', or `no', meaning that threads should not be supported.
 513 AC_MSG_CHECKING(whether to support threads)
 514 case "$with_threads" in
 515   "yes" | "qt" | "coop" | "")
 516     with_threads=qt
 517   ;;
 518   "no" )
 519   ;;
 520   * )
 521     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 522   ;;
 523 esac
 524 AC_MSG_RESULT($with_threads)
 525
 526 ## Make sure the threads package we've chosen is actually supported on
 527 ## the present platform.
 528 case "${with_threads}" in
 529   "qt" )
 530     ## This configures the QuickThreads package, and sets or clears
 531     ## the THREAD_PACKAGE variable if qthreads don't configure
 532     ## correctly.
 533     QTHREADS_CONFIGURE
 534    ;;
 535 esac
 536
 537 ## If we're using threads, bring in some other parts of Guile which
 538 ## work with them.
 539 if test "${THREAD_PACKAGE}" != "" ; then
 540   AC_DEFINE(USE_THREADS, 1)
 541
 542   ## Include the Guile thread interface in the library...
 543   LIBOBJS="$LIBOBJS threads.o"
 544
 545   ## ... and tell it which package to talk to.
 546   case "${THREAD_PACKAGE}" in
 547     "QT" )
 548       AC_DEFINE(USE_COOP_THREADS, 1)
 549     ;;
 550     * )
 551       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 552     ;;
 553   esac
 554
 555   ## Bring in scm_internal_select, if appropriate.
 556   if test $ac_cv_func_gettimeofday = yes &&
 557      test $ac_cv_func_select = yes; then
 558     AC_DEFINE(GUILE_ISELECT, 1)
 559   fi
 560
 561   AC_ARG_ENABLE(linuxthreads,
 562   [  --disable-linuxthreads  disable linuxthreads workaround],,
 563   enable_linuxthreads=yes)
 564
 565   ## Workaround for linuxthreads (optionally disabled)
 566   if test $host_os = linux-gnu -a "$enable_linuxthreads" = yes; then
 567     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 568     AC_CHECK_LIB(pthread, main)
 569   fi
 570 fi
 571 AC_SUBST(LIBGUILEQTHREADS_MAJOR_VERSION)
 572 AC_SUBST(LIBGUILEQTHREADS_MINOR_VERSION)
 573 AC_SUBST(LIBGUILEQTHREADS_REVISION_VERSION)
 574 AC_SUBST(LIBGUILEQTHREADS_VERSION)
 575
 576 ## If we're using GCC, ask for aggressive warnings.
 577 case "$GCC" in
 578   yes )
 579     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 580     ## much stuff with generic function pointers for that to really be
 581     ## less than exasperating.
 582     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 583     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 584     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 585 esac
 586
 587 AC_PROG_AWK
 588
 589 ## If we're creating a shared library (using libtool!), then we'll
 590 ## need to generate a list of .lo files corresponding to the .o files
 591 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 592 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 593
 594 ## We also need to create corresponding .doc and .x files
 595 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 596 EXTRA_DOT_X_FILES="`echo ${LIBOBJS} | sed 's/\.o/.x/g'`"
 597
 598 AC_SUBST(GUILE_MAJOR_VERSION)
 599 AC_SUBST(GUILE_MINOR_VERSION)
 600 AC_SUBST(GUILE_MICRO_VERSION)
 601 AC_SUBST(GUILE_VERSION)
 602 AC_SUBST(LIBGUILE_MAJOR_VERSION)
 603 AC_SUBST(LIBGUILE_MINOR_VERSION)
 604 AC_SUBST(LIBGUILE_REVISION_VERSION)
 605 AC_SUBST(LIBGUILE_VERSION)
 606
 607 dnl Tell guile-config what flags guile users should link against.
 608 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 609 AC_SUBST(GUILE_LIBS)
 610
 611 AC_SUBST(AWK)
 612 AC_SUBST(LIBLOBJS)
 613 AC_SUBST(EXTRA_DOT_DOC_FILES)
 614 AC_SUBST(EXTRA_DOT_X_FILES)
 615
 616 AC_CONFIG_FILES([
 617   Makefile
 618   libguile/Makefile
 619   libguile/guile-snarf
 620   libguile/guile-doc-snarf
 621   libguile/guile-func-name-check
 622   libguile/guile-snarf-docs
 623   libguile/guile-snarf-docs-texi
 624   libguile/versiondat.h
 625   ice-9/Makefile
 626   oop/Makefile
 627   oop/goops/Makefile
 628   scripts/Makefile
 629   srfi/Makefile
 630   qt/Makefile
 631   qt/qt.h
 632   qt/md/Makefile
 633   qt/time/Makefile
 634   guile-config/Makefile
 635   doc/Makefile
 636   examples/Makefile
 637   examples/scripts/Makefile
 638   examples/box/Makefile
 639   examples/box-module/Makefile
 640   examples/box-dynamic/Makefile
 641   examples/box-dynamic-module/Makefile
 642   examples/modules/Makefile
 643   examples/safe/Makefile
 644   test-suite/Makefile
 645   check-guile
 646   guile-tools])
 647
 648 AC_CONFIG_COMMANDS(default,
 649   [ chmod +x libguile/guile-snarf \
 650              libguile/guile-doc-snarf \
 651              libguile/guile-func-name-check \
 652              libguile/guile-snarf-docs \
 653              libguile/guile-snarf-docs-texi \
 654              check-guile \
 655              guile-tools])
 656
 657 AC_OUTPUT
 658
 659 dnl Local Variables:
 660 dnl comment-start: "dnl "
 661 dnl comment-end: ""
 662 dnl comment-start-skip: "\\bdnl\\b\\s *"
 663 dnl End: