configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # Independent Subdirectories
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_CONFIG_SUBDIRS(guile-readline)
  36
  37 #--------------------------------------------------------------------
  38 #
  39 # User options
  40 #
  41 #--------------------------------------------------------------------
  42
  43 AC_ARG_ENABLE(debug-freelist,
  44   [  --enable-debug-freelist  include garbage collector freelist debugging code],
  45   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  46     AC_DEFINE(GUILE_DEBUG_FREELIST)
  47   fi)
  48
  49 AC_ARG_ENABLE(debug-malloc,
  50   [  --enable-debug-malloc    include malloc debugging code],
  51   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  52     AC_DEFINE(GUILE_DEBUG_MALLOC)
  53   fi)
  54
  55 AC_ARG_ENABLE(guile-debug,
  56   [  --enable-guile-debug    include internal debugging functions],
  57   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  58     AC_DEFINE(GUILE_DEBUG)
  59   fi)
  60
  61 AC_ARG_ENABLE(arrays,
  62   [  --disable-arrays        omit array and uniform array support],,
  63   enable_arrays=yes)
  64
  65 AC_ARG_ENABLE(posix,
  66   [  --disable-posix         omit posix interfaces],,
  67   enable_posix=yes)
  68
  69 AC_ARG_ENABLE(networking,
  70   [  --disable-networking    omit networking interfaces],,
  71   enable_networking=yes)
  72
  73 AC_ARG_ENABLE(regex,
  74   [  --disable-regex         omit regular expression interfaces],,
  75   enable_regex=yes)
  76
  77 dnl The --disable-debug used to control these two.  But now they are
  78 dnl a required part of the distribution.
  79 AC_DEFINE(DEBUG_EXTENSIONS)
  80 AC_DEFINE(READER_EXTENSIONS)
  81
  82 dnl files which are destined for separate modules.
  83
  84 if test "$enable_arrays" = yes; then
  85    LIBOBJS="$LIBOBJS ramap.o unif.o"
  86    AC_DEFINE(HAVE_ARRAYS)
  87 fi
  88
  89 if test "$enable_posix" = yes; then
  90    LIBOBJS="$LIBOBJS filesys.o posix.o"
  91    AC_DEFINE(HAVE_POSIX)
  92 fi
  93
  94 if test "$enable_networking" = yes; then
  95    LIBOBJS="$LIBOBJS net_db.o socket.o"
  96    AC_DEFINE(HAVE_NETWORKING)
  97 fi
  98
  99 if test "$enable_debug_malloc" = yes; then
 100    LIBOBJS="$LIBOBJS debug-malloc.o"
 101 fi
 102
 103 #--------------------------------------------------------------------
 104
 105 AC_LIBLTDL_CONVENIENCE
 106 AC_CONFIG_SUBDIRS(libltdl)
 107
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110 AC_LIBTOOL_DLOPEN
 111
 112 AC_AIX
 113 AC_ISC_POSIX
 114 AC_MINIX
 115
 116 AM_PROG_CC_STDC
 117 AM_PROG_LIBTOOL
 118
 119 AC_C_CONST
 120 AC_C_INLINE
 121 AC_CHECK_SIZEOF(int)
 122 AC_CHECK_SIZEOF(long)
 123 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 124                AC_TRY_COMPILE(,
 125                               [long long a],
 126                               scm_cv_long_longs=yes,
 127                               scm_cv_long_longs=no))
 128 if test "$scm_cv_long_longs" = yes; then
 129   AC_DEFINE(HAVE_LONG_LONGS)
 130 fi
 131
 132 dnl check for an optimisation problem which is present in some versions
 133 dnl of gcc, including 2.95.2.
 134 AC_MSG_CHECKING(for broken GCSE optimisation)
 135 AC_CACHE_VAL(guile_cv_broken_gcse,
 136    AC_TRY_RUN([
 137         int main ()
 138         {
 139           long winds = 0;
 140
 141           while (winds != 0)
 142             {
 143               if (*(char *) 0)
 144                 break;
 145             }
 146
 147           if (winds == 0 || *(char *) 0)
 148             exit (0);
 149
 150           return 0;
 151         }],
 152         guile_cv_broken_gcse=no, guile_cv_broken_gcse=yes,
 153         guile_cv_broken_gcse=yes))
 154 AC_MSG_RESULT($guile_cv_broken_gcse)
 155 if test $guile_cv_broken_gcse = yes; then
 156    AC_DEFINE(BROKEN_GCSE)
 157 fi
 158
 159 AC_HEADER_STDC
 160 AC_HEADER_DIRENT
 161 AC_HEADER_TIME
 162 AC_HEADER_SYS_WAIT
 163 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
 164 GUILE_HEADER_LIBC_WITH_UNISTD
 165
 166 AC_TYPE_GETGROUPS
 167 AC_TYPE_SIGNAL
 168 AC_TYPE_MODE_T
 169
 170 AC_CHECK_LIB(m, main)
 171 AC_CHECK_FUNCS(gethostbyname)
 172 if test $ac_cv_func_gethostbyname = no; then
 173     AC_CHECK_LIB(nsl, gethostbyname)
 174 fi
 175 AC_CHECK_FUNCS(connect)
 176 if test $ac_cv_func_connect = no; then
 177     AC_CHECK_LIB(socket, connect)
 178 fi
 179
 180 # Check for dynamic linking
 181
 182 use_modules=yes
 183 AC_ARG_WITH(modules,
 184 [  --with-modules[=FILES]  Add support for dynamic modules],
 185 use_modules="$withval")
 186 test -z "$use_modules" && use_modules=yes
 187 DLPREOPEN=
 188 if test "$use_modules" != no; then
 189   AC_DEFINE(DYNAMIC_LINKING)
 190   if test "$use_modules" = yes; then
 191     DLPREOPEN="-dlpreopen force"
 192   else
 193     DLPREOPEN="-export-dynamic"
 194     for module in $use_modules; do
 195       DLPREOPEN="$DLPREOPEN -dlopen $module"
 196     done
 197   fi
 198 fi
 199 AC_SUBST(INCLTDL)
 200 AC_SUBST(LIBLTDL)
 201 AC_SUBST(DLPREOPEN)
 202
 203 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep atexit on_exit)
 204
 205 ### Some systems don't declare some functions.  On such systems, we
 206 ### need to at least provide our own K&R-style declarations.
 207
 208 ### GUILE_FUNC_DECLARED(function, headerfile)
 209
 210 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 211 ### not there, #define MISSING_FUNCTION_DECL.
 212 AC_DEFUN(GUILE_FUNC_DECLARED, [
 213   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 214     AC_EGREP_HEADER($1, $2,
 215                     guile_cv_func_$1_declared=yes,
 216                     guile_cv_func_$1_declared=no))
 217   if test [x$guile_cv_func_]$1[_declared] = xno; then
 218     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 219   fi
 220 ])
 221
 222 GUILE_FUNC_DECLARED(strptime, time.h)
 223 GUILE_FUNC_DECLARED(bzero, string.h)
 224 GUILE_FUNC_DECLARED(sleep, unistd.h)
 225 GUILE_FUNC_DECLARED(usleep, unistd.h)
 226
 227 ### On some systems usleep has no return value.  If it does have one,
 228 ### we'd like to return it; otherwise, we'll fake it.
 229 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 230   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 231                    /usr/include/unistd.h,
 232                    [guile_cv_func_usleep_return_type=void],
 233                    [guile_cv_func_usleep_return_type=int])])
 234 case "$guile_cv_func_usleep_return_type" in
 235   "void" )
 236     AC_DEFINE(USLEEP_RETURNS_VOID)
 237   ;;
 238 esac
 239
 240 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 241 if test -n "$have_sys_un_h" ; then
 242 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 243 fi
 244
 245 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 246
 247 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 248                setnetent    getnetent    endnetent    dnl
 249                setprotoent  getprotoent  endprotoent  dnl
 250                setservent   getservent   endservent   dnl
 251                getnetbyaddr getnetbyname dnl
 252                inet_lnaof inet_makeaddr inet_netof hstrerror)
 253
 254 dnl Some systems do not declare this.  Some systems do declare it, as a
 255 dnl macro.  With cygwin it may be in a DLL.
 256
 257 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 258 AC_CACHE_VAL(guile_cv_have_h_errno,
 259 [AC_TRY_COMPILE([#include <netdb.h>],
 260 [int a = h_errno;],
 261 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 262 AC_MSG_RESULT($guile_cv_have_h_errno)
 263 if test $guile_cv_have_h_errno = yes; then
 264   AC_DEFINE(HAVE_H_ERRNO)
 265 fi
 266
 267 AC_MSG_CHECKING(whether localtime caches TZ)
 268 AC_CACHE_VAL(guile_cv_localtime_cache,
 269 [if test x$ac_cv_func_tzset = xyes; then
 270 AC_TRY_RUN([#include <time.h>
 271 #if STDC_HEADERS
 272 # include <stdlib.h>
 273 #endif
 274 extern char **environ;
 275 unset_TZ ()
 276 {
 277   char **from, **to;
 278   for (to = from = environ; (*to = *from); from++)
 279     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 280       to++;
 281 }
 282 char TZ_GMT0[] = "TZ=GMT0";
 283 char TZ_PST8[] = "TZ=PST8";
 284 main()
 285 {
 286   time_t now = time ((time_t *) 0);
 287   int hour_GMT0, hour_unset;
 288   if (putenv (TZ_GMT0) != 0)
 289     exit (1);
 290   hour_GMT0 = localtime (&now)->tm_hour;
 291   unset_TZ ();
 292   hour_unset = localtime (&now)->tm_hour;
 293   if (putenv (TZ_PST8) != 0)
 294     exit (1);
 295   if (localtime (&now)->tm_hour == hour_GMT0)
 296     exit (1);
 297   unset_TZ ();
 298   if (localtime (&now)->tm_hour != hour_unset)
 299     exit (1);
 300   exit (0);
 301 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 302 [# If we have tzset, assume the worst when cross-compiling.
 303 guile_cv_localtime_cache=yes])
 304 else
 305         # If we lack tzset, report that localtime does not cache TZ,
 306         # since we can't invalidate the cache if we don't have tzset.
 307         guile_cv_localtime_cache=no
 308 fi])dnl
 309 AC_MSG_RESULT($guile_cv_localtime_cache)
 310 if test $guile_cv_localtime_cache = yes; then
 311   AC_DEFINE(LOCALTIME_CACHE)
 312 fi
 313
 314 dnl Test whether system calls are restartable by default on the
 315 dnl current system.  If they are not, we put a loop around every system
 316 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 317 dnl change from the default behaviour.  On the other hand, if signals
 318 dnl are restartable then the loop is not installed and when libguile
 319 dnl initialises it also resets the behaviour of each signal to cause a
 320 dnl restart (in case a different runtime had a different default
 321 dnl behaviour for some reason: e.g., different versions of linux seem
 322 dnl to behave differently.)
 323
 324 AC_SYS_RESTARTABLE_SYSCALLS
 325
 326 if test "$enable_regex" = yes; then
 327    if test "$ac_cv_header_regex_h" = yes ||
 328       test "$ac_cv_header_rxposix_h" = yes ||
 329       test "$ac_cv_header_rx_rxposix_h" = yes; then
 330      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 331      [AC_CHECK_LIB(rx, main)
 332       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 333      )
 334      dnl The following should not be necessary, but for some reason
 335      dnl autoheader misses it if we don't include it!
 336      if test "$ac_cv_func_regcomp_norx" = yes ||
 337         test "$ac_cv_func_regcomp_rx" = yes; then
 338        AC_DEFINE(HAVE_REGCOMP)
 339      fi
 340    fi
 341 fi
 342
 343 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
 344
 345 # When testing for the presence of alloca, we need to add alloca.o
 346 # explicitly to LIBOBJS to make sure that it is translated to
 347 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 348 AC_FUNC_ALLOCA
 349 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 350
 351 AC_STRUCT_ST_RDEV
 352 AC_STRUCT_ST_BLKSIZE
 353
 354 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 355 # LIBOBJS, which we don't need.  This seems more direct.
 356 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 357 [AC_TRY_COMPILE([#include <sys/types.h>
 358 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 359 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 360 if test $ac_cv_struct_st_blocks = yes; then
 361   AC_DEFINE(HAVE_ST_BLOCKS)
 362 fi
 363
 364 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 365   [AC_TRY_CPP([#include <sys/stat.h>
 366                #ifndef S_ISLNK
 367                #error no S_ISLNK
 368                #endif],
 369                ac_cv_macro_S_ISLNK=yes,
 370                ac_cv_macro_S_ISLNK=no)])
 371 if test $ac_cv_macro_S_ISLNK = yes; then
 372   AC_DEFINE(HAVE_S_ISLNK)
 373 fi
 374
 375 AC_STRUCT_TIMEZONE
 376 GUILE_STRUCT_UTIMBUF
 377
 378 #--------------------------------------------------------------------
 379 #
 380 # Which way does the stack grow?
 381 #
 382 #--------------------------------------------------------------------
 383
 384 AC_TRY_RUN(aux (l) unsigned long l;
 385              { int x; exit (l >= ((unsigned long)&x)); }
 386            main () { int q; aux((unsigned long)&q); },
 387            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 388
 389 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 390     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 391                 [guile_cv_type_float_fits_long=yes],
 392                 [guile_cv_type_float_fits_long=no],
 393                 [guile_cv_type_float_fits_long=guess-yes])])
 394 case $guile_cv_type_float_fits_long in
 395   "yes" )
 396     AC_DEFINE(SCM_SINGLES)
 397   ;;
 398   "guess-yes" )
 399     AC_DEFINE(SCM_SINGLES)
 400     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 401     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 402   ;;
 403 esac
 404
 405
 406 AC_MSG_CHECKING(for struct linger)
 407 AC_CACHE_VAL(scm_cv_struct_linger,
 408         AC_TRY_COMPILE([
 409 #include <sys/types.h>
 410 #include <sys/socket.h>],
 411                         [struct linger lgr;  lgr.l_linger = 100],
 412                         scm_cv_struct_linger="yes",
 413                         scm_cv_struct_linger="no"))
 414 AC_MSG_RESULT($scm_cv_struct_linger)
 415 if test $scm_cv_struct_linger = yes; then
 416         AC_DEFINE(HAVE_STRUCT_LINGER)
 417 fi
 418
 419
 420 AC_MSG_CHECKING(for struct timespec)
 421 AC_CACHE_VAL(scm_cv_struct_timespec,
 422         AC_TRY_COMPILE([
 423 #include <time.h>],
 424                         [struct timespec t;  t.tv_nsec = 100],
 425                         scm_cv_struct_timespec="yes",
 426                         scm_cv_struct_timespec="no"))
 427 AC_MSG_RESULT($scm_cv_struct_timespec)
 428 if test $scm_cv_struct_timespec = yes; then
 429         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 430 fi
 431
 432 #--------------------------------------------------------------------
 433 #
 434 # Flags for thread support
 435 #
 436 #--------------------------------------------------------------------
 437
 438 ### What thread package has the user asked for?
 439 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 440             , with_threads=no)
 441
 442 ### Turn $with_threads into either the name of a threads package, like
 443 ### `qt', or `no', meaning that threads should not be supported.
 444 AC_MSG_CHECKING(whether to support threads)
 445 case "$with_threads" in
 446   "yes" | "qt" | "coop" | "")
 447     with_threads=qt
 448   ;;
 449   "no" )
 450   ;;
 451   * )
 452     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 453   ;;
 454 esac
 455 AC_MSG_RESULT($with_threads)
 456
 457 ## Make sure the threads package we've chosen is actually supported on
 458 ## the present platform.
 459 case "${with_threads}" in
 460   "qt" )
 461     ## This configures the QuickThreads package, and sets or clears
 462     ## the THREAD_PACKAGE variable if qthreads don't configure
 463     ## correctly.
 464     QTHREADS_CONFIGURE
 465    ;;
 466 esac
 467
 468 ## If we're using threads, bring in some other parts of Guile which
 469 ## work with them.
 470 if test "${THREAD_PACKAGE}" != "" ; then
 471   AC_DEFINE(USE_THREADS, 1)
 472
 473   ## Include the Guile thread interface in the library...
 474   LIBOBJS="$LIBOBJS threads.o"
 475   EXTRA_DOT_DOC_FILES="$EXTRA_DOT_DOC_FILES threads.doc"
 476
 477   ## ... and tell it which package to talk to.
 478   case "${THREAD_PACKAGE}" in
 479     "QT" )
 480       AC_DEFINE(USE_COOP_THREADS, 1)
 481     ;;
 482     * )
 483       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 484     ;;
 485   esac
 486
 487   ## Bring in scm_internal_select, if appropriate.
 488   if test $ac_cv_func_gettimeofday = yes &&
 489      test $ac_cv_func_select = yes; then
 490     AC_DEFINE(GUILE_ISELECT, 1)
 491   fi
 492
 493   ## Workaround for linuxthreads (currently disabled)
 494   if test $host_os = linux-gnu; then
 495     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 496     AC_CHECK_LIB(pthread, main)
 497   fi
 498 fi
 499
 500 ## If we're using GCC, ask for aggressive warnings.
 501 case "$GCC" in
 502   yes )
 503     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 504     ## much stuff with generic function pointers for that to really be
 505     ## less than exasperating.
 506     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 507     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 508     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 509 esac
 510
 511 AC_PROG_AWK
 512
 513 ## If we're creating a shared library (using libtool!), then we'll
 514 ## need to generate a list of .lo files corresponding to the .o files
 515 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 516 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 517
 518 ## We also need to create corresponding .doc files
 519 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 520
 521 AC_SUBST(GUILE_MAJOR_VERSION)
 522 AC_SUBST(GUILE_MINOR_VERSION)
 523 AC_SUBST(GUILE_VERSION)
 524 AC_SUBST(LIBGUILE_MAJOR_VERSION)
 525 AC_SUBST(LIBGUILE_MINOR_VERSION)
 526 AC_SUBST(LIBGUILE_REVISION_VERSION)
 527 AC_SUBST(LIBGUILE_VERSION)
 528
 529 dnl Tell guile-config what flags guile users should link against.
 530 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 531 AC_SUBST(GUILE_LIBS)
 532
 533 AC_SUBST(AWK)
 534 AC_SUBST(LIBLOBJS)
 535 AC_SUBST(EXTRA_DOT_DOC_FILES)
 536
 537 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check libguile/guile-snarf.awk libguile/versiondat.h ice-9/Makefile qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check])
 538
 539 dnl Local Variables:
 540 dnl comment-start: "dnl "
 541 dnl comment-end: ""
 542 dnl comment-start-skip: "\\bdnl\\b\\s *"
 543 dnl End: