configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 Boston, MA 02111-1307, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT(m4_esyscmd(. ./GUILE-VERSION && echo -n ${PACKAGE}),
  31         m4_esyscmd(. ./GUILE-VERSION && echo -n ${GUILE_VERSION}))
  32 AC_CONFIG_SRCDIR(GUILE-VERSION)
  33 AM_INIT_AUTOMAKE([no-define])
  34
  35 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  36 AC_CONFIG_SRCDIR([GUILE-VERSION])
  37
  38 . $srcdir/GUILE-VERSION
  39
  40 AM_MAINTAINER_MODE
  41 AM_CONFIG_HEADER([config.h])
  42 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  43
  44 #--------------------------------------------------------------------
  45 #
  46 # Independent Subdirectories
  47 #
  48 #--------------------------------------------------------------------
  49
  50 AC_CONFIG_SUBDIRS(guile-readline)
  51
  52 #--------------------------------------------------------------------
  53
  54 dnl Some more checks for Win32
  55 AC_CYGWIN
  56 AC_MINGW32
  57 AC_LIBTOOL_WIN32_DLL
  58
  59 AC_PROG_INSTALL
  60 AC_PROG_CC
  61 AC_PROG_CPP
  62 AC_PROG_AWK
  63
  64 AC_AIX
  65 AC_ISC_POSIX
  66 AC_MINIX
  67
  68 AM_PROG_CC_STDC
  69
  70 AC_LIBTOOL_DLOPEN
  71 AC_PROG_LIBTOOL
  72 AC_LIB_LTDL
  73
  74 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  75 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  76
  77 AM_PATH_LISPDIR
  78
  79 #--------------------------------------------------------------------
  80 #
  81 # User options (after above tests that may set default CFLAGS etc.)
  82 #
  83 #--------------------------------------------------------------------
  84
  85 GUILE_ERROR_ON_WARNING="yes"
  86
  87 AC_ARG_ENABLE(error-on-warning,
  88   [  --enable-error-on-warning    treat compile warnings as errors],
  89   [case "${enableval}" in
  90      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  91      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  92      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  93    esac])
  94
  95 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
  96 AC_ARG_ENABLE(debug-freelist,
  97   [  --enable-debug-freelist include garbage collector freelist debugging code],
  98   if test "$enable_debug_freelist" = y \
  99      || test "$enable_debug_freelist" = yes; then
 100     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 101   fi)
 102
 103 AC_ARG_ENABLE(debug-malloc,
 104   [  --enable-debug-malloc   include malloc debugging code],
 105   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 106     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 107       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 108   fi)
 109
 110 SCM_I_GSC_GUILE_DEBUG=0
 111 AC_ARG_ENABLE(guile-debug,
 112   [AC_HELP_STRING([--enable-guile-debug],
 113                   [include internal debugging functions])],
 114   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 115     SCM_I_GSC_GUILE_DEBUG=1
 116   fi)
 117
 118 AC_ARG_ENABLE(arrays,
 119   [AC_HELP_STRING([--disable-arrays],[omit array and uniform array support])],
 120   ,
 121   enable_arrays=yes)
 122
 123 AC_ARG_ENABLE(posix,
 124   [  --disable-posix         omit posix interfaces],,
 125   enable_posix=yes)
 126
 127 AC_ARG_ENABLE(networking,
 128   [  --disable-networking    omit networking interfaces],,
 129   enable_networking=yes)
 130
 131 AC_ARG_ENABLE(regex,
 132   [  --disable-regex         omit regular expression interfaces],,
 133   enable_regex=yes)
 134
 135 AC_ARG_ENABLE([discouraged],
 136   AC_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 137
 138 if test "$enable_discouraged" = no; then
 139   SCM_I_GSC_ENABLE_DISCOURAGED=0
 140 else
 141   SCM_I_GSC_ENABLE_DISCOURAGED=1
 142 fi
 143
 144 AC_ARG_ENABLE([deprecated],
 145   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 146
 147 if test "$enable_deprecated" = no; then
 148   SCM_I_GSC_ENABLE_DEPRECATED=0
 149 else
 150   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 151     warn_default=summary
 152   elif test "$enable_deprecated" = shutup; then
 153     warn_default=no
 154   else
 155     warn_default=$enable_deprecated
 156   fi
 157   SCM_I_GSC_ENABLE_DEPRECATED=1
 158   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 159   [Define this to control the default warning level for deprecated features.])
 160 fi
 161
 162 AC_ARG_ENABLE(elisp,
 163   [  --disable-elisp         omit Emacs Lisp support],,
 164   enable_elisp=yes)
 165
 166 #--------------------------------------------------------------------
 167
 168 dnl Check for dynamic linking
 169
 170 use_modules=yes
 171 AC_ARG_WITH(modules,
 172 [  --with-modules[=FILES]  Add support for dynamic modules],
 173 use_modules="$withval")
 174 test -z "$use_modules" && use_modules=yes
 175 DLPREOPEN=
 176 if test "$use_modules" != no; then
 177   if test "$use_modules" = yes; then
 178     DLPREOPEN="-dlpreopen force"
 179   else
 180     DLPREOPEN="-export-dynamic"
 181     for module in $use_modules; do
 182       DLPREOPEN="$DLPREOPEN -dlopen $module"
 183     done
 184   fi
 185 fi
 186
 187 dnl files which are destined for separate modules.
 188
 189 if test "$use_modules" != no; then
 190    AC_LIBOBJ([dynl])
 191 fi
 192
 193 SCM_I_GSC_HAVE_ARRAYS=0
 194 if test "$enable_arrays" = yes; then
 195    AC_LIBOBJ([ramap])
 196    AC_LIBOBJ([unif])
 197    SCM_I_GSC_HAVE_ARRAYS=1
 198 fi
 199
 200 if test "$enable_posix" = yes; then
 201    AC_LIBOBJ([filesys])
 202    AC_LIBOBJ([posix])
 203    AC_DEFINE(HAVE_POSIX, 1,
 204      [Define this if you want support for POSIX system calls in Guile.])
 205 fi
 206
 207 if test "$enable_networking" = yes; then
 208    AC_LIBOBJ([net_db])
 209    AC_LIBOBJ([socket])
 210    AC_DEFINE(HAVE_NETWORKING, 1,
 211      [Define this if you want support for networking in Guile.])
 212 fi
 213
 214 if test "$enable_debug_malloc" = yes; then
 215    AC_LIBOBJ([debug-malloc])
 216 fi
 217
 218 if test "$enable_elisp" = yes; then
 219   SCM_I_GSC_ENABLE_ELISP=1
 220 else
 221   SCM_I_GSC_ENABLE_ELISP=0
 222 fi
 223
 224 AC_C_CONST
 225
 226 AC_C_INLINE
 227 if test "$ac_cv_c_inline" != no; then
 228   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 229 else
 230   SCM_I_GSC_C_INLINE=NULL
 231 fi
 232
 233 AC_C_BIGENDIAN
 234
 235 AC_CHECK_SIZEOF(char)
 236 AC_CHECK_SIZEOF(unsigned char)
 237 AC_CHECK_SIZEOF(short)
 238 AC_CHECK_SIZEOF(unsigned short)
 239 AC_CHECK_SIZEOF(int)
 240 AC_CHECK_SIZEOF(unsigned int)
 241 AC_CHECK_SIZEOF(long)
 242 AC_CHECK_SIZEOF(unsigned long)
 243 AC_CHECK_SIZEOF(size_t)
 244 AC_CHECK_SIZEOF(long long)
 245 AC_CHECK_SIZEOF(unsigned long long)
 246 AC_CHECK_SIZEOF(__int64)
 247 AC_CHECK_SIZEOF(unsigned __int64)
 248 AC_CHECK_SIZEOF(void *)
 249 AC_CHECK_SIZEOF(intptr_t)
 250 AC_CHECK_SIZEOF(uintptr_t)
 251 AC_CHECK_SIZEOF(ptrdiff_t)
 252 AC_CHECK_SIZEOF(size_t)
 253
 254 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 255   AC_MSG_ERROR(sizes of long and void* are not identical)
 256 fi
 257
 258 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 259   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 260 else
 261   SCM_I_GSC_T_PTRDIFF='"long"'
 262 fi
 263 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 264
 265 AC_CHECK_HEADERS([stdint.h])
 266 AC_CHECK_HEADERS([inttypes.h])
 267
 268 AC_CHECK_SIZEOF(intmax_t)
 269
 270 SCM_I_GSC_NEEDS_STDINT_H=0
 271 SCM_I_GSC_NEEDS_INTTYPES_H=0
 272
 273 ### intptr and uintptr (try not to use inttypes if we don't have to)
 274 if test "$ac_cv_header_inttypes_h" = yes; then
 275   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 276     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 277 #include <stdio.h>])
 278     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 279       SCM_I_GSC_NEEDS_INTTYPES_H=1
 280     fi
 281   fi
 282   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 283     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 284 #include <stdio.h>])
 285     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 286       SCM_I_GSC_NEEDS_INTTYPES_H=1
 287     fi
 288   fi
 289 fi
 290
 291 ### See what's provided by stdint.h
 292 if test "$ac_cv_header_stdint_h" = yes; then
 293    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 294    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 295    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 296    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 297    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 298    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 299    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 300    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 301    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 302    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 303 fi
 304
 305 # so we don't get confused by the cache (wish there was a better way
 306 # to check particular headers for the same type...)
 307
 308 unset ac_cv_type_int8_t
 309 unset ac_cv_type_uint8_t
 310 unset ac_cv_type_int16_t
 311 unset ac_cv_type_uint16_t
 312 unset ac_cv_type_int32_t
 313 unset ac_cv_type_uint32_t
 314 unset ac_cv_type_int64_t
 315 unset ac_cv_type_uint64_t
 316 unset ac_cv_type_intmax_t
 317 unset ac_cv_type_uintmax_t
 318
 319 ### See what's provided by inttypes.h
 320 if test "$ac_cv_header_inttypes_h" = yes; then
 321   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 322   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 323   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 324   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 325   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 326   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 327   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 328   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 329   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 330   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 331 fi
 332
 333 # Try hard to find definitions for some required scm_t_*int* types.
 334
 335 ### Required type scm_t_int8
 336 if test "$scm_stdint_has_int8"; then
 337   SCM_I_GSC_T_INT8='"int8_t"'
 338   SCM_I_GSC_NEEDS_STDINT_H=1
 339 elif test "$scm_inttypes_has_int8"; then
 340   SCM_I_GSC_T_INT8='"int8_t"'
 341   SCM_I_GSC_NEEDS_INTTYPES_H=1
 342 elif test "$ac_cv_sizeof_char" -eq 1; then
 343   SCM_I_GSC_T_INT8='"signed char"'
 344 else
 345   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 346 fi
 347 AC_SUBST([SCM_I_GSC_T_INT8])
 348
 349 ### Required type scm_t_uint8
 350 if test "$scm_stdint_has_uint8"; then
 351   SCM_I_GSC_T_UINT8='"uint8_t"'
 352   SCM_I_GSC_NEEDS_STDINT_H=1
 353 elif test "$scm_inttypes_has_uint8"; then
 354   SCM_I_GSC_T_UINT8='"uint8_t"'
 355   SCM_I_GSC_NEEDS_INTTYPES_H=1
 356 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 357   SCM_I_GSC_T_UINT8='"unsigned char"'
 358 else
 359   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 360 fi
 361 AC_SUBST([SCM_I_GSC_T_UINT8])
 362
 363 ### Required type scm_t_int16 (ANSI C says int or short might work)
 364 if test "$scm_stdint_has_int16"; then
 365   SCM_I_GSC_T_INT16='"int16_t"'
 366   SCM_I_GSC_NEEDS_STDINT_H=1
 367 elif test "$scm_inttypes_has_int16"; then
 368   SCM_I_GSC_T_INT16='"int16_t"'
 369   SCM_I_GSC_NEEDS_INTTYPES_H=1
 370 elif test "$ac_cv_sizeof_int" -eq 2; then
 371   SCM_I_GSC_T_INT16='"int"'
 372 elif test "$ac_cv_sizeof_short" -eq 2; then
 373   SCM_I_GSC_T_INT16='"short"'
 374 else
 375   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 376 fi
 377 AC_SUBST([SCM_I_GSC_T_INT16])
 378
 379 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 380 if test "$scm_stdint_has_uint16"; then
 381   SCM_I_GSC_T_UINT16='"uint16_t"'
 382   SCM_I_GSC_NEEDS_STDINT_H=1
 383 elif test "$scm_inttypes_has_uint16"; then
 384   SCM_I_GSC_T_UINT16='"uint16_t"'
 385   SCM_I_GSC_NEEDS_INTTYPES_H=1
 386 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 387   SCM_I_GSC_T_UINT16='"unsigned int"'
 388 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 389   SCM_I_GSC_T_UINT16='"unsigned short"'
 390 else
 391   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 392 fi
 393 AC_SUBST([SCM_I_GSC_T_UINT16])
 394
 395
 396 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 397 if test "$scm_stdint_has_int32"; then
 398   SCM_I_GSC_T_INT32='"int32_t"'
 399   SCM_I_GSC_NEEDS_STDINT_H=1
 400 elif test "$scm_inttypes_has_int32"; then
 401   SCM_I_GSC_T_INT32='"int32_t"'
 402   SCM_I_GSC_NEEDS_INTTYPES_H=1
 403 elif test "$ac_cv_sizeof_int" -eq 4; then
 404   SCM_I_GSC_T_INT32='"int"'
 405 elif test "$ac_cv_sizeof_long" -eq 4; then
 406   SCM_I_GSC_T_INT32='"long"'
 407 elif test "$ac_cv_sizeof_short" -eq 4; then
 408   SCM_I_GSC_T_INT32='"short"'
 409 else
 410   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 411 fi
 412 AC_SUBST([SCM_I_GSC_T_INT32])
 413
 414 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 415 if test "$scm_stdint_has_uint32"; then
 416   SCM_I_GSC_T_UINT32='"uint32_t"'
 417   SCM_I_GSC_NEEDS_STDINT_H=1
 418 elif test "$scm_inttypes_has_uint32"; then
 419   SCM_I_GSC_T_UINT32='"uint32_t"'
 420   SCM_I_GSC_NEEDS_INTTYPES_H=1
 421 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 422   SCM_I_GSC_T_UINT32='"unsigned int"'
 423 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 424   SCM_I_GSC_T_UINT32='"unsigned long"'
 425 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 426   SCM_I_GSC_T_UINT32='"unsigned short"'
 427 else
 428   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 429 fi
 430 AC_SUBST([SCM_I_GSC_T_UINT32])
 431
 432 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 433 ### Also try 'long long' and '__int64' if we have it.
 434 SCM_I_GSC_T_INT64=0
 435 if test "$scm_stdint_has_int64"; then
 436   SCM_I_GSC_T_INT64='"int64_t"'
 437   SCM_I_GSC_NEEDS_STDINT_H=1
 438 elif test "$scm_inttypes_has_int64"; then
 439   SCM_I_GSC_T_INT64='"int64_t"'
 440   SCM_I_GSC_NEEDS_INTTYPES_H=1
 441 elif test "$ac_cv_sizeof_int" -eq 8; then
 442   SCM_I_GSC_T_INT64='"int"'
 443 elif test "$ac_cv_sizeof_long" -eq 8; then
 444   SCM_I_GSC_T_INT64='"long"'
 445 elif test "$ac_cv_sizeof_short" -eq 8; then
 446   SCM_I_GSC_T_INT64='"short"'
 447 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 448   SCM_I_GSC_T_INT64='"long long"'
 449 elif test "$ac_cv_sizeof___int64" -eq 8; then
 450   SCM_I_GSC_T_INT64='"__int64"'
 451 else
 452   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 453 fi
 454 AC_SUBST([SCM_I_GSC_T_INT64])
 455
 456
 457 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 458 ### Also try 'long long' and '__int64' if we have it.
 459 SCM_I_GSC_T_UINT64=0
 460 if test "$scm_stdint_has_uint64"; then
 461   SCM_I_GSC_T_UINT64='"uint64_t"'
 462   SCM_I_GSC_NEEDS_STDINT_H=1
 463 elif test "$scm_inttypes_has_uint64"; then
 464   SCM_I_GSC_T_UINT64='"uint64_t"'
 465   SCM_I_GSC_NEEDS_INTTYPES_H=1
 466 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 467   SCM_I_GSC_T_UINT64='"unsigned int"'
 468 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 469   SCM_I_GSC_T_UINT64='"unsigned long"'
 470 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 471   SCM_I_GSC_T_UINT64='"unsigned short"'
 472 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 473   SCM_I_GSC_T_UINT64='"unsigned long long"'
 474 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 475   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 476 else
 477   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 478 fi
 479 AC_SUBST([SCM_I_GSC_T_UINT64])
 480
 481 ### Required type scm_t_intmax
 482 ###
 483 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 484 ### none of them is available, we use 'long'.
 485 ###
 486 SCM_I_GSC_T_INTMAX=0
 487 if test "$scm_stdint_has_intmax"; then
 488   SCM_I_GSC_T_INTMAX='"intmax_t"'
 489   SCM_I_GSC_NEEDS_STDINT_H=1
 490 elif test "$scm_inttypes_has_intmax"; then
 491   SCM_I_GSC_T_INTMAX='"intmax_t"'
 492   SCM_I_GSC_NEEDS_INTTYPES_H=1
 493 elif test "$ac_cv_sizeof___int64" -ne 0; then
 494   SCM_I_GSC_T_INTMAX='"__int64"'
 495 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 496   SCM_I_GSC_T_INTMAX='"long long"'
 497 else
 498   SCM_I_GSC_T_INTMAX='"long"'
 499 fi
 500 AC_SUBST([SCM_I_GSC_T_INTMAX])
 501
 502 ### Required type scm_t_uintmax
 503 ###
 504 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 505 ### this order.  When none of them is available, we use 'unsigned long'.
 506 ###
 507 SCM_I_GSC_T_UINTMAX=0
 508 if test "$scm_stdint_has_uintmax"; then
 509   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 510   SCM_I_GSC_NEEDS_STDINT_H=1
 511 elif test "$scm_inttypes_has_uintmax"; then
 512   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 513   SCM_I_GSC_NEEDS_INTTYPES_H=1
 514 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 515   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 516 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 517   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 518 else
 519   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 520 fi
 521 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 522
 523
 524 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 525 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 526
 527 AC_HEADER_STDC
 528 AC_HEADER_DIRENT
 529 AC_HEADER_TIME
 530 AC_HEADER_SYS_WAIT
 531
 532 # Reasons for testing:
 533 #   fenv.h - available in C99, but not older systems
 534 #
 535 AC_CHECK_HEADERS([fenv.h io.h libc.h limits.h malloc.h memory.h string.h \
 536 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 537 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 538 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 539 direct.h])
 540
 541 GUILE_HEADER_LIBC_WITH_UNISTD
 542
 543 AC_TYPE_GETGROUPS
 544 AC_TYPE_SIGNAL
 545 AC_TYPE_MODE_T
 546
 547 if test $MINGW32 = no; then
 548         AC_CHECK_LIB(m, main)
 549 fi
 550 AC_CHECK_FUNCS(gethostbyname)
 551 if test $ac_cv_func_gethostbyname = no; then
 552     AC_CHECK_LIB(nsl, gethostbyname)
 553 fi
 554
 555 AC_CHECK_FUNCS(connect)
 556 if test $ac_cv_func_connect = no; then
 557     AC_CHECK_LIB(socket, connect)
 558 fi
 559
 560 dnl
 561 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 562 dnl
 563 EXTRA_DEFS=""
 564 if test "$MINGW32" = "yes" ; then
 565     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 566       [Define if you have the <winsock2.h> header file.])])
 567     AC_CHECK_LIB(ws2_32, main)
 568     AC_LIBOBJ([win32-uname])
 569     AC_LIBOBJ([win32-dirent])
 570     if test "$enable_networking" = yes ; then
 571       AC_LIBOBJ([win32-socket])
 572     fi
 573     if test "$enable_shared" = yes ; then
 574       EXTRA_DEFS="-DSCM_IMPORT"
 575       AC_DEFINE(USE_DLL_IMPORT, 1,
 576         [Define if you need additional CPP macros on Win32 platforms.])
 577     fi
 578     if test x"$enable_ltdl_install" = x"yes" ; then
 579       INCLTDL="-DLIBLTDL_DLL_IMPORT $INCLTDL"
 580     fi
 581 fi
 582 AC_SUBST(EXTRA_DEFS)
 583
 584 # FIXME: check to see if we still need these.
 585 #AC_SUBST(INCLTDL)
 586 #AC_SUBST(LIBLTDL)
 587
 588 AC_SUBST(DLPREOPEN)
 589
 590 # Reasons for testing:
 591 #   crt_externs.h - Darwin specific
 592 #
 593 AC_CHECK_HEADERS([assert.h crt_externs.h])
 594
 595 # Reasons for testing:
 596 #   DINFINITY - OSF specific
 597 #   DQNAN - OSF specific
 598 #       (DINFINITY and DQNAN are actually global variables, not functions)
 599 #   fesetround - available in C99, but not older systems
 600 #   gmtime_r - recent posix, not on old systems
 601 #   readdir_r - recent posix, not on old systems
 602 #   sysconf - not on old systems
 603 #   _NSGetEnviron - Darwin specific
 604 #
 605 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid fesetround ftime fchown getcwd geteuid gettimeofday gmtime_r lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv _NSGetEnviron])
 606
 607 # Reasons for testing:
 608 #   netdb.h - not in mingw
 609 #   sys/param.h - not in mingw
 610 #
 611 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 612 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 613
 614 # crypt() may or may not be available, for instance in some countries there
 615 # are restrictions on cryptography.
 616 #
 617 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 618 # -lcrypt library (eg. Debian GNU/Linux).
 619 #
 620 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 621 # be careful to avoid -lcrypt in this case, since libtool will see there's
 622 # only a static libcrypt and decide to build only a static libguile.
 623 #
 624 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 625 # libraries already in that list.
 626 #
 627 AC_SEARCH_LIBS(crypt, crypt,
 628   [AC_DEFINE(HAVE_CRYPT,1,
 629              [Define to 1 if you have the `crypt' function.])])
 630
 631 dnl GMP tests
 632 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 633   [AC_MSG_ERROR([GNU MP not found, see http://swox.com/gmp])])
 634
 635 # mpz_import is a macro so we need to include <gmp.h>
 636 AC_TRY_LINK([#include <gmp.h>],
 637             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 638   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see http://swox.com/gmp])])
 639
 640 dnl i18n tests
 641 AM_GNU_GETTEXT([external], [need-ngettext])
 642
 643 ### Some systems don't declare some functions.  On such systems, we
 644 ### need to at least provide our own K&R-style declarations.
 645
 646 ### GUILE_FUNC_DECLARED(function, headerfile)
 647
 648 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 649 ### not there, #define MISSING_FUNCTION_DECL.
 650 AC_DEFUN([GUILE_FUNC_DECLARED], [
 651   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 652     AC_EGREP_HEADER($1, $2,
 653                     guile_cv_func_$1_declared=yes,
 654                     guile_cv_func_$1_declared=no))
 655   if test [x$guile_cv_func_]$1[_declared] = xno; then
 656     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 657       [Define if the operating system supplies $1 without declaring it.])
 658   fi
 659 ])
 660
 661 GUILE_FUNC_DECLARED(sleep, unistd.h)
 662 GUILE_FUNC_DECLARED(usleep, unistd.h)
 663
 664 AC_CHECK_DECLS([strptime],,,
 665 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 666 #include <time.h>])
 667
 668 ### On some systems usleep has no return value.  If it does have one,
 669 ### we'd like to return it; otherwise, we'll fake it.
 670 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 671   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 672                    unistd.h,
 673                    [guile_cv_func_usleep_return_type=void],
 674                    [guile_cv_func_usleep_return_type=int])])
 675 case "$guile_cv_func_usleep_return_type" in
 676   "void" )
 677     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 678       [Define if the system headers declare usleep to return void.])
 679   ;;
 680 esac
 681
 682 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 683 if test -n "$have_sys_un_h" ; then
 684   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 685     [Define if the system supports Unix-domain (file-domain) sockets.])
 686 fi
 687
 688 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 689
 690 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 691                setnetent    getnetent    endnetent    dnl
 692                setprotoent  getprotoent  endprotoent  dnl
 693                setservent   getservent   endservent   dnl
 694                getnetbyaddr getnetbyname dnl
 695                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 696                inet_pton inet_ntop)
 697
 698 # struct sockaddr field sin_len is only present on BSD systems.
 699 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 700 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 701 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 702 [#ifdef HAVE_SYS_TYPES_H
 703 #include <sys/types.h>
 704 #endif
 705 #include <netinet/in.h>])
 706
 707 AC_MSG_CHECKING(for __libc_stack_end)
 708 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 709 [AC_TRY_LINK([#include <stdio.h>
 710 extern char *__libc_stack_end;],
 711              [printf("%p", (char*) __libc_stack_end);],
 712              guile_cv_have_libc_stack_end=yes,
 713              guile_cv_have_libc_stack_end=no)])
 714 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 715
 716 if test $guile_cv_have_libc_stack_end = yes; then
 717   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 718            [Define if you have the __libc_stack_end variable.])
 719 fi
 720
 721 dnl Some systems do not declare this.  Some systems do declare it, as a
 722 dnl macro.  With cygwin it may be in a DLL.
 723
 724 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 725 AC_CACHE_VAL(guile_cv_have_h_errno,
 726 [AC_TRY_COMPILE([#include <netdb.h>],
 727 [int a = h_errno;],
 728 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 729 AC_MSG_RESULT($guile_cv_have_h_errno)
 730 if test $guile_cv_have_h_errno = yes; then
 731   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 732 fi
 733
 734 AC_MSG_CHECKING(whether uint32_t is defined)
 735 AC_CACHE_VAL(guile_cv_have_uint32_t,
 736   [AC_TRY_COMPILE([#include <sys/types.h>
 737                    #if HAVE_STDINT_H
 738                    #include <stdint.h>
 739                    #endif
 740                    #ifndef __MINGW32__
 741                    #include <netdb.h>
 742                    #endif],
 743                   [uint32_t a;],
 744                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 745 AC_MSG_RESULT($guile_cv_have_uint32_t)
 746 if test $guile_cv_have_uint32_t = yes; then
 747   AC_DEFINE(HAVE_UINT32_T, 1,
 748     [Define if uint32_t typedef is defined when netdb.h is include.])
 749 fi
 750
 751 AC_MSG_CHECKING(for working IPv6 support)
 752 AC_CACHE_VAL(guile_cv_have_ipv6,
 753 [AC_TRY_COMPILE([
 754 #ifdef HAVE_SYS_TYPES_H
 755 #include <sys/types.h>
 756 #endif
 757 #include <netinet/in.h>
 758 #include <sys/socket.h>],
 759 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 760 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 761 AC_MSG_RESULT($guile_cv_have_ipv6)
 762 if test $guile_cv_have_ipv6 = yes; then
 763   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 764 fi
 765
 766 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 767 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 768 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 769 [AC_TRY_COMPILE([
 770 #ifdef HAVE_SYS_TYPES_H
 771 #include <sys/types.h>
 772 #endif
 773 #include <netinet/in.h>],
 774 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 775 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 776 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 777 if test $guile_cv_have_sin6_scope_id = yes; then
 778   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 779     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 780 fi
 781
 782 # struct sockaddr_in6 field sin_len is only present on BSD systems
 783 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 784 [#ifdef HAVE_SYS_TYPES_H
 785 #include <sys/types.h>
 786 #endif
 787 #include <netinet/in.h>])
 788
 789 AC_MSG_CHECKING(whether localtime caches TZ)
 790 AC_CACHE_VAL(guile_cv_localtime_cache,
 791 [if test x$ac_cv_func_tzset = xyes; then
 792 AC_TRY_RUN([#include <time.h>
 793 #if STDC_HEADERS
 794 # include <stdlib.h>
 795 #endif
 796 extern char **environ;
 797 unset_TZ ()
 798 {
 799   char **from, **to;
 800   for (to = from = environ; (*to = *from); from++)
 801     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 802       to++;
 803 }
 804 char TZ_GMT0[] = "TZ=GMT0";
 805 char TZ_PST8[] = "TZ=PST8";
 806 main()
 807 {
 808   time_t now = time ((time_t *) 0);
 809   int hour_GMT0, hour_unset;
 810   if (putenv (TZ_GMT0) != 0)
 811     exit (1);
 812   hour_GMT0 = localtime (&now)->tm_hour;
 813   unset_TZ ();
 814   hour_unset = localtime (&now)->tm_hour;
 815   if (putenv (TZ_PST8) != 0)
 816     exit (1);
 817   if (localtime (&now)->tm_hour == hour_GMT0)
 818     exit (1);
 819   unset_TZ ();
 820   if (localtime (&now)->tm_hour != hour_unset)
 821     exit (1);
 822   exit (0);
 823 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 824 [# If we have tzset, assume the worst when cross-compiling.
 825 guile_cv_localtime_cache=yes])
 826 else
 827         # If we lack tzset, report that localtime does not cache TZ,
 828         # since we can't invalidate the cache if we don't have tzset.
 829         guile_cv_localtime_cache=no
 830 fi])dnl
 831 AC_MSG_RESULT($guile_cv_localtime_cache)
 832 if test $guile_cv_localtime_cache = yes; then
 833   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 834 fi
 835
 836 dnl Test whether system calls are restartable by default on the
 837 dnl current system.  If they are not, we put a loop around every system
 838 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 839 dnl change from the default behaviour.  On the other hand, if signals
 840 dnl are restartable then the loop is not installed and when libguile
 841 dnl initialises it also resets the behaviour of each signal to cause a
 842 dnl restart (in case a different runtime had a different default
 843 dnl behaviour for some reason: e.g., different versions of linux seem
 844 dnl to behave differently.)
 845
 846 AC_SYS_RESTARTABLE_SYSCALLS
 847
 848 if test "$enable_regex" = yes; then
 849    if test "$ac_cv_header_regex_h" = yes ||
 850       test "$ac_cv_header_rxposix_h" = yes ||
 851       test "$ac_cv_header_rx_rxposix_h" = yes; then
 852      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 853      [AC_CHECK_LIB(rx, main)
 854       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 855      [AC_CHECK_LIB(regex, main)
 856       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 857      )
 858      dnl The following should not be necessary, but for some reason
 859      dnl autoheader misses it if we don't include it!
 860      if test "$ac_cv_func_regcomp_norx" = yes ||
 861         test "$ac_cv_func_regcomp_regex" = yes ||
 862         test "$ac_cv_func_regcomp_rx" = yes; then
 863        AC_DEFINE(HAVE_REGCOMP, 1,
 864          [This is included as part of a workaround for a autoheader bug.])
 865      fi
 866    fi
 867 fi
 868
 869 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 870
 871 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 872
 873 # Reasons for testing:
 874 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 875 #                                older systems
 876 #   sincos - GLIBC extension
 877 #
 878 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
 879
 880 # C99 specifies isinf and isnan as macros.
 881 # HP-UX provides only macros, no functions.
 882 # glibc 2.3.2 provides both macros and functions.
 883 # IRIX 6.5 and Solaris 8 only provide functions.
 884 #
 885 # The following tests detect isinf and isnan either as functions or as
 886 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
 887 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
 888 #
 889 AC_MSG_CHECKING([for isinf])
 890 AC_LINK_IFELSE(
 891 [#include <math.h>
 892 int main () { return (isinf(0.0) != 0); }],
 893   [AC_MSG_RESULT([yes])
 894    AC_DEFINE(HAVE_ISINF, 1,
 895              [Define to 1 if you have the `isinf' macro or function.])],
 896   [AC_MSG_RESULT([no])])
 897 AC_MSG_CHECKING([for isnan])
 898 AC_LINK_IFELSE(
 899 [#include <math.h>
 900 #ifdef __MINGW32__
 901 #define isnan _isnan
 902 #endif
 903 int main () { return (isnan(0.0) != 0); }],
 904   [AC_MSG_RESULT([yes])
 905    AC_DEFINE(HAVE_ISNAN, 1,
 906              [Define to 1 if you have the `isnan' macro or function.])],
 907   [AC_MSG_RESULT([no])])
 908
 909 # We must have a proper stack-using alloca in order for stack-copying
 910 # continuations to work properly.  If we don't find a native one,
 911 # abort.
 912
 913 AC_FUNC_ALLOCA
 914 if test "$ALLOCA" = "alloca.o"
 915 then
 916   AC_ERROR([No native alloca found.])
 917 fi
 918
 919 AC_CHECK_MEMBERS([struct stat.st_rdev])
 920 AC_CHECK_MEMBERS([struct stat.st_blksize])
 921
 922 AC_STRUCT_ST_BLOCKS
 923
 924 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 925   [AC_TRY_CPP([#include <sys/stat.h>
 926                #ifndef S_ISLNK
 927                #error no S_ISLNK
 928                #endif],
 929                ac_cv_macro_S_ISLNK=yes,
 930                ac_cv_macro_S_ISLNK=no)])
 931 if test $ac_cv_macro_S_ISLNK = yes; then
 932   AC_DEFINE(HAVE_S_ISLNK, 1,
 933     [Define this if your system defines S_ISLNK in sys/stat.h.])
 934 fi
 935
 936 AC_STRUCT_TIMEZONE
 937 GUILE_STRUCT_UTIMBUF
 938
 939 #--------------------------------------------------------------------
 940 #
 941 # Which way does the stack grow?
 942 #
 943 #--------------------------------------------------------------------
 944
 945 SCM_I_GSC_STACK_GROWS_UP=0
 946 AC_TRY_RUN(aux (l) unsigned long l;
 947              { int x; exit (l >= ((unsigned long)&x)); }
 948            main () { int q; aux((unsigned long)&q); },
 949            [SCM_I_GSC_STACK_GROWS_UP=1],
 950            [],
 951            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
 952
 953 AC_CHECK_SIZEOF(float)
 954 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
 955     AC_DEFINE(SCM_SINGLES, 1,
 956               [Define this if floats are the same size as longs.])
 957 fi
 958
 959 AC_MSG_CHECKING(for struct linger)
 960 AC_CACHE_VAL(scm_cv_struct_linger,
 961         AC_TRY_COMPILE([
 962 #include <sys/types.h>
 963 #include <sys/socket.h>],
 964                         [struct linger lgr;  lgr.l_linger = 100],
 965                         scm_cv_struct_linger="yes",
 966                         scm_cv_struct_linger="no"))
 967 AC_MSG_RESULT($scm_cv_struct_linger)
 968 if test $scm_cv_struct_linger = yes; then
 969         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 970           [Define this if your system defines struct linger, for use with the
 971            getsockopt and setsockopt system calls.])
 972 fi
 973
 974
 975 AC_MSG_CHECKING(for struct timespec)
 976 AC_CACHE_VAL(scm_cv_struct_timespec,
 977         AC_TRY_COMPILE([
 978 #include <time.h>],
 979                         [struct timespec t;  t.tv_nsec = 100],
 980                         scm_cv_struct_timespec="yes",
 981                         scm_cv_struct_timespec="no"))
 982 AC_MSG_RESULT($scm_cv_struct_timespec)
 983 if test $scm_cv_struct_timespec = yes; then
 984   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 985     [Define this if your system defines struct timespec via <time.h>.])
 986 fi
 987
 988 #--------------------------------------------------------------------
 989 #
 990 # Flags for thread support
 991 #
 992 #--------------------------------------------------------------------
 993
 994 SCM_I_GSC_USE_PTHREAD_THREADS=0
 995 SCM_I_GSC_USE_NULL_THREADS=0
 996 SCM_I_GSC_USE_COOP_THREADS=0
 997 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
 998 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
 999 AC_SUBST([SCM_I_GSC_USE_COOP_THREADS])
1000
1001 ### What thread package has the user asked for?
1002 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1003             , with_threads=yes)
1004
1005 case "$with_threads" in
1006   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1007     ACX_PTHREAD(CC="$PTHREAD_CC"
1008       CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1009       LIBS="$PTHREAD_LIBS $LIBS"
1010       SCM_I_GSC_USE_PTHREAD_THREADS=1
1011       with_threads="pthreads",
1012       with_threads="null")
1013
1014     AC_MSG_CHECKING(if pthread_mutexattr_settype is declared)
1015     AC_CACHE_VAL(guile_cv_mutexattr_settype_declared,
1016       [AC_TRY_COMPILE([#include <pthread.h>],
1017           [int pthread_mutexattr_settype (int, int);],
1018           guile_cv_mutexattr_settype_declared=no,
1019           guile_cv_mutexattr_settype_declared=yes)])
1020     AC_MSG_RESULT($guile_cv_mutexattr_settype_declared)
1021     if test $guile_cv_mutexattr_settype_declared = yes; then
1022       AC_DEFINE(SCM_MUTEXATTR_SETTYPE_DECLARED, 1,
1023           [Define if pthread.h declares pthread_mutexattr_settype.])
1024     fi
1025
1026     AC_MSG_CHECKING(how to get a fast mutex)
1027     AC_CACHE_VAL(guile_cv_have_mutex_fast,
1028       [AC_TRY_COMPILE([#include <pthread.h>],
1029           [int a = PTHREAD_MUTEX_ADAPTIVE_NP;],
1030           guile_cv_have_mutex_fast=PTHREAD_MUTEX_ADAPTIVE_NP,
1031           guile_cv_have_mutex_fast=none)])
1032     AC_MSG_RESULT($guile_cv_have_mutex_fast)
1033     if test ! $guile_cv_have_mutex_fast = none; then
1034       AC_DEFINE_UNQUOTED(SCM_MUTEX_FAST, $guile_cv_have_mutex_fast,
1035           [The mutex kind enum for fast mutexes.])
1036     fi
1037
1038     AC_MSG_CHECKING(how to get a recursive mutex)
1039     AC_CACHE_VAL(guile_cv_have_mutex_recursive,
1040       [AC_TRY_COMPILE([#include <pthread.h>],
1041         [int a = PTHREAD_MUTEX_RECURSIVE_NP;],
1042          guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE_NP)
1043       if test -z "$guile_cv_have_mutex_recursive"; then
1044           AC_TRY_COMPILE([#include <pthread.h>],
1045             [int a = PTHREAD_MUTEX_RECURSIVE;],
1046             guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE,
1047             guile_cv_have_mutex_recursive=none)
1048         fi])
1049     AC_MSG_RESULT($guile_cv_have_mutex_recursive)
1050     if test ! $guile_cv_have_mutex_recursive = none; then
1051       AC_DEFINE_UNQUOTED(SCM_MUTEX_RECURSIVE, $guile_cv_have_mutex_recursive,
1052          [The mutex kind enum for recursive mutexes.])
1053     fi
1054
1055     # On Solaris, sched_yield lives in -lrt.
1056     AC_SEARCH_LIBS(sched_yield, rt)
1057
1058   ;;
1059 esac
1060
1061 case "$with_threads" in
1062   "pthreads")
1063   ;;
1064   "no" | "null")
1065     SCM_I_GSC_USE_NULL_THREADS=1
1066     with_threads="null-threads"
1067   ;;
1068   * )
1069     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1070   ;;
1071 esac
1072
1073 AC_MSG_CHECKING(what kind of threads to support)
1074 AC_MSG_RESULT($with_threads)
1075
1076 ## Cross building
1077 if test "$cross_compiling" = "yes"; then
1078   AC_MSG_CHECKING(cc for build)
1079   ## /usr/bin/cc still uses wrong assembler
1080   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1081   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1082 else
1083   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1084 fi
1085
1086 ## AC_MSG_CHECKING("if we are cross compiling")
1087 ## AC_MSG_RESULT($cross_compiling)
1088 if test "$cross_compiling" = "yes"; then
1089    AC_MSG_RESULT($CC_FOR_BUILD)
1090 fi
1091
1092 ## No need as yet to be more elaborate
1093 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1094
1095 AC_SUBST(cross_compiling)
1096 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1097 AC_SUBST(CCLD_FOR_BUILD)
1098
1099 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1100 ## --HOST is the platform that PACKAGE is compiled for.
1101 HOST_CC="$CC_FOR_BUILD"
1102 AC_SUBST(HOST_CC)
1103
1104 if test "$cross_compiling" = "yes"; then
1105   AC_MSG_CHECKING(guile for build)
1106   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1107 else
1108   GUILE_FOR_BUILD='$(preinstguile)'
1109 fi
1110
1111 ## AC_MSG_CHECKING("if we are cross compiling")
1112 ## AC_MSG_RESULT($cross_compiling)
1113 if test "$cross_compiling" = "yes"; then
1114    AC_MSG_RESULT($GUILE_FOR_BUILD)
1115 fi
1116 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1117 AC_SUBST(GUILE_FOR_BUILD)
1118
1119 ## If we're using GCC, ask for aggressive warnings.
1120 case "$GCC" in
1121   yes )
1122     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1123     ## much stuff with generic function pointers for that to really be
1124     ## less than exasperating.
1125     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1126     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1127     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1128     # Do this here so we don't screw up any of the tests above that might
1129     # not be "warning free"
1130     if test "${GUILE_ERROR_ON_WARNING}" = yes
1131     then
1132         CFLAGS="${CFLAGS} -Werror"
1133         enable_compile_warnings=no
1134     fi
1135     ;;
1136 esac
1137
1138 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
1139 ## -- I'm disabling it for now in the hopes that the newer autoconf
1140 ## will DTRT -- if not, we need to fix up the sed command to match the
1141 ## others...
1142 ##
1143 ## Remove fileblocks.o from the object list.  This file gets added by
1144 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
1145 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
1146
1147 ## If we're creating a shared library (using libtool!), then we'll
1148 ## need to generate a list of .lo files corresponding to the .o files
1149 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1150 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1151
1152 ## We also need to create corresponding .doc and .x files
1153 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1154 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1155
1156 AC_SUBST(GUILE_MAJOR_VERSION)
1157 AC_SUBST(GUILE_MINOR_VERSION)
1158 AC_SUBST(GUILE_MICRO_VERSION)
1159 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1160 AC_SUBST(GUILE_VERSION)
1161
1162 #######################################################################
1163 # library versioning
1164
1165 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1166 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1167 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1168 AC_SUBST(LIBGUILE_INTERFACE)
1169
1170 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1171 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1172 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1173 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1174 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1175
1176 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1177 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1178 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1179 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1180 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1181
1182 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1183 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1184 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1185 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1186 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1187
1188 #######################################################################
1189
1190 dnl Tell guile-config what flags guile users should link against.
1191 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
1192 AC_SUBST(GUILE_LIBS)
1193
1194 AC_SUBST(AWK)
1195 AC_SUBST(LIBLOBJS)
1196 AC_SUBST(EXTRA_DOT_DOC_FILES)
1197 AC_SUBST(EXTRA_DOT_X_FILES)
1198
1199 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1200 top_builddir_absolute=`pwd`
1201 AC_SUBST(top_builddir_absolute)
1202 top_srcdir_absolute=`(cd $srcdir && pwd)`
1203 AC_SUBST(top_srcdir_absolute)
1204
1205 # Additional SCM_I_GSC definitions are above.
1206 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1207 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1208 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1209 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1210 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1211 AC_SUBST([SCM_I_GSC_HAVE_ARRAYS])
1212 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1213 AC_SUBST([SCM_I_GSC_C_INLINE])
1214 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1215
1216 AC_CONFIG_FILES([
1217   Makefile
1218   am/Makefile
1219   benchmark-suite/Makefile
1220   doc/Makefile
1221   doc/goops/Makefile
1222   doc/r5rs/Makefile
1223   doc/ref/Makefile
1224   doc/tutorial/Makefile
1225   emacs/Makefile
1226   examples/Makefile
1227   examples/box-dynamic-module/Makefile
1228   examples/box-dynamic/Makefile
1229   examples/box-module/Makefile
1230   examples/box/Makefile
1231   examples/modules/Makefile
1232   examples/safe/Makefile
1233   examples/scripts/Makefile
1234   guile-config/Makefile
1235   ice-9/Makefile
1236   ice-9/debugger/Makefile
1237   ice-9/debugger/breakpoints/Makefile
1238   lang/Makefile
1239   lang/elisp/Makefile
1240   lang/elisp/internals/Makefile
1241   lang/elisp/primitives/Makefile
1242   libguile-ltdl/Makefile
1243   libguile-ltdl/upstream/Makefile
1244   libguile/Makefile
1245   oop/Makefile
1246   oop/goops/Makefile
1247   scripts/Makefile
1248   srfi/Makefile
1249   test-suite/Makefile
1250   test-suite/standalone/Makefile
1251 ])
1252
1253 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1254 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1255 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1256 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1257 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1258 AC_CONFIG_FILES([libguile/guile-snarf],
1259                 [chmod +x libguile/guile-snarf])
1260 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1261                 [chmod +x libguile/guile-doc-snarf])
1262 AC_CONFIG_FILES([libguile/guile-func-name-check],
1263                 [chmod +x libguile/guile-func-name-check])
1264 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1265                 [chmod +x libguile/guile-snarf-docs])
1266
1267 AC_OUTPUT
1268
1269 dnl Local Variables:
1270 dnl comment-start: "dnl "
1271 dnl comment-end: ""
1272 dnl comment-start-skip: "\\bdnl\\b\\s *"
1273 dnl End: