configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 Boston, MA 02111-1307, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT(m4_esyscmd(. ./GUILE-VERSION && echo -n ${PACKAGE}),
  31         m4_esyscmd(. ./GUILE-VERSION && echo -n ${GUILE_VERSION}))
  32 AC_CONFIG_SRCDIR(GUILE-VERSION)
  33 AM_INIT_AUTOMAKE([no-define])
  34
  35 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  36 AC_CONFIG_SRCDIR([GUILE-VERSION])
  37
  38 . $srcdir/GUILE-VERSION
  39
  40 AM_MAINTAINER_MODE
  41 AM_CONFIG_HEADER([config.h])
  42 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  43
  44 #--------------------------------------------------------------------
  45 #
  46 # Independent Subdirectories
  47 #
  48 #--------------------------------------------------------------------
  49
  50 AC_CONFIG_SUBDIRS(guile-readline)
  51
  52 #--------------------------------------------------------------------
  53
  54 dnl Some more checks for Win32
  55 AC_CYGWIN
  56 AC_MINGW32
  57 AC_LIBTOOL_WIN32_DLL
  58
  59 AC_PROG_INSTALL
  60 AC_PROG_CC
  61 AC_PROG_CPP
  62 AC_PROG_AWK
  63
  64 AC_AIX
  65 AC_ISC_POSIX
  66 AC_MINIX
  67
  68 AM_PROG_CC_STDC
  69
  70 AC_LIBTOOL_DLOPEN
  71 AC_PROG_LIBTOOL
  72 AC_LIB_LTDL
  73
  74 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  75 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  76
  77 AM_PATH_LISPDIR
  78
  79 #--------------------------------------------------------------------
  80 #
  81 # User options (after above tests that may set default CFLAGS etc.)
  82 #
  83 #--------------------------------------------------------------------
  84
  85 GUILE_ERROR_ON_WARNING="yes"
  86
  87 AC_ARG_ENABLE(error-on-warning,
  88   [  --enable-error-on-warning    treat compile warnings as errors],
  89   [case "${enableval}" in
  90      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  91      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  92      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  93    esac])
  94
  95 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
  96 AC_ARG_ENABLE(debug-freelist,
  97   [  --enable-debug-freelist include garbage collector freelist debugging code],
  98   if test "$enable_debug_freelist" = y \
  99      || test "$enable_debug_freelist" = yes; then
 100     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 101   fi)
 102
 103 AC_ARG_ENABLE(debug-malloc,
 104   [  --enable-debug-malloc   include malloc debugging code],
 105   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 106     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 107       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 108   fi)
 109
 110 SCM_I_GSC_GUILE_DEBUG=0
 111 AC_ARG_ENABLE(guile-debug,
 112   [AC_HELP_STRING([--enable-guile-debug],
 113                   [include internal debugging functions])],
 114   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 115     SCM_I_GSC_GUILE_DEBUG=1
 116   fi)
 117
 118 AC_ARG_ENABLE(arrays,
 119   [AC_HELP_STRING([--disable-arrays],[omit array and uniform array support])],
 120   ,
 121   enable_arrays=yes)
 122
 123 AC_ARG_ENABLE(posix,
 124   [  --disable-posix         omit posix interfaces],,
 125   enable_posix=yes)
 126
 127 AC_ARG_ENABLE(networking,
 128   [  --disable-networking    omit networking interfaces],,
 129   enable_networking=yes)
 130
 131 AC_ARG_ENABLE(regex,
 132   [  --disable-regex         omit regular expression interfaces],,
 133   enable_regex=yes)
 134
 135 AC_ARG_ENABLE([discouraged],
 136   AC_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 137
 138 if test "$enable_discouraged" = no; then
 139   SCM_I_GSC_ENABLE_DISCOURAGED=0
 140 else
 141   SCM_I_GSC_ENABLE_DISCOURAGED=1
 142 fi
 143
 144 AC_ARG_ENABLE([deprecated],
 145   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 146
 147 if test "$enable_deprecated" = no; then
 148   SCM_I_GSC_ENABLE_DEPRECATED=0
 149 else
 150   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 151     warn_default=summary
 152   elif test "$enable_deprecated" = shutup; then
 153     warn_default=no
 154   else
 155     warn_default=$enable_deprecated
 156   fi
 157   SCM_I_GSC_ENABLE_DEPRECATED=1
 158   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 159   [Define this to control the default warning level for deprecated features.])
 160 fi
 161
 162 AC_ARG_ENABLE(elisp,
 163   [  --disable-elisp         omit Emacs Lisp support],,
 164   enable_elisp=yes)
 165
 166 #--------------------------------------------------------------------
 167
 168 dnl Check for dynamic linking
 169
 170 use_modules=yes
 171 AC_ARG_WITH(modules,
 172 [  --with-modules[=FILES]  Add support for dynamic modules],
 173 use_modules="$withval")
 174 test -z "$use_modules" && use_modules=yes
 175 DLPREOPEN=
 176 if test "$use_modules" != no; then
 177   if test "$use_modules" = yes; then
 178     DLPREOPEN="-dlpreopen force"
 179   else
 180     DLPREOPEN="-export-dynamic"
 181     for module in $use_modules; do
 182       DLPREOPEN="$DLPREOPEN -dlopen $module"
 183     done
 184   fi
 185 fi
 186
 187 dnl files which are destined for separate modules.
 188
 189 if test "$use_modules" != no; then
 190    AC_LIBOBJ([dynl])
 191 fi
 192
 193 SCM_I_GSC_HAVE_ARRAYS=0
 194 if test "$enable_arrays" = yes; then
 195    AC_LIBOBJ([ramap])
 196    AC_LIBOBJ([unif])
 197    SCM_I_GSC_HAVE_ARRAYS=1
 198 fi
 199
 200 if test "$enable_posix" = yes; then
 201    AC_LIBOBJ([filesys])
 202    AC_LIBOBJ([posix])
 203    AC_DEFINE(HAVE_POSIX, 1,
 204      [Define this if you want support for POSIX system calls in Guile.])
 205 fi
 206
 207 if test "$enable_networking" = yes; then
 208    AC_LIBOBJ([net_db])
 209    AC_LIBOBJ([socket])
 210    AC_DEFINE(HAVE_NETWORKING, 1,
 211      [Define this if you want support for networking in Guile.])
 212 fi
 213
 214 if test "$enable_debug_malloc" = yes; then
 215    AC_LIBOBJ([debug-malloc])
 216 fi
 217
 218 if test "$enable_elisp" = yes; then
 219   SCM_I_GSC_ENABLE_ELISP=1
 220 else
 221   SCM_I_GSC_ENABLE_ELISP=0
 222 fi
 223
 224 AC_C_CONST
 225
 226 AC_C_INLINE
 227 if test "$ac_cv_c_inline" != no; then
 228   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 229 else
 230   SCM_I_GSC_C_INLINE=NULL
 231 fi
 232
 233 AC_C_BIGENDIAN
 234
 235 AC_CHECK_SIZEOF(char)
 236 AC_CHECK_SIZEOF(unsigned char)
 237 AC_CHECK_SIZEOF(short)
 238 AC_CHECK_SIZEOF(unsigned short)
 239 AC_CHECK_SIZEOF(int)
 240 AC_CHECK_SIZEOF(unsigned int)
 241 AC_CHECK_SIZEOF(long)
 242 AC_CHECK_SIZEOF(unsigned long)
 243 AC_CHECK_SIZEOF(size_t)
 244 AC_CHECK_SIZEOF(long long)
 245 AC_CHECK_SIZEOF(unsigned long long)
 246 AC_CHECK_SIZEOF(__int64)
 247 AC_CHECK_SIZEOF(unsigned __int64)
 248 AC_CHECK_SIZEOF(void *)
 249 AC_CHECK_SIZEOF(intptr_t)
 250 AC_CHECK_SIZEOF(uintptr_t)
 251 AC_CHECK_SIZEOF(ptrdiff_t)
 252 AC_CHECK_SIZEOF(size_t)
 253
 254 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 255   AC_MSG_ERROR(sizes of long and void* are not identical)
 256 fi
 257
 258 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 259   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 260 else
 261   SCM_I_GSC_T_PTRDIFF='"long"'
 262 fi
 263 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 264
 265 AC_CHECK_HEADERS([stdint.h])
 266 AC_CHECK_HEADERS([inttypes.h])
 267
 268 AC_CHECK_SIZEOF(intmax_t)
 269
 270 SCM_I_GSC_NEEDS_STDINT_H=0
 271 SCM_I_GSC_NEEDS_INTTYPES_H=0
 272
 273 ### intptr and uintptr (try not to use inttypes if we don't have to)
 274 if test "$ac_cv_header_inttypes_h" = yes; then
 275   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 276     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 277 #include <stdio.h>])
 278     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 279       SCM_I_GSC_NEEDS_INTTYPES_H=1
 280     fi
 281   fi
 282   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 283     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 284 #include <stdio.h>])
 285     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 286       SCM_I_GSC_NEEDS_INTTYPES_H=1
 287     fi
 288   fi
 289 fi
 290
 291 ### See what's provided by stdint.h
 292 if test "$ac_cv_header_stdint_h" = yes; then
 293    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 294    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 295    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 296    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 297    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 298    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 299    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 300    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 301    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 302    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 303 fi
 304
 305 # so we don't get confused by the cache (wish there was a better way
 306 # to check particular headers for the same type...)
 307
 308 unset ac_cv_type_int8_t
 309 unset ac_cv_type_uint8_t
 310 unset ac_cv_type_int16_t
 311 unset ac_cv_type_uint16_t
 312 unset ac_cv_type_int32_t
 313 unset ac_cv_type_uint32_t
 314 unset ac_cv_type_int64_t
 315 unset ac_cv_type_uint64_t
 316 unset ac_cv_type_intmax_t
 317 unset ac_cv_type_uintmax_t
 318
 319 ### See what's provided by inttypes.h
 320 if test "$ac_cv_header_inttypes_h" = yes; then
 321   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 322   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 323   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 324   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 325   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 326   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 327   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 328   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 329   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 330   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 331 fi
 332
 333 # Try hard to find definitions for some required scm_t_*int* types.
 334
 335 ### Required type scm_t_int8
 336 if test "$scm_stdint_has_int8"; then
 337   SCM_I_GSC_T_INT8='"int8_t"'
 338   SCM_I_GSC_NEEDS_STDINT_H=1
 339 elif test "$scm_inttypes_has_int8"; then
 340   SCM_I_GSC_T_INT8='"int8_t"'
 341   SCM_I_GSC_NEEDS_INTTYPES_H=1
 342 elif test "$ac_cv_sizeof_char" -eq 1; then
 343   SCM_I_GSC_T_INT8='"signed char"'
 344 else
 345   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 346 fi
 347 AC_SUBST([SCM_I_GSC_T_INT8])
 348
 349 ### Required type scm_t_uint8
 350 if test "$scm_stdint_has_uint8"; then
 351   SCM_I_GSC_T_UINT8='"uint8_t"'
 352   SCM_I_GSC_NEEDS_STDINT_H=1
 353 elif test "$scm_inttypes_has_uint8"; then
 354   SCM_I_GSC_T_UINT8='"uint8_t"'
 355   SCM_I_GSC_NEEDS_INTTYPES_H=1
 356 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 357   SCM_I_GSC_T_UINT8='"unsigned char"'
 358 else
 359   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 360 fi
 361 AC_SUBST([SCM_I_GSC_T_UINT8])
 362
 363 ### Required type scm_t_int16 (ANSI C says int or short might work)
 364 if test "$scm_stdint_has_int16"; then
 365   SCM_I_GSC_T_INT16='"int16_t"'
 366   SCM_I_GSC_NEEDS_STDINT_H=1
 367 elif test "$scm_inttypes_has_int16"; then
 368   SCM_I_GSC_T_INT16='"int16_t"'
 369   SCM_I_GSC_NEEDS_INTTYPES_H=1
 370 elif test "$ac_cv_sizeof_int" -eq 2; then
 371   SCM_I_GSC_T_INT16='"int"'
 372 elif test "$ac_cv_sizeof_short" -eq 2; then
 373   SCM_I_GSC_T_INT16='"short"'
 374 else
 375   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 376 fi
 377 AC_SUBST([SCM_I_GSC_T_INT16])
 378
 379 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 380 if test "$scm_stdint_has_uint16"; then
 381   SCM_I_GSC_T_UINT16='"uint16_t"'
 382   SCM_I_GSC_NEEDS_STDINT_H=1
 383 elif test "$scm_inttypes_has_uint16"; then
 384   SCM_I_GSC_T_UINT16='"uint16_t"'
 385   SCM_I_GSC_NEEDS_INTTYPES_H=1
 386 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 387   SCM_I_GSC_T_UINT16='"unsigned int"'
 388 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 389   SCM_I_GSC_T_UINT16='"unsigned short"'
 390 else
 391   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 392 fi
 393 AC_SUBST([SCM_I_GSC_T_UINT16])
 394
 395
 396 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 397 if test "$scm_stdint_has_int32"; then
 398   SCM_I_GSC_T_INT32='"int32_t"'
 399   SCM_I_GSC_NEEDS_STDINT_H=1
 400 elif test "$scm_inttypes_has_int32"; then
 401   SCM_I_GSC_T_INT32='"int32_t"'
 402   SCM_I_GSC_NEEDS_INTTYPES_H=1
 403 elif test "$ac_cv_sizeof_int" -eq 4; then
 404   SCM_I_GSC_T_INT32='"int"'
 405 elif test "$ac_cv_sizeof_long" -eq 4; then
 406   SCM_I_GSC_T_INT32='"long"'
 407 elif test "$ac_cv_sizeof_short" -eq 4; then
 408   SCM_I_GSC_T_INT32='"short"'
 409 else
 410   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 411 fi
 412 AC_SUBST([SCM_I_GSC_T_INT32])
 413
 414 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 415 if test "$scm_stdint_has_uint32"; then
 416   SCM_I_GSC_T_UINT32='"uint32_t"'
 417   SCM_I_GSC_NEEDS_STDINT_H=1
 418 elif test "$scm_inttypes_has_uint32"; then
 419   SCM_I_GSC_T_UINT32='"uint32_t"'
 420   SCM_I_GSC_NEEDS_INTTYPES_H=1
 421 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 422   SCM_I_GSC_T_UINT32='"unsigned int"'
 423 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 424   SCM_I_GSC_T_UINT32='"unsigned long"'
 425 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 426   SCM_I_GSC_T_UINT32='"unsigned short"'
 427 else
 428   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 429 fi
 430 AC_SUBST([SCM_I_GSC_T_UINT32])
 431
 432 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 433 ### Also try 'long long' and '__int64' if we have it.
 434 SCM_I_GSC_T_INT64=0
 435 if test "$scm_stdint_has_int64"; then
 436   SCM_I_GSC_T_INT64='"int64_t"'
 437   SCM_I_GSC_NEEDS_STDINT_H=1
 438 elif test "$scm_inttypes_has_int64"; then
 439   SCM_I_GSC_T_INT64='"int64_t"'
 440   SCM_I_GSC_NEEDS_INTTYPES_H=1
 441 elif test "$ac_cv_sizeof_int" -eq 8; then
 442   SCM_I_GSC_T_INT64='"int"'
 443 elif test "$ac_cv_sizeof_long" -eq 8; then
 444   SCM_I_GSC_T_INT64='"long"'
 445 elif test "$ac_cv_sizeof_short" -eq 8; then
 446   SCM_I_GSC_T_INT64='"short"'
 447 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 448   SCM_I_GSC_T_INT64='"long long"'
 449 elif test "$ac_cv_sizeof___int64" -eq 8; then
 450   SCM_I_GSC_T_INT64='"__int64"'
 451 else
 452   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 453 fi
 454 AC_SUBST([SCM_I_GSC_T_INT64])
 455
 456
 457 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 458 ### Also try 'long long' and '__int64' if we have it.
 459 SCM_I_GSC_T_UINT64=0
 460 if test "$scm_stdint_has_uint64"; then
 461   SCM_I_GSC_T_UINT64='"uint64_t"'
 462   SCM_I_GSC_NEEDS_STDINT_H=1
 463 elif test "$scm_inttypes_has_uint64"; then
 464   SCM_I_GSC_T_UINT64='"uint64_t"'
 465   SCM_I_GSC_NEEDS_INTTYPES_H=1
 466 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 467   SCM_I_GSC_T_UINT64='"unsigned int"'
 468 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 469   SCM_I_GSC_T_UINT64='"unsigned long"'
 470 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 471   SCM_I_GSC_T_UINT64='"unsigned short"'
 472 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 473   SCM_I_GSC_T_UINT64='"unsigned long long"'
 474 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 475   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 476 else
 477   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 478 fi
 479 AC_SUBST([SCM_I_GSC_T_UINT64])
 480
 481 ### Required type scm_t_intmax
 482 ###
 483 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 484 ### none of them is available, we use 'long'.
 485 ###
 486 SCM_I_GSC_T_INTMAX=0
 487 if test "$scm_stdint_has_intmax"; then
 488   SCM_I_GSC_T_INTMAX='"intmax_t"'
 489   SCM_I_GSC_NEEDS_STDINT_H=1
 490 elif test "$scm_inttypes_has_intmax"; then
 491   SCM_I_GSC_T_INTMAX='"intmax_t"'
 492   SCM_I_GSC_NEEDS_INTTYPES_H=1
 493 elif test "$ac_cv_sizeof___int64" -ne 0; then
 494   SCM_I_GSC_T_INTMAX='"__int64"'
 495 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 496   SCM_I_GSC_T_INTMAX='"long long"'
 497 else
 498   SCM_I_GSC_T_INTMAX='"long"'
 499 fi
 500 AC_SUBST([SCM_I_GSC_T_INTMAX])
 501
 502 ### Required type scm_t_uintmax
 503 ###
 504 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 505 ### this order.  When none of them is available, we use 'unsigned long'.
 506 ###
 507 SCM_I_GSC_T_UINTMAX=0
 508 if test "$scm_stdint_has_uintmax"; then
 509   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 510   SCM_I_GSC_NEEDS_STDINT_H=1
 511 elif test "$scm_inttypes_has_uintmax"; then
 512   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 513   SCM_I_GSC_NEEDS_INTTYPES_H=1
 514 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 515   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 516 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 517   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 518 else
 519   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 520 fi
 521 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 522
 523
 524 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 525 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 526
 527 AC_HEADER_STDC
 528 AC_HEADER_DIRENT
 529 AC_HEADER_TIME
 530 AC_HEADER_SYS_WAIT
 531
 532 # Reasons for testing:
 533 #   fenv.h - available in C99, but not older systems
 534 #
 535 AC_CHECK_HEADERS([fenv.h io.h libc.h limits.h malloc.h memory.h string.h \
 536 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 537 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 538 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 539 direct.h])
 540
 541 GUILE_HEADER_LIBC_WITH_UNISTD
 542
 543 AC_TYPE_GETGROUPS
 544 AC_TYPE_SIGNAL
 545 AC_TYPE_MODE_T
 546
 547 if test $MINGW32 = no; then
 548         AC_CHECK_LIB(m, main)
 549 fi
 550 AC_CHECK_FUNCS(gethostbyname)
 551 if test $ac_cv_func_gethostbyname = no; then
 552     AC_CHECK_LIB(nsl, gethostbyname)
 553 fi
 554
 555 AC_CHECK_FUNCS(connect)
 556 if test $ac_cv_func_connect = no; then
 557     AC_CHECK_LIB(socket, connect)
 558 fi
 559
 560 dnl
 561 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 562 dnl
 563 EXTRA_DEFS=""
 564 if test "$MINGW32" = "yes" ; then
 565     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 566       [Define if you have the <winsock2.h> header file.])])
 567     AC_CHECK_LIB(ws2_32, main)
 568     AC_LIBOBJ([win32-uname])
 569     AC_LIBOBJ([win32-dirent])
 570     if test "$enable_networking" = yes ; then
 571       AC_LIBOBJ([win32-socket])
 572     fi
 573     if test "$enable_shared" = yes ; then
 574       EXTRA_DEFS="-DSCM_IMPORT"
 575       AC_DEFINE(USE_DLL_IMPORT, 1,
 576         [Define if you need additional CPP macros on Win32 platforms.])
 577     fi
 578     if test x"$enable_ltdl_install" = x"yes" ; then
 579       INCLTDL="-DLIBLTDL_DLL_IMPORT $INCLTDL"
 580     fi
 581 fi
 582 AC_SUBST(EXTRA_DEFS)
 583
 584 # FIXME: check to see if we still need these.
 585 #AC_SUBST(INCLTDL)
 586 #AC_SUBST(LIBLTDL)
 587
 588 AC_SUBST(DLPREOPEN)
 589
 590 # Reasons for testing:
 591 #   crt_externs.h - Darwin specific
 592 #
 593 AC_CHECK_HEADERS([assert.h crt_externs.h])
 594
 595 # Reasons for testing:
 596 #   DINFINITY - OSF specific
 597 #   DQNAN - OSF specific
 598 #       (DINFINITY and DQNAN are actually global variables, not functions)
 599 #   fesetround - available in C99, but not older systems
 600 #   gmtime_r - recent posix, not on old systems
 601 #   readdir_r - recent posix, not on old systems
 602 #   sysconf - not on old systems
 603 #   _NSGetEnviron - Darwin specific
 604 #
 605 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid fesetround ftime fchown getcwd geteuid gettimeofday gmtime_r lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv _NSGetEnviron])
 606
 607 # Reasons for testing:
 608 #   netdb.h - not in mingw
 609 #   sys/param.h - not in mingw
 610 #
 611 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 612 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 613
 614 # crypt() may or may not be available, for instance in some countries there
 615 # are restrictions on cryptography.
 616 #
 617 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 618 # -lcrypt library (eg. Debian GNU/Linux).
 619 #
 620 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 621 # be careful to avoid -lcrypt in this case, since libtool will see there's
 622 # only a static libcrypt and decide to build only a static libguile.
 623 #
 624 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 625 # libraries already in that list.
 626 #
 627 AC_SEARCH_LIBS(crypt, crypt,
 628   [AC_DEFINE(HAVE_CRYPT,1,
 629              [Define to 1 if you have the `crypt' function.])])
 630
 631 dnl GMP tests
 632 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 633   [AC_MSG_ERROR([GNU MP not found, see http://swox.com/gmp])])
 634
 635 # mpz_import is a macro so we need to include <gmp.h>
 636 AC_TRY_LINK([#include <gmp.h>],
 637             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 638   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see http://swox.com/gmp])])
 639
 640 dnl i18n tests
 641 #AC_CHECK_HEADERS([libintl.h])
 642 #AC_CHECK_FUNCS(gettext)
 643 #if test $ac_cv_func_gettext = no; then
 644 #   AC_CHECK_LIB(intl, gettext)
 645 #fi
 646 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 647 AM_GNU_GETTEXT([external], [need-ngettext])
 648
 649 ### Some systems don't declare some functions.  On such systems, we
 650 ### need to at least provide our own K&R-style declarations.
 651
 652 ### GUILE_FUNC_DECLARED(function, headerfile)
 653
 654 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 655 ### not there, #define MISSING_FUNCTION_DECL.
 656 AC_DEFUN([GUILE_FUNC_DECLARED], [
 657   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 658     AC_EGREP_HEADER($1, $2,
 659                     guile_cv_func_$1_declared=yes,
 660                     guile_cv_func_$1_declared=no))
 661   if test [x$guile_cv_func_]$1[_declared] = xno; then
 662     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 663       [Define if the operating system supplies $1 without declaring it.])
 664   fi
 665 ])
 666
 667 GUILE_FUNC_DECLARED(sleep, unistd.h)
 668 GUILE_FUNC_DECLARED(usleep, unistd.h)
 669
 670 AC_CHECK_DECLS([strptime],,,
 671 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 672 #include <time.h>])
 673
 674 ### On some systems usleep has no return value.  If it does have one,
 675 ### we'd like to return it; otherwise, we'll fake it.
 676 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 677   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 678                    unistd.h,
 679                    [guile_cv_func_usleep_return_type=void],
 680                    [guile_cv_func_usleep_return_type=int])])
 681 case "$guile_cv_func_usleep_return_type" in
 682   "void" )
 683     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 684       [Define if the system headers declare usleep to return void.])
 685   ;;
 686 esac
 687
 688 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 689 if test -n "$have_sys_un_h" ; then
 690   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 691     [Define if the system supports Unix-domain (file-domain) sockets.])
 692 fi
 693
 694 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 695
 696 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 697                setnetent    getnetent    endnetent    dnl
 698                setprotoent  getprotoent  endprotoent  dnl
 699                setservent   getservent   endservent   dnl
 700                getnetbyaddr getnetbyname dnl
 701                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 702                inet_pton inet_ntop)
 703
 704 # struct sockaddr field sin_len is only present on BSD systems.
 705 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 706 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 707 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 708 [#ifdef HAVE_SYS_TYPES_H
 709 #include <sys/types.h>
 710 #endif
 711 #include <netinet/in.h>])
 712
 713 AC_MSG_CHECKING(for __libc_stack_end)
 714 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 715 [AC_TRY_LINK([#include <stdio.h>
 716 extern char *__libc_stack_end;],
 717              [printf("%p", (char*) __libc_stack_end);],
 718              guile_cv_have_libc_stack_end=yes,
 719              guile_cv_have_libc_stack_end=no)])
 720 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 721
 722 if test $guile_cv_have_libc_stack_end = yes; then
 723   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 724            [Define if you have the __libc_stack_end variable.])
 725 fi
 726
 727 dnl Some systems do not declare this.  Some systems do declare it, as a
 728 dnl macro.  With cygwin it may be in a DLL.
 729
 730 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 731 AC_CACHE_VAL(guile_cv_have_h_errno,
 732 [AC_TRY_COMPILE([#include <netdb.h>],
 733 [int a = h_errno;],
 734 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 735 AC_MSG_RESULT($guile_cv_have_h_errno)
 736 if test $guile_cv_have_h_errno = yes; then
 737   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 738 fi
 739
 740 AC_MSG_CHECKING(whether uint32_t is defined)
 741 AC_CACHE_VAL(guile_cv_have_uint32_t,
 742   [AC_TRY_COMPILE([#include <sys/types.h>
 743                    #if HAVE_STDINT_H
 744                    #include <stdint.h>
 745                    #endif
 746                    #ifndef __MINGW32__
 747                    #include <netdb.h>
 748                    #endif],
 749                   [uint32_t a;],
 750                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 751 AC_MSG_RESULT($guile_cv_have_uint32_t)
 752 if test $guile_cv_have_uint32_t = yes; then
 753   AC_DEFINE(HAVE_UINT32_T, 1,
 754     [Define if uint32_t typedef is defined when netdb.h is include.])
 755 fi
 756
 757 AC_MSG_CHECKING(for working IPv6 support)
 758 AC_CACHE_VAL(guile_cv_have_ipv6,
 759 [AC_TRY_COMPILE([
 760 #ifdef HAVE_SYS_TYPES_H
 761 #include <sys/types.h>
 762 #endif
 763 #include <netinet/in.h>
 764 #include <sys/socket.h>],
 765 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 766 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 767 AC_MSG_RESULT($guile_cv_have_ipv6)
 768 if test $guile_cv_have_ipv6 = yes; then
 769   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 770 fi
 771
 772 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 773 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 774 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 775 [AC_TRY_COMPILE([
 776 #ifdef HAVE_SYS_TYPES_H
 777 #include <sys/types.h>
 778 #endif
 779 #include <netinet/in.h>],
 780 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 781 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 782 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 783 if test $guile_cv_have_sin6_scope_id = yes; then
 784   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 785     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 786 fi
 787
 788 # struct sockaddr_in6 field sin_len is only present on BSD systems
 789 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 790 [#ifdef HAVE_SYS_TYPES_H
 791 #include <sys/types.h>
 792 #endif
 793 #include <netinet/in.h>])
 794
 795 AC_MSG_CHECKING(whether localtime caches TZ)
 796 AC_CACHE_VAL(guile_cv_localtime_cache,
 797 [if test x$ac_cv_func_tzset = xyes; then
 798 AC_TRY_RUN([#include <time.h>
 799 #if STDC_HEADERS
 800 # include <stdlib.h>
 801 #endif
 802 extern char **environ;
 803 unset_TZ ()
 804 {
 805   char **from, **to;
 806   for (to = from = environ; (*to = *from); from++)
 807     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 808       to++;
 809 }
 810 char TZ_GMT0[] = "TZ=GMT0";
 811 char TZ_PST8[] = "TZ=PST8";
 812 main()
 813 {
 814   time_t now = time ((time_t *) 0);
 815   int hour_GMT0, hour_unset;
 816   if (putenv (TZ_GMT0) != 0)
 817     exit (1);
 818   hour_GMT0 = localtime (&now)->tm_hour;
 819   unset_TZ ();
 820   hour_unset = localtime (&now)->tm_hour;
 821   if (putenv (TZ_PST8) != 0)
 822     exit (1);
 823   if (localtime (&now)->tm_hour == hour_GMT0)
 824     exit (1);
 825   unset_TZ ();
 826   if (localtime (&now)->tm_hour != hour_unset)
 827     exit (1);
 828   exit (0);
 829 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 830 [# If we have tzset, assume the worst when cross-compiling.
 831 guile_cv_localtime_cache=yes])
 832 else
 833         # If we lack tzset, report that localtime does not cache TZ,
 834         # since we can't invalidate the cache if we don't have tzset.
 835         guile_cv_localtime_cache=no
 836 fi])dnl
 837 AC_MSG_RESULT($guile_cv_localtime_cache)
 838 if test $guile_cv_localtime_cache = yes; then
 839   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 840 fi
 841
 842 dnl Test whether system calls are restartable by default on the
 843 dnl current system.  If they are not, we put a loop around every system
 844 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 845 dnl change from the default behaviour.  On the other hand, if signals
 846 dnl are restartable then the loop is not installed and when libguile
 847 dnl initialises it also resets the behaviour of each signal to cause a
 848 dnl restart (in case a different runtime had a different default
 849 dnl behaviour for some reason: e.g., different versions of linux seem
 850 dnl to behave differently.)
 851
 852 AC_SYS_RESTARTABLE_SYSCALLS
 853
 854 if test "$enable_regex" = yes; then
 855    if test "$ac_cv_header_regex_h" = yes ||
 856       test "$ac_cv_header_rxposix_h" = yes ||
 857       test "$ac_cv_header_rx_rxposix_h" = yes; then
 858      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 859      [AC_CHECK_LIB(rx, main)
 860       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 861      [AC_CHECK_LIB(regex, main)
 862       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 863      )
 864      dnl The following should not be necessary, but for some reason
 865      dnl autoheader misses it if we don't include it!
 866      if test "$ac_cv_func_regcomp_norx" = yes ||
 867         test "$ac_cv_func_regcomp_regex" = yes ||
 868         test "$ac_cv_func_regcomp_rx" = yes; then
 869        AC_DEFINE(HAVE_REGCOMP, 1,
 870          [This is included as part of a workaround for a autoheader bug.])
 871      fi
 872    fi
 873 fi
 874
 875 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 876
 877 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 878
 879 # Reasons for testing:
 880 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 881 #                                older systems
 882 #   sincos - GLIBC extension
 883 #
 884 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
 885
 886 # C99 specifies isinf and isnan as macros.
 887 # HP-UX provides only macros, no functions.
 888 # glibc 2.3.2 provides both macros and functions.
 889 # IRIX 6.5 and Solaris 8 only provide functions.
 890 #
 891 # The following tests detect isinf and isnan either as functions or as
 892 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
 893 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
 894 #
 895 AC_MSG_CHECKING([for isinf])
 896 AC_LINK_IFELSE(
 897 [#include <math.h>
 898 int main () { return (isinf(0.0) != 0); }],
 899   [AC_MSG_RESULT([yes])
 900    AC_DEFINE(HAVE_ISINF, 1,
 901              [Define to 1 if you have the `isinf' macro or function.])],
 902   [AC_MSG_RESULT([no])])
 903 AC_MSG_CHECKING([for isnan])
 904 AC_LINK_IFELSE(
 905 [#include <math.h>
 906 #ifdef __MINGW32__
 907 #define isnan _isnan
 908 #endif
 909 int main () { return (isnan(0.0) != 0); }],
 910   [AC_MSG_RESULT([yes])
 911    AC_DEFINE(HAVE_ISNAN, 1,
 912              [Define to 1 if you have the `isnan' macro or function.])],
 913   [AC_MSG_RESULT([no])])
 914
 915 # We must have a proper stack-using alloca in order for stack-copying
 916 # continuations to work properly.  If we don't find a native one,
 917 # abort.
 918
 919 AC_FUNC_ALLOCA
 920 if test "$ALLOCA" = "alloca.o"
 921 then
 922   AC_ERROR([No native alloca found.])
 923 fi
 924
 925 AC_CHECK_MEMBERS([struct stat.st_rdev])
 926 AC_CHECK_MEMBERS([struct stat.st_blksize])
 927
 928 AC_STRUCT_ST_BLOCKS
 929
 930 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 931   [AC_TRY_CPP([#include <sys/stat.h>
 932                #ifndef S_ISLNK
 933                #error no S_ISLNK
 934                #endif],
 935                ac_cv_macro_S_ISLNK=yes,
 936                ac_cv_macro_S_ISLNK=no)])
 937 if test $ac_cv_macro_S_ISLNK = yes; then
 938   AC_DEFINE(HAVE_S_ISLNK, 1,
 939     [Define this if your system defines S_ISLNK in sys/stat.h.])
 940 fi
 941
 942 AC_STRUCT_TIMEZONE
 943 GUILE_STRUCT_UTIMBUF
 944
 945 #--------------------------------------------------------------------
 946 #
 947 # Which way does the stack grow?
 948 #
 949 #--------------------------------------------------------------------
 950
 951 SCM_I_GSC_STACK_GROWS_UP=0
 952 AC_TRY_RUN(aux (l) unsigned long l;
 953              { int x; exit (l >= ((unsigned long)&x)); }
 954            main () { int q; aux((unsigned long)&q); },
 955            [SCM_I_GSC_STACK_GROWS_UP=1],
 956            [],
 957            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
 958
 959 AC_CHECK_SIZEOF(float)
 960 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
 961     AC_DEFINE(SCM_SINGLES, 1,
 962               [Define this if floats are the same size as longs.])
 963 fi
 964
 965 AC_MSG_CHECKING(for struct linger)
 966 AC_CACHE_VAL(scm_cv_struct_linger,
 967         AC_TRY_COMPILE([
 968 #include <sys/types.h>
 969 #include <sys/socket.h>],
 970                         [struct linger lgr;  lgr.l_linger = 100],
 971                         scm_cv_struct_linger="yes",
 972                         scm_cv_struct_linger="no"))
 973 AC_MSG_RESULT($scm_cv_struct_linger)
 974 if test $scm_cv_struct_linger = yes; then
 975         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 976           [Define this if your system defines struct linger, for use with the
 977            getsockopt and setsockopt system calls.])
 978 fi
 979
 980
 981 AC_MSG_CHECKING(for struct timespec)
 982 AC_CACHE_VAL(scm_cv_struct_timespec,
 983         AC_TRY_COMPILE([
 984 #include <time.h>],
 985                         [struct timespec t;  t.tv_nsec = 100],
 986                         scm_cv_struct_timespec="yes",
 987                         scm_cv_struct_timespec="no"))
 988 AC_MSG_RESULT($scm_cv_struct_timespec)
 989 if test $scm_cv_struct_timespec = yes; then
 990   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 991     [Define this if your system defines struct timespec via <time.h>.])
 992 fi
 993
 994 #--------------------------------------------------------------------
 995 #
 996 # Flags for thread support
 997 #
 998 #--------------------------------------------------------------------
 999
1000 SCM_I_GSC_USE_PTHREAD_THREADS=0
1001 SCM_I_GSC_USE_NULL_THREADS=0
1002 SCM_I_GSC_USE_COOP_THREADS=0
1003 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1004 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1005 AC_SUBST([SCM_I_GSC_USE_COOP_THREADS])
1006
1007 ### What thread package has the user asked for?
1008 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1009             , with_threads=yes)
1010
1011 case "$with_threads" in
1012   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1013     ACX_PTHREAD(CC="$PTHREAD_CC"
1014       LIBS="$PTHREAD_LIBS $LIBS"
1015       SCM_I_GSC_USE_PTHREAD_THREADS=1
1016       with_threads="pthreads",
1017       with_threads="null")
1018
1019     AC_MSG_CHECKING(if pthread_mutexattr_settype is declared)
1020     AC_CACHE_VAL(guile_cv_mutexattr_settype_declared,
1021       [AC_TRY_COMPILE([#include <pthread.h>],
1022           [int pthread_mutexattr_settype (int, int);],
1023           guile_cv_mutexattr_settype_declared=no,
1024           guile_cv_mutexattr_settype_declared=yes)])
1025     AC_MSG_RESULT($guile_cv_mutexattr_settype_declared)
1026     if test $guile_cv_mutexattr_settype_declared = yes; then
1027       AC_DEFINE(SCM_MUTEXATTR_SETTYPE_DECLARED, 1,
1028           [Define if pthread.h declares pthread_mutexattr_settype.])
1029     fi
1030
1031     AC_MSG_CHECKING(how to get a fast mutex)
1032     AC_CACHE_VAL(guile_cv_have_mutex_fast,
1033       [AC_TRY_COMPILE([#include <pthread.h>],
1034           [int a = PTHREAD_MUTEX_ADAPTIVE_NP;],
1035           guile_cv_have_mutex_fast=PTHREAD_MUTEX_ADAPTIVE_NP,
1036           guile_cv_have_mutex_fast=none)])
1037     AC_MSG_RESULT($guile_cv_have_mutex_fast)
1038     if test ! $guile_cv_have_mutex_fast = none; then
1039       AC_DEFINE_UNQUOTED(SCM_MUTEX_FAST, $guile_cv_have_mutex_fast,
1040           [The mutex kind enum for fast mutexes.])
1041     fi
1042
1043     AC_MSG_CHECKING(how to get a recursive mutex)
1044     AC_CACHE_VAL(guile_cv_have_mutex_recursive,
1045       [AC_TRY_COMPILE([#include <pthread.h>],
1046         [int a = PTHREAD_MUTEX_RECURSIVE_NP;],
1047          guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE_NP)
1048       if test -z "$guile_cv_have_mutex_recursive"; then
1049           AC_TRY_COMPILE([#include <pthread.h>],
1050             [int a = PTHREAD_MUTEX_RECURSIVE;],
1051             guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE,
1052             guile_cv_have_mutex_recursive=none)
1053         fi])
1054     AC_MSG_RESULT($guile_cv_have_mutex_recursive)
1055     if test ! $guile_cv_have_mutex_recursive = none; then
1056       AC_DEFINE_UNQUOTED(SCM_MUTEX_RECURSIVE, $guile_cv_have_mutex_recursive,
1057          [The mutex kind enum for recursive mutexes.])
1058     fi
1059
1060     # On Solaris, sched_yield lives in -lrt.
1061     AC_SEARCH_LIBS(sched_yield, rt)
1062
1063   ;;
1064 esac
1065
1066 case "$with_threads" in
1067   "pthreads")
1068   ;;
1069   "no" | "null")
1070     SCM_I_GSC_USE_NULL_THREADS=1
1071     with_threads="null-threads"
1072   ;;
1073   * )
1074     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1075   ;;
1076 esac
1077
1078 AC_MSG_CHECKING(what kind of threads to support)
1079 AC_MSG_RESULT($with_threads)
1080
1081 ## Cross building
1082 if test "$cross_compiling" = "yes"; then
1083   AC_MSG_CHECKING(cc for build)
1084   ## /usr/bin/cc still uses wrong assembler
1085   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1086   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1087 else
1088   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1089 fi
1090
1091 ## AC_MSG_CHECKING("if we are cross compiling")
1092 ## AC_MSG_RESULT($cross_compiling)
1093 if test "$cross_compiling" = "yes"; then
1094    AC_MSG_RESULT($CC_FOR_BUILD)
1095 fi
1096
1097 ## No need as yet to be more elaborate
1098 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1099
1100 AC_SUBST(cross_compiling)
1101 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1102 AC_SUBST(CCLD_FOR_BUILD)
1103
1104 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1105 ## --HOST is the platform that PACKAGE is compiled for.
1106 HOST_CC="$CC_FOR_BUILD"
1107 AC_SUBST(HOST_CC)
1108
1109 if test "$cross_compiling" = "yes"; then
1110   AC_MSG_CHECKING(guile for build)
1111   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1112 else
1113   GUILE_FOR_BUILD='$(preinstguile)'
1114 fi
1115
1116 ## AC_MSG_CHECKING("if we are cross compiling")
1117 ## AC_MSG_RESULT($cross_compiling)
1118 if test "$cross_compiling" = "yes"; then
1119    AC_MSG_RESULT($GUILE_FOR_BUILD)
1120 fi
1121 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1122 AC_SUBST(GUILE_FOR_BUILD)
1123
1124 ## If we're using GCC, ask for aggressive warnings.
1125 case "$GCC" in
1126   yes )
1127     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1128     ## much stuff with generic function pointers for that to really be
1129     ## less than exasperating.
1130     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1131     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1132     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1133     # Do this here so we don't screw up any of the tests above that might
1134     # not be "warning free"
1135     if test "${GUILE_ERROR_ON_WARNING}" = yes
1136     then
1137         CFLAGS="${CFLAGS} -Werror"
1138         enable_compile_warnings=no
1139     fi
1140     ;;
1141 esac
1142
1143 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
1144 ## -- I'm disabling it for now in the hopes that the newer autoconf
1145 ## will DTRT -- if not, we need to fix up the sed command to match the
1146 ## others...
1147 ##
1148 ## Remove fileblocks.o from the object list.  This file gets added by
1149 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
1150 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
1151
1152 ## If we're creating a shared library (using libtool!), then we'll
1153 ## need to generate a list of .lo files corresponding to the .o files
1154 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1155 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1156
1157 ## We also need to create corresponding .doc and .x files
1158 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1159 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1160
1161 AC_SUBST(GUILE_MAJOR_VERSION)
1162 AC_SUBST(GUILE_MINOR_VERSION)
1163 AC_SUBST(GUILE_MICRO_VERSION)
1164 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1165 AC_SUBST(GUILE_VERSION)
1166
1167 #######################################################################
1168 # library versioning
1169
1170 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1171 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1172 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1173 AC_SUBST(LIBGUILE_INTERFACE)
1174
1175 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1176 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1177 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1178 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1179 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1180
1181 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1182 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1183 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1184 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1185 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1186
1187 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1188 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1189 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1190 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1191 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1192
1193 #######################################################################
1194
1195 dnl Tell guile-config what flags guile users should compile and link with.
1196 GUILE_LIBS="$LDFLAGS $LIBS"
1197 GUILE_CFLAGS="$PTHREAD_CFLAGS"
1198 AC_SUBST(GUILE_LIBS)
1199 AC_SUBST(GUILE_CFLAGS)
1200
1201 AC_SUBST(AWK)
1202 AC_SUBST(LIBLOBJS)
1203 AC_SUBST(EXTRA_DOT_DOC_FILES)
1204 AC_SUBST(EXTRA_DOT_X_FILES)
1205
1206 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1207 top_builddir_absolute=`pwd`
1208 AC_SUBST(top_builddir_absolute)
1209 top_srcdir_absolute=`(cd $srcdir && pwd)`
1210 AC_SUBST(top_srcdir_absolute)
1211
1212 # Additional SCM_I_GSC definitions are above.
1213 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1214 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1215 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1216 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1217 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1218 AC_SUBST([SCM_I_GSC_HAVE_ARRAYS])
1219 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1220 AC_SUBST([SCM_I_GSC_C_INLINE])
1221 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1222
1223 AC_CONFIG_FILES([
1224   Makefile
1225   am/Makefile
1226   benchmark-suite/Makefile
1227   doc/Makefile
1228   doc/goops/Makefile
1229   doc/r5rs/Makefile
1230   doc/ref/Makefile
1231   doc/tutorial/Makefile
1232   emacs/Makefile
1233   examples/Makefile
1234   examples/box-dynamic-module/Makefile
1235   examples/box-dynamic/Makefile
1236   examples/box-module/Makefile
1237   examples/box/Makefile
1238   examples/modules/Makefile
1239   examples/safe/Makefile
1240   examples/scripts/Makefile
1241   guile-config/Makefile
1242   ice-9/Makefile
1243   ice-9/debugger/Makefile
1244   ice-9/debugger/breakpoints/Makefile
1245   lang/Makefile
1246   lang/elisp/Makefile
1247   lang/elisp/internals/Makefile
1248   lang/elisp/primitives/Makefile
1249   libguile-ltdl/Makefile
1250   libguile-ltdl/upstream/Makefile
1251   libguile/Makefile
1252   oop/Makefile
1253   oop/goops/Makefile
1254   scripts/Makefile
1255   srfi/Makefile
1256   test-suite/Makefile
1257   test-suite/standalone/Makefile
1258 ])
1259
1260 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1261 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1262 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1263 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1264 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1265 AC_CONFIG_FILES([libguile/guile-snarf],
1266                 [chmod +x libguile/guile-snarf])
1267 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1268                 [chmod +x libguile/guile-doc-snarf])
1269 AC_CONFIG_FILES([libguile/guile-func-name-check],
1270                 [chmod +x libguile/guile-func-name-check])
1271 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1272                 [chmod +x libguile/guile-snarf-docs])
1273
1274 AC_OUTPUT
1275
1276 dnl Local Variables:
1277 dnl comment-start: "dnl "
1278 dnl comment-end: ""
1279 dnl comment-start-skip: "\\bdnl\\b\\s *"
1280 dnl End: