m4/duplocale.m4

   1 # duplocale.m4 serial 4
   2 dnl Copyright (C) 2009-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 AC_DEFUN([gl_FUNC_DUPLOCALE],
   8 [
   9   AC_REQUIRE([gl_LOCALE_H_DEFAULTS])
  10   AC_REQUIRE([AC_CANONICAL_HOST])
  11   AC_CHECK_FUNCS_ONCE([duplocale])
  12   if test $ac_cv_func_duplocale = yes; then
  13     dnl Check against glibc bug where duplocale crashes.
  14     dnl See <http://sourceware.org/bugzilla/show_bug.cgi?id=10969>.
  15     dnl Also, on AIX 7.1, duplocale(LC_GLOBAL_LOCALE) returns (locale_t)0 with
  16     dnl errno set to EINVAL.
  17     AC_REQUIRE([gl_LOCALE_H])
  18     AC_CACHE_CHECK([whether duplocale(LC_GLOBAL_LOCALE) works],
  19       [gl_cv_func_duplocale_works],
  20       [AC_RUN_IFELSE(
  21          [AC_LANG_SOURCE([[
  22 #include <locale.h>
  23 #if HAVE_XLOCALE_H
  24 # include <xlocale.h>
  25 #endif
  26 int main ()
  27 {
  28   if (duplocale (LC_GLOBAL_LOCALE) == (locale_t)0)
  29     return 1;
  30   return 0;
  31 }]])],
  32          [gl_cv_func_duplocale_works=yes],
  33          [gl_cv_func_duplocale_works=no],
  34          [dnl Guess it works except on glibc < 2.12 and AIX.
  35           case "$host_os" in
  36             aix*) gl_cv_func_duplocale_works="guessing no";;
  37             *-gnu*)
  38               AC_EGREP_CPP([Unlucky GNU user], [
  39 #include <features.h>
  40 #ifdef __GNU_LIBRARY__
  41  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ < 12)
  42   Unlucky GNU user
  43  #endif
  44 #endif
  45                 ],
  46                 [gl_cv_func_duplocale_works="guessing no"],
  47                 [gl_cv_func_duplocale_works="guessing yes"])
  48               ;;
  49             *) gl_cv_func_duplocale_works="guessing yes";;
  50           esac
  51          ])
  52       ])
  53     case "$gl_cv_func_duplocale_works" in
  54       *no) REPLACE_DUPLOCALE=1 ;;
  55     esac
  56   else
  57     HAVE_DUPLOCALE=0
  58   fi
  59   if test $REPLACE_DUPLOCALE = 1; then
  60     gl_REPLACE_LOCALE_H
  61     AC_LIBOBJ([duplocale])
  62     gl_PREREQ_DUPLOCALE
  63   fi
  64 ])
  65
  66 # Prerequisites of lib/duplocale.c.
  67 AC_DEFUN([gl_PREREQ_DUPLOCALE],
  68 [
  69   :
  70 ])