configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # Independent Subdirectories
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_CONFIG_SUBDIRS(guile-readline)
  36
  37 #--------------------------------------------------------------------
  38 #
  39 # User options
  40 #
  41 #--------------------------------------------------------------------
  42
  43 AC_ARG_ENABLE(dynamic-linking,
  44   [  --enable-dynamic-linking  Include support for dynamic linking],,
  45   enable_dynamic_linking=yes)
  46
  47 AC_ARG_ENABLE(guile-debug,
  48   [  --enable-guile-debug    Include internal debugging functions],
  49   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  50     AC_DEFINE(GUILE_DEBUG)
  51   fi)
  52
  53 dnl The --disable-debug used to control these two.  But now they are
  54 dnl a required part of the distribution.
  55 AC_DEFINE(DEBUG_EXTENSIONS)
  56 AC_DEFINE(READER_EXTENSIONS)
  57
  58 #--------------------------------------------------------------------
  59
  60 AC_PROG_CC
  61 AC_PROG_CPP
  62 AM_PROG_LIBTOOL
  63
  64 AC_AIX
  65 AC_ISC_POSIX
  66 AC_MINIX
  67
  68 AM_PROG_CC_STDC
  69
  70 AC_C_CONST
  71 AC_C_INLINE
  72 AC_CHECK_SIZEOF(int)
  73 AC_CHECK_SIZEOF(long)
  74 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
  75                AC_TRY_COMPILE(,
  76                               [long long a],
  77                               scm_cv_long_longs=yes,
  78                               scm_cv_long_longs=no))
  79 if test "$scm_cv_long_longs" = yes; then
  80   AC_DEFINE(HAVE_LONG_LONGS)
  81 fi
  82
  83 AC_HEADER_STDC
  84 AC_HEADER_DIRENT
  85 AC_HEADER_TIME
  86 AC_HEADER_SYS_WAIT
  87 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
  88 GUILE_HEADER_LIBC_WITH_UNISTD
  89
  90 AC_TYPE_GETGROUPS
  91 AC_TYPE_SIGNAL
  92 AC_TYPE_MODE_T
  93
  94 AC_CHECK_LIB(m, main)
  95 AC_CHECK_FUNCS(gethostbyname)
  96 if test $ac_cv_func_gethostbyname = no; then
  97     AC_CHECK_LIB(nsl, gethostbyname)
  98 fi
  99 AC_CHECK_FUNCS(connect)
 100 if test $ac_cv_func_connect = no; then
 101     AC_CHECK_LIB(socket, connect)
 102 fi
 103
 104 # Checks for dynamic linking
 105
 106 if test "$enable_dynamic_linking" = "yes"; then
 107
 108 AC_CHECK_LIB(dl,dlopen)
 109 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 110   AC_CHECK_FUNCS(dlopen)
 111   AC_DEFINE(DYNAMIC_LINKING)
 112 else
 113 AC_CHECK_LIB(dld,dld_link)
 114 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
 115   AC_DEFINE(DYNAMIC_LINKING)
 116 else
 117 AC_CHECK_FUNCS(shl_load)
 118 if test "$ac_cv_func_shl_load" = "yes"; then
 119   AC_DEFINE(DYNAMIC_LINKING)
 120 else
 121 AC_CHECK_FUNCS(dlopen)
 122 if test "$ac_cv_func_dlopen" = "yes"; then
 123   AC_DEFINE(DYNAMIC_LINKING)
 124 fi
 125 fi
 126 fi
 127 fi
 128
 129 fi
 130
 131 GUILE_DLSYM_USCORE
 132
 133 AC_CHECK_FUNCS(ctermid ftime getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep atexit on_exit)
 134
 135 ### Some systems don't declare some functions.  On such systems, we
 136 ### need to at least provide our own K&R-style declarations.
 137
 138 ### GUILE_FUNC_DECLARED(function, headerfile)
 139
 140 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 141 ### not there, #define MISSING_FUNCTION_DECL.
 142 AC_DEFUN(GUILE_FUNC_DECLARED, [
 143   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 144     AC_EGREP_HEADER($1, $2,
 145                     guile_cv_func_$1_declared=yes,
 146                     guile_cv_func_$1_declared=no))
 147   if test [x$guile_cv_func_]$1[_declared] = xno; then
 148     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 149   fi
 150 ])
 151
 152 GUILE_FUNC_DECLARED(strptime, time.h)
 153 GUILE_FUNC_DECLARED(bzero, string.h)
 154 GUILE_FUNC_DECLARED(sleep, unistd.h)
 155 GUILE_FUNC_DECLARED(usleep, unistd.h)
 156
 157 ### On some systems usleep has no return value.  If it does have one,
 158 ### we'd like to return it; otherwise, we'll fake it.
 159 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 160   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 161                    /usr/include/unistd.h,
 162                    [guile_cv_func_usleep_return_type=void],
 163                    [guile_cv_func_usleep_return_type=int])])
 164 case "$guile_cv_func_usleep_return_type" in
 165   "void" )
 166     AC_DEFINE(USLEEP_RETURNS_VOID)
 167   ;;
 168 esac
 169
 170 dnl <GNU-WIN32 hacks>
 171
 172 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 173 if test -n "$have_sys_un_h" ; then
 174 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 175 fi
 176
 177 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 178
 179 dnl I don't know what this prefixing of cygwin32_ is for.
 180 dnl scmconfig.h wasn't updated with the test results.
 181 dnl so use AC_CHECK_FUNCS for now.
 182
 183 dnl how about:
 184 dnl save confdefs.h
 185 dnl if test $ac_cv_cigwin = yes; then
 186 dnl   modify confdefs.h
 187 dnl fi
 188 dnl AC_CHECK_FUNCS...
 189 dnl restore confdefs.h
 190
 191 dnl cp confdefs.h confdefs.h.bak
 192 dnl for func in gethostent sethostent endhostent getnetent setnetent endnetent getprotoent setprotoent endprotoent getservent setservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof ; do
 193 dnl cp confdefs.h.bak confdefs.h
 194 dnl cat >> confdefs.h << EOF
 195 dnl #ifdef __CYGWIN32__
 196 dnl #define $func cygwin32_$func
 197 dnl #endif
 198 dnl EOF
 199 dnl AC_CHECK_FUNC($func)
 200 dnl done
 201 dnl cp confdefs.h.bak confdefs.h
 202
 203 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 204                setnetent    getnetent    endnetent    dnl
 205                setprotoent  getprotoent  endprotoent  dnl
 206                setservent   getservent   endservent   dnl
 207                getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof)
 208
 209 dnl </GNU-WIN32 hacks>
 210
 211 AC_CACHE_CHECK([for restartable system calls], scm_cv_restarts,
 212         if test $ac_cv_func_sigaction = yes; then
 213                 [AC_TRY_COMPILE([#include <signal.h>],
 214                                 [int a = SA_RESTART],
 215                                 scm_cv_restarts=yes,
 216                                 scm_cv_restarts=no)]
 217         else
 218                 scm_cv_restarts=no
 219         fi)
 220 if test $scm_cv_restarts = yes; then
 221         AC_DEFINE(HAVE_RESTARTS)
 222 fi
 223
 224 if test "$ac_cv_header_regex_h" = yes ||
 225    test "$ac_cv_header_rxposix_h" = yes ||
 226    test "$ac_cv_header_rx_rxposix_h" = yes; then
 227   GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 228   [AC_CHECK_LIB(rx, main)
 229    GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 230   )
 231   dnl The following should not be necessary, but for some reason
 232   dnl autoheader misses it if we don't include it!
 233   if test "$ac_cv_func_regcomp_norx" = yes ||
 234      test "$ac_cv_func_regcomp_rx" = yes; then
 235     AC_DEFINE(HAVE_REGCOMP)
 236   fi
 237 fi
 238
 239 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
 240
 241 # When testing for the presence of alloca, we need to add alloca.o
 242 # explicitly to LIBOBJS to make sure that it is translated to
 243 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 244 AC_FUNC_ALLOCA
 245 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 246
 247 AC_STRUCT_ST_RDEV
 248 AC_STRUCT_ST_BLKSIZE
 249
 250 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 251 # LIBOBJS, which we don't need.  This seems more direct.
 252 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 253 [AC_TRY_COMPILE([#include <sys/types.h>
 254 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 255 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 256 if test $ac_cv_struct_st_blocks = yes; then
 257   AC_DEFINE(HAVE_ST_BLOCKS)
 258 fi
 259
 260 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 261   [AC_TRY_CPP([#include <sys/stat.h>
 262                #ifndef S_ISLNK
 263                #error no S_ISLNK
 264                #endif],
 265                ac_cv_macro_S_ISLNK=yes,
 266                ac_cv_macro_S_ISLNK=no)])
 267 if test $ac_cv_macro_S_ISLNK = yes; then
 268   AC_DEFINE(HAVE_S_ISLNK)
 269 fi
 270
 271 AC_STRUCT_TIMEZONE
 272 GUILE_STRUCT_UTIMBUF
 273
 274 #--------------------------------------------------------------------
 275 #
 276 # Which way does the stack grow?
 277 #
 278 #--------------------------------------------------------------------
 279
 280 AC_TRY_RUN(aux (l) unsigned long l;
 281              { int x; exit (l >= ((unsigned long)&x)); }
 282            main () { int q; aux((unsigned long)&q); },
 283            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 284
 285 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 286     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 287                 [guile_cv_type_float_fits_long=yes],
 288                 [guile_cv_type_float_fits_long=no],
 289                 [guile_cv_type_float_fits_long=guess-yes])])
 290 case $guile_cv_type_float_fits_long in
 291   "yes" )
 292     AC_DEFINE(SCM_SINGLES)
 293   ;;
 294   "guess-yes" )
 295     AC_DEFINE(SCM_SINGLES)
 296     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 297     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 298   ;;
 299 esac
 300
 301
 302 AC_MSG_CHECKING(for struct linger)
 303 AC_CACHE_VAL(scm_cv_struct_linger,
 304         AC_TRY_COMPILE([
 305 #include <sys/types.h>
 306 #include <sys/socket.h>],
 307                         [struct linger lgr;  lgr.l_linger = 100],
 308                         scm_cv_struct_linger="yes",
 309                         scm_cv_struct_linger="no"))
 310 AC_MSG_RESULT($scm_cv_struct_linger)
 311 if test $scm_cv_struct_linger = yes; then
 312         AC_DEFINE(HAVE_STRUCT_LINGER)
 313 fi
 314
 315 #--------------------------------------------------------------------
 316 #
 317 # How can you violate a stdio abstraction by setting a stream's fd?
 318 #
 319 #--------------------------------------------------------------------
 320
 321 dnl  AC_MSG_CHECKING(how to set a stream file descriptor)
 322 dnl  AC_CACHE_VAL(scm_cv_fd_setter,
 323 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 324 dnl                     [stdout->_file = 1],
 325 dnl                     scm_cv_fd_setter="_file",
 326 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 327 dnl                     [stdout->__file = 1],
 328 dnl                     scm_cv_fd_setter="__file",
 329 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 330 dnl                     [stdout->_fileno = 1],
 331 dnl                     scm_cv_fd_setter="_fileno",
 332 dnl                     scm_cv_fd_setter=""))))
 333
 334 dnl  if test "$scm_cv_fd_setter"; then
 335 dnl     AC_MSG_RESULT($scm_cv_fd_setter)
 336 dnl     AC_DEFINE_UNQUOTED(FD_SETTER, $scm_cv_fd_setter)
 337 dnl  else
 338 dnl     AC_MSG_RESULT(we couldn't do it!)
 339 dnl  fi
 340
 341 #--------------------------------------------------------------------
 342 # How to find out whether a FILE structure contains buffered data.
 343 # From Tk we have the following list:
 344 #               _cnt:           Most UNIX systems
 345 #               __cnt:          HPUX and SCO
 346 #               _r:             BSD
 347 #               readCount:      Sprite
 348 #       Or, in GNU libc there are two fields, _gptr and _egptr, which
 349 #       have to be compared.
 350 #       These can also be known as _IO_read_ptr and _IO_read_end.
 351 #--------------------------------------------------------------------
 352
 353 dnl  AC_MSG_CHECKING(how to get buffer char count from FILE structure)
 354 dnl  AC_CACHE_VAL(scm_cv_struct_file_count,
 355 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 356 dnl                     [FILE *f = stdin; f->_cnt = 0],
 357 dnl                     scm_cv_struct_file_count="_cnt",
 358 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 359 dnl                     [FILE *f = stdin; f->__cnt = 0],
 360 dnl                     scm_cv_struct_file_count="__cnt",
 361 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 362 dnl                     [FILE *f = stdin; f->_r = 0],
 363 dnl                     scm_cv_struct_file_count="_r",
 364 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 365 dnl                     [FILE *f = stdin; f->readCount = 0],
 366 dnl                     scm_cv_struct_file_count="readCount",
 367 dnl     scm_cv_struct_file_count="")))))
 368 dnl  if test "$scm_cv_struct_file_count"; then
 369 dnl     AC_MSG_RESULT($scm_cv_struct_file_count)
 370 dnl     AC_DEFINE_UNQUOTED(FILE_CNT_FIELD, $scm_cv_struct_file_count)
 371 dnl  else
 372 dnl  AC_CACHE_VAL(scm_cv_struct_file_gptr,
 373 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 374 dnl                     [FILE *f = stdin; f->_gptr = f->egptr;],
 375 dnl                     scm_cv_struct_file_gptr=1,
 376 dnl     scm_cv_struct_file_gptr=""))
 377 dnl  if test "$scm_cv_struct_gptr"; then
 378 dnl     AC_MSG_RESULT(gptr)
 379 dnl     AC_DEFINE_UNQUOTED(FILE_CNT_GPTR, $scm_cv_struct_file_gptr)
 380 dnl  else
 381 dnl  AC_CACHE_VAL(scm_cv_struct_file_readptr,
 382 dnl     AC_TRY_COMPILE([#include <stdio.h>],
 383 dnl                     [FILE *f = stdin; f->_IO_read_ptr = f->_IO_read_end;],
 384 dnl                     scm_cv_struct_file_readptr=1))
 385 dnl  if test "$scm_cv_struct_file_readptr"; then
 386 dnl     AC_MSG_RESULT(read_ptr)
 387 dnl     AC_DEFINE_UNQUOTED(FILE_CNT_READPTR, $scm_cv_struct_file_readptr)
 388 dnl  else
 389 dnl     AC_MSG_RESULT(we couldn't do it!)
 390 dnl  fi
 391 dnl  fi
 392 dnl  fi
 393
 394 #--------------------------------------------------------------------
 395 #
 396 # Flags for thread support
 397 #
 398 #--------------------------------------------------------------------
 399
 400 ### What thread package has the user asked for?
 401 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 402             , with_threads=no)
 403
 404 ### Turn $with_threads into either the name of a threads package, like
 405 ### `qt', or `no', meaning that threads should not be supported.
 406 AC_MSG_CHECKING(whether to support threads)
 407 case "$with_threads" in
 408   "yes" | "qt" | "coop" | "")
 409     with_threads=qt
 410   ;;
 411   "no" )
 412   ;;
 413   * )
 414     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 415   ;;
 416 esac
 417 AC_MSG_RESULT($with_threads)
 418
 419 ## Make sure the threads package we've chosen is actually supported on
 420 ## the present platform.
 421 case "${with_threads}" in
 422   "qt" )
 423     ## This configures the QuickThreads package, and sets or clears
 424     ## the THREAD_PACKAGE variable if qthreads don't configure
 425     ## correctly.
 426     QTHREADS_CONFIGURE
 427    ;;
 428 esac
 429
 430 ## If we're using threads, bring in some other parts of Guile which
 431 ## work with them.
 432 if test "${THREAD_PACKAGE}" != "" ; then
 433   AC_DEFINE(USE_THREADS, 1)
 434
 435   ## Include the Guile thread interface in the library...
 436   LIBOBJS="$LIBOBJS threads.o"
 437
 438   ## ... and tell it which package to talk to.
 439   case "${THREAD_PACKAGE}" in
 440     "QT" )
 441       AC_DEFINE(USE_COOP_THREADS, 1)
 442     ;;
 443     * )
 444       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 445     ;;
 446   esac
 447
 448   ## Bring in scm_internal_select, if appropriate.
 449   if test $ac_cv_func_gettimeofday = yes &&
 450      test $ac_cv_func_select = yes; then
 451     LIBOBJS="$LIBOBJS iselect.o"
 452     AC_DEFINE(GUILE_ISELECT, 1)
 453   fi
 454 fi
 455
 456
 457 ## If we're using GCC, ask for aggressive warnings.
 458 case "$GCC" in
 459   yes )
 460     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 461     ## much stuff with generic function pointers for that to really be
 462     ## less than exasperating.
 463     CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wmissing-prototypes" ;;
 464 esac
 465
 466 AC_PROG_AWK
 467
 468 ## If we're creating a shared library (using libtool!), then we'll
 469 ## need to generate a list of .lo files corresponding to the .o files
 470 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 471 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 472
 473 AC_SUBST(GUILE_MAJOR_VERSION)
 474 AC_SUBST(GUILE_MINOR_VERSION)
 475 AC_SUBST(GUILE_VERSION)
 476
 477 dnl Tell guile-config what flags guile users should link against.
 478 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 479 AC_SUBST(GUILE_LIBS)
 480
 481 AC_SUBST(AWK)
 482 AC_SUBST(LIBLOBJS)
 483
 484 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/versiondat.h ice-9/Makefile ice-9/version.scm qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf])
 485
 486 dnl Local Variables:
 487 dnl comment-start: "dnl "
 488 dnl comment-end: ""
 489 dnl comment-start-skip: "\\bdnl\\b\\s *"
 490 dnl End: