configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 Boston, MA 02111-1307, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT(m4_esyscmd(. ./GUILE-VERSION && echo -n ${PACKAGE}),
  31         m4_esyscmd(. ./GUILE-VERSION && echo -n ${GUILE_VERSION}))
  32 AC_CONFIG_SRCDIR(GUILE-VERSION)
  33 AM_INIT_AUTOMAKE([no-define])
  34
  35 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  36 AC_CONFIG_SRCDIR([GUILE-VERSION])
  37
  38 . $srcdir/GUILE-VERSION
  39
  40 AM_MAINTAINER_MODE
  41 AM_CONFIG_HEADER([config.h])
  42 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  43
  44 #--------------------------------------------------------------------
  45 #
  46 # Independent Subdirectories
  47 #
  48 #--------------------------------------------------------------------
  49
  50 AC_CONFIG_SUBDIRS(libltdl)
  51 AC_CONFIG_SUBDIRS(guile-readline)
  52
  53 #--------------------------------------------------------------------
  54
  55 dnl Some more checks for Win32
  56 AC_CYGWIN
  57 AC_MINGW32
  58 AC_LIBTOOL_WIN32_DLL
  59
  60 AC_PROG_INSTALL
  61 AC_PROG_CC
  62 AC_PROG_CPP
  63 AC_PROG_AWK
  64
  65 AC_AIX
  66 AC_ISC_POSIX
  67 AC_MINIX
  68
  69 AM_PROG_CC_STDC
  70
  71 AC_LIBTOOL_DLOPEN
  72 AC_LIBLTDL_INSTALLABLE
  73 AC_PROG_LIBTOOL
  74
  75 AC_SUBST(DLPREOPEN)
  76 AC_SUBST(LTDLINCL)
  77 AC_SUBST(LIBLTDL)
  78
  79 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  80 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  81
  82 AM_PATH_LISPDIR
  83
  84 #--------------------------------------------------------------------
  85 #
  86 # User options (after above tests that may set default CFLAGS etc.)
  87 #
  88 #--------------------------------------------------------------------
  89
  90 GUILE_ERROR_ON_WARNING="yes"
  91
  92 AC_ARG_ENABLE(error-on-warning,
  93   [  --enable-error-on-warning    treat compile warnings as errors],
  94   [case "${enableval}" in
  95      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  96      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  97      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  98    esac])
  99
 100 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
 101 AC_ARG_ENABLE(debug-freelist,
 102   [  --enable-debug-freelist include garbage collector freelist debugging code],
 103   if test "$enable_debug_freelist" = y \
 104      || test "$enable_debug_freelist" = yes; then
 105     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 106   fi)
 107
 108 AC_ARG_ENABLE(debug-malloc,
 109   [  --enable-debug-malloc   include malloc debugging code],
 110   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 111     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 112       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 113   fi)
 114
 115 SCM_I_GSC_GUILE_DEBUG=0
 116 AC_ARG_ENABLE(guile-debug,
 117   [AC_HELP_STRING([--enable-guile-debug],
 118                   [include internal debugging functions])],
 119   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 120     SCM_I_GSC_GUILE_DEBUG=1
 121   fi)
 122
 123 AC_ARG_ENABLE(arrays,
 124   [AC_HELP_STRING([--disable-arrays],[omit array and uniform array support])],
 125   ,
 126   enable_arrays=yes)
 127
 128 AC_ARG_ENABLE(posix,
 129   [  --disable-posix         omit posix interfaces],,
 130   enable_posix=yes)
 131
 132 AC_ARG_ENABLE(networking,
 133   [  --disable-networking    omit networking interfaces],,
 134   enable_networking=yes)
 135
 136 AC_ARG_ENABLE(regex,
 137   [  --disable-regex         omit regular expression interfaces],,
 138   enable_regex=yes)
 139
 140 AC_ARG_ENABLE([discouraged],
 141   AC_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 142
 143 if test "$enable_discouraged" = no; then
 144   SCM_I_GSC_ENABLE_DISCOURAGED=0
 145 else
 146   SCM_I_GSC_ENABLE_DISCOURAGED=1
 147 fi
 148
 149 AC_ARG_ENABLE([deprecated],
 150   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 151
 152 if test "$enable_deprecated" = no; then
 153   SCM_I_GSC_ENABLE_DEPRECATED=0
 154 else
 155   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 156     warn_default=summary
 157   elif test "$enable_deprecated" = shutup; then
 158     warn_default=no
 159   else
 160     warn_default=$enable_deprecated
 161   fi
 162   SCM_I_GSC_ENABLE_DEPRECATED=1
 163   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 164   [Define this to control the default warning level for deprecated features.])
 165 fi
 166
 167 AC_ARG_ENABLE(elisp,
 168   [  --disable-elisp         omit Emacs Lisp support],,
 169   enable_elisp=yes)
 170
 171 #--------------------------------------------------------------------
 172
 173 dnl Check for dynamic linking
 174
 175 use_modules=yes
 176 AC_ARG_WITH(modules,
 177 [  --with-modules[=FILES]  Add support for dynamic modules],
 178 use_modules="$withval")
 179 test -z "$use_modules" && use_modules=yes
 180 DLPREOPEN=
 181 if test "$use_modules" != no; then
 182   if test "$use_modules" = yes; then
 183     DLPREOPEN="-dlpreopen force"
 184   else
 185     DLPREOPEN="-export-dynamic"
 186     for module in $use_modules; do
 187       DLPREOPEN="$DLPREOPEN -dlopen $module"
 188     done
 189   fi
 190 fi
 191
 192 dnl files which are destined for separate modules.
 193
 194 if test "$use_modules" != no; then
 195    AC_LIBOBJ([dynl])
 196 fi
 197
 198 SCM_I_GSC_HAVE_ARRAYS=0
 199 if test "$enable_arrays" = yes; then
 200    AC_LIBOBJ([ramap])
 201    AC_LIBOBJ([unif])
 202    SCM_I_GSC_HAVE_ARRAYS=1
 203 fi
 204
 205 if test "$enable_posix" = yes; then
 206    AC_LIBOBJ([filesys])
 207    AC_LIBOBJ([posix])
 208    AC_DEFINE(HAVE_POSIX, 1,
 209      [Define this if you want support for POSIX system calls in Guile.])
 210 fi
 211
 212 if test "$enable_networking" = yes; then
 213    AC_LIBOBJ([net_db])
 214    AC_LIBOBJ([socket])
 215    AC_DEFINE(HAVE_NETWORKING, 1,
 216      [Define this if you want support for networking in Guile.])
 217 fi
 218
 219 if test "$enable_debug_malloc" = yes; then
 220    AC_LIBOBJ([debug-malloc])
 221 fi
 222
 223 if test "$enable_elisp" = yes; then
 224   SCM_I_GSC_ENABLE_ELISP=1
 225 else
 226   SCM_I_GSC_ENABLE_ELISP=0
 227 fi
 228
 229 AC_C_CONST
 230
 231 AC_C_INLINE
 232 if test "$ac_cv_c_inline" != no; then
 233   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 234 else
 235   SCM_I_GSC_C_INLINE=NULL
 236 fi
 237
 238 AC_C_BIGENDIAN
 239
 240 AC_CHECK_SIZEOF(char)
 241 AC_CHECK_SIZEOF(unsigned char)
 242 AC_CHECK_SIZEOF(short)
 243 AC_CHECK_SIZEOF(unsigned short)
 244 AC_CHECK_SIZEOF(int)
 245 AC_CHECK_SIZEOF(unsigned int)
 246 AC_CHECK_SIZEOF(long)
 247 AC_CHECK_SIZEOF(unsigned long)
 248 AC_CHECK_SIZEOF(size_t)
 249 AC_CHECK_SIZEOF(long long)
 250 AC_CHECK_SIZEOF(unsigned long long)
 251 AC_CHECK_SIZEOF(__int64)
 252 AC_CHECK_SIZEOF(unsigned __int64)
 253 AC_CHECK_SIZEOF(void *)
 254 AC_CHECK_SIZEOF(intptr_t)
 255 AC_CHECK_SIZEOF(uintptr_t)
 256 AC_CHECK_SIZEOF(ptrdiff_t)
 257 AC_CHECK_SIZEOF(size_t)
 258
 259 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 260   AC_MSG_ERROR(sizes of long and void* are not identical)
 261 fi
 262
 263 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 264   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 265 else
 266   SCM_I_GSC_T_PTRDIFF='"long"'
 267 fi
 268 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 269
 270 AC_CHECK_HEADERS([stdint.h])
 271 AC_CHECK_HEADERS([inttypes.h])
 272
 273 AC_CHECK_SIZEOF(intmax_t)
 274
 275 SCM_I_GSC_NEEDS_STDINT_H=0
 276 SCM_I_GSC_NEEDS_INTTYPES_H=0
 277
 278 ### intptr and uintptr (try not to use inttypes if we don't have to)
 279 if test "$ac_cv_header_inttypes_h" = yes; then
 280   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 281     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 282 #include <stdio.h>])
 283     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 284       SCM_I_GSC_NEEDS_INTTYPES_H=1
 285     fi
 286   fi
 287   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 288     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 289 #include <stdio.h>])
 290     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 291       SCM_I_GSC_NEEDS_INTTYPES_H=1
 292     fi
 293   fi
 294 fi
 295
 296 ### See what's provided by stdint.h
 297 if test "$ac_cv_header_stdint_h" = yes; then
 298    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 299    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 300    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 301    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 302    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 303    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 304    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 305    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 306    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 307    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 308 fi
 309
 310 # so we don't get confused by the cache (wish there was a better way
 311 # to check particular headers for the same type...)
 312
 313 unset ac_cv_type_int8_t
 314 unset ac_cv_type_uint8_t
 315 unset ac_cv_type_int16_t
 316 unset ac_cv_type_uint16_t
 317 unset ac_cv_type_int32_t
 318 unset ac_cv_type_uint32_t
 319 unset ac_cv_type_int64_t
 320 unset ac_cv_type_uint64_t
 321 unset ac_cv_type_intmax_t
 322 unset ac_cv_type_uintmax_t
 323
 324 ### See what's provided by inttypes.h
 325 if test "$ac_cv_header_inttypes_h" = yes; then
 326   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 327   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 328   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 329   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 330   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 331   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 332   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 333   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 334   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 335   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 336 fi
 337
 338 # Try hard to find definitions for some required scm_t_*int* types.
 339
 340 ### Required type scm_t_int8
 341 if test "$scm_stdint_has_int8"; then
 342   SCM_I_GSC_T_INT8='"int8_t"'
 343   SCM_I_GSC_NEEDS_STDINT_H=1
 344 elif test "$scm_inttypes_has_int8"; then
 345   SCM_I_GSC_T_INT8='"int8_t"'
 346   SCM_I_GSC_NEEDS_INTTYPES_H=1
 347 elif test "$ac_cv_sizeof_char" -eq 1; then
 348   SCM_I_GSC_T_INT8='"signed char"'
 349 else
 350   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 351 fi
 352 AC_SUBST([SCM_I_GSC_T_INT8])
 353
 354 ### Required type scm_t_uint8
 355 if test "$scm_stdint_has_uint8"; then
 356   SCM_I_GSC_T_UINT8='"uint8_t"'
 357   SCM_I_GSC_NEEDS_STDINT_H=1
 358 elif test "$scm_inttypes_has_uint8"; then
 359   SCM_I_GSC_T_UINT8='"uint8_t"'
 360   SCM_I_GSC_NEEDS_INTTYPES_H=1
 361 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 362   SCM_I_GSC_T_UINT8='"unsigned char"'
 363 else
 364   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 365 fi
 366 AC_SUBST([SCM_I_GSC_T_UINT8])
 367
 368 ### Required type scm_t_int16 (ANSI C says int or short might work)
 369 if test "$scm_stdint_has_int16"; then
 370   SCM_I_GSC_T_INT16='"int16_t"'
 371   SCM_I_GSC_NEEDS_STDINT_H=1
 372 elif test "$scm_inttypes_has_int16"; then
 373   SCM_I_GSC_T_INT16='"int16_t"'
 374   SCM_I_GSC_NEEDS_INTTYPES_H=1
 375 elif test "$ac_cv_sizeof_int" -eq 2; then
 376   SCM_I_GSC_T_INT16='"int"'
 377 elif test "$ac_cv_sizeof_short" -eq 2; then
 378   SCM_I_GSC_T_INT16='"short"'
 379 else
 380   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 381 fi
 382 AC_SUBST([SCM_I_GSC_T_INT16])
 383
 384 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 385 if test "$scm_stdint_has_uint16"; then
 386   SCM_I_GSC_T_UINT16='"uint16_t"'
 387   SCM_I_GSC_NEEDS_STDINT_H=1
 388 elif test "$scm_inttypes_has_uint16"; then
 389   SCM_I_GSC_T_UINT16='"uint16_t"'
 390   SCM_I_GSC_NEEDS_INTTYPES_H=1
 391 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 392   SCM_I_GSC_T_UINT16='"unsigned int"'
 393 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 394   SCM_I_GSC_T_UINT16='"unsigned short"'
 395 else
 396   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 397 fi
 398 AC_SUBST([SCM_I_GSC_T_UINT16])
 399
 400
 401 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 402 if test "$scm_stdint_has_int32"; then
 403   SCM_I_GSC_T_INT32='"int32_t"'
 404   SCM_I_GSC_NEEDS_STDINT_H=1
 405 elif test "$scm_inttypes_has_int32"; then
 406   SCM_I_GSC_T_INT32='"int32_t"'
 407   SCM_I_GSC_NEEDS_INTTYPES_H=1
 408 elif test "$ac_cv_sizeof_int" -eq 4; then
 409   SCM_I_GSC_T_INT32='"int"'
 410 elif test "$ac_cv_sizeof_long" -eq 4; then
 411   SCM_I_GSC_T_INT32='"long"'
 412 elif test "$ac_cv_sizeof_short" -eq 4; then
 413   SCM_I_GSC_T_INT32='"short"'
 414 else
 415   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 416 fi
 417 AC_SUBST([SCM_I_GSC_T_INT32])
 418
 419 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 420 if test "$scm_stdint_has_uint32"; then
 421   SCM_I_GSC_T_UINT32='"uint32_t"'
 422   SCM_I_GSC_NEEDS_STDINT_H=1
 423 elif test "$scm_inttypes_has_uint32"; then
 424   SCM_I_GSC_T_UINT32='"uint32_t"'
 425   SCM_I_GSC_NEEDS_INTTYPES_H=1
 426 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 427   SCM_I_GSC_T_UINT32='"unsigned int"'
 428 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 429   SCM_I_GSC_T_UINT32='"unsigned long"'
 430 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 431   SCM_I_GSC_T_UINT32='"unsigned short"'
 432 else
 433   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 434 fi
 435 AC_SUBST([SCM_I_GSC_T_UINT32])
 436
 437 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 438 ### Also try 'long long' and '__int64' if we have it.
 439 SCM_I_GSC_T_INT64=0
 440 if test "$scm_stdint_has_int64"; then
 441   SCM_I_GSC_T_INT64='"int64_t"'
 442   SCM_I_GSC_NEEDS_STDINT_H=1
 443 elif test "$scm_inttypes_has_int64"; then
 444   SCM_I_GSC_T_INT64='"int64_t"'
 445   SCM_I_GSC_NEEDS_INTTYPES_H=1
 446 elif test "$ac_cv_sizeof_int" -eq 8; then
 447   SCM_I_GSC_T_INT64='"int"'
 448 elif test "$ac_cv_sizeof_long" -eq 8; then
 449   SCM_I_GSC_T_INT64='"long"'
 450 elif test "$ac_cv_sizeof_short" -eq 8; then
 451   SCM_I_GSC_T_INT64='"short"'
 452 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 453   SCM_I_GSC_T_INT64='"long long"'
 454 elif test "$ac_cv_sizeof___int64" -eq 8; then
 455   SCM_I_GSC_T_INT64='"__int64"'
 456 else
 457   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 458 fi
 459 AC_SUBST([SCM_I_GSC_T_INT64])
 460
 461
 462 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 463 ### Also try 'long long' and '__int64' if we have it.
 464 SCM_I_GSC_T_UINT64=0
 465 if test "$scm_stdint_has_uint64"; then
 466   SCM_I_GSC_T_UINT64='"uint64_t"'
 467   SCM_I_GSC_NEEDS_STDINT_H=1
 468 elif test "$scm_inttypes_has_uint64"; then
 469   SCM_I_GSC_T_UINT64='"uint64_t"'
 470   SCM_I_GSC_NEEDS_INTTYPES_H=1
 471 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 472   SCM_I_GSC_T_UINT64='"unsigned int"'
 473 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 474   SCM_I_GSC_T_UINT64='"unsigned long"'
 475 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 476   SCM_I_GSC_T_UINT64='"unsigned short"'
 477 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 478   SCM_I_GSC_T_UINT64='"unsigned long long"'
 479 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 480   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 481 else
 482   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 483 fi
 484 AC_SUBST([SCM_I_GSC_T_UINT64])
 485
 486 ### Required type scm_t_intmax
 487 ###
 488 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 489 ### none of them is available, we use 'long'.
 490 ###
 491 SCM_I_GSC_T_INTMAX=0
 492 if test "$scm_stdint_has_intmax"; then
 493   SCM_I_GSC_T_INTMAX='"intmax_t"'
 494   SCM_I_GSC_NEEDS_STDINT_H=1
 495 elif test "$scm_inttypes_has_intmax"; then
 496   SCM_I_GSC_T_INTMAX='"intmax_t"'
 497   SCM_I_GSC_NEEDS_INTTYPES_H=1
 498 elif test "$ac_cv_sizeof___int64" -ne 0; then
 499   SCM_I_GSC_T_INTMAX='"__int64"'
 500 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 501   SCM_I_GSC_T_INTMAX='"long long"'
 502 else
 503   SCM_I_GSC_T_INTMAX='"long"'
 504 fi
 505 AC_SUBST([SCM_I_GSC_T_INTMAX])
 506
 507 ### Required type scm_t_uintmax
 508 ###
 509 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 510 ### this order.  When none of them is available, we use 'unsigned long'.
 511 ###
 512 SCM_I_GSC_T_UINTMAX=0
 513 if test "$scm_stdint_has_uintmax"; then
 514   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 515   SCM_I_GSC_NEEDS_STDINT_H=1
 516 elif test "$scm_inttypes_has_uintmax"; then
 517   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 518   SCM_I_GSC_NEEDS_INTTYPES_H=1
 519 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 520   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 521 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 522   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 523 else
 524   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 525 fi
 526 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 527
 528
 529 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 530 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 531
 532 AC_HEADER_STDC
 533 AC_HEADER_DIRENT
 534 AC_HEADER_TIME
 535 AC_HEADER_SYS_WAIT
 536
 537 # Reasons for testing:
 538 #   fenv.h - available in C99, but not older systems
 539 #
 540 AC_CHECK_HEADERS([fenv.h io.h libc.h limits.h malloc.h memory.h string.h \
 541 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 542 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 543 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 544 direct.h])
 545
 546 GUILE_HEADER_LIBC_WITH_UNISTD
 547
 548 AC_TYPE_GETGROUPS
 549 AC_TYPE_SIGNAL
 550 AC_TYPE_MODE_T
 551
 552 if test $MINGW32 = no; then
 553         AC_CHECK_LIB(m, main)
 554 fi
 555 AC_CHECK_FUNCS(gethostbyname)
 556 if test $ac_cv_func_gethostbyname = no; then
 557     AC_CHECK_LIB(nsl, gethostbyname)
 558 fi
 559
 560 AC_CHECK_FUNCS(connect)
 561 if test $ac_cv_func_connect = no; then
 562     AC_CHECK_LIB(socket, connect)
 563 fi
 564
 565 dnl
 566 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 567 dnl
 568 EXTRA_DEFS=""
 569 if test "$MINGW32" = "yes" ; then
 570     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 571       [Define if you have the <winsock2.h> header file.])])
 572     AC_CHECK_LIB(ws2_32, main)
 573     AC_LIBOBJ([win32-uname])
 574     AC_LIBOBJ([win32-dirent])
 575     if test "$enable_networking" = yes ; then
 576       AC_LIBOBJ([win32-socket])
 577     fi
 578     if test "$enable_shared" = yes ; then
 579       EXTRA_DEFS="-DSCM_IMPORT"
 580       AC_DEFINE(USE_DLL_IMPORT, 1,
 581         [Define if you need additional CPP macros on Win32 platforms.])
 582     fi
 583     if test x"$enable_ltdl_install" = x"yes" ; then
 584       INCLTDL="-DLIBLTDL_DLL_IMPORT $INCLTDL"
 585     fi
 586 fi
 587 AC_SUBST(EXTRA_DEFS)
 588
 589 # Reasons for testing:
 590 #   crt_externs.h - Darwin specific
 591 #
 592 AC_CHECK_HEADERS([assert.h crt_externs.h])
 593
 594 # Reasons for testing:
 595 #   DINFINITY - OSF specific
 596 #   DQNAN - OSF specific
 597 #       (DINFINITY and DQNAN are actually global variables, not functions)
 598 #   fesetround - available in C99, but not older systems
 599 #   gmtime_r - recent posix, not on old systems
 600 #   readdir_r - recent posix, not on old systems
 601 #   sysconf - not on old systems
 602 #   _NSGetEnviron - Darwin specific
 603 #
 604 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid fesetround ftime fchown getcwd geteuid gettimeofday gmtime_r lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv _NSGetEnviron])
 605
 606 # Reasons for testing:
 607 #   netdb.h - not in mingw
 608 #   sys/param.h - not in mingw
 609 #
 610 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 611 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 612
 613 # crypt() may or may not be available, for instance in some countries there
 614 # are restrictions on cryptography.
 615 #
 616 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 617 # -lcrypt library (eg. Debian GNU/Linux).
 618 #
 619 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 620 # be careful to avoid -lcrypt in this case, since libtool will see there's
 621 # only a static libcrypt and decide to build only a static libguile.
 622 #
 623 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 624 # libraries already in that list.
 625 #
 626 AC_SEARCH_LIBS(crypt, crypt,
 627   [AC_DEFINE(HAVE_CRYPT,1,
 628              [Define to 1 if you have the `crypt' function.])])
 629
 630 dnl GMP tests
 631 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 632   [AC_MSG_ERROR([GNU MP not found, see http://swox.com/gmp])])
 633
 634 # mpz_import is a macro so we need to include <gmp.h>
 635 AC_TRY_LINK([#include <gmp.h>],
 636             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 637   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see http://swox.com/gmp])])
 638
 639 dnl i18n tests
 640 #AC_CHECK_HEADERS([libintl.h])
 641 #AC_CHECK_FUNCS(gettext)
 642 #if test $ac_cv_func_gettext = no; then
 643 #   AC_CHECK_LIB(intl, gettext)
 644 #fi
 645 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 646 AM_GNU_GETTEXT([external], [need-ngettext])
 647
 648 ### Some systems don't declare some functions.  On such systems, we
 649 ### need to at least provide our own K&R-style declarations.
 650
 651 ### GUILE_FUNC_DECLARED(function, headerfile)
 652
 653 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 654 ### not there, #define MISSING_FUNCTION_DECL.
 655 AC_DEFUN([GUILE_FUNC_DECLARED], [
 656   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 657     AC_EGREP_HEADER($1, $2,
 658                     guile_cv_func_$1_declared=yes,
 659                     guile_cv_func_$1_declared=no))
 660   if test [x$guile_cv_func_]$1[_declared] = xno; then
 661     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 662       [Define if the operating system supplies $1 without declaring it.])
 663   fi
 664 ])
 665
 666 GUILE_FUNC_DECLARED(sleep, unistd.h)
 667 GUILE_FUNC_DECLARED(usleep, unistd.h)
 668
 669 AC_CHECK_DECLS([strptime],,,
 670 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 671 #include <time.h>])
 672
 673 ### On some systems usleep has no return value.  If it does have one,
 674 ### we'd like to return it; otherwise, we'll fake it.
 675 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 676   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 677                    unistd.h,
 678                    [guile_cv_func_usleep_return_type=void],
 679                    [guile_cv_func_usleep_return_type=int])])
 680 case "$guile_cv_func_usleep_return_type" in
 681   "void" )
 682     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 683       [Define if the system headers declare usleep to return void.])
 684   ;;
 685 esac
 686
 687 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 688 if test -n "$have_sys_un_h" ; then
 689   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 690     [Define if the system supports Unix-domain (file-domain) sockets.])
 691 fi
 692
 693 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 694
 695 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 696                setnetent    getnetent    endnetent    dnl
 697                setprotoent  getprotoent  endprotoent  dnl
 698                setservent   getservent   endservent   dnl
 699                getnetbyaddr getnetbyname dnl
 700                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 701                inet_pton inet_ntop)
 702
 703 # struct sockaddr field sin_len is only present on BSD systems.
 704 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 705 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 706 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 707 [#ifdef HAVE_SYS_TYPES_H
 708 #include <sys/types.h>
 709 #endif
 710 #include <netinet/in.h>])
 711
 712 AC_MSG_CHECKING(for __libc_stack_end)
 713 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 714 [AC_TRY_LINK([#include <stdio.h>
 715 extern char *__libc_stack_end;],
 716              [printf("%p", (char*) __libc_stack_end);],
 717              guile_cv_have_libc_stack_end=yes,
 718              guile_cv_have_libc_stack_end=no)])
 719 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 720
 721 if test $guile_cv_have_libc_stack_end = yes; then
 722   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 723            [Define if you have the __libc_stack_end variable.])
 724 fi
 725
 726 dnl Some systems do not declare this.  Some systems do declare it, as a
 727 dnl macro.  With cygwin it may be in a DLL.
 728
 729 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 730 AC_CACHE_VAL(guile_cv_have_h_errno,
 731 [AC_TRY_COMPILE([#include <netdb.h>],
 732 [int a = h_errno;],
 733 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 734 AC_MSG_RESULT($guile_cv_have_h_errno)
 735 if test $guile_cv_have_h_errno = yes; then
 736   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 737 fi
 738
 739 AC_MSG_CHECKING(whether uint32_t is defined)
 740 AC_CACHE_VAL(guile_cv_have_uint32_t,
 741   [AC_TRY_COMPILE([#include <sys/types.h>
 742                    #if HAVE_STDINT_H
 743                    #include <stdint.h>
 744                    #endif
 745                    #ifndef __MINGW32__
 746                    #include <netdb.h>
 747                    #endif],
 748                   [uint32_t a;],
 749                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 750 AC_MSG_RESULT($guile_cv_have_uint32_t)
 751 if test $guile_cv_have_uint32_t = yes; then
 752   AC_DEFINE(HAVE_UINT32_T, 1,
 753     [Define if uint32_t typedef is defined when netdb.h is include.])
 754 fi
 755
 756 AC_MSG_CHECKING(for working IPv6 support)
 757 AC_CACHE_VAL(guile_cv_have_ipv6,
 758 [AC_TRY_COMPILE([
 759 #ifdef HAVE_SYS_TYPES_H
 760 #include <sys/types.h>
 761 #endif
 762 #include <netinet/in.h>
 763 #include <sys/socket.h>],
 764 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 765 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 766 AC_MSG_RESULT($guile_cv_have_ipv6)
 767 if test $guile_cv_have_ipv6 = yes; then
 768   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 769 fi
 770
 771 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 772 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 773 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 774 [AC_TRY_COMPILE([
 775 #ifdef HAVE_SYS_TYPES_H
 776 #include <sys/types.h>
 777 #endif
 778 #include <netinet/in.h>],
 779 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 780 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 781 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 782 if test $guile_cv_have_sin6_scope_id = yes; then
 783   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 784     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 785 fi
 786
 787 # struct sockaddr_in6 field sin_len is only present on BSD systems
 788 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 789 [#ifdef HAVE_SYS_TYPES_H
 790 #include <sys/types.h>
 791 #endif
 792 #include <netinet/in.h>])
 793
 794 AC_MSG_CHECKING(whether localtime caches TZ)
 795 AC_CACHE_VAL(guile_cv_localtime_cache,
 796 [if test x$ac_cv_func_tzset = xyes; then
 797 AC_TRY_RUN([#include <time.h>
 798 #if STDC_HEADERS
 799 # include <stdlib.h>
 800 #endif
 801 extern char **environ;
 802 unset_TZ ()
 803 {
 804   char **from, **to;
 805   for (to = from = environ; (*to = *from); from++)
 806     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 807       to++;
 808 }
 809 char TZ_GMT0[] = "TZ=GMT0";
 810 char TZ_PST8[] = "TZ=PST8";
 811 main()
 812 {
 813   time_t now = time ((time_t *) 0);
 814   int hour_GMT0, hour_unset;
 815   if (putenv (TZ_GMT0) != 0)
 816     exit (1);
 817   hour_GMT0 = localtime (&now)->tm_hour;
 818   unset_TZ ();
 819   hour_unset = localtime (&now)->tm_hour;
 820   if (putenv (TZ_PST8) != 0)
 821     exit (1);
 822   if (localtime (&now)->tm_hour == hour_GMT0)
 823     exit (1);
 824   unset_TZ ();
 825   if (localtime (&now)->tm_hour != hour_unset)
 826     exit (1);
 827   exit (0);
 828 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 829 [# If we have tzset, assume the worst when cross-compiling.
 830 guile_cv_localtime_cache=yes])
 831 else
 832         # If we lack tzset, report that localtime does not cache TZ,
 833         # since we can't invalidate the cache if we don't have tzset.
 834         guile_cv_localtime_cache=no
 835 fi])dnl
 836 AC_MSG_RESULT($guile_cv_localtime_cache)
 837 if test $guile_cv_localtime_cache = yes; then
 838   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 839 fi
 840
 841 dnl Test whether system calls are restartable by default on the
 842 dnl current system.  If they are not, we put a loop around every system
 843 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 844 dnl change from the default behaviour.  On the other hand, if signals
 845 dnl are restartable then the loop is not installed and when libguile
 846 dnl initialises it also resets the behaviour of each signal to cause a
 847 dnl restart (in case a different runtime had a different default
 848 dnl behaviour for some reason: e.g., different versions of linux seem
 849 dnl to behave differently.)
 850
 851 AC_SYS_RESTARTABLE_SYSCALLS
 852
 853 if test "$enable_regex" = yes; then
 854    if test "$ac_cv_header_regex_h" = yes ||
 855       test "$ac_cv_header_rxposix_h" = yes ||
 856       test "$ac_cv_header_rx_rxposix_h" = yes; then
 857      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 858      [AC_CHECK_LIB(rx, main)
 859       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 860      [AC_CHECK_LIB(regex, main)
 861       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 862      )
 863      dnl The following should not be necessary, but for some reason
 864      dnl autoheader misses it if we don't include it!
 865      if test "$ac_cv_func_regcomp_norx" = yes ||
 866         test "$ac_cv_func_regcomp_regex" = yes ||
 867         test "$ac_cv_func_regcomp_rx" = yes; then
 868        AC_DEFINE(HAVE_REGCOMP, 1,
 869          [This is included as part of a workaround for a autoheader bug.])
 870      fi
 871    fi
 872 fi
 873
 874 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 875
 876 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 877
 878 # Reasons for testing:
 879 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 880 #                                older systems
 881 #   sincos - GLIBC extension
 882 #
 883 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
 884
 885 # C99 specifies isinf and isnan as macros.
 886 # HP-UX provides only macros, no functions.
 887 # glibc 2.3.2 provides both macros and functions.
 888 # IRIX 6.5 and Solaris 8 only provide functions.
 889 #
 890 # The following tests detect isinf and isnan either as functions or as
 891 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
 892 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
 893 #
 894 AC_MSG_CHECKING([for isinf])
 895 AC_LINK_IFELSE(
 896 [#include <math.h>
 897 int main () { return (isinf(0.0) != 0); }],
 898   [AC_MSG_RESULT([yes])
 899    AC_DEFINE(HAVE_ISINF, 1,
 900              [Define to 1 if you have the `isinf' macro or function.])],
 901   [AC_MSG_RESULT([no])])
 902 AC_MSG_CHECKING([for isnan])
 903 AC_LINK_IFELSE(
 904 [#include <math.h>
 905 #ifdef __MINGW32__
 906 #define isnan _isnan
 907 #endif
 908 int main () { return (isnan(0.0) != 0); }],
 909   [AC_MSG_RESULT([yes])
 910    AC_DEFINE(HAVE_ISNAN, 1,
 911              [Define to 1 if you have the `isnan' macro or function.])],
 912   [AC_MSG_RESULT([no])])
 913
 914 # We must have a proper stack-using alloca in order for stack-copying
 915 # continuations to work properly.  If we don't find a native one,
 916 # abort.
 917
 918 AC_FUNC_ALLOCA
 919 if test "$ALLOCA" = "alloca.o"
 920 then
 921   AC_ERROR([No native alloca found.])
 922 fi
 923
 924 AC_CHECK_MEMBERS([struct stat.st_rdev])
 925 AC_CHECK_MEMBERS([struct stat.st_blksize])
 926
 927 AC_STRUCT_ST_BLOCKS
 928
 929 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 930   [AC_TRY_CPP([#include <sys/stat.h>
 931                #ifndef S_ISLNK
 932                #error no S_ISLNK
 933                #endif],
 934                ac_cv_macro_S_ISLNK=yes,
 935                ac_cv_macro_S_ISLNK=no)])
 936 if test $ac_cv_macro_S_ISLNK = yes; then
 937   AC_DEFINE(HAVE_S_ISLNK, 1,
 938     [Define this if your system defines S_ISLNK in sys/stat.h.])
 939 fi
 940
 941 AC_STRUCT_TIMEZONE
 942 GUILE_STRUCT_UTIMBUF
 943
 944 #--------------------------------------------------------------------
 945 #
 946 # Which way does the stack grow?
 947 #
 948 #--------------------------------------------------------------------
 949
 950 SCM_I_GSC_STACK_GROWS_UP=0
 951 AC_TRY_RUN(aux (l) unsigned long l;
 952              { int x; exit (l >= ((unsigned long)&x)); }
 953            main () { int q; aux((unsigned long)&q); },
 954            [SCM_I_GSC_STACK_GROWS_UP=1],
 955            [],
 956            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
 957
 958 AC_CHECK_SIZEOF(float)
 959 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
 960     AC_DEFINE(SCM_SINGLES, 1,
 961               [Define this if floats are the same size as longs.])
 962 fi
 963
 964 AC_MSG_CHECKING(for struct linger)
 965 AC_CACHE_VAL(scm_cv_struct_linger,
 966         AC_TRY_COMPILE([
 967 #include <sys/types.h>
 968 #include <sys/socket.h>],
 969                         [struct linger lgr;  lgr.l_linger = 100],
 970                         scm_cv_struct_linger="yes",
 971                         scm_cv_struct_linger="no"))
 972 AC_MSG_RESULT($scm_cv_struct_linger)
 973 if test $scm_cv_struct_linger = yes; then
 974         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 975           [Define this if your system defines struct linger, for use with the
 976            getsockopt and setsockopt system calls.])
 977 fi
 978
 979
 980 AC_MSG_CHECKING(for struct timespec)
 981 AC_CACHE_VAL(scm_cv_struct_timespec,
 982         AC_TRY_COMPILE([
 983 #include <time.h>],
 984                         [struct timespec t;  t.tv_nsec = 100],
 985                         scm_cv_struct_timespec="yes",
 986                         scm_cv_struct_timespec="no"))
 987 AC_MSG_RESULT($scm_cv_struct_timespec)
 988 if test $scm_cv_struct_timespec = yes; then
 989   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 990     [Define this if your system defines struct timespec via <time.h>.])
 991 fi
 992
 993 #--------------------------------------------------------------------
 994 #
 995 # Flags for thread support
 996 #
 997 #--------------------------------------------------------------------
 998
 999 SCM_I_GSC_USE_PTHREAD_THREADS=0
1000 SCM_I_GSC_USE_NULL_THREADS=0
1001 SCM_I_GSC_USE_COOP_THREADS=0
1002 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1003 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1004 AC_SUBST([SCM_I_GSC_USE_COOP_THREADS])
1005
1006 ### What thread package has the user asked for?
1007 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1008             , with_threads=yes)
1009
1010 case "$with_threads" in
1011   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1012     ACX_PTHREAD(CC="$PTHREAD_CC"
1013       LIBS="$PTHREAD_LIBS $LIBS"
1014       SCM_I_GSC_USE_PTHREAD_THREADS=1
1015       with_threads="pthreads",
1016       with_threads="null")
1017
1018     AC_MSG_CHECKING(if pthread_mutexattr_settype is declared)
1019     AC_CACHE_VAL(guile_cv_mutexattr_settype_declared,
1020       [AC_TRY_COMPILE([#include <pthread.h>],
1021           [int pthread_mutexattr_settype (int, int);],
1022           guile_cv_mutexattr_settype_declared=no,
1023           guile_cv_mutexattr_settype_declared=yes)])
1024     AC_MSG_RESULT($guile_cv_mutexattr_settype_declared)
1025     if test $guile_cv_mutexattr_settype_declared = yes; then
1026       AC_DEFINE(SCM_MUTEXATTR_SETTYPE_DECLARED, 1,
1027           [Define if pthread.h declares pthread_mutexattr_settype.])
1028     fi
1029
1030     AC_MSG_CHECKING(how to get a fast mutex)
1031     AC_CACHE_VAL(guile_cv_have_mutex_fast,
1032       [AC_TRY_COMPILE([#include <pthread.h>],
1033           [int a = PTHREAD_MUTEX_ADAPTIVE_NP;],
1034           guile_cv_have_mutex_fast=PTHREAD_MUTEX_ADAPTIVE_NP,
1035           guile_cv_have_mutex_fast=none)])
1036     AC_MSG_RESULT($guile_cv_have_mutex_fast)
1037     if test ! $guile_cv_have_mutex_fast = none; then
1038       AC_DEFINE_UNQUOTED(SCM_MUTEX_FAST, $guile_cv_have_mutex_fast,
1039           [The mutex kind enum for fast mutexes.])
1040     fi
1041
1042     AC_MSG_CHECKING(how to get a recursive mutex)
1043     AC_CACHE_VAL(guile_cv_have_mutex_recursive,
1044       [AC_TRY_COMPILE([#include <pthread.h>],
1045         [int a = PTHREAD_MUTEX_RECURSIVE_NP;],
1046          guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE_NP)
1047       if test -z "$guile_cv_have_mutex_recursive"; then
1048           AC_TRY_COMPILE([#include <pthread.h>],
1049             [int a = PTHREAD_MUTEX_RECURSIVE;],
1050             guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE,
1051             guile_cv_have_mutex_recursive=none)
1052         fi])
1053     AC_MSG_RESULT($guile_cv_have_mutex_recursive)
1054     if test ! $guile_cv_have_mutex_recursive = none; then
1055       AC_DEFINE_UNQUOTED(SCM_MUTEX_RECURSIVE, $guile_cv_have_mutex_recursive,
1056          [The mutex kind enum for recursive mutexes.])
1057     fi
1058
1059     # On Solaris, sched_yield lives in -lrt.
1060     AC_SEARCH_LIBS(sched_yield, rt)
1061
1062   ;;
1063 esac
1064
1065 case "$with_threads" in
1066   "pthreads")
1067   ;;
1068   "no" | "null")
1069     SCM_I_GSC_USE_NULL_THREADS=1
1070     with_threads="null-threads"
1071   ;;
1072   * )
1073     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1074   ;;
1075 esac
1076
1077 AC_MSG_CHECKING(what kind of threads to support)
1078 AC_MSG_RESULT($with_threads)
1079
1080 ## Cross building
1081 if test "$cross_compiling" = "yes"; then
1082   AC_MSG_CHECKING(cc for build)
1083   ## /usr/bin/cc still uses wrong assembler
1084   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1085   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1086 else
1087   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1088 fi
1089
1090 ## AC_MSG_CHECKING("if we are cross compiling")
1091 ## AC_MSG_RESULT($cross_compiling)
1092 if test "$cross_compiling" = "yes"; then
1093    AC_MSG_RESULT($CC_FOR_BUILD)
1094 fi
1095
1096 ## No need as yet to be more elaborate
1097 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1098
1099 AC_SUBST(cross_compiling)
1100 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1101 AC_SUBST(CCLD_FOR_BUILD)
1102
1103 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1104 ## --HOST is the platform that PACKAGE is compiled for.
1105 HOST_CC="$CC_FOR_BUILD"
1106 AC_SUBST(HOST_CC)
1107
1108 if test "$cross_compiling" = "yes"; then
1109   AC_MSG_CHECKING(guile for build)
1110   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1111 else
1112   GUILE_FOR_BUILD='$(preinstguile)'
1113 fi
1114
1115 ## AC_MSG_CHECKING("if we are cross compiling")
1116 ## AC_MSG_RESULT($cross_compiling)
1117 if test "$cross_compiling" = "yes"; then
1118    AC_MSG_RESULT($GUILE_FOR_BUILD)
1119 fi
1120 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1121 AC_SUBST(GUILE_FOR_BUILD)
1122
1123 ## If we're using GCC, ask for aggressive warnings.
1124 case "$GCC" in
1125   yes )
1126     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1127     ## much stuff with generic function pointers for that to really be
1128     ## less than exasperating.
1129     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1130     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1131     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1132     # Do this here so we don't screw up any of the tests above that might
1133     # not be "warning free"
1134     if test "${GUILE_ERROR_ON_WARNING}" = yes
1135     then
1136         CFLAGS="${CFLAGS} -Werror"
1137         enable_compile_warnings=no
1138     fi
1139     ;;
1140 esac
1141
1142 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
1143 ## -- I'm disabling it for now in the hopes that the newer autoconf
1144 ## will DTRT -- if not, we need to fix up the sed command to match the
1145 ## others...
1146 ##
1147 ## Remove fileblocks.o from the object list.  This file gets added by
1148 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
1149 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
1150
1151 ## If we're creating a shared library (using libtool!), then we'll
1152 ## need to generate a list of .lo files corresponding to the .o files
1153 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1154 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1155
1156 ## We also need to create corresponding .doc and .x files
1157 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1158 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1159
1160 AC_SUBST(GUILE_MAJOR_VERSION)
1161 AC_SUBST(GUILE_MINOR_VERSION)
1162 AC_SUBST(GUILE_MICRO_VERSION)
1163 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1164 AC_SUBST(GUILE_VERSION)
1165
1166 #######################################################################
1167 # library versioning
1168
1169 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1170 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1171 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1172 AC_SUBST(LIBGUILE_INTERFACE)
1173
1174 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1175 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1176 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1177 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1178 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1179
1180 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1181 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1182 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1183 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1184 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1185
1186 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1187 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1188 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1189 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1190 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1191
1192 #######################################################################
1193
1194 dnl Tell guile-config what flags guile users should compile and link with.
1195 GUILE_LIBS="$LDFLAGS $LIBS"
1196 GUILE_CFLAGS="$PTHREAD_CFLAGS"
1197 AC_SUBST(GUILE_LIBS)
1198 AC_SUBST(GUILE_CFLAGS)
1199
1200 AC_SUBST(AWK)
1201 AC_SUBST(LIBLOBJS)
1202 AC_SUBST(EXTRA_DOT_DOC_FILES)
1203 AC_SUBST(EXTRA_DOT_X_FILES)
1204
1205 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1206 top_builddir_absolute=`pwd`
1207 AC_SUBST(top_builddir_absolute)
1208 top_srcdir_absolute=`(cd $srcdir && pwd)`
1209 AC_SUBST(top_srcdir_absolute)
1210
1211 # Additional SCM_I_GSC definitions are above.
1212 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1213 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1214 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1215 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1216 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1217 AC_SUBST([SCM_I_GSC_HAVE_ARRAYS])
1218 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1219 AC_SUBST([SCM_I_GSC_C_INLINE])
1220 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1221
1222 AC_CONFIG_FILES([
1223   Makefile
1224   am/Makefile
1225   benchmark-suite/Makefile
1226   doc/Makefile
1227   doc/goops/Makefile
1228   doc/r5rs/Makefile
1229   doc/ref/Makefile
1230   doc/tutorial/Makefile
1231   emacs/Makefile
1232   examples/Makefile
1233   examples/box-dynamic-module/Makefile
1234   examples/box-dynamic/Makefile
1235   examples/box-module/Makefile
1236   examples/box/Makefile
1237   examples/modules/Makefile
1238   examples/safe/Makefile
1239   examples/scripts/Makefile
1240   guile-config/Makefile
1241   ice-9/Makefile
1242   ice-9/debugger/Makefile
1243   ice-9/debugger/breakpoints/Makefile
1244   lang/Makefile
1245   lang/elisp/Makefile
1246   lang/elisp/internals/Makefile
1247   lang/elisp/primitives/Makefile
1248   libguile/Makefile
1249   oop/Makefile
1250   oop/goops/Makefile
1251   scripts/Makefile
1252   srfi/Makefile
1253   test-suite/Makefile
1254   test-suite/standalone/Makefile
1255 ])
1256
1257 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1258 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1259 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1260 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1261 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1262 AC_CONFIG_FILES([libguile/guile-snarf],
1263                 [chmod +x libguile/guile-snarf])
1264 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1265                 [chmod +x libguile/guile-doc-snarf])
1266 AC_CONFIG_FILES([libguile/guile-func-name-check],
1267                 [chmod +x libguile/guile-func-name-check])
1268 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1269                 [chmod +x libguile/guile-snarf-docs])
1270
1271 AC_OUTPUT
1272
1273 dnl Local Variables:
1274 dnl comment-start: "dnl "
1275 dnl comment-end: ""
1276 dnl comment-start-skip: "\\bdnl\\b\\s *"
1277 dnl End: