1 dnl configuration script for Guile
2 dnl Process this file with autoconf to produce configure.
5 define(GUILE_CONFIGURE_COPYRIGHT,[[
7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
9 This file is part of GUILE
11 GUILE is free software; you can redistribute it and/or modify it
12 under the terms of the GNU General Public License as published by
13 the Free Software Foundation; either version 2, or (at your
14 option) any later version.
16 GUILE is distributed in the hope that it will be useful, but
17 WITHOUT ANY WARRANTY; without even the implied warranty of
18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
19 General Public License for more details.
21 You should have received a copy of the GNU General Public License
22 along with GUILE; see the file COPYING. If not, write to the
23 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
24 Boston, MA 02111-1307, USA.
30 AC_INIT(m4_esyscmd(. ./GUILE-VERSION && echo -n ${PACKAGE}),
31 m4_esyscmd(. ./GUILE-VERSION && echo -n ${GUILE_VERSION}))
32 AC_CONFIG_SRCDIR(GUILE-VERSION)
33 AM_INIT_AUTOMAKE([no-define])
35 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
36 AC_CONFIG_SRCDIR([GUILE-VERSION])
38 . $srcdir/GUILE-VERSION
41 AM_CONFIG_HEADER([config.h])
42 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
44 #--------------------------------------------------------------------
46 # Independent Subdirectories
48 #--------------------------------------------------------------------
50 AC_CONFIG_SUBDIRS(guile-readline)
52 #--------------------------------------------------------------------
54 dnl Some more checks for Win32
74 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
75 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
79 #--------------------------------------------------------------------
81 # User options (after above tests that may set default CFLAGS etc.)
83 #--------------------------------------------------------------------
85 GUILE_ERROR_ON_WARNING="yes"
87 AC_ARG_ENABLE(error-on-warning,
88 [ --enable-error-on-warning treat compile warnings as errors],
89 [case "${enableval}" in
90 yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
91 no | n) GUILE_ERROR_ON_WARNING="no" ;;
92 *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
95 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
96 AC_ARG_ENABLE(debug-freelist,
97 [ --enable-debug-freelist include garbage collector freelist debugging code],
98 if test "$enable_debug_freelist" = y \
99 || test "$enable_debug_freelist" = yes; then
100 SCM_I_GSC_GUILE_DEBUG_FREELIST=1
103 AC_ARG_ENABLE(debug-malloc,
104 [ --enable-debug-malloc include malloc debugging code],
105 if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
106 AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
107 [Define this if you want to debug scm_must_malloc/realloc/free calls.])
110 SCM_I_GSC_GUILE_DEBUG=0
111 AC_ARG_ENABLE(guile-debug,
112 [AC_HELP_STRING([--enable-guile-debug],
113 [include internal debugging functions])],
114 if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
115 SCM_I_GSC_GUILE_DEBUG=1
118 AC_ARG_ENABLE(arrays,
119 [AC_HELP_STRING([--disable-arrays],[omit array and uniform array support])],
124 [ --disable-posix omit posix interfaces],,
127 AC_ARG_ENABLE(networking,
128 [ --disable-networking omit networking interfaces],,
129 enable_networking=yes)
132 [ --disable-regex omit regular expression interfaces],,
135 AC_ARG_ENABLE([discouraged],
136 AC_HELP_STRING([--disable-discouraged],[omit discouraged features]))
138 if test "$enable_discouraged" = no; then
139 SCM_I_GSC_ENABLE_DISCOURAGED=0
141 SCM_I_GSC_ENABLE_DISCOURAGED=1
144 AC_ARG_ENABLE([deprecated],
145 AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
147 if test "$enable_deprecated" = no; then
148 SCM_I_GSC_ENABLE_DEPRECATED=0
150 if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
152 elif test "$enable_deprecated" = shutup; then
155 warn_default=$enable_deprecated
157 SCM_I_GSC_ENABLE_DEPRECATED=1
158 AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
159 [Define this to control the default warning level for deprecated features.])
163 [ --disable-elisp omit Emacs Lisp support],,
166 #--------------------------------------------------------------------
168 dnl Check for dynamic linking
172 [ --with-modules[=FILES] Add support for dynamic modules],
173 use_modules="$withval")
174 test -z "$use_modules" && use_modules=yes
176 if test "$use_modules" != no; then
177 if test "$use_modules" = yes; then
178 DLPREOPEN="-dlpreopen force"
180 DLPREOPEN="-export-dynamic"
181 for module in $use_modules; do
182 DLPREOPEN="$DLPREOPEN -dlopen $module"
187 dnl files which are destined for separate modules.
189 if test "$use_modules" != no; then
193 SCM_I_GSC_HAVE_ARRAYS=0
194 if test "$enable_arrays" = yes; then
197 SCM_I_GSC_HAVE_ARRAYS=1
200 if test "$enable_posix" = yes; then
203 AC_DEFINE(HAVE_POSIX, 1,
204 [Define this if you want support for POSIX system calls in Guile.])
207 if test "$enable_networking" = yes; then
210 AC_DEFINE(HAVE_NETWORKING, 1,
211 [Define this if you want support for networking in Guile.])
214 if test "$enable_debug_malloc" = yes; then
215 AC_LIBOBJ([debug-malloc])
218 if test "$enable_elisp" = yes; then
219 SCM_I_GSC_ENABLE_ELISP=1
221 SCM_I_GSC_ENABLE_ELISP=0
227 if test "$ac_cv_c_inline" != no; then
228 SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
230 SCM_I_GSC_C_INLINE=NULL
235 AC_CHECK_SIZEOF(char)
236 AC_CHECK_SIZEOF(unsigned char)
237 AC_CHECK_SIZEOF(short)
238 AC_CHECK_SIZEOF(unsigned short)
240 AC_CHECK_SIZEOF(unsigned int)
241 AC_CHECK_SIZEOF(long)
242 AC_CHECK_SIZEOF(unsigned long)
243 AC_CHECK_SIZEOF(size_t)
244 AC_CHECK_SIZEOF(long long)
245 AC_CHECK_SIZEOF(unsigned long long)
246 AC_CHECK_SIZEOF(__int64)
247 AC_CHECK_SIZEOF(unsigned __int64)
248 AC_CHECK_SIZEOF(void *)
249 AC_CHECK_SIZEOF(intptr_t)
250 AC_CHECK_SIZEOF(uintptr_t)
251 AC_CHECK_SIZEOF(ptrdiff_t)
252 AC_CHECK_SIZEOF(size_t)
254 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
255 AC_MSG_ERROR(sizes of long and void* are not identical)
258 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
259 SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
261 SCM_I_GSC_T_PTRDIFF='"long"'
263 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
265 AC_CHECK_HEADERS([stdint.h])
266 AC_CHECK_HEADERS([inttypes.h])
268 AC_CHECK_SIZEOF(intmax_t)
270 SCM_I_GSC_NEEDS_STDINT_H=0
271 SCM_I_GSC_NEEDS_INTTYPES_H=0
273 ### intptr and uintptr (try not to use inttypes if we don't have to)
274 if test "$ac_cv_header_inttypes_h" = yes; then
275 if test "$ac_cv_sizeof_intptr_t" -eq 0; then
276 AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
278 if test "$ac_cv_sizeof_intptr_t" -ne 0; then
279 SCM_I_GSC_NEEDS_INTTYPES_H=1
282 if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
283 AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
285 if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
286 SCM_I_GSC_NEEDS_INTTYPES_H=1
291 ### See what's provided by stdint.h
292 if test "$ac_cv_header_stdint_h" = yes; then
293 AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
294 AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
295 AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
296 AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
297 AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
298 AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
299 AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
300 AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
301 AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
302 AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
305 # so we don't get confused by the cache (wish there was a better way
306 # to check particular headers for the same type...)
308 unset ac_cv_type_int8_t
309 unset ac_cv_type_uint8_t
310 unset ac_cv_type_int16_t
311 unset ac_cv_type_uint16_t
312 unset ac_cv_type_int32_t
313 unset ac_cv_type_uint32_t
314 unset ac_cv_type_int64_t
315 unset ac_cv_type_uint64_t
316 unset ac_cv_type_intmax_t
317 unset ac_cv_type_uintmax_t
319 ### See what's provided by inttypes.h
320 if test "$ac_cv_header_inttypes_h" = yes; then
321 AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
322 AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
323 AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
324 AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
325 AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
326 AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
327 AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
328 AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
329 AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
330 AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
333 # Try hard to find definitions for some required scm_t_*int* types.
335 ### Required type scm_t_int8
336 if test "$scm_stdint_has_int8"; then
337 SCM_I_GSC_T_INT8='"int8_t"'
338 SCM_I_GSC_NEEDS_STDINT_H=1
339 elif test "$scm_inttypes_has_int8"; then
340 SCM_I_GSC_T_INT8='"int8_t"'
341 SCM_I_GSC_NEEDS_INTTYPES_H=1
342 elif test "$ac_cv_sizeof_char" -eq 1; then
343 SCM_I_GSC_T_INT8='"signed char"'
345 AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
347 AC_SUBST([SCM_I_GSC_T_INT8])
349 ### Required type scm_t_uint8
350 if test "$scm_stdint_has_uint8"; then
351 SCM_I_GSC_T_UINT8='"uint8_t"'
352 SCM_I_GSC_NEEDS_STDINT_H=1
353 elif test "$scm_inttypes_has_uint8"; then
354 SCM_I_GSC_T_UINT8='"uint8_t"'
355 SCM_I_GSC_NEEDS_INTTYPES_H=1
356 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
357 SCM_I_GSC_T_UINT8='"unsigned char"'
359 AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
361 AC_SUBST([SCM_I_GSC_T_UINT8])
363 ### Required type scm_t_int16 (ANSI C says int or short might work)
364 if test "$scm_stdint_has_int16"; then
365 SCM_I_GSC_T_INT16='"int16_t"'
366 SCM_I_GSC_NEEDS_STDINT_H=1
367 elif test "$scm_inttypes_has_int16"; then
368 SCM_I_GSC_T_INT16='"int16_t"'
369 SCM_I_GSC_NEEDS_INTTYPES_H=1
370 elif test "$ac_cv_sizeof_int" -eq 2; then
371 SCM_I_GSC_T_INT16='"int"'
372 elif test "$ac_cv_sizeof_short" -eq 2; then
373 SCM_I_GSC_T_INT16='"short"'
375 AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
377 AC_SUBST([SCM_I_GSC_T_INT16])
379 ### Required type scm_t_uint16 (ANSI C says int or short might work)
380 if test "$scm_stdint_has_uint16"; then
381 SCM_I_GSC_T_UINT16='"uint16_t"'
382 SCM_I_GSC_NEEDS_STDINT_H=1
383 elif test "$scm_inttypes_has_uint16"; then
384 SCM_I_GSC_T_UINT16='"uint16_t"'
385 SCM_I_GSC_NEEDS_INTTYPES_H=1
386 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
387 SCM_I_GSC_T_UINT16='"unsigned int"'
388 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
389 SCM_I_GSC_T_UINT16='"unsigned short"'
391 AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
393 AC_SUBST([SCM_I_GSC_T_UINT16])
396 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
397 if test "$scm_stdint_has_int32"; then
398 SCM_I_GSC_T_INT32='"int32_t"'
399 SCM_I_GSC_NEEDS_STDINT_H=1
400 elif test "$scm_inttypes_has_int32"; then
401 SCM_I_GSC_T_INT32='"int32_t"'
402 SCM_I_GSC_NEEDS_INTTYPES_H=1
403 elif test "$ac_cv_sizeof_int" -eq 4; then
404 SCM_I_GSC_T_INT32='"int"'
405 elif test "$ac_cv_sizeof_long" -eq 4; then
406 SCM_I_GSC_T_INT32='"long"'
407 elif test "$ac_cv_sizeof_short" -eq 4; then
408 SCM_I_GSC_T_INT32='"short"'
410 AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
412 AC_SUBST([SCM_I_GSC_T_INT32])
414 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
415 if test "$scm_stdint_has_uint32"; then
416 SCM_I_GSC_T_UINT32='"uint32_t"'
417 SCM_I_GSC_NEEDS_STDINT_H=1
418 elif test "$scm_inttypes_has_uint32"; then
419 SCM_I_GSC_T_UINT32='"uint32_t"'
420 SCM_I_GSC_NEEDS_INTTYPES_H=1
421 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
422 SCM_I_GSC_T_UINT32='"unsigned int"'
423 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
424 SCM_I_GSC_T_UINT32='"unsigned long"'
425 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
426 SCM_I_GSC_T_UINT32='"unsigned short"'
428 AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
430 AC_SUBST([SCM_I_GSC_T_UINT32])
432 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
433 ### Also try 'long long' and '__int64' if we have it.
435 if test "$scm_stdint_has_int64"; then
436 SCM_I_GSC_T_INT64='"int64_t"'
437 SCM_I_GSC_NEEDS_STDINT_H=1
438 elif test "$scm_inttypes_has_int64"; then
439 SCM_I_GSC_T_INT64='"int64_t"'
440 SCM_I_GSC_NEEDS_INTTYPES_H=1
441 elif test "$ac_cv_sizeof_int" -eq 8; then
442 SCM_I_GSC_T_INT64='"int"'
443 elif test "$ac_cv_sizeof_long" -eq 8; then
444 SCM_I_GSC_T_INT64='"long"'
445 elif test "$ac_cv_sizeof_short" -eq 8; then
446 SCM_I_GSC_T_INT64='"short"'
447 elif test "$ac_cv_sizeof_long_long" -eq 8; then
448 SCM_I_GSC_T_INT64='"long long"'
449 elif test "$ac_cv_sizeof___int64" -eq 8; then
450 SCM_I_GSC_T_INT64='"__int64"'
452 AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
454 AC_SUBST([SCM_I_GSC_T_INT64])
457 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
458 ### Also try 'long long' and '__int64' if we have it.
460 if test "$scm_stdint_has_uint64"; then
461 SCM_I_GSC_T_UINT64='"uint64_t"'
462 SCM_I_GSC_NEEDS_STDINT_H=1
463 elif test "$scm_inttypes_has_uint64"; then
464 SCM_I_GSC_T_UINT64='"uint64_t"'
465 SCM_I_GSC_NEEDS_INTTYPES_H=1
466 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
467 SCM_I_GSC_T_UINT64='"unsigned int"'
468 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
469 SCM_I_GSC_T_UINT64='"unsigned long"'
470 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
471 SCM_I_GSC_T_UINT64='"unsigned short"'
472 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
473 SCM_I_GSC_T_UINT64='"unsigned long long"'
474 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
475 SCM_I_GSC_T_UINT64='"unsigned __int64"'
477 AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
479 AC_SUBST([SCM_I_GSC_T_UINT64])
481 ### Required type scm_t_intmax
483 ### We try 'intmax_t', '__int64', 'long long' in this order. When
484 ### none of them is available, we use 'long'.
487 if test "$scm_stdint_has_intmax"; then
488 SCM_I_GSC_T_INTMAX='"intmax_t"'
489 SCM_I_GSC_NEEDS_STDINT_H=1
490 elif test "$scm_inttypes_has_intmax"; then
491 SCM_I_GSC_T_INTMAX='"intmax_t"'
492 SCM_I_GSC_NEEDS_INTTYPES_H=1
493 elif test "$ac_cv_sizeof___int64" -ne 0; then
494 SCM_I_GSC_T_INTMAX='"__int64"'
495 elif test "$ac_cv_sizeof_long_long" -ne 0; then
496 SCM_I_GSC_T_INTMAX='"long long"'
498 SCM_I_GSC_T_INTMAX='"long"'
500 AC_SUBST([SCM_I_GSC_T_INTMAX])
502 ### Required type scm_t_uintmax
504 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
505 ### this order. When none of them is available, we use 'unsigned long'.
507 SCM_I_GSC_T_UINTMAX=0
508 if test "$scm_stdint_has_uintmax"; then
509 SCM_I_GSC_T_UINTMAX='"uintmax_t"'
510 SCM_I_GSC_NEEDS_STDINT_H=1
511 elif test "$scm_inttypes_has_uintmax"; then
512 SCM_I_GSC_T_UINTMAX='"uintmax_t"'
513 SCM_I_GSC_NEEDS_INTTYPES_H=1
514 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
515 SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
516 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
517 SCM_I_GSC_T_UINTMAX='"unsigned long long"'
519 SCM_I_GSC_T_UINTMAX='"unsigned long"'
521 AC_SUBST([SCM_I_GSC_T_UINTMAX])
524 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
525 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
532 # Reasons for testing:
533 # fenv.h - available in C99, but not older systems
535 AC_CHECK_HEADERS([fenv.h io.h libc.h limits.h malloc.h memory.h string.h \
536 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
537 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
538 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
541 GUILE_HEADER_LIBC_WITH_UNISTD
547 if test $MINGW32 = no; then
548 AC_CHECK_LIB(m, main)
550 AC_CHECK_FUNCS(gethostbyname)
551 if test $ac_cv_func_gethostbyname = no; then
552 AC_CHECK_LIB(nsl, gethostbyname)
555 AC_CHECK_FUNCS(connect)
556 if test $ac_cv_func_connect = no; then
557 AC_CHECK_LIB(socket, connect)
561 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
564 if test "$MINGW32" = "yes" ; then
565 AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
566 [Define if you have the <winsock2.h> header file.])])
567 AC_CHECK_LIB(ws2_32, main)
568 AC_LIBOBJ([win32-uname])
569 AC_LIBOBJ([win32-dirent])
570 if test "$enable_networking" = yes ; then
571 AC_LIBOBJ([win32-socket])
573 if test "$enable_shared" = yes ; then
574 EXTRA_DEFS="-DSCM_IMPORT"
575 AC_DEFINE(USE_DLL_IMPORT, 1,
576 [Define if you need additional CPP macros on Win32 platforms.])
578 if test x"$enable_ltdl_install" = x"yes" ; then
579 INCLTDL="-DLIBLTDL_DLL_IMPORT $INCLTDL"
584 # FIXME: check to see if we still need these.
590 # Reasons for testing:
591 # crt_externs.h - Darwin specific
593 AC_CHECK_HEADERS([assert.h crt_externs.h])
595 # Reasons for testing:
596 # DINFINITY - OSF specific
597 # DQNAN - OSF specific
598 # (DINFINITY and DQNAN are actually global variables, not functions)
599 # fesetround - available in C99, but not older systems
600 # gmtime_r - recent posix, not on old systems
601 # readdir_r - recent posix, not on old systems
602 # sysconf - not on old systems
603 # _NSGetEnviron - Darwin specific
605 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid fesetround ftime fchown getcwd geteuid gettimeofday gmtime_r lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv _NSGetEnviron])
607 # Reasons for testing:
608 # netdb.h - not in mingw
609 # sys/param.h - not in mingw
611 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
612 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
614 # crypt() may or may not be available, for instance in some countries there
615 # are restrictions on cryptography.
617 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
618 # -lcrypt library (eg. Debian GNU/Linux).
620 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a. We must
621 # be careful to avoid -lcrypt in this case, since libtool will see there's
622 # only a static libcrypt and decide to build only a static libguile.
624 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
625 # libraries already in that list.
627 AC_SEARCH_LIBS(crypt, crypt,
628 [AC_DEFINE(HAVE_CRYPT,1,
629 [Define to 1 if you have the `crypt' function.])])
632 AC_CHECK_LIB([gmp], [__gmpz_init], ,
633 [AC_MSG_ERROR([GNU MP not found, see http://swox.com/gmp])])
635 # mpz_import is a macro so we need to include <gmp.h>
636 AC_TRY_LINK([#include <gmp.h>],
637 [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
638 [AC_MSG_ERROR([At least GNU MP 4.1 is required, see http://swox.com/gmp])])
640 ### Some systems don't declare some functions. On such systems, we
641 ### need to at least provide our own K&R-style declarations.
643 ### GUILE_FUNC_DECLARED(function, headerfile)
645 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
646 ### not there, #define MISSING_FUNCTION_DECL.
647 AC_DEFUN([GUILE_FUNC_DECLARED], [
648 AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
649 AC_EGREP_HEADER($1, $2,
650 guile_cv_func_$1_declared=yes,
651 guile_cv_func_$1_declared=no))
652 if test [x$guile_cv_func_]$1[_declared] = xno; then
653 AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
654 [Define if the operating system supplies $1 without declaring it.])
658 GUILE_FUNC_DECLARED(sleep, unistd.h)
659 GUILE_FUNC_DECLARED(usleep, unistd.h)
661 AC_CHECK_DECLS([strptime],,,
662 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
665 ### On some systems usleep has no return value. If it does have one,
666 ### we'd like to return it; otherwise, we'll fake it.
667 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
668 [AC_EGREP_HEADER(changequote(<, >)<void[ ]+usleep>changequote([, ]),
670 [guile_cv_func_usleep_return_type=void],
671 [guile_cv_func_usleep_return_type=int])])
672 case "$guile_cv_func_usleep_return_type" in
674 AC_DEFINE(USLEEP_RETURNS_VOID, 1,
675 [Define if the system headers declare usleep to return void.])
679 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
680 if test -n "$have_sys_un_h" ; then
681 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
682 [Define if the system supports Unix-domain (file-domain) sockets.])
685 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
687 AC_CHECK_FUNCS(sethostent gethostent endhostent dnl
688 setnetent getnetent endnetent dnl
689 setprotoent getprotoent endprotoent dnl
690 setservent getservent endservent dnl
691 getnetbyaddr getnetbyname dnl
692 inet_lnaof inet_makeaddr inet_netof hstrerror dnl
695 AC_MSG_CHECKING(for __libc_stack_end)
696 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
697 [AC_TRY_LINK([#include <stdio.h>
698 extern char *__libc_stack_end;],
699 [printf("%p", (char*) __libc_stack_end);],
700 guile_cv_have_libc_stack_end=yes,
701 guile_cv_have_libc_stack_end=no)])
702 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
704 if test $guile_cv_have_libc_stack_end = yes; then
705 AC_DEFINE(HAVE_LIBC_STACK_END, 1,
706 [Define if you have the __libc_stack_end variable.])
709 dnl Some systems do not declare this. Some systems do declare it, as a
710 dnl macro. With cygwin it may be in a DLL.
712 AC_MSG_CHECKING(whether netdb.h declares h_errno)
713 AC_CACHE_VAL(guile_cv_have_h_errno,
714 [AC_TRY_COMPILE([#include <netdb.h>],
716 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
717 AC_MSG_RESULT($guile_cv_have_h_errno)
718 if test $guile_cv_have_h_errno = yes; then
719 AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
722 AC_MSG_CHECKING(whether uint32_t is defined)
723 AC_CACHE_VAL(guile_cv_have_uint32_t,
724 [AC_TRY_COMPILE([#include <sys/types.h>
732 guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
733 AC_MSG_RESULT($guile_cv_have_uint32_t)
734 if test $guile_cv_have_uint32_t = yes; then
735 AC_DEFINE(HAVE_UINT32_T, 1,
736 [Define if uint32_t typedef is defined when netdb.h is include.])
739 AC_MSG_CHECKING(for working IPv6 support)
740 AC_CACHE_VAL(guile_cv_have_ipv6,
742 #ifdef HAVE_SYS_TYPES_H
743 #include <sys/types.h>
745 #include <netinet/in.h>
746 #include <sys/socket.h>],
747 [struct sockaddr_in6 a; a.sin6_family = AF_INET6;],
748 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
749 AC_MSG_RESULT($guile_cv_have_ipv6)
750 if test $guile_cv_have_ipv6 = yes; then
751 AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
754 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
755 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
756 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
758 #ifdef HAVE_SYS_TYPES_H
759 #include <sys/types.h>
761 #include <netinet/in.h>],
762 [struct sockaddr_in6 sok; sok.sin6_scope_id = 0;],
763 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
764 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
765 if test $guile_cv_have_sin6_scope_id = yes; then
766 AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
767 [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
770 AC_MSG_CHECKING(whether localtime caches TZ)
771 AC_CACHE_VAL(guile_cv_localtime_cache,
772 [if test x$ac_cv_func_tzset = xyes; then
773 AC_TRY_RUN([#include <time.h>
777 extern char **environ;
781 for (to = from = environ; (*to = *from); from++)
782 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
785 char TZ_GMT0[] = "TZ=GMT0";
786 char TZ_PST8[] = "TZ=PST8";
789 time_t now = time ((time_t *) 0);
790 int hour_GMT0, hour_unset;
791 if (putenv (TZ_GMT0) != 0)
793 hour_GMT0 = localtime (&now)->tm_hour;
795 hour_unset = localtime (&now)->tm_hour;
796 if (putenv (TZ_PST8) != 0)
798 if (localtime (&now)->tm_hour == hour_GMT0)
801 if (localtime (&now)->tm_hour != hour_unset)
804 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
805 [# If we have tzset, assume the worst when cross-compiling.
806 guile_cv_localtime_cache=yes])
808 # If we lack tzset, report that localtime does not cache TZ,
809 # since we can't invalidate the cache if we don't have tzset.
810 guile_cv_localtime_cache=no
812 AC_MSG_RESULT($guile_cv_localtime_cache)
813 if test $guile_cv_localtime_cache = yes; then
814 AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
817 dnl Test whether system calls are restartable by default on the
818 dnl current system. If they are not, we put a loop around every system
819 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
820 dnl change from the default behaviour. On the other hand, if signals
821 dnl are restartable then the loop is not installed and when libguile
822 dnl initialises it also resets the behaviour of each signal to cause a
823 dnl restart (in case a different runtime had a different default
824 dnl behaviour for some reason: e.g., different versions of linux seem
825 dnl to behave differently.)
827 AC_SYS_RESTARTABLE_SYSCALLS
829 if test "$enable_regex" = yes; then
830 if test "$ac_cv_header_regex_h" = yes ||
831 test "$ac_cv_header_rxposix_h" = yes ||
832 test "$ac_cv_header_rx_rxposix_h" = yes; then
833 GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
834 [AC_CHECK_LIB(rx, main)
835 GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
836 [AC_CHECK_LIB(regex, main)
837 GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
839 dnl The following should not be necessary, but for some reason
840 dnl autoheader misses it if we don't include it!
841 if test "$ac_cv_func_regcomp_norx" = yes ||
842 test "$ac_cv_func_regcomp_regex" = yes ||
843 test "$ac_cv_func_regcomp_rx" = yes; then
844 AC_DEFINE(HAVE_REGCOMP, 1,
845 [This is included as part of a workaround for a autoheader bug.])
850 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
852 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
854 # Reasons for testing:
855 # asinh, acosh, atanh, trunc - C99 standard, generally not available on
857 # sincos - GLIBC extension
859 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
861 # C99 specifies isinf and isnan as macros.
862 # HP-UX provides only macros, no functions.
863 # glibc 2.3.2 provides both macros and functions.
864 # IRIX 6.5 and Solaris 8 only provide functions.
866 # The following tests detect isinf and isnan either as functions or as
867 # macros from <math.h>. Plain AC_CHECK_FUNCS is insufficient, it doesn't
868 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
870 AC_MSG_CHECKING([for isinf])
873 int main () { return (isinf(0.0) != 0); }],
874 [AC_MSG_RESULT([yes])
875 AC_DEFINE(HAVE_ISINF, 1,
876 [Define to 1 if you have the `isinf' macro or function.])],
877 [AC_MSG_RESULT([no])])
878 AC_MSG_CHECKING([for isnan])
881 int main () { return (isnan(0.0) != 0); }],
882 [AC_MSG_RESULT([yes])
883 AC_DEFINE(HAVE_ISNAN, 1,
884 [Define to 1 if you have the `isnan' macro or function.])],
885 [AC_MSG_RESULT([no])])
887 # When testing for the presence of alloca, we need to add alloca.o
888 # explicitly to LIBOBJS to make sure that it is translated to
889 # `alloca.lo' for libtool later on. This can and should be done more cleanly.
891 if test "$ALLOCA" = "alloca.o"
896 AC_CHECK_MEMBERS([struct stat.st_rdev])
897 AC_CHECK_MEMBERS([struct stat.st_blksize])
901 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
902 [AC_TRY_CPP([#include <sys/stat.h>
906 ac_cv_macro_S_ISLNK=yes,
907 ac_cv_macro_S_ISLNK=no)])
908 if test $ac_cv_macro_S_ISLNK = yes; then
909 AC_DEFINE(HAVE_S_ISLNK, 1,
910 [Define this if your system defines S_ISLNK in sys/stat.h.])
916 #--------------------------------------------------------------------
918 # Which way does the stack grow?
920 #--------------------------------------------------------------------
922 SCM_I_GSC_STACK_GROWS_UP=0
923 AC_TRY_RUN(aux (l) unsigned long l;
924 { int x; exit (l >= ((unsigned long)&x)); }
925 main () { int q; aux((unsigned long)&q); },
926 [SCM_I_GSC_STACK_GROWS_UP=1],
928 [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
930 AC_CHECK_SIZEOF(float)
931 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
932 AC_DEFINE(SCM_SINGLES, 1,
933 [Define this if floats are the same size as longs.])
936 AC_MSG_CHECKING(for struct linger)
937 AC_CACHE_VAL(scm_cv_struct_linger,
939 #include <sys/types.h>
940 #include <sys/socket.h>],
941 [struct linger lgr; lgr.l_linger = 100],
942 scm_cv_struct_linger="yes",
943 scm_cv_struct_linger="no"))
944 AC_MSG_RESULT($scm_cv_struct_linger)
945 if test $scm_cv_struct_linger = yes; then
946 AC_DEFINE(HAVE_STRUCT_LINGER, 1,
947 [Define this if your system defines struct linger, for use with the
948 getsockopt and setsockopt system calls.])
952 AC_MSG_CHECKING(for struct timespec)
953 AC_CACHE_VAL(scm_cv_struct_timespec,
956 [struct timespec t; t.tv_nsec = 100],
957 scm_cv_struct_timespec="yes",
958 scm_cv_struct_timespec="no"))
959 AC_MSG_RESULT($scm_cv_struct_timespec)
960 if test $scm_cv_struct_timespec = yes; then
961 AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
962 [Define this if your system defines struct timespec via <time.h>.])
965 #--------------------------------------------------------------------
967 # Flags for thread support
969 #--------------------------------------------------------------------
971 SCM_I_GSC_USE_PTHREAD_THREADS=0
972 SCM_I_GSC_USE_NULL_THREADS=0
973 SCM_I_GSC_USE_COOP_THREADS=0
974 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
975 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
976 AC_SUBST([SCM_I_GSC_USE_COOP_THREADS])
978 ### What thread package has the user asked for?
979 AC_ARG_WITH(threads, [ --with-threads thread interface],
982 case "$with_threads" in
983 "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
984 AC_CHECK_LIB(pthread, main,
985 LIBS="-lpthread $LIBS"
986 SCM_I_GSC_USE_PTHREAD_THREADS=1
987 with_threads="pthreads",
990 if test $GCC = yes; then
991 AC_DEFINE(_THREAD_SAFE, 1,
992 [Use thread safe versions of GNU Libc functions.])
995 AC_MSG_CHECKING(if pthread_mutexattr_settype is declared)
996 AC_CACHE_VAL(guile_cv_mutexattr_settype_declared,
997 [AC_TRY_COMPILE([#include <pthread.h>],
998 [int pthread_mutexattr_settype (int, int);],
999 guile_cv_mutexattr_settype_declared=no,
1000 guile_cv_mutexattr_settype_declared=yes)])
1001 AC_MSG_RESULT($guile_cv_mutexattr_settype_declared)
1002 if test $guile_cv_mutexattr_settype_declared = yes; then
1003 AC_DEFINE(SCM_MUTEXATTR_SETTYPE_DECLARED, 1,
1004 [Define if pthread.h declares pthread_mutexattr_settype.])
1007 AC_MSG_CHECKING(how to get a fast mutex)
1008 AC_CACHE_VAL(guile_cv_have_mutex_fast,
1009 [AC_TRY_COMPILE([#include <pthread.h>],
1010 [int a = PTHREAD_MUTEX_ADAPTIVE_NP;],
1011 guile_cv_have_mutex_fast=PTHREAD_MUTEX_ADAPTIVE_NP,
1012 guile_cv_have_mutex_fast=none)])
1013 AC_MSG_RESULT($guile_cv_have_mutex_fast)
1014 if test ! $guile_cv_have_mutex_fast = none; then
1015 AC_DEFINE_UNQUOTED(SCM_MUTEX_FAST, $guile_cv_have_mutex_fast,
1016 [The mutex kind enum for fast mutexes.])
1019 AC_MSG_CHECKING(how to get a recursive mutex)
1020 AC_CACHE_VAL(guile_cv_have_mutex_recursive,
1021 [AC_TRY_COMPILE([#include <pthread.h>],
1022 [int a = PTHREAD_MUTEX_RECURSIVE_NP;],
1023 guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE_NP)
1024 if test -z "$guile_cv_have_mutex_recursive"; then
1025 AC_TRY_COMPILE([#include <pthread.h>],
1026 [int a = PTHREAD_MUTEX_RECURSIVE;],
1027 guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE,
1028 guile_cv_have_mutex_recursive=none)
1030 AC_MSG_RESULT($guile_cv_have_mutex_recursive)
1031 if test ! $guile_cv_have_mutex_recursive = none; then
1032 AC_DEFINE_UNQUOTED(SCM_MUTEX_RECURSIVE, $guile_cv_have_mutex_recursive,
1033 [The mutex kind enum for recursive mutexes.])
1036 # On Solaris, sched_yield lives in -lrt.
1037 AC_SEARCH_LIBS(sched_yield, rt)
1042 case "$with_threads" in
1046 SCM_I_GSC_USE_NULL_THREADS=1
1047 with_threads="null-threads"
1050 AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1054 AC_MSG_CHECKING(what kind of threads to support)
1055 AC_MSG_RESULT($with_threads)
1058 if test "$cross_compiling" = "yes"; then
1059 AC_MSG_CHECKING(cc for build)
1060 ## /usr/bin/cc still uses wrong assembler
1061 ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1062 CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1064 CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1067 ## AC_MSG_CHECKING("if we are cross compiling")
1068 ## AC_MSG_RESULT($cross_compiling)
1069 if test "$cross_compiling" = "yes"; then
1070 AC_MSG_RESULT($CC_FOR_BUILD)
1073 ## No need as yet to be more elaborate
1074 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1076 AC_SUBST(cross_compiling)
1077 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1078 AC_SUBST(CCLD_FOR_BUILD)
1080 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1081 ## --HOST is the platform that PACKAGE is compiled for.
1082 HOST_CC="$CC_FOR_BUILD"
1085 if test "$cross_compiling" = "yes"; then
1086 AC_MSG_CHECKING(guile for build)
1087 GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1089 GUILE_FOR_BUILD='$(preinstguile)'
1092 ## AC_MSG_CHECKING("if we are cross compiling")
1093 ## AC_MSG_RESULT($cross_compiling)
1094 if test "$cross_compiling" = "yes"; then
1095 AC_MSG_RESULT($GUILE_FOR_BUILD)
1097 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1098 AC_SUBST(GUILE_FOR_BUILD)
1100 ## If we're using GCC, ask for aggressive warnings.
1103 ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1104 ## much stuff with generic function pointers for that to really be
1105 ## less than exasperating.
1106 ## -Wpointer-arith was here too, but something changed in gcc/glibc
1107 ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1108 CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1109 # Do this here so we don't screw up any of the tests above that might
1110 # not be "warning free"
1111 if test "${GUILE_ERROR_ON_WARNING}" = yes
1113 CFLAGS="${CFLAGS} -Werror"
1114 enable_compile_warnings=no
1119 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
1120 ## -- I'm disabling it for now in the hopes that the newer autoconf
1121 ## will DTRT -- if not, we need to fix up the sed command to match the
1124 ## Remove fileblocks.o from the object list. This file gets added by
1125 ## the Autoconf macro AC_STRUCT_ST_BLOCKS. But there is no need.
1126 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
1128 ## If we're creating a shared library (using libtool!), then we'll
1129 ## need to generate a list of .lo files corresponding to the .o files
1130 ## given in LIBOBJS. We'll call it LIBLOBJS.
1131 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1133 ## We also need to create corresponding .doc and .x files
1134 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1135 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1137 AC_SUBST(GUILE_MAJOR_VERSION)
1138 AC_SUBST(GUILE_MINOR_VERSION)
1139 AC_SUBST(GUILE_MICRO_VERSION)
1140 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1141 AC_SUBST(GUILE_VERSION)
1143 #######################################################################
1144 # library versioning
1146 AC_SUBST(LIBQTHREADS_INTERFACE_CURRENT)
1147 AC_SUBST(LIBQTHREADS_INTERFACE_REVISION)
1148 AC_SUBST(LIBQTHREADS_INTERFACE_AGE)
1149 AC_SUBST(LIBQTHREADS_INTERFACE)
1151 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1152 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1153 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1154 AC_SUBST(LIBGUILE_INTERFACE)
1156 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1157 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1158 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1159 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1161 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1162 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1163 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1164 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1166 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1167 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1168 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1169 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1171 #######################################################################
1173 dnl Tell guile-config what flags guile users should link against.
1174 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
1175 AC_SUBST(GUILE_LIBS)
1179 AC_SUBST(EXTRA_DOT_DOC_FILES)
1180 AC_SUBST(EXTRA_DOT_X_FILES)
1182 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1183 top_builddir_absolute=`pwd`
1184 AC_SUBST(top_builddir_absolute)
1185 top_srcdir_absolute=`(cd $srcdir && pwd)`
1186 AC_SUBST(top_srcdir_absolute)
1188 # Additional SCM_I_GSC definitions are above.
1189 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1190 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1191 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1192 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1193 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1194 AC_SUBST([SCM_I_GSC_HAVE_ARRAYS])
1195 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1196 AC_SUBST([SCM_I_GSC_C_INLINE])
1197 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1202 benchmark-suite/Makefile
1207 doc/tutorial/Makefile
1210 examples/box-dynamic-module/Makefile
1211 examples/box-dynamic/Makefile
1212 examples/box-module/Makefile
1213 examples/box/Makefile
1214 examples/modules/Makefile
1215 examples/safe/Makefile
1216 examples/scripts/Makefile
1217 guile-config/Makefile
1219 ice-9/debugger/Makefile
1220 ice-9/debugger/breakpoints/Makefile
1223 lang/elisp/internals/Makefile
1224 lang/elisp/primitives/Makefile
1225 libguile-ltdl/Makefile
1226 libguile-ltdl/upstream/Makefile
1233 test-suite/standalone/Makefile
1236 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1237 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1238 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1239 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1240 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1241 AC_CONFIG_FILES([libguile/guile-snarf],
1242 [chmod +x libguile/guile-snarf])
1243 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1244 [chmod +x libguile/guile-doc-snarf])
1245 AC_CONFIG_FILES([libguile/guile-func-name-check],
1246 [chmod +x libguile/guile-func-name-check])
1247 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1248 [chmod +x libguile/guile-snarf-docs])
1252 dnl Local Variables:
1253 dnl comment-start: "dnl "
1255 dnl comment-start-skip: "\\bdnl\\b\\s *"