configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # Independent Subdirectories
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_CONFIG_SUBDIRS(guile-readline)
  36
  37 #--------------------------------------------------------------------
  38 #
  39 # User options
  40 #
  41 #--------------------------------------------------------------------
  42
  43 AC_ARG_ENABLE(dynamic-linking,
  44   [  --enable-dynamic-linking  include support for dynamic linking],,
  45   enable_dynamic_linking=yes)
  46
  47 AC_ARG_ENABLE(guile-debug,
  48   [  --enable-guile-debug    include internal debugging functions],
  49   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  50     AC_DEFINE(GUILE_DEBUG)
  51   fi)
  52
  53 AC_ARG_ENABLE(debug-freelist,
  54   [  --enable-debug-freelist    Include garbage collector freelist debugging code],
  55   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  56     AC_DEFINE(GUILE_DEBUG_FREELIST)
  57   fi)
  58
  59 AC_ARG_ENABLE(arrays,
  60   [  --disable-arrays        omit array and uniform array support],,
  61   enable_arrays=yes)
  62
  63 AC_ARG_ENABLE(posix,
  64   [  --disable-posix         omit posix interfaces],,
  65   enable_posix=yes)
  66
  67 AC_ARG_ENABLE(networking,
  68   [  --disable-net           omit networking interfaces],,
  69   enable_networking=yes)
  70
  71 AC_ARG_ENABLE(regex,
  72   [  --disable-regex         omit regular expression interfaces],,
  73   enable_regex=yes)
  74
  75 dnl The --disable-debug used to control these two.  But now they are
  76 dnl a required part of the distribution.
  77 AC_DEFINE(DEBUG_EXTENSIONS)
  78 AC_DEFINE(READER_EXTENSIONS)
  79
  80 dnl files which are destined for separate modules.
  81
  82 if test "$enable_arrays" = yes; then
  83    LIBOBJS="$LIBOBJS ramap.o unif.o"
  84    AC_DEFINE(HAVE_ARRAYS)
  85 fi
  86
  87 if test "$enable_posix" = yes; then
  88    LIBOBJS="$LIBOBJS filesys.o posix.o"
  89    AC_DEFINE(HAVE_POSIX)
  90 fi
  91
  92 if test "$enable_networking" = yes; then
  93    LIBOBJS="$LIBOBJS net_db.o socket.o"
  94    AC_DEFINE(HAVE_NETWORKING)
  95 fi
  96
  97 #--------------------------------------------------------------------
  98
  99 AC_PROG_CC
 100 AC_PROG_CPP
 101
 102 AC_AIX
 103 AC_ISC_POSIX
 104 AC_MINIX
 105
 106 AM_PROG_CC_STDC
 107 AM_PROG_LIBTOOL
 108
 109 AC_C_CONST
 110 AC_C_INLINE
 111 AC_CHECK_SIZEOF(int)
 112 AC_CHECK_SIZEOF(long)
 113 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 114                AC_TRY_COMPILE(,
 115                               [long long a],
 116                               scm_cv_long_longs=yes,
 117                               scm_cv_long_longs=no))
 118 if test "$scm_cv_long_longs" = yes; then
 119   AC_DEFINE(HAVE_LONG_LONGS)
 120 fi
 121
 122 AC_HEADER_STDC
 123 AC_HEADER_DIRENT
 124 AC_HEADER_TIME
 125 AC_HEADER_SYS_WAIT
 126 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
 127 GUILE_HEADER_LIBC_WITH_UNISTD
 128
 129 AC_TYPE_GETGROUPS
 130 AC_TYPE_SIGNAL
 131 AC_TYPE_MODE_T
 132
 133 AC_CHECK_LIB(m, main)
 134 AC_CHECK_FUNCS(gethostbyname)
 135 if test $ac_cv_func_gethostbyname = no; then
 136     AC_CHECK_LIB(nsl, gethostbyname)
 137 fi
 138 AC_CHECK_FUNCS(connect)
 139 if test $ac_cv_func_connect = no; then
 140     AC_CHECK_LIB(socket, connect)
 141 fi
 142
 143 # Checks for dynamic linking
 144
 145 if test "$enable_dynamic_linking" = "yes"; then
 146
 147 AC_CHECK_LIB(dl,dlopen)
 148 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 149   AC_CHECK_FUNCS(dlopen)
 150   AC_DEFINE(DYNAMIC_LINKING)
 151 else
 152 AC_CHECK_LIB(dld,dld_link)
 153 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
 154   AC_DEFINE(DYNAMIC_LINKING)
 155 else
 156 AC_CHECK_FUNCS(shl_load)
 157 if test "$ac_cv_func_shl_load" = "yes"; then
 158   AC_DEFINE(DYNAMIC_LINKING)
 159 else
 160 AC_CHECK_FUNCS(dlopen)
 161 if test "$ac_cv_func_dlopen" = "yes"; then
 162   AC_DEFINE(DYNAMIC_LINKING)
 163 fi
 164 fi
 165 fi
 166 fi
 167
 168 fi
 169
 170 GUILE_DLSYM_USCORE
 171
 172 AC_CHECK_FUNCS(ctermid ftime getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep atexit on_exit)
 173
 174 ### Some systems don't declare some functions.  On such systems, we
 175 ### need to at least provide our own K&R-style declarations.
 176
 177 ### GUILE_FUNC_DECLARED(function, headerfile)
 178
 179 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 180 ### not there, #define MISSING_FUNCTION_DECL.
 181 AC_DEFUN(GUILE_FUNC_DECLARED, [
 182   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 183     AC_EGREP_HEADER($1, $2,
 184                     guile_cv_func_$1_declared=yes,
 185                     guile_cv_func_$1_declared=no))
 186   if test [x$guile_cv_func_]$1[_declared] = xno; then
 187     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 188   fi
 189 ])
 190
 191 GUILE_FUNC_DECLARED(strptime, time.h)
 192 GUILE_FUNC_DECLARED(bzero, string.h)
 193 GUILE_FUNC_DECLARED(sleep, unistd.h)
 194 GUILE_FUNC_DECLARED(usleep, unistd.h)
 195
 196 ### On some systems usleep has no return value.  If it does have one,
 197 ### we'd like to return it; otherwise, we'll fake it.
 198 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 199   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 200                    /usr/include/unistd.h,
 201                    [guile_cv_func_usleep_return_type=void],
 202                    [guile_cv_func_usleep_return_type=int])])
 203 case "$guile_cv_func_usleep_return_type" in
 204   "void" )
 205     AC_DEFINE(USLEEP_RETURNS_VOID)
 206   ;;
 207 esac
 208
 209 dnl <GNU-WIN32 hacks>
 210
 211 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 212 if test -n "$have_sys_un_h" ; then
 213 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 214 fi
 215
 216 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 217
 218 dnl I don't know what this prefixing of cygwin32_ is for.
 219 dnl scmconfig.h wasn't updated with the test results.
 220 dnl so use AC_CHECK_FUNCS for now.
 221
 222 dnl how about:
 223 dnl save confdefs.h
 224 dnl if test $ac_cv_cigwin = yes; then
 225 dnl   modify confdefs.h
 226 dnl fi
 227 dnl AC_CHECK_FUNCS...
 228 dnl restore confdefs.h
 229
 230 dnl cp confdefs.h confdefs.h.bak
 231 dnl for func in gethostent sethostent endhostent getnetent setnetent endnetent getprotoent setprotoent endprotoent getservent setservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof hstrerror; do
 232 dnl cp confdefs.h.bak confdefs.h
 233 dnl cat >> confdefs.h << EOF
 234 dnl #ifdef __CYGWIN32__
 235 dnl #define $func cygwin32_$func
 236 dnl #endif
 237 dnl EOF
 238 dnl AC_CHECK_FUNC($func)
 239 dnl done
 240 dnl cp confdefs.h.bak confdefs.h
 241
 242 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 243                setnetent    getnetent    endnetent    dnl
 244                setprotoent  getprotoent  endprotoent  dnl
 245                setservent   getservent   endservent   dnl
 246                getnetbyaddr getnetbyname dnl
 247                inet_lnaof inet_makeaddr inet_netof hstrerror)
 248
 249 dnl </GNU-WIN32 hacks>
 250
 251 dnl Test whether system calls are restartable by default on the
 252 dnl current system.  If they are not, we put a loop around every system
 253 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 254 dnl change from the default behaviour.  On the other hand, if signals
 255 dnl are restartable then the loop is not installed and when libguile
 256 dnl initialises it also resets the behaviour of each signal to cause a
 257 dnl restart (in case a different runtime had a different default
 258 dnl behaviour for some reason: e.g., different versions of linux seem
 259 dnl to behave differently.)
 260
 261 AC_SYS_RESTARTABLE_SYSCALLS
 262
 263 if test "$enable_regex" = yes; then
 264    if test "$ac_cv_header_regex_h" = yes ||
 265       test "$ac_cv_header_rxposix_h" = yes ||
 266       test "$ac_cv_header_rx_rxposix_h" = yes; then
 267      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 268      [AC_CHECK_LIB(rx, main)
 269       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 270      )
 271      dnl The following should not be necessary, but for some reason
 272      dnl autoheader misses it if we don't include it!
 273      if test "$ac_cv_func_regcomp_norx" = yes ||
 274         test "$ac_cv_func_regcomp_rx" = yes; then
 275        AC_DEFINE(HAVE_REGCOMP)
 276      fi
 277    fi
 278 fi
 279
 280 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
 281
 282 # When testing for the presence of alloca, we need to add alloca.o
 283 # explicitly to LIBOBJS to make sure that it is translated to
 284 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 285 AC_FUNC_ALLOCA
 286 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 287
 288 AC_STRUCT_ST_RDEV
 289 AC_STRUCT_ST_BLKSIZE
 290
 291 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 292 # LIBOBJS, which we don't need.  This seems more direct.
 293 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 294 [AC_TRY_COMPILE([#include <sys/types.h>
 295 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 296 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 297 if test $ac_cv_struct_st_blocks = yes; then
 298   AC_DEFINE(HAVE_ST_BLOCKS)
 299 fi
 300
 301 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 302   [AC_TRY_CPP([#include <sys/stat.h>
 303                #ifndef S_ISLNK
 304                #error no S_ISLNK
 305                #endif],
 306                ac_cv_macro_S_ISLNK=yes,
 307                ac_cv_macro_S_ISLNK=no)])
 308 if test $ac_cv_macro_S_ISLNK = yes; then
 309   AC_DEFINE(HAVE_S_ISLNK)
 310 fi
 311
 312 AC_STRUCT_TIMEZONE
 313 GUILE_STRUCT_UTIMBUF
 314
 315 #--------------------------------------------------------------------
 316 #
 317 # Which way does the stack grow?
 318 #
 319 #--------------------------------------------------------------------
 320
 321 AC_TRY_RUN(aux (l) unsigned long l;
 322              { int x; exit (l >= ((unsigned long)&x)); }
 323            main () { int q; aux((unsigned long)&q); },
 324            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 325
 326 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 327     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 328                 [guile_cv_type_float_fits_long=yes],
 329                 [guile_cv_type_float_fits_long=no],
 330                 [guile_cv_type_float_fits_long=guess-yes])])
 331 case $guile_cv_type_float_fits_long in
 332   "yes" )
 333     AC_DEFINE(SCM_SINGLES)
 334   ;;
 335   "guess-yes" )
 336     AC_DEFINE(SCM_SINGLES)
 337     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 338     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 339   ;;
 340 esac
 341
 342
 343 AC_MSG_CHECKING(for struct linger)
 344 AC_CACHE_VAL(scm_cv_struct_linger,
 345         AC_TRY_COMPILE([
 346 #include <sys/types.h>
 347 #include <sys/socket.h>],
 348                         [struct linger lgr;  lgr.l_linger = 100],
 349                         scm_cv_struct_linger="yes",
 350                         scm_cv_struct_linger="no"))
 351 AC_MSG_RESULT($scm_cv_struct_linger)
 352 if test $scm_cv_struct_linger = yes; then
 353         AC_DEFINE(HAVE_STRUCT_LINGER)
 354 fi
 355
 356 #--------------------------------------------------------------------
 357 #
 358 # Flags for thread support
 359 #
 360 #--------------------------------------------------------------------
 361
 362 ### What thread package has the user asked for?
 363 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 364             , with_threads=no)
 365
 366 ### Turn $with_threads into either the name of a threads package, like
 367 ### `qt', or `no', meaning that threads should not be supported.
 368 AC_MSG_CHECKING(whether to support threads)
 369 case "$with_threads" in
 370   "yes" | "qt" | "coop" | "")
 371     with_threads=qt
 372   ;;
 373   "no" )
 374   ;;
 375   * )
 376     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 377   ;;
 378 esac
 379 AC_MSG_RESULT($with_threads)
 380
 381 ## Make sure the threads package we've chosen is actually supported on
 382 ## the present platform.
 383 case "${with_threads}" in
 384   "qt" )
 385     ## This configures the QuickThreads package, and sets or clears
 386     ## the THREAD_PACKAGE variable if qthreads don't configure
 387     ## correctly.
 388     QTHREADS_CONFIGURE
 389    ;;
 390 esac
 391
 392 ## If we're using threads, bring in some other parts of Guile which
 393 ## work with them.
 394 if test "${THREAD_PACKAGE}" != "" ; then
 395   AC_DEFINE(USE_THREADS, 1)
 396
 397   ## Include the Guile thread interface in the library...
 398   LIBOBJS="$LIBOBJS threads.o"
 399
 400   ## ... and tell it which package to talk to.
 401   case "${THREAD_PACKAGE}" in
 402     "QT" )
 403       AC_DEFINE(USE_COOP_THREADS, 1)
 404     ;;
 405     * )
 406       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 407     ;;
 408   esac
 409
 410   ## Bring in scm_internal_select, if appropriate.
 411   if test $ac_cv_func_gettimeofday = yes &&
 412      test $ac_cv_func_select = yes; then
 413     LIBOBJS="$LIBOBJS iselect.o"
 414     AC_DEFINE(GUILE_ISELECT, 1)
 415   fi
 416 fi
 417
 418 ## If we're using GCC, ask for aggressive warnings.
 419 case "$GCC" in
 420   yes )
 421     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 422     ## much stuff with generic function pointers for that to really be
 423     ## less than exasperating.
 424     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 425     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 426     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 427 esac
 428
 429 AC_PROG_AWK
 430
 431 ## If we're creating a shared library (using libtool!), then we'll
 432 ## need to generate a list of .lo files corresponding to the .o files
 433 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 434 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 435
 436 AC_SUBST(GUILE_MAJOR_VERSION)
 437 AC_SUBST(GUILE_MINOR_VERSION)
 438 AC_SUBST(GUILE_VERSION)
 439
 440 dnl Tell guile-config what flags guile users should link against.
 441 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 442 AC_SUBST(GUILE_LIBS)
 443
 444 AC_SUBST(AWK)
 445 AC_SUBST(LIBLOBJS)
 446
 447 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/versiondat.h ice-9/Makefile qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf])
 448
 449 dnl Local Variables:
 450 dnl comment-start: "dnl "
 451 dnl comment-end: ""
 452 dnl comment-start-skip: "\\bdnl\\b\\s *"
 453 dnl End: