configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it under
  12 the terms of the GNU Lesser General Public License as published by the
  13 Free Software Foundation; either version 3, or (at your option) any
  14 later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but WITHOUT
  17 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  18 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  19 License for more details.
  20
  21 You should have received a copy of the GNU Lesser General Public
  22 License along with GUILE; see the file COPYING.LESSER.  If not, write
  23 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  24 Floor, Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.61)
  29
  30 AC_INIT([GNU Guile],
  31         m4_esyscmd([build-aux/git-version-gen                                   \
  32           .tarball-version                                                      \
  33           's/^release_\([0-9][0-9]*\)-\([0-9][0-9]*\)-\([0-9][0-9]*\)/v\1.\2\.\3/g']),
  34         [bug-guile@gnu.org])
  35 AC_CONFIG_AUX_DIR([build-aux])
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AC_CONFIG_SRCDIR(GUILE-VERSION)
  38
  39 AM_INIT_AUTOMAKE([gnu no-define -Wall -Wno-override])
  40 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  41
  42 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  43 AC_CONFIG_SRCDIR([GUILE-VERSION])
  44
  45 . $srcdir/GUILE-VERSION
  46 GUILE_VERSION="$PACKAGE_VERSION"
  47
  48 AC_CONFIG_HEADERS([config.h])
  49 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  50
  51 #--------------------------------------------------------------------
  52
  53 AC_LANG([C])
  54
  55 dnl Some more checks for Win32
  56 AC_CANONICAL_HOST
  57
  58 AC_LIBTOOL_WIN32_DLL
  59
  60 AC_PROG_INSTALL
  61 AC_PROG_CC
  62 gl_EARLY
  63 AC_PROG_CPP
  64 AC_PROG_SED
  65 AC_PROG_AWK
  66
  67 dnl Gnulib.
  68 gl_INIT
  69
  70 AC_PROG_CC_C89
  71
  72 # for per-target cflags in the libguile subdir
  73 AM_PROG_CC_C_O
  74
  75 AC_LIBTOOL_DLOPEN
  76 AC_PROG_LIBTOOL
  77 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  78   [AC_MSG_ERROR([libltdl not found.  See README.])])
  79 AC_CHECK_HEADER([ltdl.h], [],
  80   [AC_MSG_ERROR([<ltdl.h> not found.  See README.])])
  81
  82 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  83 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  84
  85 AM_PATH_LISPDIR
  86
  87 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
  88   [Define to the host's GNU triplet.])
  89
  90 #--------------------------------------------------------------------
  91 #
  92 # User options (after above tests that may set default CFLAGS etc.)
  93 #
  94 #--------------------------------------------------------------------
  95
  96 GUILE_ERROR_ON_WARNING="no"
  97
  98 AC_ARG_ENABLE(error-on-warning,
  99   [  --enable-error-on-warning    treat compile warnings as errors],
 100   [case "${enableval}" in
 101      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 102      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 103      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 104    esac])
 105
 106 AC_ARG_ENABLE(debug-malloc,
 107   [  --enable-debug-malloc   include malloc debugging code],
 108   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 109     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 110       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 111   fi)
 112
 113 SCM_I_GSC_GUILE_DEBUG=0
 114 AC_ARG_ENABLE(guile-debug,
 115   [AS_HELP_STRING([--enable-guile-debug],
 116                   [include internal debugging functions])],
 117   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 118     SCM_I_GSC_GUILE_DEBUG=1
 119   fi)
 120
 121 AC_ARG_ENABLE(posix,
 122   [  --disable-posix         omit posix interfaces],,
 123   enable_posix=yes)
 124
 125 AC_ARG_ENABLE(networking,
 126   [  --disable-networking    omit networking interfaces],,
 127   enable_networking=yes)
 128
 129 AC_ARG_ENABLE(regex,
 130   [  --disable-regex         omit regular expression interfaces],,
 131   enable_regex=yes)
 132
 133 AC_ARG_ENABLE([deprecated],
 134   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 135
 136 if test "$enable_deprecated" = no; then
 137   SCM_I_GSC_ENABLE_DEPRECATED=0
 138   warn_default=no
 139 else
 140   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 141     warn_default=summary
 142   elif test "$enable_deprecated" = shutup; then
 143     warn_default=no
 144   else
 145     warn_default=$enable_deprecated
 146   fi
 147   SCM_I_GSC_ENABLE_DEPRECATED=1
 148 fi
 149 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 150 [Define this to control the default warning level for deprecated features.])
 151
 152 dnl  Added the following configure option in January 2008 following
 153 dnl  investigation of problems with "64" system and library calls on
 154 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 155 dnl  system has stat64, it will have all the other 64 APIs too; but on
 156 dnl  Darwin, stat64 is there but other APIs are missing.
 157 dnl
 158 dnl  It also appears, from the Darwin docs, that most system call APIs
 159 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 160 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 161 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 162 dnl
 163 dnl  A similar problem has been reported for HP-UX:
 164 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 165 dnl
 166 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 167 dnl  better than no Guile at all, we provide this option to suppress
 168 dnl  trying to use "64" calls.
 169 dnl
 170 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 171 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 172 dnl  missing out on that.  If so, someone can work on that in the future.
 173 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 174 dnl  wasn't building before.
 175 AC_MSG_CHECKING([whether to use system and library "64" calls])
 176 AC_ARG_WITH([64-calls],
 177   AS_HELP_STRING([--without-64-calls],
 178                  [don't attempt to use system and library calls with "64" in their names]),
 179   [use_64_calls=$withval],
 180   [use_64_calls=yes
 181    case $host in
 182      *-apple-darwin* )
 183        use_64_calls=no
 184        ;;
 185      powerpc-ibm-aix* )
 186        use_64_calls=no
 187        ;;
 188    esac])
 189 AC_MSG_RESULT($use_64_calls)
 190 case "$use_64_calls" in
 191   y* )
 192     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 193       [Define to 1 in order to try to use "64" versions of system and library calls.])
 194     ;;
 195 esac
 196
 197 #--------------------------------------------------------------------
 198
 199 dnl Check for dynamic linking
 200
 201 use_modules=yes
 202 AC_ARG_WITH(modules,
 203 [  --with-modules[=FILES]  Add support for dynamic modules],
 204 use_modules="$withval")
 205 test -z "$use_modules" && use_modules=yes
 206 DLPREOPEN=
 207 if test "$use_modules" != no; then
 208   if test "$use_modules" = yes; then
 209     DLPREOPEN="-dlpreopen force"
 210   else
 211     DLPREOPEN="-export-dynamic"
 212     for module in $use_modules; do
 213       DLPREOPEN="$DLPREOPEN -dlopen $module"
 214     done
 215   fi
 216 fi
 217
 218 dnl files which are destined for separate modules.
 219
 220 if test "$use_modules" != no; then
 221    AC_LIBOBJ([dynl])
 222 fi
 223
 224 if test "$enable_posix" = yes; then
 225    AC_LIBOBJ([filesys])
 226    AC_LIBOBJ([posix])
 227    AC_DEFINE([HAVE_POSIX], 1,
 228      [Define this if you want support for POSIX system calls in Guile.])
 229 fi
 230
 231 if test "$enable_networking" = yes; then
 232    AC_LIBOBJ([net_db])
 233    AC_LIBOBJ([socket])
 234    AC_DEFINE([HAVE_NETWORKING], 1,
 235      [Define this if you want support for networking in Guile.])
 236 fi
 237
 238 if test "$enable_debug_malloc" = yes; then
 239    AC_LIBOBJ([debug-malloc])
 240 fi
 241
 242 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 243
 244 AC_C_CONST
 245
 246 # "volatile" is used in a couple of tests below.
 247 AC_C_VOLATILE
 248
 249 AC_C_INLINE
 250 if test "$ac_cv_c_inline" != no; then
 251   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 252 else
 253   SCM_I_GSC_C_INLINE=NULL
 254 fi
 255 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 256
 257 AC_C_BIGENDIAN
 258
 259 AC_C_LABELS_AS_VALUES
 260
 261 AC_CHECK_SIZEOF(char)
 262 AC_CHECK_SIZEOF(unsigned char)
 263 AC_CHECK_SIZEOF(short)
 264 AC_CHECK_SIZEOF(unsigned short)
 265 AC_CHECK_SIZEOF(int)
 266 AC_CHECK_SIZEOF(unsigned int)
 267 AC_CHECK_SIZEOF(long)
 268 AC_CHECK_SIZEOF(unsigned long)
 269 AC_CHECK_SIZEOF(size_t)
 270 AC_CHECK_SIZEOF(long long)
 271 AC_CHECK_SIZEOF(unsigned long long)
 272 AC_CHECK_SIZEOF(__int64)
 273 AC_CHECK_SIZEOF(unsigned __int64)
 274 AC_CHECK_SIZEOF(void *)
 275 AC_CHECK_SIZEOF(intptr_t)
 276 AC_CHECK_SIZEOF(uintptr_t)
 277 AC_CHECK_SIZEOF(ptrdiff_t)
 278 AC_CHECK_SIZEOF(size_t)
 279 AC_CHECK_SIZEOF(off_t)
 280
 281 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 282   AC_MSG_ERROR(sizes of long and void* are not identical)
 283 fi
 284
 285 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 286   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 287 else
 288   SCM_I_GSC_T_PTRDIFF='"long"'
 289 fi
 290 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 291
 292 AC_CHECK_HEADERS([stdint.h])
 293 AC_CHECK_HEADERS([inttypes.h])
 294
 295 AC_CHECK_SIZEOF(intmax_t)
 296
 297 SCM_I_GSC_NEEDS_STDINT_H=0
 298 SCM_I_GSC_NEEDS_INTTYPES_H=0
 299
 300 ### intptr and uintptr (try not to use inttypes if we don't have to)
 301 if test "$ac_cv_header_inttypes_h" = yes; then
 302   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 303     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 304 #include <stdio.h>])
 305     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 306       SCM_I_GSC_NEEDS_INTTYPES_H=1
 307     fi
 308   fi
 309   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 310     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 311 #include <stdio.h>])
 312     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 313       SCM_I_GSC_NEEDS_INTTYPES_H=1
 314     fi
 315   fi
 316 fi
 317
 318 ### See what's provided by stdint.h
 319 if test "$ac_cv_header_stdint_h" = yes; then
 320    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 321    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 322    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 323    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 324    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 325    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 326    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 327    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 328    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 329    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 330    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 331    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 332 fi
 333
 334 # so we don't get confused by the cache (wish there was a better way
 335 # to check particular headers for the same type...)
 336
 337 unset ac_cv_type_int8_t
 338 unset ac_cv_type_uint8_t
 339 unset ac_cv_type_int16_t
 340 unset ac_cv_type_uint16_t
 341 unset ac_cv_type_int32_t
 342 unset ac_cv_type_uint32_t
 343 unset ac_cv_type_int64_t
 344 unset ac_cv_type_uint64_t
 345 unset ac_cv_type_intmax_t
 346 unset ac_cv_type_uintmax_t
 347
 348 ### See what's provided by inttypes.h
 349 if test "$ac_cv_header_inttypes_h" = yes; then
 350   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 351   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 352   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 353   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 354   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 355   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 356   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 357   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 358   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 359   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 360   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 361   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 362 fi
 363
 364 # Try hard to find definitions for some required scm_t_*int* types.
 365
 366 ### Required type scm_t_int8
 367 if test "$scm_stdint_has_int8"; then
 368   SCM_I_GSC_T_INT8='"int8_t"'
 369   SCM_I_GSC_NEEDS_STDINT_H=1
 370 elif test "$scm_inttypes_has_int8"; then
 371   SCM_I_GSC_T_INT8='"int8_t"'
 372   SCM_I_GSC_NEEDS_INTTYPES_H=1
 373 elif test "$ac_cv_sizeof_char" -eq 1; then
 374   SCM_I_GSC_T_INT8='"signed char"'
 375 else
 376   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 377 fi
 378 AC_SUBST([SCM_I_GSC_T_INT8])
 379
 380 ### Required type scm_t_uint8
 381 if test "$scm_stdint_has_uint8"; then
 382   SCM_I_GSC_T_UINT8='"uint8_t"'
 383   SCM_I_GSC_NEEDS_STDINT_H=1
 384 elif test "$scm_inttypes_has_uint8"; then
 385   SCM_I_GSC_T_UINT8='"uint8_t"'
 386   SCM_I_GSC_NEEDS_INTTYPES_H=1
 387 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 388   SCM_I_GSC_T_UINT8='"unsigned char"'
 389 else
 390   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 391 fi
 392 AC_SUBST([SCM_I_GSC_T_UINT8])
 393
 394 ### Required type scm_t_int16 (ANSI C says int or short might work)
 395 if test "$scm_stdint_has_int16"; then
 396   SCM_I_GSC_T_INT16='"int16_t"'
 397   SCM_I_GSC_NEEDS_STDINT_H=1
 398 elif test "$scm_inttypes_has_int16"; then
 399   SCM_I_GSC_T_INT16='"int16_t"'
 400   SCM_I_GSC_NEEDS_INTTYPES_H=1
 401 elif test "$ac_cv_sizeof_int" -eq 2; then
 402   SCM_I_GSC_T_INT16='"int"'
 403 elif test "$ac_cv_sizeof_short" -eq 2; then
 404   SCM_I_GSC_T_INT16='"short"'
 405 else
 406   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 407 fi
 408 AC_SUBST([SCM_I_GSC_T_INT16])
 409
 410 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 411 if test "$scm_stdint_has_uint16"; then
 412   SCM_I_GSC_T_UINT16='"uint16_t"'
 413   SCM_I_GSC_NEEDS_STDINT_H=1
 414 elif test "$scm_inttypes_has_uint16"; then
 415   SCM_I_GSC_T_UINT16='"uint16_t"'
 416   SCM_I_GSC_NEEDS_INTTYPES_H=1
 417 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 418   SCM_I_GSC_T_UINT16='"unsigned int"'
 419 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 420   SCM_I_GSC_T_UINT16='"unsigned short"'
 421 else
 422   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 423 fi
 424 AC_SUBST([SCM_I_GSC_T_UINT16])
 425
 426
 427 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 428 if test "$scm_stdint_has_int32"; then
 429   SCM_I_GSC_T_INT32='"int32_t"'
 430   SCM_I_GSC_NEEDS_STDINT_H=1
 431 elif test "$scm_inttypes_has_int32"; then
 432   SCM_I_GSC_T_INT32='"int32_t"'
 433   SCM_I_GSC_NEEDS_INTTYPES_H=1
 434 elif test "$ac_cv_sizeof_int" -eq 4; then
 435   SCM_I_GSC_T_INT32='"int"'
 436 elif test "$ac_cv_sizeof_long" -eq 4; then
 437   SCM_I_GSC_T_INT32='"long"'
 438 elif test "$ac_cv_sizeof_short" -eq 4; then
 439   SCM_I_GSC_T_INT32='"short"'
 440 else
 441   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 442 fi
 443 AC_SUBST([SCM_I_GSC_T_INT32])
 444
 445 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 446 if test "$scm_stdint_has_uint32"; then
 447   SCM_I_GSC_T_UINT32='"uint32_t"'
 448   SCM_I_GSC_NEEDS_STDINT_H=1
 449 elif test "$scm_inttypes_has_uint32"; then
 450   SCM_I_GSC_T_UINT32='"uint32_t"'
 451   SCM_I_GSC_NEEDS_INTTYPES_H=1
 452 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 453   SCM_I_GSC_T_UINT32='"unsigned int"'
 454 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 455   SCM_I_GSC_T_UINT32='"unsigned long"'
 456 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 457   SCM_I_GSC_T_UINT32='"unsigned short"'
 458 else
 459   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 460 fi
 461 AC_SUBST([SCM_I_GSC_T_UINT32])
 462
 463 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 464 ### Also try 'long long' and '__int64' if we have it.
 465 SCM_I_GSC_T_INT64=0
 466 if test "$scm_stdint_has_int64"; then
 467   SCM_I_GSC_T_INT64='"int64_t"'
 468   SCM_I_GSC_NEEDS_STDINT_H=1
 469 elif test "$scm_inttypes_has_int64"; then
 470   SCM_I_GSC_T_INT64='"int64_t"'
 471   SCM_I_GSC_NEEDS_INTTYPES_H=1
 472 elif test "$ac_cv_sizeof_int" -eq 8; then
 473   SCM_I_GSC_T_INT64='"int"'
 474 elif test "$ac_cv_sizeof_long" -eq 8; then
 475   SCM_I_GSC_T_INT64='"long"'
 476 elif test "$ac_cv_sizeof_short" -eq 8; then
 477   SCM_I_GSC_T_INT64='"short"'
 478 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 479   SCM_I_GSC_T_INT64='"long long"'
 480 elif test "$ac_cv_sizeof___int64" -eq 8; then
 481   SCM_I_GSC_T_INT64='"__int64"'
 482 else
 483   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 484 fi
 485 AC_SUBST([SCM_I_GSC_T_INT64])
 486
 487
 488 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 489 ### Also try 'long long' and '__int64' if we have it.
 490 SCM_I_GSC_T_UINT64=0
 491 if test "$scm_stdint_has_uint64"; then
 492   SCM_I_GSC_T_UINT64='"uint64_t"'
 493   SCM_I_GSC_NEEDS_STDINT_H=1
 494 elif test "$scm_inttypes_has_uint64"; then
 495   SCM_I_GSC_T_UINT64='"uint64_t"'
 496   SCM_I_GSC_NEEDS_INTTYPES_H=1
 497 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 498   SCM_I_GSC_T_UINT64='"unsigned int"'
 499 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 500   SCM_I_GSC_T_UINT64='"unsigned long"'
 501 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 502   SCM_I_GSC_T_UINT64='"unsigned short"'
 503 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 504   SCM_I_GSC_T_UINT64='"unsigned long long"'
 505 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 506   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 507 else
 508   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 509 fi
 510 AC_SUBST([SCM_I_GSC_T_UINT64])
 511
 512 ### Required type scm_t_intmax
 513 ###
 514 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 515 ### none of them is available, we use 'long'.
 516 ###
 517 SCM_I_GSC_T_INTMAX=0
 518 if test "$scm_stdint_has_intmax"; then
 519   SCM_I_GSC_T_INTMAX='"intmax_t"'
 520   SCM_I_GSC_NEEDS_STDINT_H=1
 521 elif test "$scm_inttypes_has_intmax"; then
 522   SCM_I_GSC_T_INTMAX='"intmax_t"'
 523   SCM_I_GSC_NEEDS_INTTYPES_H=1
 524 elif test "$ac_cv_sizeof___int64" -ne 0; then
 525   SCM_I_GSC_T_INTMAX='"__int64"'
 526 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 527   SCM_I_GSC_T_INTMAX='"long long"'
 528 else
 529   SCM_I_GSC_T_INTMAX='"long"'
 530 fi
 531 AC_SUBST([SCM_I_GSC_T_INTMAX])
 532
 533 ### Required type scm_t_uintmax
 534 ###
 535 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 536 ### this order.  When none of them is available, we use 'unsigned long'.
 537 ###
 538 SCM_I_GSC_T_UINTMAX=0
 539 if test "$scm_stdint_has_uintmax"; then
 540   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 541   SCM_I_GSC_NEEDS_STDINT_H=1
 542 elif test "$scm_inttypes_has_uintmax"; then
 543   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 544   SCM_I_GSC_NEEDS_INTTYPES_H=1
 545 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 546   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 547 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 548   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 549 else
 550   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 551 fi
 552 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 553
 554 ### Required type scm_t_intptr
 555 ###
 556 SCM_I_GSC_T_INTPTR=0
 557 if test "$scm_stdint_has_intptr"; then
 558   SCM_I_GSC_T_INTPTR='"intptr_t"'
 559   SCM_I_GSC_NEEDS_STDINT_H=1
 560 elif test "$scm_inttypes_has_intptr"; then
 561   SCM_I_GSC_T_INTPTR='"intptr_t"'
 562   SCM_I_GSC_NEEDS_INTTYPES_H=1
 563 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 564   SCM_I_GSC_T_INTPTR='"int"'
 565 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 566   SCM_I_GSC_T_INTPTR='"long"'
 567 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 568   SCM_I_GSC_T_INTPTR='"long long"'
 569 else
 570   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 571 fi
 572 AC_SUBST([SCM_I_GSC_T_INTPTR])
 573
 574 ### Required type scm_t_uintptr
 575 ###
 576 SCM_I_GSC_T_UINTPTR=0
 577 if test "$scm_stdint_has_uintptr"; then
 578   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 579   SCM_I_GSC_NEEDS_STDINT_H=1
 580 elif test "$scm_inttypes_has_uintptr"; then
 581   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 582   SCM_I_GSC_NEEDS_INTTYPES_H=1
 583 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 584   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 585 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 586   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 587 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 588   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 589 else
 590   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 591 fi
 592 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 593
 594
 595 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 596 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 597
 598 AC_HEADER_STDC
 599 AC_HEADER_TIME
 600 AC_HEADER_SYS_WAIT
 601 AC_HEADER_DIRENT
 602
 603 # Reason for checking:
 604 #
 605 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 606 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 607 #
 608 AC_CHECK_MEMBER([struct dirent64.d_name],
 609   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 610   [ #ifndef _LARGEFILE64_SOURCE
 611     # define _LARGEFILE64_SOURCE
 612     #endif
 613
 614     /* Per Autoconf manual.  */
 615     #include <sys/types.h>
 616     #ifdef HAVE_DIRENT_H
 617     # include <dirent.h>
 618     #else
 619     # define dirent direct
 620     # ifdef HAVE_SYS_NDIR_H
 621     #  include <sys/ndir.h>
 622     # endif
 623     # ifdef HAVE_SYS_DIR_H
 624     #  include <sys/dir.h>
 625     # endif
 626     # ifdef HAVE_NDIR_H
 627     #  include <ndir.h>
 628     # endif
 629     #endif ])
 630 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 631
 632 # Reasons for testing:
 633 #   complex.h - new in C99
 634 #   fenv.h - available in C99, but not older systems
 635 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 636 #     this file instead of <fenv.h>
 637 #   process.h - mingw specific
 638 #   langinfo.h, nl_types.h - SuS v2
 639 #
 640 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 641 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 642 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 643 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 644 direct.h langinfo.h nl_types.h machine/fpu.h])
 645
 646 # Reasons for testing:
 647 #   nl_item - lacking on Cygwin
 648 AC_CHECK_TYPES([nl_item], [], [],
 649   [[#ifdef HAVE_LANGINFO_H
 650     # include <langinfo.h>
 651     #endif
 652     #ifdef HAVE_NL_TYPES_H
 653     # include <nl_types.h>
 654     #endif]])
 655
 656 # "complex double" is new in C99, and "complex" is only a keyword if
 657 # <complex.h> is included
 658 AC_CHECK_TYPES(complex double,,,
 659 [#if HAVE_COMPLEX_H
 660 #include <complex.h>
 661 #endif])
 662
 663 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 664 # when testing.
 665 AC_CHECK_TYPE(socklen_t, ,
 666   [AC_DEFINE_UNQUOTED([socklen_t], int,
 667                       [Define to `int' if <sys/socket.h> does not define.])],
 668   [#if HAVE_SYS_TYPES_H
 669 #include <sys/types.h>
 670 #endif
 671 #include <sys/socket.h>
 672 ])
 673 AC_CHECK_TYPE(struct ip_mreq)
 674
 675 GUILE_HEADER_LIBC_WITH_UNISTD
 676
 677 AC_TYPE_GETGROUPS
 678 AC_TYPE_SIGNAL
 679 AC_TYPE_MODE_T
 680
 681 # On mingw -lm is empty, so this test is unnecessary, but it's
 682 # harmless so we don't hard-code to suppress it.
 683 #
 684 AC_CHECK_LIB(m, cos)
 685
 686 AC_CHECK_FUNCS(gethostbyname)
 687 if test $ac_cv_func_gethostbyname = no; then
 688     AC_CHECK_LIB(nsl, gethostbyname)
 689 fi
 690
 691 AC_CHECK_FUNCS(connect)
 692 if test $ac_cv_func_connect = no; then
 693     AC_CHECK_LIB(socket, connect)
 694 fi
 695
 696 dnl
 697 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 698 dnl
 699 EXTRA_DEFS=""
 700 case $host in
 701   *-*-mingw*)
 702     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 703       [Define if you have the <winsock2.h> header file.])])
 704     AC_CHECK_LIB(ws2_32, main)
 705     AC_LIBOBJ([win32-uname])
 706     AC_LIBOBJ([win32-dirent])
 707     if test "$enable_networking" = yes ; then
 708       AC_LIBOBJ([win32-socket])
 709     fi
 710     if test "$enable_shared" = yes ; then
 711       EXTRA_DEFS="-DSCM_IMPORT"
 712       AC_DEFINE([USE_DLL_IMPORT], 1,
 713         [Define if you need additional CPP macros on Win32 platforms.])
 714     fi
 715     ;;
 716 esac
 717 AC_SUBST(EXTRA_DEFS)
 718
 719 # Reasons for testing:
 720 #   crt_externs.h - Darwin specific
 721 #
 722 AC_CHECK_HEADERS([assert.h crt_externs.h])
 723
 724 # Reasons for testing:
 725 #   DINFINITY - OSF specific
 726 #   DQNAN - OSF specific
 727 #       (DINFINITY and DQNAN are actually global variables, not functions)
 728 #   chsize - an MS-DOS-ism, found in mingw
 729 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 730 #       for gcc to provide the "complex double" type but the system to not
 731 #       have functions like cexp and clog
 732 #   clog10 - not in mingw (though others like clog and csqrt are)
 733 #   fesetround - available in C99, but not older systems
 734 #   ftruncate - posix, but probably not older systems (current mingw
 735 #               has it as an inline for chsize)
 736 #   ioctl - not in mingw.
 737 #   gmtime_r - recent posix, not on old systems
 738 #   pipe - not in mingw
 739 #   _pipe - specific to mingw, taking 3 args
 740 #   readdir_r - recent posix, not on old systems
 741 #   readdir64_r - not available on HP-UX 11.11
 742 #   stat64 - SuS largefile stuff, not on old systems
 743 #   sysconf - not on old systems
 744 #   truncate - not in mingw
 745 #   isblank - available as a GNU extension or in C99
 746 #   _NSGetEnviron - Darwin specific
 747 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 748 #   nl_langinfo - X/Open, not available on Windows.
 749 #   utimensat: posix.1-2008
 750 #
 751 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat])
 752
 753 # Reasons for testing:
 754 #   netdb.h - not in mingw
 755 #   sys/param.h - not in mingw
 756 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 757 #       check this specifically, we need it for the timespec test below.
 758 #   sethostname - the function itself check because it's not in mingw,
 759 #       the DECL is checked because Solaris 10 doens't have in any header
 760 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 761 #       declaration isn't anywhere.
 762 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 763 #       only with `_XOPEN_SOURCE' or some such.
 764 #
 765 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h])
 766 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 767 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 768
 769 # crypt() may or may not be available, for instance in some countries there
 770 # are restrictions on cryptography.
 771 #
 772 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 773 # -lcrypt library (eg. Debian GNU/Linux).
 774 #
 775 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 776 # be careful to avoid -lcrypt in this case, since libtool will see there's
 777 # only a static libcrypt and decide to build only a static libguile.
 778 #
 779 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 780 # libraries already in that list.
 781 #
 782 AC_SEARCH_LIBS(crypt, crypt,
 783   [AC_DEFINE([HAVE_CRYPT],1,
 784              [Define to 1 if you have the `crypt' function.])])
 785
 786 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 787 # work; in the reported cases so far, 1.0fi works well instead.  According
 788 # to the C99 spec, the complex.h header must provide a working definition
 789 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 790 # is a workaround for the failure of some systems to conform to C99.
 791 if test "$ac_cv_type_complex_double" = yes; then
 792   AC_MSG_CHECKING([for i])
 793   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 794 #if HAVE_COMPLEX_H
 795 #include <complex.h>
 796 #endif
 797 complex double z;
 798 ]], [[
 799 z = _Complex_I;
 800 ]])],
 801     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 802      AC_MSG_RESULT([_Complex_I])],
 803     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 804 #if HAVE_COMPLEX_H
 805 #include <complex.h>
 806 #endif
 807 complex double z;
 808 ]],[[
 809 z = 1.0fi;
 810 ]])],
 811   [AC_DEFINE([GUILE_I],1.0fi)
 812    AC_MSG_RESULT([1.0fi])],
 813   [ac_cv_type_complex_double=no
 814    AC_MSG_RESULT([not available])])])
 815 fi
 816
 817 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 818 # csqrt(-i) returned a negative real part, when it should be positive
 819 # for the principal root.
 820 #
 821 if test "$ac_cv_type_complex_double" = yes; then
 822
 823   AC_CACHE_CHECK([whether csqrt is usable],
 824     guile_cv_use_csqrt,
 825     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 826 #include <complex.h>
 827 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 828    constant, we want to test libc. */
 829 volatile complex double z = - _Complex_I;
 830 int
 831 main (void)
 832 {
 833   z = csqrt (z);
 834   if (creal (z) > 0.0)
 835     return 0;  /* good */
 836   else
 837     return 1;  /* bad */
 838 }]])],
 839     [guile_cv_use_csqrt=yes],
 840     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 841     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 842   case $guile_cv_use_csqrt in
 843     yes*)
 844       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 845       ;;
 846   esac
 847 fi
 848
 849
 850 dnl GMP tests
 851 AC_LIB_HAVE_LINKFLAGS([gmp],
 852   [],
 853   [#include <gmp.h>],
 854   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 855
 856 if test "x$HAVE_LIBGMP" != "xyes"; then
 857   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 858 fi
 859
 860 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 861 if test "x$LTLIBUNISTRING" != "x"; then
 862   LIBS="$LTLIBUNISTRING $LIBS"
 863 else
 864   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 865 fi
 866
 867 dnl Libffi is needed to compile Guile's foreign function interface, but its
 868 dnl interface isn't exposed in Guile's API.
 869 PKG_CHECK_MODULES(LIBFFI, libffi)
 870 AC_SUBST(LIBFFI_CFLAGS)
 871 AC_SUBST(LIBFFI_LIBS)
 872
 873 dnl figure out approriate ffi type for size_t
 874 AC_CHECK_SIZEOF(size_t)
 875 AC_CHECK_SIZEOF(ssize_t)
 876 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 877 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 878 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 879                    [ffi type for size_t])
 880 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 881                    [ffi type for ssize_t])
 882
 883 dnl i18n tests
 884 #AC_CHECK_HEADERS([libintl.h])
 885 #AC_CHECK_FUNCS(gettext)
 886 #if test $ac_cv_func_gettext = no; then
 887 #   AC_CHECK_LIB(intl, gettext)
 888 #fi
 889 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 890 AM_GNU_GETTEXT([external], [need-ngettext])
 891
 892 ### Some systems don't declare some functions.  On such systems, we
 893 ### need to at least provide our own K&R-style declarations.
 894
 895 ### GUILE_FUNC_DECLARED(function, headerfile)
 896
 897 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 898 ### not there, #define MISSING_FUNCTION_DECL.
 899 AC_DEFUN([GUILE_FUNC_DECLARED], [
 900   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 901     AC_EGREP_HEADER($1, $2,
 902                     guile_cv_func_$1_declared=yes,
 903                     guile_cv_func_$1_declared=no))
 904   if test [x$guile_cv_func_]$1[_declared] = xno; then
 905     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 906       [Define if the operating system supplies $1 without declaring it.])
 907   fi
 908 ])
 909
 910 GUILE_FUNC_DECLARED(sleep, unistd.h)
 911 GUILE_FUNC_DECLARED(usleep, unistd.h)
 912
 913 AC_CHECK_DECLS([strptime],,,
 914 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 915 #include <time.h>])
 916
 917 ### On some systems usleep has no return value.  If it does have one,
 918 ### we'd like to return it; otherwise, we'll fake it.
 919 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 920   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 921                    unistd.h,
 922                    [guile_cv_func_usleep_return_type=void],
 923                    [guile_cv_func_usleep_return_type=int])])
 924 case "$guile_cv_func_usleep_return_type" in
 925   "void" )
 926     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 927       [Define if the system headers declare usleep to return void.])
 928   ;;
 929 esac
 930
 931 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 932 if test -n "$have_sys_un_h" ; then
 933   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 934     [Define if the system supports Unix-domain (file-domain) sockets.])
 935 fi
 936
 937 AC_CHECK_FUNCS(getrlimit setrlimit)
 938
 939 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 940
 941 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 942                setnetent    getnetent    endnetent    dnl
 943                setprotoent  getprotoent  endprotoent  dnl
 944                setservent   getservent   endservent   dnl
 945                getnetbyaddr getnetbyname dnl
 946                inet_lnaof inet_makeaddr inet_netof hstrerror)
 947
 948 # struct sockaddr field sin_len is only present on BSD systems.
 949 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 950 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 951 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 952 [#ifdef HAVE_SYS_TYPES_H
 953 #include <sys/types.h>
 954 #endif
 955 #include <netinet/in.h>])
 956
 957 AC_MSG_CHECKING(for __libc_stack_end)
 958 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 959 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 960 extern char *__libc_stack_end;]],
 961    [[printf("%p", (char*) __libc_stack_end);]])],
 962    [guile_cv_have_libc_stack_end=yes],
 963    [guile_cv_have_libc_stack_end=no])])
 964 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 965
 966 if test $guile_cv_have_libc_stack_end = yes; then
 967   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 968            [Define if you have the __libc_stack_end variable.])
 969 fi
 970
 971 dnl Some systems do not declare this.  Some systems do declare it, as a
 972 dnl macro.  With cygwin it may be in a DLL.
 973
 974 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 975 AC_CACHE_VAL(guile_cv_have_h_errno,
 976   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 977                                       [[int a = h_errno;]])],
 978   [guile_cv_have_h_errno=yes],
 979   [guile_cv_have_h_errno=no])])
 980 AC_MSG_RESULT($guile_cv_have_h_errno)
 981 if test $guile_cv_have_h_errno = yes; then
 982   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
 983 fi
 984
 985 AC_MSG_CHECKING(whether uint32_t is defined)
 986 AC_CACHE_VAL(guile_cv_have_uint32_t,
 987   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 988                    #if HAVE_STDINT_H
 989                    #include <stdint.h>
 990                    #endif
 991                    #ifndef HAVE_NETDB_H
 992                    #include <netdb.h>
 993                    #endif]],
 994                    [[uint32_t a;]])],
 995                    [guile_cv_have_uint32_t=yes],
 996                    [guile_cv_have_uint32_t=no])])
 997 AC_MSG_RESULT($guile_cv_have_uint32_t)
 998 if test $guile_cv_have_uint32_t = yes; then
 999   AC_DEFINE([HAVE_UINT32_T], 1,
1000     [Define if uint32_t typedef is defined when netdb.h is include.])
1001 fi
1002
1003 AC_MSG_CHECKING(for working IPv6 support)
1004 AC_CACHE_VAL(guile_cv_have_ipv6,
1005 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1006 #ifdef HAVE_SYS_TYPES_H
1007 #include <sys/types.h>
1008 #endif
1009 #include <netinet/in.h>
1010 #include <sys/socket.h>]],
1011 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1012 [guile_cv_have_ipv6=yes],
1013 [guile_cv_have_ipv6=no])])
1014 AC_MSG_RESULT($guile_cv_have_ipv6)
1015 if test $guile_cv_have_ipv6 = yes; then
1016   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1017 fi
1018
1019 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1020 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1021 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1022 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1023 #ifdef HAVE_SYS_TYPES_H
1024 #include <sys/types.h>
1025 #endif
1026 #include <netinet/in.h>]],
1027 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1028 [guile_cv_have_sin6_scope_id=yes],
1029 [guile_cv_have_sin6_scope_id=no])])
1030 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1031 if test $guile_cv_have_sin6_scope_id = yes; then
1032   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1033     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1034 fi
1035
1036 # struct sockaddr_in6 field sin_len is only present on BSD systems
1037 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1038 [#ifdef HAVE_SYS_TYPES_H
1039 #include <sys/types.h>
1040 #endif
1041 #include <netinet/in.h>])
1042
1043 AC_MSG_CHECKING(whether localtime caches TZ)
1044 AC_CACHE_VAL(guile_cv_localtime_cache,
1045 [if test x$ac_cv_func_tzset = xyes; then
1046 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1047 #if STDC_HEADERS
1048 # include <stdlib.h>
1049 #endif
1050 extern char **environ;
1051 unset_TZ ()
1052 {
1053   char **from, **to;
1054   for (to = from = environ; (*to = *from); from++)
1055     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1056       to++;
1057 }
1058 char TZ_GMT0[] = "TZ=GMT0";
1059 char TZ_PST8[] = "TZ=PST8";
1060 main()
1061 {
1062   time_t now = time ((time_t *) 0);
1063   int hour_GMT0, hour_unset;
1064   if (putenv (TZ_GMT0) != 0)
1065     exit (1);
1066   hour_GMT0 = localtime (&now)->tm_hour;
1067   unset_TZ ();
1068   hour_unset = localtime (&now)->tm_hour;
1069   if (putenv (TZ_PST8) != 0)
1070     exit (1);
1071   if (localtime (&now)->tm_hour == hour_GMT0)
1072     exit (1);
1073   unset_TZ ();
1074   if (localtime (&now)->tm_hour != hour_unset)
1075     exit (1);
1076   exit (0);
1077 }]])],
1078 [guile_cv_localtime_cache=no],
1079 [guile_cv_localtime_cache=yes],
1080 [# If we have tzset, assume the worst when cross-compiling.
1081 guile_cv_localtime_cache=yes])
1082 else
1083         # If we lack tzset, report that localtime does not cache TZ,
1084         # since we can't invalidate the cache if we don't have tzset.
1085         guile_cv_localtime_cache=no
1086 fi])dnl
1087 AC_MSG_RESULT($guile_cv_localtime_cache)
1088 if test $guile_cv_localtime_cache = yes; then
1089   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1090 fi
1091
1092 if test "$enable_regex" = yes; then
1093    if test "$ac_cv_header_regex_h" = yes ||
1094       test "$ac_cv_header_rxposix_h" = yes ||
1095       test "$ac_cv_header_rx_rxposix_h" = yes; then
1096      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1097      [AC_CHECK_LIB(rx, main)
1098       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1099      [AC_CHECK_LIB(regex, main)
1100       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1101      )
1102      dnl The following should not be necessary, but for some reason
1103      dnl autoheader misses it if we don't include it!
1104      if test "$ac_cv_func_regcomp_norx" = yes ||
1105         test "$ac_cv_func_regcomp_regex" = yes ||
1106         test "$ac_cv_func_regcomp_rx" = yes; then
1107        AC_DEFINE([HAVE_REGCOMP], 1,
1108          [This is included as part of a workaround for a autoheader bug.])
1109      fi
1110    fi
1111 fi
1112
1113 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1114
1115 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
1116
1117 # Reasons for testing:
1118 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1119 #                                older systems
1120 #   sincos - GLIBC extension
1121 #
1122 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1123
1124 # C99 specifies isinf and isnan as macros.
1125 # HP-UX provides only macros, no functions.
1126 # glibc 2.3.2 provides both macros and functions.
1127 # IRIX 6.5 and Solaris 8 only provide functions.
1128 #
1129 # The following tests detect isinf and isnan either as functions or as
1130 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1131 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1132 #
1133 AC_MSG_CHECKING([for isinf])
1134 AC_LINK_IFELSE(AC_LANG_SOURCE(
1135 [[#include <math.h>
1136 volatile double x = 0.0;
1137 int main () { return (isinf(x) != 0); }]]),
1138   [AC_MSG_RESULT([yes])
1139    AC_DEFINE([HAVE_ISINF], 1,
1140              [Define to 1 if you have the `isinf' macro or function.])],
1141   [AC_MSG_RESULT([no])])
1142 AC_MSG_CHECKING([for isnan])
1143 AC_LINK_IFELSE(AC_LANG_SOURCE(
1144 [[#include <math.h>
1145 volatile double x = 0.0;
1146 int main () { return (isnan(x) != 0); }]]),
1147   [AC_MSG_RESULT([yes])
1148    AC_DEFINE([HAVE_ISNAN], 1,
1149              [Define to 1 if you have the `isnan' macro or function.])],
1150   [AC_MSG_RESULT([no])])
1151
1152 # Reasons for checking:
1153 #
1154 #     st_rdev
1155 #     st_blksize
1156 #     st_blocks   not in mingw
1157 #     tm_gmtoff   BSD+GNU, not in C99
1158 #
1159 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1160 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1161 #
1162 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1163                  [#define _GNU_SOURCE
1164 AC_INCLUDES_DEFAULT
1165 ])
1166
1167 AC_STRUCT_TIMEZONE
1168 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1169 [#include <time.h>
1170 #ifdef TIME_WITH_SYS_TIME
1171 # include <sys/time.h>
1172 # include <time.h>
1173 #else
1174 # if HAVE_SYS_TIME_H
1175 #  include <sys/time.h>
1176 # else
1177 #  include <time.h>
1178 # endif
1179 #endif
1180 ])
1181 GUILE_STRUCT_UTIMBUF
1182
1183
1184 #--------------------------------------------------------------------
1185 #
1186 # Which way does the stack grow?
1187 #
1188 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1189 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1190 # very similar code, so in future we could look at using that.
1191 #
1192 # An important detail is that the code involves find_stack_direction
1193 # calling _itself_ - which means that find_stack_direction (or at
1194 # least the second find_stack_direction() call) cannot be inlined.
1195 # If the code could be inlined, that might cause the test to give
1196 # an incorrect answer.
1197 #--------------------------------------------------------------------
1198
1199 SCM_I_GSC_STACK_GROWS_UP=0
1200 AC_RUN_IFELSE([AC_LANG_SOURCE(
1201 [AC_INCLUDES_DEFAULT
1202 int
1203 find_stack_direction ()
1204 {
1205   static char *addr = 0;
1206   auto char dummy;
1207   if (addr == 0)
1208     {
1209       addr = &dummy;
1210       return find_stack_direction ();
1211     }
1212   else
1213     return (&dummy > addr) ? 1 : -1;
1214 }
1215
1216 int
1217 main ()
1218 {
1219   return find_stack_direction () < 0;
1220 }])],
1221                [SCM_I_GSC_STACK_GROWS_UP=1],
1222                [],
1223                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1224
1225 #--------------------------------------------------------------------
1226 #
1227 # Boehm's GC library
1228 #
1229 #--------------------------------------------------------------------
1230 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1231
1232 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1233 LIBS="$BDW_GC_LIBS $LIBS"
1234
1235 # `GC_do_blocking ()' is available in GC 7.1 but not declared.
1236 AC_CHECK_FUNCS([GC_do_blocking])
1237 AC_CHECK_DECL([GC_do_blocking],
1238   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1239     [Define this if the `GC_do_blocking ()' function is declared])],
1240   [],
1241   [#include <gc/gc.h>])
1242
1243 # `GC_fn_type' is not available in GC 7.1 and earlier.
1244 AC_CHECK_TYPE([GC_fn_type],
1245   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1246     [Define this if the `GC_fn_type' type is available.])],
1247   [],
1248   [#include <gc/gc.h>])
1249
1250
1251 AC_CHECK_SIZEOF(float)
1252 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1253     AC_DEFINE([SCM_SINGLES], 1,
1254               [Define this if floats are the same size as longs.])
1255 fi
1256
1257 AC_MSG_CHECKING(for struct linger)
1258 AC_CACHE_VAL(scm_cv_struct_linger,
1259         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1260 #include <sys/types.h>
1261 #include <sys/socket.h>]],
1262                           [[struct linger lgr;  lgr.l_linger = 100]])],
1263                           [scm_cv_struct_linger="yes"],
1264                           [scm_cv_struct_linger="no"]))
1265 AC_MSG_RESULT($scm_cv_struct_linger)
1266 if test $scm_cv_struct_linger = yes; then
1267         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1268           [Define this if your system defines struct linger, for use with the
1269            getsockopt and setsockopt system calls.])
1270 fi
1271
1272
1273 # On mingw, struct timespec is in <pthread.h>.
1274 #
1275 AC_MSG_CHECKING(for struct timespec)
1276 AC_CACHE_VAL(scm_cv_struct_timespec,
1277         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1278 #include <time.h>
1279 #if HAVE_PTHREAD_H
1280 #include <pthread.h>
1281 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1282           [scm_cv_struct_timespec="yes"],
1283           [scm_cv_struct_timespec="no"]))
1284 AC_MSG_RESULT($scm_cv_struct_timespec)
1285 if test $scm_cv_struct_timespec = yes; then
1286   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1287     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1288 fi
1289
1290 #--------------------------------------------------------------------
1291 #
1292 # Flags for thread support
1293 #
1294 #--------------------------------------------------------------------
1295
1296 SCM_I_GSC_USE_PTHREAD_THREADS=0
1297 SCM_I_GSC_USE_NULL_THREADS=0
1298 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1299 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1300
1301 ### What thread package has the user asked for?
1302 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1303             , with_threads=yes)
1304
1305 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1306 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1307
1308 case "$with_threads" in
1309   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1310
1311     build_pthread_support="yes"
1312
1313     ACX_PTHREAD([CC="$PTHREAD_CC"
1314        LIBS="$PTHREAD_LIBS $LIBS"
1315        SCM_I_GSC_USE_PTHREAD_THREADS=1
1316        with_threads="pthreads"],
1317       [with_threads="null"
1318        build_pthread_support="no"])
1319
1320     old_CFLAGS="$CFLAGS"
1321     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1322
1323     # Reasons for testing:
1324     #     pthread_getattr_np - "np" meaning "non portable" says it
1325     #         all; not present on MacOS X or Solaris 10
1326     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1327     #         all; specific to MacOS X
1328     #     pthread_sigmask - not available on mingw
1329     #
1330     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1331
1332     # On past versions of Solaris, believe 8 through 10 at least, you
1333     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1334     # This is contrary to POSIX:
1335     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1336     # Check here if this style is required.
1337     #
1338     # glibc (2.3.6 at least) works both with or without braces, so the
1339     # test checks whether it works without.
1340     #
1341
1342     if test "$GCC" = "yes"; then
1343       # Since GCC only issues a warning for missing braces, so we need
1344       # `-Werror' to catch it.
1345       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1346     fi
1347
1348     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1349       guile_cv_need_braces_on_pthread_once_init,
1350       [AC_COMPILE_IFELSE([#include <pthread.h>
1351          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1352         [guile_cv_need_braces_on_pthread_once_init=no],
1353         [guile_cv_need_braces_on_pthread_once_init=yes])])
1354     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1355       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1356     fi
1357
1358     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1359     # 6.5.30m with GCC 3.3.
1360     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1361       guile_cv_need_braces_on_pthread_mutex_initializer,
1362       [AC_COMPILE_IFELSE([#include <pthread.h>
1363          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1364         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1365         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1366     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1367       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1368     fi
1369
1370     CFLAGS="$old_CFLAGS"
1371
1372     # On Solaris, sched_yield lives in -lrt.
1373     AC_SEARCH_LIBS(sched_yield, rt)
1374
1375   ;;
1376 esac
1377
1378 case "$with_threads" in
1379   "pthreads")
1380   ;;
1381   "no" | "null")
1382     SCM_I_GSC_USE_NULL_THREADS=1
1383     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1384     with_threads="null-threads"
1385   ;;
1386   * )
1387     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1388   ;;
1389 esac
1390
1391 AC_MSG_CHECKING(what kind of threads to support)
1392 AC_MSG_RESULT($with_threads)
1393
1394 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1395   [test "x$build_pthread_support" = "xyes"])
1396
1397
1398 ## Check whether pthread_attr_getstack works for the main thread
1399
1400 if test "$with_threads" = pthreads; then
1401
1402 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1403 old_CFLAGS="$CFLAGS"
1404 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1405 if test "$cross_compiling" = "no"; then
1406   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1407   #if HAVE_PTHREAD_ATTR_GETSTACK
1408   #include <pthread.h>
1409
1410   int main ()
1411   {
1412     pthread_attr_t attr;
1413     void *start, *end;
1414     size_t size;
1415
1416     pthread_getattr_np (pthread_self (), &attr);
1417     pthread_attr_getstack (&attr, &start, &size);
1418     end = (char *)start + size;
1419
1420     if ((void *)&attr < start || (void *)&attr >= end)
1421       return 1;
1422     else
1423       return 0;
1424   }
1425   #else
1426   int main ()
1427   {
1428     return 1;
1429   }
1430   #endif
1431   ]])],
1432   [works=yes
1433    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1434   [works=no],
1435   [])
1436 else
1437   works="assuming it doesn't"
1438 fi
1439 CFLAGS="$old_CFLAGS"
1440 AC_MSG_RESULT($works)
1441
1442 GUILE_THREAD_LOCAL_STORAGE
1443
1444 fi # with_threads=pthreads
1445
1446
1447 ## Cross building
1448 if test "$cross_compiling" = "yes"; then
1449   AC_MSG_CHECKING(cc for build)
1450   ## /usr/bin/cc still uses wrong assembler
1451   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1452   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1453 else
1454   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1455 fi
1456
1457 ## AC_MSG_CHECKING("if we are cross compiling")
1458 ## AC_MSG_RESULT($cross_compiling)
1459 if test "$cross_compiling" = "yes"; then
1460    AC_MSG_RESULT($CC_FOR_BUILD)
1461 fi
1462
1463 ## No need as yet to be more elaborate
1464 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1465
1466 AC_SUBST(cross_compiling)
1467 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1468 AC_SUBST(CCLD_FOR_BUILD)
1469
1470 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1471 ## --HOST is the platform that PACKAGE is compiled for.
1472 HOST_CC="$CC_FOR_BUILD"
1473 AC_SUBST(HOST_CC)
1474
1475 if test "$cross_compiling" = "yes"; then
1476   AC_MSG_CHECKING(guile for build)
1477   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1478 else
1479   GUILE_FOR_BUILD='$(preinstguile)'
1480 fi
1481
1482 ## AC_MSG_CHECKING("if we are cross compiling")
1483 ## AC_MSG_RESULT($cross_compiling)
1484 if test "$cross_compiling" = "yes"; then
1485    AC_MSG_RESULT($GUILE_FOR_BUILD)
1486 fi
1487 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1488 AC_SUBST(GUILE_FOR_BUILD)
1489
1490 ## If we're using GCC, ask for aggressive warnings.
1491 GCC_CFLAGS=""
1492 case "$GCC" in
1493   yes )
1494     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1495     ## much stuff with generic function pointers for that to really be
1496     ## less than exasperating.
1497     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1498     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1499     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1500       -Wdeclaration-after-statement -Wundef \
1501       -Wswitch-enum"
1502     # Do this here so we don't screw up any of the tests above that might
1503     # not be "warning free"
1504     if test "${GUILE_ERROR_ON_WARNING}" = yes
1505     then
1506         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1507         enable_compile_warnings=no
1508     fi
1509
1510     for flag in $POTENTIAL_GCC_CFLAGS
1511     do
1512         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1513     done
1514     ;;
1515 esac
1516
1517 AC_SUBST(GCC_CFLAGS)
1518
1519 # Check for GNU ld's "-z relro".
1520 GUILE_GNU_LD_RELRO
1521
1522
1523 ## If we're creating a shared library (using libtool!), then we'll
1524 ## need to generate a list of .lo files corresponding to the .o files
1525 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1526 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1527
1528 ## We also need to create corresponding .doc and .x files
1529 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1530 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1531
1532 # GNU Readline bindings.
1533 GUILE_READLINE
1534
1535 AC_SUBST(GUILE_MAJOR_VERSION)
1536 AC_SUBST(GUILE_MINOR_VERSION)
1537 AC_SUBST(GUILE_MICRO_VERSION)
1538 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1539 AC_SUBST(GUILE_VERSION)
1540
1541 #######################################################################
1542 # library versioning
1543
1544 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1545 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1546 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1547 AC_SUBST(LIBGUILE_INTERFACE)
1548
1549 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1550 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1551 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1552 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1553 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1554
1555 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1556 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1557 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1558 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1559 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1560
1561 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1562 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1563 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1564 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1565 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1566
1567 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1568 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1569 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1570 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1571 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1572
1573 AC_SUBST(LIBGUILE_I18N_MAJOR)
1574 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1575 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1576 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1577 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1578
1579
1580 #######################################################################
1581
1582 dnl Tell guile-config what flags guile users should compile and link with.
1583 GUILE_LIBS="$LDFLAGS $LIBS"
1584 GUILE_CFLAGS="$CPPFLAGS $PTHREAD_CFLAGS"
1585 AC_SUBST(GUILE_LIBS)
1586 AC_SUBST(GUILE_CFLAGS)
1587
1588 AC_SUBST(AWK)
1589 AC_SUBST(LIBLOBJS)
1590 AC_SUBST(EXTRA_DOT_DOC_FILES)
1591 AC_SUBST(EXTRA_DOT_X_FILES)
1592
1593 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1594 top_builddir_absolute=`pwd`
1595 AC_SUBST(top_builddir_absolute)
1596 top_srcdir_absolute=`(cd $srcdir && pwd)`
1597 AC_SUBST(top_srcdir_absolute)
1598
1599 dnl We need `sitedir' in `guile-1.8.pc'.
1600 dnl Note: `sitedir' must be kept in sync with `GUILE_SITE_DIR' in `guile.m4'.
1601 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1602 sitedir="$pkgdatadir/site"
1603 AC_SUBST([sitedir])
1604
1605 # Additional SCM_I_GSC definitions are above.
1606 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1607 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1608 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1609 AC_SUBST([SCM_I_GSC_C_INLINE])
1610 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1611
1612 AC_CONFIG_FILES([
1613   Makefile
1614   am/Makefile
1615   lib/Makefile
1616   benchmark-suite/Makefile
1617   doc/Makefile
1618   doc/r5rs/Makefile
1619   doc/ref/Makefile
1620   emacs/Makefile
1621   examples/Makefile
1622   libguile/Makefile
1623   libguile/version.h
1624   srfi/Makefile
1625   guile-readline/Makefile
1626   test-suite/Makefile
1627   test-suite/standalone/Makefile
1628   test-suite/vm/Makefile
1629   meta/Makefile
1630   module/Makefile
1631 ])
1632
1633 AC_CONFIG_FILES([meta/guile-2.0.pc])
1634 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1635 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1636
1637 GUILE_CONFIG_SCRIPT([check-guile])
1638 GUILE_CONFIG_SCRIPT([benchmark-guile])
1639 GUILE_CONFIG_SCRIPT([meta/guile])
1640 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1641 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1642 GUILE_CONFIG_SCRIPT([meta/guile-tools])
1643 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1644 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1645 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1646 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1647
1648 AC_OUTPUT
1649
1650 dnl Local Variables:
1651 dnl comment-start: "dnl "
1652 dnl comment-end: ""
1653 dnl comment-start-skip: "\\bdnl\\b\\s *"
1654 dnl End: