test-suite/tests/foreign.test

   1 ;;;; foreign.test --- FFI.           -*- mode: scheme; coding: utf-8; -*-
   2 ;;;;
   3 ;;;;    Copyright (C) 2010, 2011, 2012, 2013 Free Software Foundation, Inc.
   4 ;;;;
   5 ;;;; This library is free software; you can redistribute it and/or
   6 ;;;; modify it under the terms of the GNU Lesser General Public
   7 ;;;; License as published by the Free Software Foundation; either
   8 ;;;; version 3 of the License, or (at your option) any later version.
   9 ;;;;
  10 ;;;; This library is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 ;;;; Lesser General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU Lesser General Public
  16 ;;;; License along with this library; if not, write to the Free Software
  17 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  18
  19 ;;;
  20 ;;; See also ../standalone/test-ffi for FFI tests.
  21 ;;;
  22
  23 (define-module (test-foreign)
  24   #:use-module (system foreign)
  25   #:use-module (rnrs bytevectors)
  26   #:use-module (srfi srfi-1)
  27   #:use-module (srfi srfi-26)
  28   #:use-module (ice-9 format)
  29   #:use-module (test-suite lib))
  30
  31 \f
  32 (with-test-prefix "dynamic-pointer"
  33
  34   (pass-if-exception
  35    "error message"
  36    '(misc-error . "^Symbol not found")
  37    (dynamic-func "does_not_exist___" (dynamic-link))))
  38
  39 \f
  40 (with-test-prefix "null pointer"
  41
  42   (pass-if "pointer?"
  43     (pointer? %null-pointer))
  44
  45   (pass-if "zero"
  46     (= 0 (pointer-address %null-pointer)))
  47
  48   (pass-if "null pointer identity"
  49     (eq? %null-pointer (make-pointer 0)))
  50
  51   (pass-if "null-pointer? %null-pointer"
  52     (null-pointer? %null-pointer))
  53
  54   (pass-if-exception "pointer->bytevector %null-pointer"
  55     exception:null-pointer-error
  56     (pointer->bytevector %null-pointer 7)))
  57
  58 \f
  59 (with-test-prefix "make-pointer"
  60
  61   (pass-if "pointer?"
  62     (pointer? (make-pointer 123)))
  63
  64   (pass-if "address preserved"
  65     (= 123 (pointer-address (make-pointer 123))))
  66
  67   (pass-if "equal?"
  68     (equal? (make-pointer 123) (make-pointer 123)))
  69
  70   (pass-if "equal? modulo finalizer"
  71     (let ((finalizer (false-if-exception
  72                       (dynamic-func "scm_is_pair" (dynamic-link)))))
  73       (if (not finalizer)
  74           (throw 'unresolved)               ;  Windows or a static build
  75           (equal? (make-pointer 123)
  76                   (make-pointer 123 finalizer)))))
  77
  78   (pass-if "equal? modulo finalizer (set-pointer-finalizer!)"
  79     (let ((finalizer (false-if-exception
  80                       (dynamic-func "scm_is_pair" (dynamic-link))))
  81           (ptr       (make-pointer 123)))
  82       (if (not finalizer)
  83           (throw 'unresolved)                ; Windows or a static build
  84           (begin
  85             (set-pointer-finalizer! ptr finalizer)
  86             (equal? (make-pointer 123) ptr)))))
  87
  88   (pass-if "not equal?"
  89     (not (equal? (make-pointer 123) (make-pointer 456)))))
  90
  91 \f
  92 (with-test-prefix "pointer<->scm"
  93
  94   (pass-if "immediates"
  95     (equal? (pointer->scm (scm->pointer #\newline))
  96             #\newline))
  97
  98   (pass-if "non-immediates"
  99     (equal? (pointer->scm (scm->pointer "Hello, world!"))
 100             "Hello, world!")))
 101
 102 \f
 103 (define-wrapped-pointer-type foo
 104   foo?
 105   wrap-foo unwrap-foo
 106   (lambda (x p)
 107     (format p "#<foo! ~a>" (pointer-address (unwrap-foo x)))))
 108
 109 (with-test-prefix "define-wrapped-pointer-type"
 110
 111   (pass-if "foo?"
 112     (foo? (wrap-foo %null-pointer)))
 113
 114   (pass-if "unwrap-foo"
 115     (let ((p (make-pointer 123)))
 116       (eq? p (unwrap-foo (wrap-foo p)))))
 117
 118   (pass-if "identity"
 119     (let ((p1 (make-pointer 123))
 120           (p2 (make-pointer 123)))
 121       (eq? (wrap-foo p1)
 122            (wrap-foo p2))))
 123
 124   (pass-if "printer"
 125     (string=? "#<foo! 123>"
 126               (with-output-to-string
 127                 (lambda ()
 128                   (write (wrap-foo (make-pointer 123))))))))
 129
 130 \f
 131 (with-test-prefix "pointer<->bytevector"
 132
 133   (pass-if "bijection"
 134     (let ((bv #vu8(0 1 2 3 4 5 6 7)))
 135       (equal? (pointer->bytevector (bytevector->pointer bv)
 136                                    (bytevector-length bv))
 137               bv)))
 138
 139   (pass-if "pointer from bits"
 140     (let* ((bytes (iota (sizeof '*)))
 141            (bv    (u8-list->bytevector bytes))
 142            (fold  (case (native-endianness)
 143                     ((little) fold-right)
 144                     ((big)    fold)
 145                     (else     (error "unsupported endianness")))))
 146       (= (pointer-address
 147           (make-pointer (bytevector-uint-ref bv 0 (native-endianness)
 148                                              (sizeof '*))))
 149          (fold (lambda (byte address)
 150                  (+ byte (* 256 address)))
 151                0
 152                bytes))))
 153
 154   (pass-if "dereference-pointer"
 155     (let* ((bytes (iota (sizeof '*)))
 156            (bv    (u8-list->bytevector bytes))
 157            (fold  (case (native-endianness)
 158                     ((little) fold-right)
 159                     ((big)    fold)
 160                     (else     (error "unsupported endianness")))))
 161       (= (pointer-address
 162           (dereference-pointer (bytevector->pointer bv)))
 163          (fold (lambda (byte address)
 164                  (+ byte (* 256 address)))
 165                0
 166                bytes)))))
 167
 168 \f
 169 (with-test-prefix "pointer<->string"
 170
 171   (pass-if-exception "%default-port-conversion-strategy is error"
 172     exception:encoding-error
 173     (let ((s "χαοσ"))
 174       (with-fluids ((%default-port-conversion-strategy 'error))
 175         (string->pointer s "ISO-8859-1"))))
 176
 177   (pass-if "%default-port-conversion-strategy is escape"
 178     (let ((s "teĥniko"))
 179       (equal? (with-fluids ((%default-port-conversion-strategy 'escape))
 180                 (pointer->string (string->pointer s "ISO-8859-1")))
 181               (format #f "te\\u~4,'0xniko"
 182                       (char->integer #\ĥ)))))
 183
 184   (pass-if "%default-port-conversion-strategy is substitute"
 185     (let ((s "teĥniko")
 186           (member (negate (negate member))))
 187       (member (with-fluids ((%default-port-conversion-strategy 'substitute))
 188                 (pointer->string (string->pointer s "ISO-8859-1")))
 189               '("te?niko"
 190
 191                 ;; This form is found on FreeBSD 8.2 and Darwin 10.8.0.
 192                 "te^hniko"))))
 193
 194   (pass-if "bijection"
 195     (let ((s "hello, world"))
 196       (string=? s (pointer->string (string->pointer s)))))
 197
 198   (pass-if "bijection [latin1]"
 199     (with-latin1-locale
 200       (let ((s "Szép jó napot!"))
 201         (string=? s (pointer->string (string->pointer s))))))
 202
 203   (pass-if "bijection, utf-8"
 204     (let ((s "hello, world"))
 205       (string=? s (pointer->string (string->pointer s "utf-8")
 206                                    -1 "utf-8"))))
 207
 208   (pass-if "bijection, utf-8 [latin1]"
 209     (let ((s "Szép jó napot!"))
 210       (string=? s (pointer->string (string->pointer s "utf-8")
 211                                    -1 "utf-8")))))
 212
 213
 214 \f
 215 (with-test-prefix "pointer->procedure"
 216
 217   (pass-if-exception "object instead of pointer"
 218     exception:wrong-type-arg
 219     (let ((p (pointer->procedure '* %null-pointer '(*))))
 220       (p #t))))
 221
 222 \f
 223 (with-test-prefix "procedure->pointer"
 224
 225   (define qsort
 226     ;; Bindings for libc's `qsort' function.
 227     (pointer->procedure void
 228                         (dynamic-func "qsort" (dynamic-link))
 229                         (list '* size_t size_t '*)))
 230
 231   (define (dereference-pointer-to-byte ptr)
 232     (let ((b (pointer->bytevector ptr 1)))
 233       (bytevector-u8-ref b 0)))
 234
 235   (define input
 236     '(7 1 127 3 5 4 77 2 9 0))
 237
 238   (pass-if "qsort"
 239     (if (defined? 'procedure->pointer)
 240         (let* ((called? #f)
 241                (cmp     (lambda (x y)
 242                           (set! called? #t)
 243                           (- (dereference-pointer-to-byte x)
 244                              (dereference-pointer-to-byte y))))
 245                (ptr     (procedure->pointer int cmp (list '* '*)))
 246                (bv      (u8-list->bytevector input)))
 247           (qsort (bytevector->pointer bv) (bytevector-length bv) 1
 248                  (procedure->pointer int cmp (list '* '*)))
 249           (and called?
 250                (equal? (bytevector->u8-list bv)
 251                        (sort input <))))
 252         (throw 'unresolved)))
 253
 254   (pass-if-exception "qsort, wrong return type"
 255     exception:wrong-type-arg
 256
 257     (if (defined? 'procedure->pointer)
 258         (let* ((cmp     (lambda (x y) #f)) ; wrong return type
 259                (ptr     (procedure->pointer int cmp (list '* '*)))
 260                (bv      (u8-list->bytevector input)))
 261           (qsort (bytevector->pointer bv) (bytevector-length bv) 1
 262                  (procedure->pointer int cmp (list '* '*)))
 263           #f)
 264         (throw 'unresolved)))
 265
 266   (pass-if-exception "qsort, wrong arity"
 267     exception:wrong-num-args
 268
 269     (if (defined? 'procedure->pointer)
 270         (let* ((cmp     (lambda (x y z) #f)) ; wrong arity
 271                (ptr     (procedure->pointer int cmp (list '* '*)))
 272                (bv      (u8-list->bytevector input)))
 273           (qsort (bytevector->pointer bv) (bytevector-length bv) 1
 274                  (procedure->pointer int cmp (list '* '*)))
 275           #f)
 276         (throw 'unresolved)))
 277
 278   (pass-if "bijection"
 279     (if (defined? 'procedure->pointer)
 280         (let* ((proc  (lambda (x y z)
 281                         (+ x y z 0.0)))
 282                (ret   double)
 283                (args  (list float int16 double))
 284                (proc* (pointer->procedure ret
 285                                           (procedure->pointer ret proc args)
 286                                           args))
 287                (arg1  (map (cut / <> 2.0) (iota 123)))
 288                (arg2  (iota 123 32000))
 289                (arg3  (map (cut / <> 4.0) (iota 123 100 4))))
 290           (equal? (map proc arg1 arg2 arg3)
 291                   (map proc* arg1 arg2 arg3)))
 292         (throw 'unresolved)))
 293
 294   (pass-if "procedures returning a pointer"
 295     (if (defined? 'procedure->pointer)
 296         (let* ((called? #f)
 297                (proc    (lambda (i) (set! called? #t) (make-pointer i)))
 298                (pointer (procedure->pointer '* proc (list int)))
 299                (proc*   (pointer->procedure '* pointer (list int)))
 300                (result  (proc* 777)))
 301           (and called? (equal? result (make-pointer 777))))
 302         (throw 'unresolved)))
 303
 304   (pass-if "procedures returning void"
 305     (if (defined? 'procedure->pointer)
 306         (let* ((called? #f)
 307                (proc    (lambda () (set! called? #t)))
 308                (pointer (procedure->pointer void proc '()))
 309                (proc*   (pointer->procedure void pointer '())))
 310           (proc*)
 311           called?)
 312         (throw 'unresolved)))
 313
 314   (pass-if "procedure is retained"
 315     ;; The lambda passed to `procedure->pointer' must remain live.
 316     (if (defined? 'procedure->pointer)
 317         (let* ((ptr   (procedure->pointer int
 318                                           (lambda (x) (+ x 7))
 319                                           (list int)))
 320                (procs (unfold (cut >= <> 10000)
 321                               (lambda (i)
 322                                 (pointer->procedure int ptr (list int)))
 323                               1+
 324                               0)))
 325           (gc) (gc) (gc)
 326           (every (cut = <> 9)
 327                  (map (lambda (f) (f 2)) procs)))
 328         (throw 'unresolved))))
 329
 330 \f
 331 (with-test-prefix "structs"
 332
 333   (pass-if "sizeof { int8, double }"
 334     (= (sizeof (list int8 double))
 335        (+ (alignof double) (sizeof double))))
 336
 337   (pass-if "sizeof { short, int, long, pointer }"
 338     (let ((layout (list short int long '*)))
 339       (>= (sizeof layout)
 340           (reduce + 0.0 (map sizeof layout)))))
 341
 342   (pass-if "alignof { int8, double, int8 }"
 343     ;; alignment of the most strictly aligned component
 344     (let ((layout (list int8 double int8)))
 345       (= (alignof layout) (alignof double))))
 346
 347   (pass-if "parse-c-struct"
 348     (let ((layout (list int64 uint8))
 349           (data   (list -300 43)))
 350       (equal? (parse-c-struct (make-c-struct layout data)
 351                               layout)
 352               data)))
 353
 354   (pass-if "alignment constraints honored"
 355     (let ((layout (list int8 double))
 356           (data   (list -7 3.14)))
 357       (equal? (parse-c-struct (make-c-struct layout data)
 358                               layout)
 359               data)))
 360
 361   (pass-if "int8, pointer"
 362     (let ((layout (list uint8 '*))
 363           (data   (list 222 (make-pointer 7777))))
 364       (equal? (parse-c-struct (make-c-struct layout data)
 365                               layout)
 366               data)))
 367
 368   (pass-if "unsigned-long, int8, size_t"
 369     (let ((layout (list unsigned-long int8 size_t))
 370           (data   (list (expt 2 17) -128 (expt 2 18))))
 371       (equal? (parse-c-struct (make-c-struct layout data)
 372                               layout)
 373               data)))
 374
 375   (pass-if "long, int, pointer"
 376     (let ((layout (list long int '*))
 377           (data   (list (- (expt 2 17)) -222 (make-pointer 777))))
 378       (equal? (parse-c-struct (make-c-struct layout data)
 379                               layout)
 380               data)))
 381
 382   (pass-if "int8, pointer, short, double"
 383     (let ((layout (list int8 '* short double))
 384           (data   (list 77 %null-pointer -42 3.14)))
 385       (equal? (parse-c-struct (make-c-struct layout data)
 386                               layout)
 387               data)))
 388
 389   (pass-if "int8, { int8, double, int8 }, int16"
 390     (let ((layout (list int8 (list int8 double int8) int16))
 391           (data   (list 77 (list 42 4.2 55) 88)))
 392       (equal? (parse-c-struct (make-c-struct layout data)
 393                               layout)
 394               data))))