configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT(m4_esyscmd(. ./GUILE-VERSION && echo -n ${PACKAGE}),
  31         m4_esyscmd(. ./GUILE-VERSION && echo -n ${GUILE_VERSION}))
  32 AC_CONFIG_SRCDIR(GUILE-VERSION)
  33 AM_INIT_AUTOMAKE([no-define])
  34
  35 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  36 AC_CONFIG_SRCDIR([GUILE-VERSION])
  37
  38 . $srcdir/GUILE-VERSION
  39
  40 AM_MAINTAINER_MODE
  41 AM_CONFIG_HEADER([config.h])
  42 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  43
  44 #--------------------------------------------------------------------
  45 #
  46 # Independent Subdirectories
  47 #
  48 #--------------------------------------------------------------------
  49
  50 AC_CONFIG_SUBDIRS(guile-readline)
  51
  52 #--------------------------------------------------------------------
  53
  54 dnl Some more checks for Win32
  55 AC_CYGWIN
  56 AC_MINGW32
  57 AC_LIBTOOL_WIN32_DLL
  58
  59 AC_PROG_INSTALL
  60 AC_PROG_CC
  61 AC_PROG_CPP
  62 AC_PROG_AWK
  63
  64 AC_AIX
  65 AC_ISC_POSIX
  66 AC_MINIX
  67
  68 AM_PROG_CC_STDC
  69
  70 AC_LIBTOOL_DLOPEN
  71 AC_PROG_LIBTOOL
  72 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  73   [AC_MSG_ERROR([libltdl not found.  See README.])])
  74
  75 AC_SUBST(DLPREOPEN)
  76
  77 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  78 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  79
  80 AM_PATH_LISPDIR
  81
  82 #--------------------------------------------------------------------
  83 #
  84 # User options (after above tests that may set default CFLAGS etc.)
  85 #
  86 #--------------------------------------------------------------------
  87
  88 GUILE_ERROR_ON_WARNING="yes"
  89
  90 AC_ARG_ENABLE(error-on-warning,
  91   [  --enable-error-on-warning    treat compile warnings as errors],
  92   [case "${enableval}" in
  93      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  94      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  95      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  96    esac])
  97
  98 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
  99 AC_ARG_ENABLE(debug-freelist,
 100   [  --enable-debug-freelist include garbage collector freelist debugging code],
 101   if test "$enable_debug_freelist" = y \
 102      || test "$enable_debug_freelist" = yes; then
 103     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 104   fi)
 105
 106 AC_ARG_ENABLE(debug-malloc,
 107   [  --enable-debug-malloc   include malloc debugging code],
 108   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 109     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 110       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 111   fi)
 112
 113 SCM_I_GSC_GUILE_DEBUG=0
 114 AC_ARG_ENABLE(guile-debug,
 115   [AC_HELP_STRING([--enable-guile-debug],
 116                   [include internal debugging functions])],
 117   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 118     SCM_I_GSC_GUILE_DEBUG=1
 119   fi)
 120
 121 AC_ARG_ENABLE(arrays,
 122   [AC_HELP_STRING([--disable-arrays],[omit array and uniform array support])],
 123   ,
 124   enable_arrays=yes)
 125
 126 AC_ARG_ENABLE(posix,
 127   [  --disable-posix         omit posix interfaces],,
 128   enable_posix=yes)
 129
 130 AC_ARG_ENABLE(networking,
 131   [  --disable-networking    omit networking interfaces],,
 132   enable_networking=yes)
 133
 134 AC_ARG_ENABLE(regex,
 135   [  --disable-regex         omit regular expression interfaces],,
 136   enable_regex=yes)
 137
 138 AC_ARG_ENABLE([discouraged],
 139   AC_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 140
 141 if test "$enable_discouraged" = no; then
 142   SCM_I_GSC_ENABLE_DISCOURAGED=0
 143 else
 144   SCM_I_GSC_ENABLE_DISCOURAGED=1
 145 fi
 146
 147 AC_ARG_ENABLE([deprecated],
 148   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 149
 150 if test "$enable_deprecated" = no; then
 151   SCM_I_GSC_ENABLE_DEPRECATED=0
 152 else
 153   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 154     warn_default=summary
 155   elif test "$enable_deprecated" = shutup; then
 156     warn_default=no
 157   else
 158     warn_default=$enable_deprecated
 159   fi
 160   SCM_I_GSC_ENABLE_DEPRECATED=1
 161   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 162   [Define this to control the default warning level for deprecated features.])
 163 fi
 164
 165 AC_ARG_ENABLE(elisp,
 166   [  --disable-elisp         omit Emacs Lisp support],,
 167   enable_elisp=yes)
 168
 169 #--------------------------------------------------------------------
 170
 171 dnl Check for dynamic linking
 172
 173 use_modules=yes
 174 AC_ARG_WITH(modules,
 175 [  --with-modules[=FILES]  Add support for dynamic modules],
 176 use_modules="$withval")
 177 test -z "$use_modules" && use_modules=yes
 178 DLPREOPEN=
 179 if test "$use_modules" != no; then
 180   if test "$use_modules" = yes; then
 181     DLPREOPEN="-dlpreopen force"
 182   else
 183     DLPREOPEN="-export-dynamic"
 184     for module in $use_modules; do
 185       DLPREOPEN="$DLPREOPEN -dlopen $module"
 186     done
 187   fi
 188 fi
 189
 190 dnl files which are destined for separate modules.
 191
 192 if test "$use_modules" != no; then
 193    AC_LIBOBJ([dynl])
 194 fi
 195
 196 if test "$enable_posix" = yes; then
 197    AC_LIBOBJ([filesys])
 198    AC_LIBOBJ([posix])
 199    AC_DEFINE(HAVE_POSIX, 1,
 200      [Define this if you want support for POSIX system calls in Guile.])
 201 fi
 202
 203 if test "$enable_networking" = yes; then
 204    AC_LIBOBJ([net_db])
 205    AC_LIBOBJ([socket])
 206    AC_DEFINE(HAVE_NETWORKING, 1,
 207      [Define this if you want support for networking in Guile.])
 208 fi
 209
 210 if test "$enable_debug_malloc" = yes; then
 211    AC_LIBOBJ([debug-malloc])
 212 fi
 213
 214 if test "$enable_elisp" = yes; then
 215   SCM_I_GSC_ENABLE_ELISP=1
 216 else
 217   SCM_I_GSC_ENABLE_ELISP=0
 218 fi
 219
 220 AC_C_CONST
 221
 222 AC_C_INLINE
 223 if test "$ac_cv_c_inline" != no; then
 224   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 225 else
 226   SCM_I_GSC_C_INLINE=NULL
 227 fi
 228
 229 AC_C_BIGENDIAN
 230
 231 AC_CHECK_SIZEOF(char)
 232 AC_CHECK_SIZEOF(unsigned char)
 233 AC_CHECK_SIZEOF(short)
 234 AC_CHECK_SIZEOF(unsigned short)
 235 AC_CHECK_SIZEOF(int)
 236 AC_CHECK_SIZEOF(unsigned int)
 237 AC_CHECK_SIZEOF(long)
 238 AC_CHECK_SIZEOF(unsigned long)
 239 AC_CHECK_SIZEOF(size_t)
 240 AC_CHECK_SIZEOF(long long)
 241 AC_CHECK_SIZEOF(unsigned long long)
 242 AC_CHECK_SIZEOF(__int64)
 243 AC_CHECK_SIZEOF(unsigned __int64)
 244 AC_CHECK_SIZEOF(void *)
 245 AC_CHECK_SIZEOF(intptr_t)
 246 AC_CHECK_SIZEOF(uintptr_t)
 247 AC_CHECK_SIZEOF(ptrdiff_t)
 248 AC_CHECK_SIZEOF(size_t)
 249
 250 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 251   AC_MSG_ERROR(sizes of long and void* are not identical)
 252 fi
 253
 254 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 255   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 256 else
 257   SCM_I_GSC_T_PTRDIFF='"long"'
 258 fi
 259 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 260
 261 AC_CHECK_HEADERS([stdint.h])
 262 AC_CHECK_HEADERS([inttypes.h])
 263
 264 AC_CHECK_SIZEOF(intmax_t)
 265
 266 SCM_I_GSC_NEEDS_STDINT_H=0
 267 SCM_I_GSC_NEEDS_INTTYPES_H=0
 268
 269 ### intptr and uintptr (try not to use inttypes if we don't have to)
 270 if test "$ac_cv_header_inttypes_h" = yes; then
 271   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 272     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 273 #include <stdio.h>])
 274     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 275       SCM_I_GSC_NEEDS_INTTYPES_H=1
 276     fi
 277   fi
 278   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 279     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 280 #include <stdio.h>])
 281     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 282       SCM_I_GSC_NEEDS_INTTYPES_H=1
 283     fi
 284   fi
 285 fi
 286
 287 ### See what's provided by stdint.h
 288 if test "$ac_cv_header_stdint_h" = yes; then
 289    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 290    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 291    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 292    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 293    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 294    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 295    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 296    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 297    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 298    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 299 fi
 300
 301 # so we don't get confused by the cache (wish there was a better way
 302 # to check particular headers for the same type...)
 303
 304 unset ac_cv_type_int8_t
 305 unset ac_cv_type_uint8_t
 306 unset ac_cv_type_int16_t
 307 unset ac_cv_type_uint16_t
 308 unset ac_cv_type_int32_t
 309 unset ac_cv_type_uint32_t
 310 unset ac_cv_type_int64_t
 311 unset ac_cv_type_uint64_t
 312 unset ac_cv_type_intmax_t
 313 unset ac_cv_type_uintmax_t
 314
 315 ### See what's provided by inttypes.h
 316 if test "$ac_cv_header_inttypes_h" = yes; then
 317   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 318   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 319   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 320   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 321   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 322   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 323   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 324   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 325   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 326   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 327 fi
 328
 329 # Try hard to find definitions for some required scm_t_*int* types.
 330
 331 ### Required type scm_t_int8
 332 if test "$scm_stdint_has_int8"; then
 333   SCM_I_GSC_T_INT8='"int8_t"'
 334   SCM_I_GSC_NEEDS_STDINT_H=1
 335 elif test "$scm_inttypes_has_int8"; then
 336   SCM_I_GSC_T_INT8='"int8_t"'
 337   SCM_I_GSC_NEEDS_INTTYPES_H=1
 338 elif test "$ac_cv_sizeof_char" -eq 1; then
 339   SCM_I_GSC_T_INT8='"signed char"'
 340 else
 341   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 342 fi
 343 AC_SUBST([SCM_I_GSC_T_INT8])
 344
 345 ### Required type scm_t_uint8
 346 if test "$scm_stdint_has_uint8"; then
 347   SCM_I_GSC_T_UINT8='"uint8_t"'
 348   SCM_I_GSC_NEEDS_STDINT_H=1
 349 elif test "$scm_inttypes_has_uint8"; then
 350   SCM_I_GSC_T_UINT8='"uint8_t"'
 351   SCM_I_GSC_NEEDS_INTTYPES_H=1
 352 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 353   SCM_I_GSC_T_UINT8='"unsigned char"'
 354 else
 355   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 356 fi
 357 AC_SUBST([SCM_I_GSC_T_UINT8])
 358
 359 ### Required type scm_t_int16 (ANSI C says int or short might work)
 360 if test "$scm_stdint_has_int16"; then
 361   SCM_I_GSC_T_INT16='"int16_t"'
 362   SCM_I_GSC_NEEDS_STDINT_H=1
 363 elif test "$scm_inttypes_has_int16"; then
 364   SCM_I_GSC_T_INT16='"int16_t"'
 365   SCM_I_GSC_NEEDS_INTTYPES_H=1
 366 elif test "$ac_cv_sizeof_int" -eq 2; then
 367   SCM_I_GSC_T_INT16='"int"'
 368 elif test "$ac_cv_sizeof_short" -eq 2; then
 369   SCM_I_GSC_T_INT16='"short"'
 370 else
 371   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 372 fi
 373 AC_SUBST([SCM_I_GSC_T_INT16])
 374
 375 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 376 if test "$scm_stdint_has_uint16"; then
 377   SCM_I_GSC_T_UINT16='"uint16_t"'
 378   SCM_I_GSC_NEEDS_STDINT_H=1
 379 elif test "$scm_inttypes_has_uint16"; then
 380   SCM_I_GSC_T_UINT16='"uint16_t"'
 381   SCM_I_GSC_NEEDS_INTTYPES_H=1
 382 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 383   SCM_I_GSC_T_UINT16='"unsigned int"'
 384 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 385   SCM_I_GSC_T_UINT16='"unsigned short"'
 386 else
 387   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 388 fi
 389 AC_SUBST([SCM_I_GSC_T_UINT16])
 390
 391
 392 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 393 if test "$scm_stdint_has_int32"; then
 394   SCM_I_GSC_T_INT32='"int32_t"'
 395   SCM_I_GSC_NEEDS_STDINT_H=1
 396 elif test "$scm_inttypes_has_int32"; then
 397   SCM_I_GSC_T_INT32='"int32_t"'
 398   SCM_I_GSC_NEEDS_INTTYPES_H=1
 399 elif test "$ac_cv_sizeof_int" -eq 4; then
 400   SCM_I_GSC_T_INT32='"int"'
 401 elif test "$ac_cv_sizeof_long" -eq 4; then
 402   SCM_I_GSC_T_INT32='"long"'
 403 elif test "$ac_cv_sizeof_short" -eq 4; then
 404   SCM_I_GSC_T_INT32='"short"'
 405 else
 406   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 407 fi
 408 AC_SUBST([SCM_I_GSC_T_INT32])
 409
 410 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 411 if test "$scm_stdint_has_uint32"; then
 412   SCM_I_GSC_T_UINT32='"uint32_t"'
 413   SCM_I_GSC_NEEDS_STDINT_H=1
 414 elif test "$scm_inttypes_has_uint32"; then
 415   SCM_I_GSC_T_UINT32='"uint32_t"'
 416   SCM_I_GSC_NEEDS_INTTYPES_H=1
 417 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 418   SCM_I_GSC_T_UINT32='"unsigned int"'
 419 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 420   SCM_I_GSC_T_UINT32='"unsigned long"'
 421 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 422   SCM_I_GSC_T_UINT32='"unsigned short"'
 423 else
 424   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 425 fi
 426 AC_SUBST([SCM_I_GSC_T_UINT32])
 427
 428 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 429 ### Also try 'long long' and '__int64' if we have it.
 430 SCM_I_GSC_T_INT64=0
 431 if test "$scm_stdint_has_int64"; then
 432   SCM_I_GSC_T_INT64='"int64_t"'
 433   SCM_I_GSC_NEEDS_STDINT_H=1
 434 elif test "$scm_inttypes_has_int64"; then
 435   SCM_I_GSC_T_INT64='"int64_t"'
 436   SCM_I_GSC_NEEDS_INTTYPES_H=1
 437 elif test "$ac_cv_sizeof_int" -eq 8; then
 438   SCM_I_GSC_T_INT64='"int"'
 439 elif test "$ac_cv_sizeof_long" -eq 8; then
 440   SCM_I_GSC_T_INT64='"long"'
 441 elif test "$ac_cv_sizeof_short" -eq 8; then
 442   SCM_I_GSC_T_INT64='"short"'
 443 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 444   SCM_I_GSC_T_INT64='"long long"'
 445 elif test "$ac_cv_sizeof___int64" -eq 8; then
 446   SCM_I_GSC_T_INT64='"__int64"'
 447 else
 448   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 449 fi
 450 AC_SUBST([SCM_I_GSC_T_INT64])
 451
 452
 453 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 454 ### Also try 'long long' and '__int64' if we have it.
 455 SCM_I_GSC_T_UINT64=0
 456 if test "$scm_stdint_has_uint64"; then
 457   SCM_I_GSC_T_UINT64='"uint64_t"'
 458   SCM_I_GSC_NEEDS_STDINT_H=1
 459 elif test "$scm_inttypes_has_uint64"; then
 460   SCM_I_GSC_T_UINT64='"uint64_t"'
 461   SCM_I_GSC_NEEDS_INTTYPES_H=1
 462 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 463   SCM_I_GSC_T_UINT64='"unsigned int"'
 464 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 465   SCM_I_GSC_T_UINT64='"unsigned long"'
 466 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 467   SCM_I_GSC_T_UINT64='"unsigned short"'
 468 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 469   SCM_I_GSC_T_UINT64='"unsigned long long"'
 470 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 471   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 472 else
 473   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 474 fi
 475 AC_SUBST([SCM_I_GSC_T_UINT64])
 476
 477 ### Required type scm_t_intmax
 478 ###
 479 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 480 ### none of them is available, we use 'long'.
 481 ###
 482 SCM_I_GSC_T_INTMAX=0
 483 if test "$scm_stdint_has_intmax"; then
 484   SCM_I_GSC_T_INTMAX='"intmax_t"'
 485   SCM_I_GSC_NEEDS_STDINT_H=1
 486 elif test "$scm_inttypes_has_intmax"; then
 487   SCM_I_GSC_T_INTMAX='"intmax_t"'
 488   SCM_I_GSC_NEEDS_INTTYPES_H=1
 489 elif test "$ac_cv_sizeof___int64" -ne 0; then
 490   SCM_I_GSC_T_INTMAX='"__int64"'
 491 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 492   SCM_I_GSC_T_INTMAX='"long long"'
 493 else
 494   SCM_I_GSC_T_INTMAX='"long"'
 495 fi
 496 AC_SUBST([SCM_I_GSC_T_INTMAX])
 497
 498 ### Required type scm_t_uintmax
 499 ###
 500 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 501 ### this order.  When none of them is available, we use 'unsigned long'.
 502 ###
 503 SCM_I_GSC_T_UINTMAX=0
 504 if test "$scm_stdint_has_uintmax"; then
 505   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 506   SCM_I_GSC_NEEDS_STDINT_H=1
 507 elif test "$scm_inttypes_has_uintmax"; then
 508   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 509   SCM_I_GSC_NEEDS_INTTYPES_H=1
 510 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 511   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 512 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 513   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 514 else
 515   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 516 fi
 517 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 518
 519
 520 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 521 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 522
 523 AC_HEADER_STDC
 524 AC_HEADER_DIRENT
 525 AC_HEADER_TIME
 526 AC_HEADER_SYS_WAIT
 527
 528 # Reasons for testing:
 529 #   fenv.h - available in C99, but not older systems
 530 #
 531 AC_CHECK_HEADERS([fenv.h io.h libc.h limits.h malloc.h memory.h string.h \
 532 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 533 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 534 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 535 direct.h])
 536
 537 GUILE_HEADER_LIBC_WITH_UNISTD
 538
 539 AC_TYPE_GETGROUPS
 540 AC_TYPE_SIGNAL
 541 AC_TYPE_MODE_T
 542
 543 if test $MINGW32 = no; then
 544         AC_CHECK_LIB(m, main)
 545 fi
 546 AC_CHECK_FUNCS(gethostbyname)
 547 if test $ac_cv_func_gethostbyname = no; then
 548     AC_CHECK_LIB(nsl, gethostbyname)
 549 fi
 550
 551 AC_CHECK_FUNCS(connect)
 552 if test $ac_cv_func_connect = no; then
 553     AC_CHECK_LIB(socket, connect)
 554 fi
 555
 556 dnl
 557 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 558 dnl
 559 EXTRA_DEFS=""
 560 if test "$MINGW32" = "yes" ; then
 561     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 562       [Define if you have the <winsock2.h> header file.])])
 563     AC_CHECK_LIB(ws2_32, main)
 564     AC_LIBOBJ([win32-uname])
 565     AC_LIBOBJ([win32-dirent])
 566     if test "$enable_networking" = yes ; then
 567       AC_LIBOBJ([win32-socket])
 568     fi
 569     if test "$enable_shared" = yes ; then
 570       EXTRA_DEFS="-DSCM_IMPORT"
 571       AC_DEFINE(USE_DLL_IMPORT, 1,
 572         [Define if you need additional CPP macros on Win32 platforms.])
 573     fi
 574 fi
 575 AC_SUBST(EXTRA_DEFS)
 576
 577 # Reasons for testing:
 578 #   crt_externs.h - Darwin specific
 579 #
 580 AC_CHECK_HEADERS([assert.h crt_externs.h])
 581
 582 # Reasons for testing:
 583 #   DINFINITY - OSF specific
 584 #   DQNAN - OSF specific
 585 #       (DINFINITY and DQNAN are actually global variables, not functions)
 586 #   fesetround - available in C99, but not older systems
 587 #   gmtime_r - recent posix, not on old systems
 588 #   readdir_r - recent posix, not on old systems
 589 #   sysconf - not on old systems
 590 #   _NSGetEnviron - Darwin specific
 591 #
 592 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid fesetround ftime fchown getcwd geteuid gettimeofday gmtime_r lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv _NSGetEnviron])
 593
 594 # Reasons for testing:
 595 #   netdb.h - not in mingw
 596 #   sys/param.h - not in mingw
 597 #
 598 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 599 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 600
 601 # crypt() may or may not be available, for instance in some countries there
 602 # are restrictions on cryptography.
 603 #
 604 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 605 # -lcrypt library (eg. Debian GNU/Linux).
 606 #
 607 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 608 # be careful to avoid -lcrypt in this case, since libtool will see there's
 609 # only a static libcrypt and decide to build only a static libguile.
 610 #
 611 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 612 # libraries already in that list.
 613 #
 614 AC_SEARCH_LIBS(crypt, crypt,
 615   [AC_DEFINE(HAVE_CRYPT,1,
 616              [Define to 1 if you have the `crypt' function.])])
 617
 618 dnl GMP tests
 619 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 620   [AC_MSG_ERROR([GNU MP not found, see README])])
 621
 622 # mpz_import is a macro so we need to include <gmp.h>
 623 AC_TRY_LINK([#include <gmp.h>],
 624             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 625   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see README])])
 626
 627 dnl i18n tests
 628 #AC_CHECK_HEADERS([libintl.h])
 629 #AC_CHECK_FUNCS(gettext)
 630 #if test $ac_cv_func_gettext = no; then
 631 #   AC_CHECK_LIB(intl, gettext)
 632 #fi
 633 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 634 AM_GNU_GETTEXT([external], [need-ngettext])
 635
 636 ### Some systems don't declare some functions.  On such systems, we
 637 ### need to at least provide our own K&R-style declarations.
 638
 639 ### GUILE_FUNC_DECLARED(function, headerfile)
 640
 641 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 642 ### not there, #define MISSING_FUNCTION_DECL.
 643 AC_DEFUN([GUILE_FUNC_DECLARED], [
 644   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 645     AC_EGREP_HEADER($1, $2,
 646                     guile_cv_func_$1_declared=yes,
 647                     guile_cv_func_$1_declared=no))
 648   if test [x$guile_cv_func_]$1[_declared] = xno; then
 649     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 650       [Define if the operating system supplies $1 without declaring it.])
 651   fi
 652 ])
 653
 654 GUILE_FUNC_DECLARED(sleep, unistd.h)
 655 GUILE_FUNC_DECLARED(usleep, unistd.h)
 656
 657 AC_CHECK_DECLS([strptime],,,
 658 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 659 #include <time.h>])
 660
 661 ### On some systems usleep has no return value.  If it does have one,
 662 ### we'd like to return it; otherwise, we'll fake it.
 663 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 664   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 665                    unistd.h,
 666                    [guile_cv_func_usleep_return_type=void],
 667                    [guile_cv_func_usleep_return_type=int])])
 668 case "$guile_cv_func_usleep_return_type" in
 669   "void" )
 670     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 671       [Define if the system headers declare usleep to return void.])
 672   ;;
 673 esac
 674
 675 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 676 if test -n "$have_sys_un_h" ; then
 677   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 678     [Define if the system supports Unix-domain (file-domain) sockets.])
 679 fi
 680
 681 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 682
 683 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 684                setnetent    getnetent    endnetent    dnl
 685                setprotoent  getprotoent  endprotoent  dnl
 686                setservent   getservent   endservent   dnl
 687                getnetbyaddr getnetbyname dnl
 688                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 689                inet_pton inet_ntop)
 690
 691 # struct sockaddr field sin_len is only present on BSD systems.
 692 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 693 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 694 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 695 [#ifdef HAVE_SYS_TYPES_H
 696 #include <sys/types.h>
 697 #endif
 698 #include <netinet/in.h>])
 699
 700 AC_MSG_CHECKING(for __libc_stack_end)
 701 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 702 [AC_TRY_LINK([#include <stdio.h>
 703 extern char *__libc_stack_end;],
 704              [printf("%p", (char*) __libc_stack_end);],
 705              guile_cv_have_libc_stack_end=yes,
 706              guile_cv_have_libc_stack_end=no)])
 707 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 708
 709 if test $guile_cv_have_libc_stack_end = yes; then
 710   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 711            [Define if you have the __libc_stack_end variable.])
 712 fi
 713
 714 dnl Some systems do not declare this.  Some systems do declare it, as a
 715 dnl macro.  With cygwin it may be in a DLL.
 716
 717 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 718 AC_CACHE_VAL(guile_cv_have_h_errno,
 719 [AC_TRY_COMPILE([#include <netdb.h>],
 720 [int a = h_errno;],
 721 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 722 AC_MSG_RESULT($guile_cv_have_h_errno)
 723 if test $guile_cv_have_h_errno = yes; then
 724   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 725 fi
 726
 727 AC_MSG_CHECKING(whether uint32_t is defined)
 728 AC_CACHE_VAL(guile_cv_have_uint32_t,
 729   [AC_TRY_COMPILE([#include <sys/types.h>
 730                    #if HAVE_STDINT_H
 731                    #include <stdint.h>
 732                    #endif
 733                    #ifndef __MINGW32__
 734                    #include <netdb.h>
 735                    #endif],
 736                   [uint32_t a;],
 737                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 738 AC_MSG_RESULT($guile_cv_have_uint32_t)
 739 if test $guile_cv_have_uint32_t = yes; then
 740   AC_DEFINE(HAVE_UINT32_T, 1,
 741     [Define if uint32_t typedef is defined when netdb.h is include.])
 742 fi
 743
 744 AC_MSG_CHECKING(for working IPv6 support)
 745 AC_CACHE_VAL(guile_cv_have_ipv6,
 746 [AC_TRY_COMPILE([
 747 #ifdef HAVE_SYS_TYPES_H
 748 #include <sys/types.h>
 749 #endif
 750 #include <netinet/in.h>
 751 #include <sys/socket.h>],
 752 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 753 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 754 AC_MSG_RESULT($guile_cv_have_ipv6)
 755 if test $guile_cv_have_ipv6 = yes; then
 756   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 757 fi
 758
 759 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 760 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 761 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 762 [AC_TRY_COMPILE([
 763 #ifdef HAVE_SYS_TYPES_H
 764 #include <sys/types.h>
 765 #endif
 766 #include <netinet/in.h>],
 767 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 768 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 769 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 770 if test $guile_cv_have_sin6_scope_id = yes; then
 771   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 772     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 773 fi
 774
 775 # struct sockaddr_in6 field sin_len is only present on BSD systems
 776 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 777 [#ifdef HAVE_SYS_TYPES_H
 778 #include <sys/types.h>
 779 #endif
 780 #include <netinet/in.h>])
 781
 782 AC_MSG_CHECKING(whether localtime caches TZ)
 783 AC_CACHE_VAL(guile_cv_localtime_cache,
 784 [if test x$ac_cv_func_tzset = xyes; then
 785 AC_TRY_RUN([#include <time.h>
 786 #if STDC_HEADERS
 787 # include <stdlib.h>
 788 #endif
 789 extern char **environ;
 790 unset_TZ ()
 791 {
 792   char **from, **to;
 793   for (to = from = environ; (*to = *from); from++)
 794     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 795       to++;
 796 }
 797 char TZ_GMT0[] = "TZ=GMT0";
 798 char TZ_PST8[] = "TZ=PST8";
 799 main()
 800 {
 801   time_t now = time ((time_t *) 0);
 802   int hour_GMT0, hour_unset;
 803   if (putenv (TZ_GMT0) != 0)
 804     exit (1);
 805   hour_GMT0 = localtime (&now)->tm_hour;
 806   unset_TZ ();
 807   hour_unset = localtime (&now)->tm_hour;
 808   if (putenv (TZ_PST8) != 0)
 809     exit (1);
 810   if (localtime (&now)->tm_hour == hour_GMT0)
 811     exit (1);
 812   unset_TZ ();
 813   if (localtime (&now)->tm_hour != hour_unset)
 814     exit (1);
 815   exit (0);
 816 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 817 [# If we have tzset, assume the worst when cross-compiling.
 818 guile_cv_localtime_cache=yes])
 819 else
 820         # If we lack tzset, report that localtime does not cache TZ,
 821         # since we can't invalidate the cache if we don't have tzset.
 822         guile_cv_localtime_cache=no
 823 fi])dnl
 824 AC_MSG_RESULT($guile_cv_localtime_cache)
 825 if test $guile_cv_localtime_cache = yes; then
 826   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 827 fi
 828
 829 dnl Test whether system calls are restartable by default on the
 830 dnl current system.  If they are not, we put a loop around every system
 831 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 832 dnl change from the default behaviour.  On the other hand, if signals
 833 dnl are restartable then the loop is not installed and when libguile
 834 dnl initialises it also resets the behaviour of each signal to cause a
 835 dnl restart (in case a different runtime had a different default
 836 dnl behaviour for some reason: e.g., different versions of linux seem
 837 dnl to behave differently.)
 838
 839 AC_SYS_RESTARTABLE_SYSCALLS
 840
 841 if test "$enable_regex" = yes; then
 842    if test "$ac_cv_header_regex_h" = yes ||
 843       test "$ac_cv_header_rxposix_h" = yes ||
 844       test "$ac_cv_header_rx_rxposix_h" = yes; then
 845      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 846      [AC_CHECK_LIB(rx, main)
 847       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 848      [AC_CHECK_LIB(regex, main)
 849       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 850      )
 851      dnl The following should not be necessary, but for some reason
 852      dnl autoheader misses it if we don't include it!
 853      if test "$ac_cv_func_regcomp_norx" = yes ||
 854         test "$ac_cv_func_regcomp_regex" = yes ||
 855         test "$ac_cv_func_regcomp_rx" = yes; then
 856        AC_DEFINE(HAVE_REGCOMP, 1,
 857          [This is included as part of a workaround for a autoheader bug.])
 858      fi
 859    fi
 860 fi
 861
 862 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 863
 864 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 865
 866 # Reasons for testing:
 867 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 868 #                                older systems
 869 #   sincos - GLIBC extension
 870 #
 871 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
 872
 873 # C99 specifies isinf and isnan as macros.
 874 # HP-UX provides only macros, no functions.
 875 # glibc 2.3.2 provides both macros and functions.
 876 # IRIX 6.5 and Solaris 8 only provide functions.
 877 #
 878 # The following tests detect isinf and isnan either as functions or as
 879 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
 880 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
 881 #
 882 AC_MSG_CHECKING([for isinf])
 883 AC_LINK_IFELSE(
 884 [#include <math.h>
 885 int main () { return (isinf(0.0) != 0); }],
 886   [AC_MSG_RESULT([yes])
 887    AC_DEFINE(HAVE_ISINF, 1,
 888              [Define to 1 if you have the `isinf' macro or function.])],
 889   [AC_MSG_RESULT([no])])
 890 AC_MSG_CHECKING([for isnan])
 891 AC_LINK_IFELSE(
 892 [#include <math.h>
 893 #ifdef __MINGW32__
 894 #define isnan _isnan
 895 #endif
 896 int main () { return (isnan(0.0) != 0); }],
 897   [AC_MSG_RESULT([yes])
 898    AC_DEFINE(HAVE_ISNAN, 1,
 899              [Define to 1 if you have the `isnan' macro or function.])],
 900   [AC_MSG_RESULT([no])])
 901
 902 # We must have a proper stack-using alloca in order for stack-copying
 903 # continuations to work properly.  If we don't find a native one,
 904 # abort.
 905
 906 AC_FUNC_ALLOCA
 907 if test "$ALLOCA" = "alloca.o"
 908 then
 909   AC_ERROR([No native alloca found.])
 910 fi
 911
 912 AC_CHECK_MEMBERS([struct stat.st_rdev])
 913 AC_CHECK_MEMBERS([struct stat.st_blksize])
 914
 915 AC_STRUCT_ST_BLOCKS
 916
 917 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 918   [AC_TRY_CPP([#include <sys/stat.h>
 919                #ifndef S_ISLNK
 920                #error no S_ISLNK
 921                #endif],
 922                ac_cv_macro_S_ISLNK=yes,
 923                ac_cv_macro_S_ISLNK=no)])
 924 if test $ac_cv_macro_S_ISLNK = yes; then
 925   AC_DEFINE(HAVE_S_ISLNK, 1,
 926     [Define this if your system defines S_ISLNK in sys/stat.h.])
 927 fi
 928
 929 AC_STRUCT_TIMEZONE
 930 GUILE_STRUCT_UTIMBUF
 931
 932 #--------------------------------------------------------------------
 933 #
 934 # Which way does the stack grow?
 935 #
 936 #--------------------------------------------------------------------
 937
 938 SCM_I_GSC_STACK_GROWS_UP=0
 939 AC_TRY_RUN(aux (l) unsigned long l;
 940              { int x; exit (l >= ((unsigned long)&x)); }
 941            main () { int q; aux((unsigned long)&q); },
 942            [SCM_I_GSC_STACK_GROWS_UP=1],
 943            [],
 944            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
 945
 946 AC_CHECK_SIZEOF(float)
 947 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
 948     AC_DEFINE(SCM_SINGLES, 1,
 949               [Define this if floats are the same size as longs.])
 950 fi
 951
 952 AC_MSG_CHECKING(for struct linger)
 953 AC_CACHE_VAL(scm_cv_struct_linger,
 954         AC_TRY_COMPILE([
 955 #include <sys/types.h>
 956 #include <sys/socket.h>],
 957                         [struct linger lgr;  lgr.l_linger = 100],
 958                         scm_cv_struct_linger="yes",
 959                         scm_cv_struct_linger="no"))
 960 AC_MSG_RESULT($scm_cv_struct_linger)
 961 if test $scm_cv_struct_linger = yes; then
 962         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 963           [Define this if your system defines struct linger, for use with the
 964            getsockopt and setsockopt system calls.])
 965 fi
 966
 967
 968 AC_MSG_CHECKING(for struct timespec)
 969 AC_CACHE_VAL(scm_cv_struct_timespec,
 970         AC_TRY_COMPILE([
 971 #include <time.h>],
 972                         [struct timespec t;  t.tv_nsec = 100],
 973                         scm_cv_struct_timespec="yes",
 974                         scm_cv_struct_timespec="no"))
 975 AC_MSG_RESULT($scm_cv_struct_timespec)
 976 if test $scm_cv_struct_timespec = yes; then
 977   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 978     [Define this if your system defines struct timespec via <time.h>.])
 979 fi
 980
 981 #--------------------------------------------------------------------
 982 #
 983 # Flags for thread support
 984 #
 985 #--------------------------------------------------------------------
 986
 987 SCM_I_GSC_USE_PTHREAD_THREADS=0
 988 SCM_I_GSC_USE_NULL_THREADS=0
 989 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
 990 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
 991
 992 ### What thread package has the user asked for?
 993 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 994             , with_threads=yes)
 995
 996 case "$with_threads" in
 997   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
 998     ACX_PTHREAD(CC="$PTHREAD_CC"
 999       LIBS="$PTHREAD_LIBS $LIBS"
1000       SCM_I_GSC_USE_PTHREAD_THREADS=1
1001       with_threads="pthreads",
1002       with_threads="null")
1003
1004     old_CFLAGS="$CFLAGS"
1005     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1006     AC_CHECK_FUNCS(pthread_attr_getstack)
1007     CFLAGS="$old_CFLAGS"
1008
1009     # On Solaris, sched_yield lives in -lrt.
1010     AC_SEARCH_LIBS(sched_yield, rt)
1011
1012   ;;
1013 esac
1014
1015 case "$with_threads" in
1016   "pthreads")
1017   ;;
1018   "no" | "null")
1019     SCM_I_GSC_USE_NULL_THREADS=1
1020     with_threads="null-threads"
1021   ;;
1022   * )
1023     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1024   ;;
1025 esac
1026
1027 AC_MSG_CHECKING(what kind of threads to support)
1028 AC_MSG_RESULT($with_threads)
1029
1030 ## Cross building
1031 if test "$cross_compiling" = "yes"; then
1032   AC_MSG_CHECKING(cc for build)
1033   ## /usr/bin/cc still uses wrong assembler
1034   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1035   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1036 else
1037   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1038 fi
1039
1040 ## AC_MSG_CHECKING("if we are cross compiling")
1041 ## AC_MSG_RESULT($cross_compiling)
1042 if test "$cross_compiling" = "yes"; then
1043    AC_MSG_RESULT($CC_FOR_BUILD)
1044 fi
1045
1046 ## No need as yet to be more elaborate
1047 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1048
1049 AC_SUBST(cross_compiling)
1050 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1051 AC_SUBST(CCLD_FOR_BUILD)
1052
1053 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1054 ## --HOST is the platform that PACKAGE is compiled for.
1055 HOST_CC="$CC_FOR_BUILD"
1056 AC_SUBST(HOST_CC)
1057
1058 if test "$cross_compiling" = "yes"; then
1059   AC_MSG_CHECKING(guile for build)
1060   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1061 else
1062   GUILE_FOR_BUILD='$(preinstguile)'
1063 fi
1064
1065 ## AC_MSG_CHECKING("if we are cross compiling")
1066 ## AC_MSG_RESULT($cross_compiling)
1067 if test "$cross_compiling" = "yes"; then
1068    AC_MSG_RESULT($GUILE_FOR_BUILD)
1069 fi
1070 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1071 AC_SUBST(GUILE_FOR_BUILD)
1072
1073 ## If we're using GCC, ask for aggressive warnings.
1074 case "$GCC" in
1075   yes )
1076     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1077     ## much stuff with generic function pointers for that to really be
1078     ## less than exasperating.
1079     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1080     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1081     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1082     # Do this here so we don't screw up any of the tests above that might
1083     # not be "warning free"
1084     if test "${GUILE_ERROR_ON_WARNING}" = yes
1085     then
1086         CFLAGS="${CFLAGS} -Werror"
1087         enable_compile_warnings=no
1088     fi
1089     ;;
1090 esac
1091
1092 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
1093 ## -- I'm disabling it for now in the hopes that the newer autoconf
1094 ## will DTRT -- if not, we need to fix up the sed command to match the
1095 ## others...
1096 ##
1097 ## Remove fileblocks.o from the object list.  This file gets added by
1098 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
1099 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
1100
1101 ## If we're creating a shared library (using libtool!), then we'll
1102 ## need to generate a list of .lo files corresponding to the .o files
1103 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1104 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1105
1106 ## We also need to create corresponding .doc and .x files
1107 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1108 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1109
1110 AC_SUBST(GUILE_MAJOR_VERSION)
1111 AC_SUBST(GUILE_MINOR_VERSION)
1112 AC_SUBST(GUILE_MICRO_VERSION)
1113 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1114 AC_SUBST(GUILE_VERSION)
1115
1116 #######################################################################
1117 # library versioning
1118
1119 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1120 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1121 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1122 AC_SUBST(LIBGUILE_INTERFACE)
1123
1124 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1125 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1126 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1127 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1128 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1129
1130 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1131 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1132 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1133 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1134 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1135
1136 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1137 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1138 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1139 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1140 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1141
1142 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1143 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1144 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1145 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1146 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1147
1148 #######################################################################
1149
1150 dnl Tell guile-config what flags guile users should compile and link with.
1151 GUILE_LIBS="$LDFLAGS $LIBS"
1152 GUILE_CFLAGS="$PTHREAD_CFLAGS"
1153 AC_SUBST(GUILE_LIBS)
1154 AC_SUBST(GUILE_CFLAGS)
1155
1156 AC_SUBST(AWK)
1157 AC_SUBST(LIBLOBJS)
1158 AC_SUBST(EXTRA_DOT_DOC_FILES)
1159 AC_SUBST(EXTRA_DOT_X_FILES)
1160
1161 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1162 top_builddir_absolute=`pwd`
1163 AC_SUBST(top_builddir_absolute)
1164 top_srcdir_absolute=`(cd $srcdir && pwd)`
1165 AC_SUBST(top_srcdir_absolute)
1166
1167 # Additional SCM_I_GSC definitions are above.
1168 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1169 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1170 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1171 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1172 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1173 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1174 AC_SUBST([SCM_I_GSC_C_INLINE])
1175 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1176
1177 AC_CONFIG_FILES([
1178   Makefile
1179   am/Makefile
1180   benchmark-suite/Makefile
1181   doc/Makefile
1182   doc/goops/Makefile
1183   doc/r5rs/Makefile
1184   doc/ref/Makefile
1185   doc/tutorial/Makefile
1186   emacs/Makefile
1187   examples/Makefile
1188   examples/box-dynamic-module/Makefile
1189   examples/box-dynamic/Makefile
1190   examples/box-module/Makefile
1191   examples/box/Makefile
1192   examples/modules/Makefile
1193   examples/safe/Makefile
1194   examples/scripts/Makefile
1195   guile-config/Makefile
1196   ice-9/Makefile
1197   ice-9/debugger/Makefile
1198   ice-9/debugger/breakpoints/Makefile
1199   lang/Makefile
1200   lang/elisp/Makefile
1201   lang/elisp/internals/Makefile
1202   lang/elisp/primitives/Makefile
1203   libguile/Makefile
1204   oop/Makefile
1205   oop/goops/Makefile
1206   scripts/Makefile
1207   srfi/Makefile
1208   test-suite/Makefile
1209   test-suite/standalone/Makefile
1210 ])
1211
1212 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1213 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1214 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1215 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1216 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1217 AC_CONFIG_FILES([libguile/guile-snarf],
1218                 [chmod +x libguile/guile-snarf])
1219 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1220                 [chmod +x libguile/guile-doc-snarf])
1221 AC_CONFIG_FILES([libguile/guile-func-name-check],
1222                 [chmod +x libguile/guile-func-name-check])
1223 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1224                 [chmod +x libguile/guile-snarf-docs])
1225
1226 AC_OUTPUT
1227
1228 dnl Local Variables:
1229 dnl comment-start: "dnl "
1230 dnl comment-end: ""
1231 dnl comment-start-skip: "\\bdnl\\b\\s *"
1232 dnl End: