m4/inet_ntop.m4

   1 # inet_ntop.m4 serial 15
   2 dnl Copyright (C) 2005-2006, 2008-2011 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_INET_NTOP],
   8 [
   9   dnl Persuade Solaris <arpa/inet.h> to declare inet_ntop.
  10   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  11
  12   dnl Most platforms that provide inet_ntop define it in libc.
  13   dnl Solaris 8..10 provide inet_ntop in libnsl instead.
  14   HAVE_INET_NTOP=1
  15   gl_save_LIBS=$LIBS
  16   AC_SEARCH_LIBS([inet_ntop], [nsl], [],
  17     [AC_CHECK_FUNCS([inet_ntop])
  18      if test $ac_cv_func_inet_ntop = no; then
  19        HAVE_INET_NTOP=0
  20      fi
  21     ])
  22   LIBS=$gl_save_LIBS
  23
  24   INET_NTOP_LIB=
  25   if test "$ac_cv_search_inet_ntop" != "no" &&
  26      test "$ac_cv_search_inet_ntop" != "none required"; then
  27     INET_NTOP_LIB="$ac_cv_search_inet_ntop"
  28   fi
  29   AC_SUBST([INET_NTOP_LIB])
  30
  31   AC_CHECK_HEADERS_ONCE([netdb.h])
  32   AC_CHECK_DECLS([inet_ntop],,,
  33     [#include <arpa/inet.h>
  34      #if HAVE_NETDB_H
  35      # include <netdb.h>
  36      #endif
  37     ])
  38   if test $ac_cv_have_decl_inet_ntop = no; then
  39     HAVE_DECL_INET_NTOP=0
  40     AC_REQUIRE([AC_C_RESTRICT])
  41   fi
  42 ])
  43
  44 # Prerequisites of lib/inet_ntop.c.
  45 AC_DEFUN([gl_PREREQ_INET_NTOP], [
  46   AC_REQUIRE([gl_SOCKET_FAMILIES])
  47 ])