configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # Independent Subdirectories
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_CONFIG_SUBDIRS(guile-readline)
  36
  37 #--------------------------------------------------------------------
  38 #
  39 # User options
  40 #
  41 #--------------------------------------------------------------------
  42
  43 AC_ARG_ENABLE(debug-freelist,
  44   [  --enable-debug-freelist  include garbage collector freelist debugging code],
  45   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  46     AC_DEFINE(GUILE_DEBUG_FREELIST)
  47   fi)
  48
  49 AC_ARG_ENABLE(debug-malloc,
  50   [  --enable-debug-malloc    include malloc debugging code],
  51   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  52     AC_DEFINE(GUILE_DEBUG_MALLOC)
  53   fi)
  54
  55 AC_ARG_ENABLE(guile-debug,
  56   [  --enable-guile-debug    include internal debugging functions],
  57   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  58     AC_DEFINE(GUILE_DEBUG)
  59   fi)
  60
  61 AC_ARG_ENABLE(arrays,
  62   [  --disable-arrays        omit array and uniform array support],,
  63   enable_arrays=yes)
  64
  65 AC_ARG_ENABLE(posix,
  66   [  --disable-posix         omit posix interfaces],,
  67   enable_posix=yes)
  68
  69 AC_ARG_ENABLE(networking,
  70   [  --disable-networking    omit networking interfaces],,
  71   enable_networking=yes)
  72
  73 AC_ARG_ENABLE(regex,
  74   [  --disable-regex         omit regular expression interfaces],,
  75   enable_regex=yes)
  76
  77 dnl The --disable-debug used to control these two.  But now they are
  78 dnl a required part of the distribution.
  79 AC_DEFINE(DEBUG_EXTENSIONS)
  80 AC_DEFINE(READER_EXTENSIONS)
  81
  82 dnl files which are destined for separate modules.
  83
  84 if test "$enable_arrays" = yes; then
  85    LIBOBJS="$LIBOBJS ramap.o unif.o"
  86    AC_DEFINE(HAVE_ARRAYS)
  87 fi
  88
  89 if test "$enable_posix" = yes; then
  90    LIBOBJS="$LIBOBJS filesys.o posix.o"
  91    AC_DEFINE(HAVE_POSIX)
  92 fi
  93
  94 if test "$enable_networking" = yes; then
  95    LIBOBJS="$LIBOBJS net_db.o socket.o"
  96    AC_DEFINE(HAVE_NETWORKING)
  97 fi
  98
  99 if test "$enable_debug_malloc" = yes; then
 100    LIBOBJS="$LIBOBJS debug-malloc.o"
 101 fi
 102
 103 #--------------------------------------------------------------------
 104
 105 AC_LIBLTDL_CONVENIENCE
 106 AC_CONFIG_SUBDIRS(libltdl)
 107
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110 AC_LIBTOOL_DLOPEN
 111
 112 AC_AIX
 113 AC_ISC_POSIX
 114 AC_MINIX
 115
 116 AM_PROG_CC_STDC
 117 AM_PROG_LIBTOOL
 118
 119 AC_C_CONST
 120 AC_C_INLINE
 121 AC_CHECK_SIZEOF(int)
 122 AC_CHECK_SIZEOF(long)
 123 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 124                AC_TRY_COMPILE(,
 125                               [long long a],
 126                               scm_cv_long_longs=yes,
 127                               scm_cv_long_longs=no))
 128 if test "$scm_cv_long_longs" = yes; then
 129   AC_DEFINE(HAVE_LONG_LONGS)
 130 fi
 131
 132 AC_HEADER_STDC
 133 AC_HEADER_DIRENT
 134 AC_HEADER_TIME
 135 AC_HEADER_SYS_WAIT
 136 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
 137 GUILE_HEADER_LIBC_WITH_UNISTD
 138
 139 AC_TYPE_GETGROUPS
 140 AC_TYPE_SIGNAL
 141 AC_TYPE_MODE_T
 142
 143 AC_CHECK_LIB(m, main)
 144 AC_CHECK_FUNCS(gethostbyname)
 145 if test $ac_cv_func_gethostbyname = no; then
 146     AC_CHECK_LIB(nsl, gethostbyname)
 147 fi
 148 AC_CHECK_FUNCS(connect)
 149 if test $ac_cv_func_connect = no; then
 150     AC_CHECK_LIB(socket, connect)
 151 fi
 152
 153 # Check for dynamic linking
 154
 155 use_modules=yes
 156 AC_ARG_WITH(modules,
 157 [  --with-modules[=FILES]  Add support for dynamic modules],
 158 use_modules="$withval")
 159 test -z "$use_modules" && use_modules=yes
 160 DLPREOPEN=
 161 if test "$use_modules" != no; then
 162   AC_DEFINE(DYNAMIC_LINKING)
 163   if test "$use_modules" = yes; then
 164     DLPREOPEN="-dlpreopen force"
 165   else
 166     DLPREOPEN="-export-dynamic"
 167     for module in $use_modules; do
 168       DLPREOPEN="$DLPREOPEN -dlopen $module"
 169     done
 170   fi
 171 fi
 172 AC_SUBST(INCLTDL)
 173 AC_SUBST(LIBLTDL)
 174 AC_SUBST(DLPREOPEN)
 175
 176 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep atexit on_exit)
 177
 178 ### Some systems don't declare some functions.  On such systems, we
 179 ### need to at least provide our own K&R-style declarations.
 180
 181 ### GUILE_FUNC_DECLARED(function, headerfile)
 182
 183 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 184 ### not there, #define MISSING_FUNCTION_DECL.
 185 AC_DEFUN(GUILE_FUNC_DECLARED, [
 186   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 187     AC_EGREP_HEADER($1, $2,
 188                     guile_cv_func_$1_declared=yes,
 189                     guile_cv_func_$1_declared=no))
 190   if test [x$guile_cv_func_]$1[_declared] = xno; then
 191     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 192   fi
 193 ])
 194
 195 GUILE_FUNC_DECLARED(strptime, time.h)
 196 GUILE_FUNC_DECLARED(bzero, string.h)
 197 GUILE_FUNC_DECLARED(sleep, unistd.h)
 198 GUILE_FUNC_DECLARED(usleep, unistd.h)
 199 GUILE_FUNC_DECLARED(inet_aton, arpa/inet.h)
 200
 201 ### On some systems usleep has no return value.  If it does have one,
 202 ### we'd like to return it; otherwise, we'll fake it.
 203 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 204   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 205                    /usr/include/unistd.h,
 206                    [guile_cv_func_usleep_return_type=void],
 207                    [guile_cv_func_usleep_return_type=int])])
 208 case "$guile_cv_func_usleep_return_type" in
 209   "void" )
 210     AC_DEFINE(USLEEP_RETURNS_VOID)
 211   ;;
 212 esac
 213
 214 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 215 if test -n "$have_sys_un_h" ; then
 216 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 217 fi
 218
 219 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 220
 221 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 222                setnetent    getnetent    endnetent    dnl
 223                setprotoent  getprotoent  endprotoent  dnl
 224                setservent   getservent   endservent   dnl
 225                getnetbyaddr getnetbyname dnl
 226                inet_lnaof inet_makeaddr inet_netof hstrerror)
 227
 228 dnl Some systems do not declare this.  Some systems do declare it, as a
 229 dnl macro.  With cygwin it may be in a DLL.
 230
 231 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 232 AC_CACHE_VAL(guile_cv_have_h_errno,
 233 [AC_TRY_COMPILE([#include <netdb.h>],
 234 [int a = h_errno;],
 235 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 236 AC_MSG_RESULT($guile_cv_have_h_errno)
 237 if test $guile_cv_have_h_errno = yes; then
 238   AC_DEFINE(HAVE_H_ERRNO)
 239 fi
 240
 241 AC_MSG_CHECKING(whether localtime caches TZ)
 242 AC_CACHE_VAL(guile_cv_localtime_cache,
 243 [if test x$ac_cv_func_tzset = xyes; then
 244 AC_TRY_RUN([#include <time.h>
 245 #if STDC_HEADERS
 246 # include <stdlib.h>
 247 #endif
 248 extern char **environ;
 249 unset_TZ ()
 250 {
 251   char **from, **to;
 252   for (to = from = environ; (*to = *from); from++)
 253     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 254       to++;
 255 }
 256 char TZ_GMT0[] = "TZ=GMT0";
 257 char TZ_PST8[] = "TZ=PST8";
 258 main()
 259 {
 260   time_t now = time ((time_t *) 0);
 261   int hour_GMT0, hour_unset;
 262   if (putenv (TZ_GMT0) != 0)
 263     exit (1);
 264   hour_GMT0 = localtime (&now)->tm_hour;
 265   unset_TZ ();
 266   hour_unset = localtime (&now)->tm_hour;
 267   if (putenv (TZ_PST8) != 0)
 268     exit (1);
 269   if (localtime (&now)->tm_hour == hour_GMT0)
 270     exit (1);
 271   unset_TZ ();
 272   if (localtime (&now)->tm_hour != hour_unset)
 273     exit (1);
 274   exit (0);
 275 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 276 [# If we have tzset, assume the worst when cross-compiling.
 277 guile_cv_localtime_cache=yes])
 278 else
 279         # If we lack tzset, report that localtime does not cache TZ,
 280         # since we can't invalidate the cache if we don't have tzset.
 281         guile_cv_localtime_cache=no
 282 fi])dnl
 283 AC_MSG_RESULT($guile_cv_localtime_cache)
 284 if test $guile_cv_localtime_cache = yes; then
 285   AC_DEFINE(LOCALTIME_CACHE)
 286 fi
 287
 288 dnl Test whether system calls are restartable by default on the
 289 dnl current system.  If they are not, we put a loop around every system
 290 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 291 dnl change from the default behaviour.  On the other hand, if signals
 292 dnl are restartable then the loop is not installed and when libguile
 293 dnl initialises it also resets the behaviour of each signal to cause a
 294 dnl restart (in case a different runtime had a different default
 295 dnl behaviour for some reason: e.g., different versions of linux seem
 296 dnl to behave differently.)
 297
 298 AC_SYS_RESTARTABLE_SYSCALLS
 299
 300 if test "$enable_regex" = yes; then
 301    if test "$ac_cv_header_regex_h" = yes ||
 302       test "$ac_cv_header_rxposix_h" = yes ||
 303       test "$ac_cv_header_rx_rxposix_h" = yes; then
 304      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 305      [AC_CHECK_LIB(rx, main)
 306       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 307      )
 308      dnl The following should not be necessary, but for some reason
 309      dnl autoheader misses it if we don't include it!
 310      if test "$ac_cv_func_regcomp_norx" = yes ||
 311         test "$ac_cv_func_regcomp_rx" = yes; then
 312        AC_DEFINE(HAVE_REGCOMP)
 313      fi
 314    fi
 315 fi
 316
 317 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
 318
 319 # When testing for the presence of alloca, we need to add alloca.o
 320 # explicitly to LIBOBJS to make sure that it is translated to
 321 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 322 AC_FUNC_ALLOCA
 323 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 324
 325 AC_STRUCT_ST_RDEV
 326 AC_STRUCT_ST_BLKSIZE
 327
 328 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 329 # LIBOBJS, which we don't need.  This seems more direct.
 330 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 331 [AC_TRY_COMPILE([#include <sys/types.h>
 332 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 333 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 334 if test $ac_cv_struct_st_blocks = yes; then
 335   AC_DEFINE(HAVE_ST_BLOCKS)
 336 fi
 337
 338 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 339   [AC_TRY_CPP([#include <sys/stat.h>
 340                #ifndef S_ISLNK
 341                #error no S_ISLNK
 342                #endif],
 343                ac_cv_macro_S_ISLNK=yes,
 344                ac_cv_macro_S_ISLNK=no)])
 345 if test $ac_cv_macro_S_ISLNK = yes; then
 346   AC_DEFINE(HAVE_S_ISLNK)
 347 fi
 348
 349 AC_STRUCT_TIMEZONE
 350 GUILE_STRUCT_UTIMBUF
 351
 352 #--------------------------------------------------------------------
 353 #
 354 # Which way does the stack grow?
 355 #
 356 #--------------------------------------------------------------------
 357
 358 AC_TRY_RUN(aux (l) unsigned long l;
 359              { int x; exit (l >= ((unsigned long)&x)); }
 360            main () { int q; aux((unsigned long)&q); },
 361            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 362
 363 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 364     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 365                 [guile_cv_type_float_fits_long=yes],
 366                 [guile_cv_type_float_fits_long=no],
 367                 [guile_cv_type_float_fits_long=guess-yes])])
 368 case $guile_cv_type_float_fits_long in
 369   "yes" )
 370     AC_DEFINE(SCM_SINGLES)
 371   ;;
 372   "guess-yes" )
 373     AC_DEFINE(SCM_SINGLES)
 374     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 375     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 376   ;;
 377 esac
 378
 379
 380 AC_MSG_CHECKING(for struct linger)
 381 AC_CACHE_VAL(scm_cv_struct_linger,
 382         AC_TRY_COMPILE([
 383 #include <sys/types.h>
 384 #include <sys/socket.h>],
 385                         [struct linger lgr;  lgr.l_linger = 100],
 386                         scm_cv_struct_linger="yes",
 387                         scm_cv_struct_linger="no"))
 388 AC_MSG_RESULT($scm_cv_struct_linger)
 389 if test $scm_cv_struct_linger = yes; then
 390         AC_DEFINE(HAVE_STRUCT_LINGER)
 391 fi
 392
 393
 394 AC_MSG_CHECKING(for struct timespec)
 395 AC_CACHE_VAL(scm_cv_struct_timespec,
 396         AC_TRY_COMPILE([
 397 #include <time.h>],
 398                         [struct timespec t;  t.tv_nsec = 100],
 399                         scm_cv_struct_timespec="yes",
 400                         scm_cv_struct_timespec="no"))
 401 AC_MSG_RESULT($scm_cv_struct_timespec)
 402 if test $scm_cv_struct_timespec = yes; then
 403         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 404 fi
 405
 406 #--------------------------------------------------------------------
 407 #
 408 # Flags for thread support
 409 #
 410 #--------------------------------------------------------------------
 411
 412 ### What thread package has the user asked for?
 413 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 414             , with_threads=no)
 415
 416 ### Turn $with_threads into either the name of a threads package, like
 417 ### `qt', or `no', meaning that threads should not be supported.
 418 AC_MSG_CHECKING(whether to support threads)
 419 case "$with_threads" in
 420   "yes" | "qt" | "coop" | "")
 421     with_threads=qt
 422   ;;
 423   "no" )
 424   ;;
 425   * )
 426     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 427   ;;
 428 esac
 429 AC_MSG_RESULT($with_threads)
 430
 431 ## Make sure the threads package we've chosen is actually supported on
 432 ## the present platform.
 433 case "${with_threads}" in
 434   "qt" )
 435     ## This configures the QuickThreads package, and sets or clears
 436     ## the THREAD_PACKAGE variable if qthreads don't configure
 437     ## correctly.
 438     QTHREADS_CONFIGURE
 439    ;;
 440 esac
 441
 442 ## If we're using threads, bring in some other parts of Guile which
 443 ## work with them.
 444 if test "${THREAD_PACKAGE}" != "" ; then
 445   AC_DEFINE(USE_THREADS, 1)
 446
 447   ## Include the Guile thread interface in the library...
 448   LIBOBJS="$LIBOBJS threads.o"
 449   EXTRA_DOT_DOC_FILES="$EXTRA_DOT_DOC_FILES threads.doc"
 450
 451   ## ... and tell it which package to talk to.
 452   case "${THREAD_PACKAGE}" in
 453     "QT" )
 454       AC_DEFINE(USE_COOP_THREADS, 1)
 455     ;;
 456     * )
 457       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 458     ;;
 459   esac
 460
 461   ## Bring in scm_internal_select, if appropriate.
 462   if test $ac_cv_func_gettimeofday = yes &&
 463      test $ac_cv_func_select = yes; then
 464     AC_DEFINE(GUILE_ISELECT, 1)
 465   fi
 466
 467   ## Workaround for linuxthreads (currently disabled)
 468   if test $host_os = linux-gnu; then
 469     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 470     AC_CHECK_LIB(pthread, main)
 471   fi
 472 fi
 473
 474 ## If we're using GCC, ask for aggressive warnings.
 475 case "$GCC" in
 476   yes )
 477     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 478     ## much stuff with generic function pointers for that to really be
 479     ## less than exasperating.
 480     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 481     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 482     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 483 esac
 484
 485 AC_PROG_AWK
 486
 487 ## If we're creating a shared library (using libtool!), then we'll
 488 ## need to generate a list of .lo files corresponding to the .o files
 489 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 490 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 491
 492 ## We also need to create corresponding .doc files
 493 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 494
 495 AC_SUBST(GUILE_MAJOR_VERSION)
 496 AC_SUBST(GUILE_MINOR_VERSION)
 497 AC_SUBST(GUILE_VERSION)
 498 AC_SUBST(LIBGUILE_MAJOR_VERSION)
 499 AC_SUBST(LIBGUILE_MINOR_VERSION)
 500 AC_SUBST(LIBGUILE_REVISION_VERSION)
 501 AC_SUBST(LIBGUILE_VERSION)
 502
 503 dnl Tell guile-config what flags guile users should link against.
 504 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 505 AC_SUBST(GUILE_LIBS)
 506
 507 AC_SUBST(AWK)
 508 AC_SUBST(LIBLOBJS)
 509 AC_SUBST(EXTRA_DOT_DOC_FILES)
 510
 511 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check libguile/guile-snarf.awk libguile/versiondat.h ice-9/Makefile qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check])
 512
 513 dnl Local Variables:
 514 dnl comment-start: "dnl "
 515 dnl comment-end: ""
 516 dnl comment-start-skip: "\\bdnl\\b\\s *"
 517 dnl End: