configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # User options
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_ARG_ENABLE(dynamic-linking,
  36   [  --enable-dynamic-linking  Include support for dynamic linking],,
  37   enable_dynamic_linking=yes)
  38
  39 AC_ARG_ENABLE(guile-debug,
  40 [  --enable-guile-debug    Include internal debugging functions])
  41 if test "$enableval" = y || test "$enableval" = yes; then
  42   AC_DEFINE(GUILE_DEBUG)
  43 fi
  44
  45 dnl The --disable-debug used to control these two.  But now they are
  46 dnl a required part of the distribution.
  47 AC_DEFINE(DEBUG_EXTENSIONS)
  48 AC_DEFINE(READER_EXTENSIONS)
  49
  50 #--------------------------------------------------------------------
  51
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AM_PROG_LIBTOOL
  55
  56 AC_AIX
  57 AC_ISC_POSIX
  58 AC_MINIX
  59
  60 AM_PROG_CC_STDC
  61
  62 AC_C_CONST
  63 AC_C_INLINE
  64
  65 AC_HEADER_STDC
  66 AC_HEADER_DIRENT
  67 AC_HEADER_TIME
  68 AC_HEADER_SYS_WAIT
  69 AC_CHECK_HEADERS(libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
  70 GUILE_HEADER_LIBC_WITH_UNISTD
  71
  72 AC_TYPE_GETGROUPS
  73 AC_TYPE_SIGNAL
  74 AC_TYPE_MODE_T
  75
  76 AC_CHECK_LIB(m, main)
  77 AC_CHECK_FUNCS(gethostbyname)
  78 if test $ac_cv_func_gethostbyname = no; then
  79     AC_CHECK_LIB(nsl, gethostbyname)
  80 fi
  81 AC_CHECK_FUNCS(connect)
  82 if test $ac_cv_func_connect = no; then
  83     AC_CHECK_LIB(socket, connect)
  84 fi
  85
  86 dnl Should we check for curses, terminfo, and termlib, too?
  87 for termlib in ncurses termcap ; do
  88    AC_CHECK_LIB(${termlib}, tgoto,
  89                 [LIBS="-l${termlib} $LIBS"; break])
  90 done
  91 AC_CHECK_LIB(readline, main)
  92 AC_CHECK_FUNCS(rl_clear_signals rl_cleanup_after_signal)
  93
  94 AC_CACHE_CHECK([for rl_getc_function pointer in readline],
  95                ac_cv_var_rl_getc_function,
  96                [AC_TRY_LINK([
  97 #include <stdio.h>
  98 #include <readline/readline.h>],
  99                             [rl_getc_function;],
 100                             [ac_cv_var_rl_getc_function=yes],
 101                             [ac_cv_var_rl_getc_function=no])])
 102 if test "$ac_cv_var_rl_getc_function" = "yes"; then
 103   AC_DEFINE(HAVE_RL_GETC_FUNCTION)
 104 fi
 105
 106 if test $ac_cv_lib_readline_readline = yes -a $ac_cv_var_rl_getc_function = no; then
 107   echo 'Warning: libreadline is too old on your system.  Need >= 2.1.'
 108 fi
 109
 110 # Checks for dynamic linking
 111
 112 if test "$enable_dynamic_linking" = "yes"; then
 113
 114 AC_CHECK_LIB(dl,dlopen)
 115 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 116   AC_CHECK_FUNCS(dlopen)
 117   AC_DEFINE(DYNAMIC_LINKING)
 118 else
 119 AC_CHECK_LIB(dld,dld_link)
 120 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
 121   AC_DEFINE(DYNAMIC_LINKING)
 122 else
 123 AC_CHECK_FUNCS(shl_load)
 124 if test "$ac_cv_func_shl_load" = "yes"; then
 125   AC_DEFINE(DYNAMIC_LINKING)
 126 else
 127 AC_CHECK_FUNCS(dlopen)
 128 if test "$ac_cv_func_dlopen" = "yes"; then
 129   AC_DEFINE(DYNAMIC_LINKING)
 130 fi
 131 fi
 132 fi
 133 fi
 134
 135 fi
 136
 137 GUILE_DLSYM_USCORE
 138
 139 AC_CHECK_FUNCS(ctermid ftime getcwd geteuid gethostent gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep)
 140
 141 ### Some systems don't declare some functions.  On such systems, we
 142 ### need to at least provide our own K&R-style declarations.
 143
 144 ### GUILE_FUNC_DECLARED(function, headerfile)
 145
 146 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 147 ### not there, #define MISSING_FUNCTION_DECL.
 148 AC_DEFUN(GUILE_FUNC_DECLARED, [
 149   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 150     AC_EGREP_HEADER($1, $2,
 151                     guile_cv_func_$1_declared=yes,
 152                     guile_cv_func_$1_declared=no))
 153   if test [x$guile_cv_func_]$1[_declared] = xno; then
 154     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 155   fi
 156 ])
 157
 158 GUILE_FUNC_DECLARED(strptime, time.h)
 159 GUILE_FUNC_DECLARED(bzero, string.h)
 160 GUILE_FUNC_DECLARED(sleep, unistd.h)
 161 GUILE_FUNC_DECLARED(usleep, unistd.h)
 162
 163 ### On some systems usleep has no return value.  If it does have one,
 164 ### we'd like to return it; otherwise, we'll fake it.
 165 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 166   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 167                    /usr/include/unistd.h,
 168                    [guile_cv_func_usleep_return_type=void],
 169                    [guile_cv_func_usleep_return_type=int])])
 170 case "$guile_cv_func_usleep_return_type" in
 171   "void" )
 172     AC_DEFINE(USLEEP_RETURNS_VOID)
 173   ;;
 174 esac
 175
 176 dnl <GNU-WIN32 hacks>
 177
 178 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 179 if test -n "$have_sys_un_h" ; then
 180 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 181 fi
 182
 183 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 184
 185 dnl I don't know what this prefixing of cygwin32_ is for.
 186 dnl scmconfig.h wasn't updated with the test results.
 187 dnl so use AC_CHECK_FUNCS for now.
 188
 189 dnl how about:
 190 dnl save confdefs.h
 191 dnl if test $ac_cv_cigwin = yes; then
 192 dnl   modify confdefs.h
 193 dnl fi
 194 dnl AC_CHECK_FUNCS...
 195 dnl restore confdefs.h
 196
 197 dnl cp confdefs.h confdefs.h.bak
 198 dnl for func in sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof ; do
 199 dnl cp confdefs.h.bak confdefs.h
 200 dnl cat >> confdefs.h << EOF
 201 dnl #ifdef __CYGWIN32__
 202 dnl #define $func cygwin32_$func
 203 dnl #endif
 204 dnl EOF
 205 dnl AC_CHECK_FUNC($func)
 206 dnl done
 207 dnl cp confdefs.h.bak confdefs.h
 208
 209 AC_CHECK_FUNCS(sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof)
 210
 211 dnl </GNU-WIN32 hacks>
 212
 213 AC_CACHE_CHECK([for restartable system calls], scm_cv_restarts,
 214         if test $ac_cv_func_sigaction = yes; then
 215                 [AC_TRY_COMPILE([#include <signal.h>],
 216                                 [int a = SA_RESTART],
 217                                 scm_cv_restarts=yes,
 218                                 scm_cv_restarts=no)]
 219         else
 220                 scm_cv_restarts=no
 221         fi)
 222 if test $scm_cv_restarts = yes; then
 223         AC_DEFINE(HAVE_RESTARTS)
 224 fi
 225
 226 if test "$ac_cv_header_regex_h" = yes ||
 227    test "$ac_cv_header_rxposix_h" = yes ||
 228    test "$ac_cv_header_rx_rxposix_h" = yes; then
 229   GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 230   [AC_CHECK_LIB(rx, main)
 231    GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 232   )
 233   dnl The following should not be necessary, but for some reason
 234   dnl autoheader misses it if we don't include it!
 235   if test "$ac_cv_func_regcomp_norx" = yes ||
 236      test "$ac_cv_func_regcomp_rx" = yes; then
 237     AC_DEFINE(HAVE_REGCOMP)
 238   fi
 239 fi
 240
 241 AC_REPLACE_FUNCS(inet_aton putenv strerror)
 242
 243 # When testing for the presence of alloca, we need to add alloca.o
 244 # explicitly to LIBOBJS to make sure that it is translated to
 245 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 246 AC_FUNC_ALLOCA
 247 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 248
 249 AC_STRUCT_ST_RDEV
 250 AC_STRUCT_ST_BLKSIZE
 251
 252 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 253 # LIBOBJS, which we don't need.  This seems more direct.
 254 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 255 [AC_TRY_COMPILE([#include <sys/types.h>
 256 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 257 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 258 if test $ac_cv_struct_st_blocks = yes; then
 259   AC_DEFINE(HAVE_ST_BLOCKS)
 260 fi
 261
 262 AC_STRUCT_TIMEZONE
 263 GUILE_STRUCT_UTIMBUF
 264
 265 #--------------------------------------------------------------------
 266 #
 267 # Which way does the stack grow?
 268 #
 269 #--------------------------------------------------------------------
 270
 271 AC_TRY_RUN(aux (l) unsigned long l;
 272              { int x; exit (l >= ((unsigned long)&x)); }
 273            main () { int q; aux((unsigned long)&q); },
 274            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 275
 276 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 277     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 278                 [guile_cv_type_float_fits_long=yes],
 279                 [guile_cv_type_float_fits_long=no],
 280                 [guile_cv_type_float_fits_long=guess-yes])])
 281 case $guile_cv_type_float_fits_long in
 282   "yes" )
 283     AC_DEFINE(SCM_SINGLES)
 284   ;;
 285   "guess-yes" )
 286     AC_DEFINE(SCM_SINGLES)
 287     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 288     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 289   ;;
 290 esac
 291
 292
 293 AC_MSG_CHECKING(for struct linger)
 294 AC_CACHE_VAL(scm_cv_struct_linger,
 295         AC_TRY_COMPILE([
 296 #include <sys/types.h>
 297 #include <sys/socket.h>],
 298                         [struct linger lgr;  lgr.l_linger = 100],
 299                         scm_cv_struct_linger="yes",
 300                         scm_cv_struct_linger="no"))
 301 AC_MSG_RESULT($scm_cv_struct_linger)
 302 if test $scm_cv_struct_linger = yes; then
 303         AC_DEFINE(HAVE_STRUCT_LINGER)
 304 fi
 305
 306 #--------------------------------------------------------------------
 307 #
 308 # How can you violate a stdio abstraction by setting a stream's fd?
 309 #
 310 #--------------------------------------------------------------------
 311
 312 AC_MSG_CHECKING(how to set a stream file descriptor)
 313 AC_CACHE_VAL(scm_cv_fd_setter,
 314         AC_TRY_COMPILE([#include <stdio.h>],
 315                         [stdout->_file = 1],
 316                         scm_cv_fd_setter="_file",
 317         AC_TRY_COMPILE([#include <stdio.h>],
 318                         [stdout->__file = 1],
 319                         scm_cv_fd_setter="__file",
 320         AC_TRY_COMPILE([#include <stdio.h>],
 321                         [stdout->_fileno = 1],
 322                         scm_cv_fd_setter="_fileno",
 323                         scm_cv_fd_setter=""))))
 324
 325 if test "$scm_cv_fd_setter"; then
 326         AC_MSG_RESULT($scm_cv_fd_setter)
 327         AC_DEFINE_UNQUOTED(FD_SETTER, $scm_cv_fd_setter)
 328 else
 329         AC_MSG_RESULT(we couldn't do it!)
 330 fi
 331
 332 #--------------------------------------------------------------------
 333 # How to find out whether a FILE structure contains buffered data.
 334 # From Tk we have the following list:
 335 #               _cnt:           Most UNIX systems
 336 #               __cnt:          HPUX and SCO
 337 #               _r:             BSD
 338 #               readCount:      Sprite
 339 #       Or, in GNU libc there are two fields, _gptr and _egptr, which
 340 #       have to be compared.
 341 #       These can also be known as _IO_read_ptr and _IO_read_end.
 342 #--------------------------------------------------------------------
 343
 344 AC_MSG_CHECKING(how to get buffer char count from FILE structure)
 345 AC_CACHE_VAL(scm_cv_struct_file_count,
 346         AC_TRY_COMPILE([#include <stdio.h>],
 347                         [FILE *f = stdin; f->_cnt = 0],
 348                         scm_cv_struct_file_count="_cnt",
 349         AC_TRY_COMPILE([#include <stdio.h>],
 350                         [FILE *f = stdin; f->__cnt = 0],
 351                         scm_cv_struct_file_count="__cnt",
 352         AC_TRY_COMPILE([#include <stdio.h>],
 353                         [FILE *f = stdin; f->_r = 0],
 354                         scm_cv_struct_file_count="_r",
 355         AC_TRY_COMPILE([#include <stdio.h>],
 356                         [FILE *f = stdin; f->readCount = 0],
 357                         scm_cv_struct_file_count="readCount",
 358         scm_cv_struct_file_count="")))))
 359 if test "$scm_cv_struct_file_count"; then
 360         AC_MSG_RESULT($scm_cv_struct_file_count)
 361         AC_DEFINE_UNQUOTED(FILE_CNT_FIELD, $scm_cv_struct_file_count)
 362 else
 363 AC_CACHE_VAL(scm_cv_struct_file_gptr,
 364         AC_TRY_COMPILE([#include <stdio.h>],
 365                         [FILE *f = stdin; f->_gptr = f->egptr;],
 366                         scm_cv_struct_file_gptr=1,
 367         scm_cv_struct_file_gptr=""))
 368 if test "$scm_cv_struct_gptr"; then
 369         AC_MSG_RESULT(gptr)
 370         AC_DEFINE_UNQUOTED(FILE_CNT_GPTR, $scm_cv_struct_file_gptr)
 371 else
 372 AC_CACHE_VAL(scm_cv_struct_file_readptr,
 373         AC_TRY_COMPILE([#include <stdio.h>],
 374                         [FILE *f = stdin; f->_IO_read_ptr = f->_IO_read_end;],
 375                         scm_cv_struct_file_readptr=1))
 376 if test "$scm_cv_struct_file_readptr"; then
 377         AC_MSG_RESULT(read_ptr)
 378         AC_DEFINE_UNQUOTED(FILE_CNT_READPTR, $scm_cv_struct_file_readptr)
 379 else
 380         AC_MSG_RESULT(we couldn't do it!)
 381 fi
 382 fi
 383 fi
 384
 385 #--------------------------------------------------------------------
 386 #
 387 # Flags for thread support
 388 #
 389 #--------------------------------------------------------------------
 390
 391 ### What thread package has the user asked for?
 392 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 393             , with_threads=no)
 394
 395 ### Turn $with_threads into either the name of a threads package, like
 396 ### `qt', or `no', meaning that threads should not be supported.
 397 AC_MSG_CHECKING(whether to support threads)
 398 case "$with_threads" in
 399   "yes" | "qt" | "coop" | "")
 400     with_threads=qt
 401   ;;
 402   "no" )
 403   ;;
 404   * )
 405     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 406   ;;
 407 esac
 408 AC_MSG_RESULT($with_threads)
 409
 410 ## Make sure the threads package we've chosen is actually supported on
 411 ## the present platform.
 412 case "${with_threads}" in
 413   "qt" )
 414     ## This configures the QuickThreads package, and sets or clears
 415     ## the THREAD_PACKAGE variable if qthreads don't configure
 416     ## correctly.
 417     QTHREADS_CONFIGURE
 418    ;;
 419 esac
 420
 421 ## If we're using threads, bring in some other parts of Guile which
 422 ## work with them.
 423 if test "${THREAD_PACKAGE}" != "" ; then
 424   AC_DEFINE(USE_THREADS, 1)
 425
 426   ## Include the Guile thread interface in the library...
 427   LIBOBJS="$LIBOBJS threads.o"
 428
 429   ## ... and tell it which package to talk to.
 430   case "${THREAD_PACKAGE}" in
 431     "QT" )
 432       AC_DEFINE(USE_COOP_THREADS, 1)
 433     ;;
 434     * )
 435       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 436     ;;
 437   esac
 438
 439   ## Bring in scm_internal_select, if appropriate.
 440   if test $ac_cv_func_gettimeofday = yes &&
 441      test $ac_cv_func_select = yes; then
 442     LIBOBJS="$LIBOBJS iselect.o"
 443     AC_DEFINE(GUILE_ISELECT, 1)
 444   fi
 445 fi
 446
 447 ## If we're using GCC, ask for aggressive warnings.
 448 case "$GCC" in
 449   yes )
 450     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 451     ## much stuff with generic function pointers for that to really be
 452     ## less than exasperating.
 453     CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wmissing-prototypes" ;;
 454 esac
 455
 456 AC_PROG_AWK
 457
 458 ## If we're creating a shared library (using libtool!), then we'll
 459 ## need to generate a list of .lo files corresponding to the .o files
 460 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 461 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 462
 463 AC_SUBST(GUILE_MAJOR_VERSION)
 464 AC_SUBST(GUILE_MINOR_VERSION)
 465 AC_SUBST(GUILE_VERSION)
 466
 467 dnl Tell guile-config what flags guile users should link against.
 468 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 469 AC_SUBST(GUILE_LIBS)
 470
 471 dnl timestamping the interpreter and scheme libraries:
 472 dnl
 473 dnl Help us notice when we're running one version of the Guile
 474 dnl interpreter against a different version of the ice-9 Scheme code.
 475 dnl This will definitely detect version skew due to differing
 476 dnl snapshots and releases, but may not catch skew for the developers.
 477 dnl Hopefully it will not detect skew when there is none; if that
 478 dnl happens, the warnings will be useless, and we should remove this.
 479 GUILE_STAMP="`date`"
 480 AC_SUBST(GUILE_STAMP)
 481
 482 AC_SUBST(AWK)
 483 AC_SUBST(LIBLOBJS)
 484
 485 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/versiondat.h ice-9/Makefile ice-9/version.scm qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf])
 486
 487 dnl Local Variables:
 488 dnl comment-start: "dnl "
 489 dnl comment-end: ""
 490 dnl comment-start-skip: "\\bdnl\\b\\s *"
 491 dnl End: