configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # Independent Subdirectories
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_CONFIG_SUBDIRS(guile-readline)
  36
  37 #--------------------------------------------------------------------
  38 #
  39 # User options
  40 #
  41 #--------------------------------------------------------------------
  42
  43 AC_ARG_ENABLE(guile-debug,
  44   [  --enable-guile-debug    include internal debugging functions],
  45   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  46     AC_DEFINE(GUILE_DEBUG)
  47   fi)
  48
  49 AC_ARG_ENABLE(debug-freelist,
  50   [  --enable-debug-freelist    Include garbage collector freelist debugging code],
  51   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  52     AC_DEFINE(GUILE_DEBUG_FREELIST)
  53   fi)
  54
  55 AC_ARG_ENABLE(arrays,
  56   [  --disable-arrays        omit array and uniform array support],,
  57   enable_arrays=yes)
  58
  59 AC_ARG_ENABLE(posix,
  60   [  --disable-posix         omit posix interfaces],,
  61   enable_posix=yes)
  62
  63 AC_ARG_ENABLE(networking,
  64   [  --disable-networking    omit networking interfaces],,
  65   enable_networking=yes)
  66
  67 AC_ARG_ENABLE(regex,
  68   [  --disable-regex         omit regular expression interfaces],,
  69   enable_regex=yes)
  70
  71 dnl The --disable-debug used to control these two.  But now they are
  72 dnl a required part of the distribution.
  73 AC_DEFINE(DEBUG_EXTENSIONS)
  74 AC_DEFINE(READER_EXTENSIONS)
  75
  76 dnl files which are destined for separate modules.
  77
  78 if test "$enable_arrays" = yes; then
  79    LIBOBJS="$LIBOBJS ramap.o unif.o"
  80    AC_DEFINE(HAVE_ARRAYS)
  81 fi
  82
  83 if test "$enable_posix" = yes; then
  84    LIBOBJS="$LIBOBJS filesys.o posix.o"
  85    AC_DEFINE(HAVE_POSIX)
  86 fi
  87
  88 if test "$enable_networking" = yes; then
  89    LIBOBJS="$LIBOBJS net_db.o socket.o"
  90    AC_DEFINE(HAVE_NETWORKING)
  91 fi
  92
  93 #--------------------------------------------------------------------
  94
  95 AC_LIBLTDL_CONVENIENCE
  96 AC_CONFIG_SUBDIRS(libltdl)
  97
  98 AC_PROG_CC
  99 AC_PROG_CPP
 100 AC_LIBTOOL_DLOPEN
 101
 102 AC_AIX
 103 AC_ISC_POSIX
 104 AC_MINIX
 105
 106 AM_PROG_CC_STDC
 107 AM_PROG_LIBTOOL
 108
 109 AC_C_CONST
 110 AC_C_INLINE
 111 AC_CHECK_SIZEOF(int)
 112 AC_CHECK_SIZEOF(long)
 113 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 114                AC_TRY_COMPILE(,
 115                               [long long a],
 116                               scm_cv_long_longs=yes,
 117                               scm_cv_long_longs=no))
 118 if test "$scm_cv_long_longs" = yes; then
 119   AC_DEFINE(HAVE_LONG_LONGS)
 120 fi
 121
 122 AC_HEADER_STDC
 123 AC_HEADER_DIRENT
 124 AC_HEADER_TIME
 125 AC_HEADER_SYS_WAIT
 126 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
 127 GUILE_HEADER_LIBC_WITH_UNISTD
 128
 129 AC_TYPE_GETGROUPS
 130 AC_TYPE_SIGNAL
 131 AC_TYPE_MODE_T
 132
 133 AC_CHECK_LIB(m, main)
 134 AC_CHECK_FUNCS(gethostbyname)
 135 if test $ac_cv_func_gethostbyname = no; then
 136     AC_CHECK_LIB(nsl, gethostbyname)
 137 fi
 138 AC_CHECK_FUNCS(connect)
 139 if test $ac_cv_func_connect = no; then
 140     AC_CHECK_LIB(socket, connect)
 141 fi
 142
 143 # Check for dynamic linking
 144
 145 use_modules=yes
 146 AC_ARG_WITH(modules,
 147 [  --with-modules[=FILES]  Add support for dynamic modules],
 148 use_modules="$withval")
 149 test -z "$use_modules" && use_modules=yes
 150 DLPREOPEN=
 151 if test "$use_modules" != no; then
 152   AC_DEFINE(DYNAMIC_LINKING)
 153   if test "$use_modules" = yes; then
 154     DLPREOPEN="-dlpreopen force"
 155   else
 156     DLPREOPEN="-export-dynamic"
 157     for module in $use_modules; do
 158       DLPREOPEN="$DLPREOPEN -dlopen $module"
 159     done
 160   fi
 161 fi
 162 AC_SUBST(INCLTDL)
 163 AC_SUBST(LIBLTDL)
 164 AC_SUBST(DLPREOPEN)
 165
 166 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep atexit on_exit)
 167
 168 ### Some systems don't declare some functions.  On such systems, we
 169 ### need to at least provide our own K&R-style declarations.
 170
 171 ### GUILE_FUNC_DECLARED(function, headerfile)
 172
 173 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 174 ### not there, #define MISSING_FUNCTION_DECL.
 175 AC_DEFUN(GUILE_FUNC_DECLARED, [
 176   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 177     AC_EGREP_HEADER($1, $2,
 178                     guile_cv_func_$1_declared=yes,
 179                     guile_cv_func_$1_declared=no))
 180   if test [x$guile_cv_func_]$1[_declared] = xno; then
 181     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 182   fi
 183 ])
 184
 185 GUILE_FUNC_DECLARED(strptime, time.h)
 186 GUILE_FUNC_DECLARED(bzero, string.h)
 187 GUILE_FUNC_DECLARED(sleep, unistd.h)
 188 GUILE_FUNC_DECLARED(usleep, unistd.h)
 189
 190 ### On some systems usleep has no return value.  If it does have one,
 191 ### we'd like to return it; otherwise, we'll fake it.
 192 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 193   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 194                    /usr/include/unistd.h,
 195                    [guile_cv_func_usleep_return_type=void],
 196                    [guile_cv_func_usleep_return_type=int])])
 197 case "$guile_cv_func_usleep_return_type" in
 198   "void" )
 199     AC_DEFINE(USLEEP_RETURNS_VOID)
 200   ;;
 201 esac
 202
 203 dnl <GNU-WIN32 hacks>
 204
 205 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 206 if test -n "$have_sys_un_h" ; then
 207 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 208 fi
 209
 210 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 211
 212 dnl I don't know what this prefixing of cygwin32_ is for.
 213 dnl scmconfig.h wasn't updated with the test results.
 214 dnl so use AC_CHECK_FUNCS for now.
 215
 216 dnl how about:
 217 dnl save confdefs.h
 218 dnl if test $ac_cv_cigwin = yes; then
 219 dnl   modify confdefs.h
 220 dnl fi
 221 dnl AC_CHECK_FUNCS...
 222 dnl restore confdefs.h
 223
 224 dnl cp confdefs.h confdefs.h.bak
 225 dnl for func in gethostent sethostent endhostent getnetent setnetent endnetent getprotoent setprotoent endprotoent getservent setservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof hstrerror; do
 226 dnl cp confdefs.h.bak confdefs.h
 227 dnl cat >> confdefs.h << EOF
 228 dnl #ifdef __CYGWIN32__
 229 dnl #define $func cygwin32_$func
 230 dnl #endif
 231 dnl EOF
 232 dnl AC_CHECK_FUNC($func)
 233 dnl done
 234 dnl cp confdefs.h.bak confdefs.h
 235
 236 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 237                setnetent    getnetent    endnetent    dnl
 238                setprotoent  getprotoent  endprotoent  dnl
 239                setservent   getservent   endservent   dnl
 240                getnetbyaddr getnetbyname dnl
 241                inet_lnaof inet_makeaddr inet_netof hstrerror)
 242
 243 dnl </GNU-WIN32 hacks>
 244
 245 AC_MSG_CHECKING(whether localtime caches TZ)
 246 AC_CACHE_VAL(guile_cv_localtime_cache,
 247 [if test x$ac_cv_func_tzset = xyes; then
 248 AC_TRY_RUN([#include <time.h>
 249 #if STDC_HEADERS
 250 # include <stdlib.h>
 251 #endif
 252 extern char **environ;
 253 unset_TZ ()
 254 {
 255   char **from, **to;
 256   for (to = from = environ; (*to = *from); from++)
 257     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 258       to++;
 259 }
 260 char TZ_GMT0[] = "TZ=GMT0";
 261 char TZ_PST8[] = "TZ=PST8";
 262 main()
 263 {
 264   time_t now = time ((time_t *) 0);
 265   int hour_GMT0, hour_unset;
 266   if (putenv (TZ_GMT0) != 0)
 267     exit (1);
 268   hour_GMT0 = localtime (&now)->tm_hour;
 269   unset_TZ ();
 270   hour_unset = localtime (&now)->tm_hour;
 271   if (putenv (TZ_PST8) != 0)
 272     exit (1);
 273   if (localtime (&now)->tm_hour == hour_GMT0)
 274     exit (1);
 275   unset_TZ ();
 276   if (localtime (&now)->tm_hour != hour_unset)
 277     exit (1);
 278   exit (0);
 279 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 280 [# If we have tzset, assume the worst when cross-compiling.
 281 guile_cv_localtime_cache=yes])
 282 else
 283         # If we lack tzset, report that localtime does not cache TZ,
 284         # since we can't invalidate the cache if we don't have tzset.
 285         guile_cv_localtime_cache=no
 286 fi])dnl
 287 AC_MSG_RESULT($guile_cv_localtime_cache)
 288 if test $guile_cv_localtime_cache = yes; then
 289   AC_DEFINE(LOCALTIME_CACHE)
 290 fi
 291
 292 dnl Test whether system calls are restartable by default on the
 293 dnl current system.  If they are not, we put a loop around every system
 294 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 295 dnl change from the default behaviour.  On the other hand, if signals
 296 dnl are restartable then the loop is not installed and when libguile
 297 dnl initialises it also resets the behaviour of each signal to cause a
 298 dnl restart (in case a different runtime had a different default
 299 dnl behaviour for some reason: e.g., different versions of linux seem
 300 dnl to behave differently.)
 301
 302 AC_SYS_RESTARTABLE_SYSCALLS
 303
 304 if test "$enable_regex" = yes; then
 305    if test "$ac_cv_header_regex_h" = yes ||
 306       test "$ac_cv_header_rxposix_h" = yes ||
 307       test "$ac_cv_header_rx_rxposix_h" = yes; then
 308      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 309      [AC_CHECK_LIB(rx, main)
 310       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 311      )
 312      dnl The following should not be necessary, but for some reason
 313      dnl autoheader misses it if we don't include it!
 314      if test "$ac_cv_func_regcomp_norx" = yes ||
 315         test "$ac_cv_func_regcomp_rx" = yes; then
 316        AC_DEFINE(HAVE_REGCOMP)
 317      fi
 318    fi
 319 fi
 320
 321 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
 322
 323 # When testing for the presence of alloca, we need to add alloca.o
 324 # explicitly to LIBOBJS to make sure that it is translated to
 325 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 326 AC_FUNC_ALLOCA
 327 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 328
 329 AC_STRUCT_ST_RDEV
 330 AC_STRUCT_ST_BLKSIZE
 331
 332 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 333 # LIBOBJS, which we don't need.  This seems more direct.
 334 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 335 [AC_TRY_COMPILE([#include <sys/types.h>
 336 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 337 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 338 if test $ac_cv_struct_st_blocks = yes; then
 339   AC_DEFINE(HAVE_ST_BLOCKS)
 340 fi
 341
 342 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 343   [AC_TRY_CPP([#include <sys/stat.h>
 344                #ifndef S_ISLNK
 345                #error no S_ISLNK
 346                #endif],
 347                ac_cv_macro_S_ISLNK=yes,
 348                ac_cv_macro_S_ISLNK=no)])
 349 if test $ac_cv_macro_S_ISLNK = yes; then
 350   AC_DEFINE(HAVE_S_ISLNK)
 351 fi
 352
 353 AC_STRUCT_TIMEZONE
 354 GUILE_STRUCT_UTIMBUF
 355
 356 #--------------------------------------------------------------------
 357 #
 358 # Which way does the stack grow?
 359 #
 360 #--------------------------------------------------------------------
 361
 362 AC_TRY_RUN(aux (l) unsigned long l;
 363              { int x; exit (l >= ((unsigned long)&x)); }
 364            main () { int q; aux((unsigned long)&q); },
 365            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 366
 367 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 368     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 369                 [guile_cv_type_float_fits_long=yes],
 370                 [guile_cv_type_float_fits_long=no],
 371                 [guile_cv_type_float_fits_long=guess-yes])])
 372 case $guile_cv_type_float_fits_long in
 373   "yes" )
 374     AC_DEFINE(SCM_SINGLES)
 375   ;;
 376   "guess-yes" )
 377     AC_DEFINE(SCM_SINGLES)
 378     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 379     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 380   ;;
 381 esac
 382
 383
 384 AC_MSG_CHECKING(for struct linger)
 385 AC_CACHE_VAL(scm_cv_struct_linger,
 386         AC_TRY_COMPILE([
 387 #include <sys/types.h>
 388 #include <sys/socket.h>],
 389                         [struct linger lgr;  lgr.l_linger = 100],
 390                         scm_cv_struct_linger="yes",
 391                         scm_cv_struct_linger="no"))
 392 AC_MSG_RESULT($scm_cv_struct_linger)
 393 if test $scm_cv_struct_linger = yes; then
 394         AC_DEFINE(HAVE_STRUCT_LINGER)
 395 fi
 396
 397
 398 AC_MSG_CHECKING(for struct timespec)
 399 AC_CACHE_VAL(scm_cv_struct_timespec,
 400         AC_TRY_COMPILE([
 401 #include <time.h>],
 402                         [struct timespec t;  t.tv_nsec = 100],
 403                         scm_cv_struct_timespec="yes",
 404                         scm_cv_struct_timespec="no"))
 405 AC_MSG_RESULT($scm_cv_struct_timespec)
 406 if test $scm_cv_struct_timespec = yes; then
 407         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 408 fi
 409
 410 #--------------------------------------------------------------------
 411 #
 412 # Flags for thread support
 413 #
 414 #--------------------------------------------------------------------
 415
 416 ### What thread package has the user asked for?
 417 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 418             , with_threads=no)
 419
 420 ### Turn $with_threads into either the name of a threads package, like
 421 ### `qt', or `no', meaning that threads should not be supported.
 422 AC_MSG_CHECKING(whether to support threads)
 423 case "$with_threads" in
 424   "yes" | "qt" | "coop" | "")
 425     with_threads=qt
 426   ;;
 427   "no" )
 428   ;;
 429   * )
 430     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 431   ;;
 432 esac
 433 AC_MSG_RESULT($with_threads)
 434
 435 ## Make sure the threads package we've chosen is actually supported on
 436 ## the present platform.
 437 case "${with_threads}" in
 438   "qt" )
 439     ## This configures the QuickThreads package, and sets or clears
 440     ## the THREAD_PACKAGE variable if qthreads don't configure
 441     ## correctly.
 442     QTHREADS_CONFIGURE
 443    ;;
 444 esac
 445
 446 ## If we're using threads, bring in some other parts of Guile which
 447 ## work with them.
 448 if test "${THREAD_PACKAGE}" != "" ; then
 449   AC_DEFINE(USE_THREADS, 1)
 450
 451   ## Include the Guile thread interface in the library...
 452   LIBOBJS="$LIBOBJS threads.o"
 453
 454   ## ... and tell it which package to talk to.
 455   case "${THREAD_PACKAGE}" in
 456     "QT" )
 457       AC_DEFINE(USE_COOP_THREADS, 1)
 458     ;;
 459     * )
 460       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 461     ;;
 462   esac
 463
 464   ## Bring in scm_internal_select, if appropriate.
 465   if test $ac_cv_func_gettimeofday = yes &&
 466      test $ac_cv_func_select = yes; then
 467     AC_DEFINE(GUILE_ISELECT, 1)
 468   fi
 469
 470   ## Workaround for linuxthreads (currently disabled)
 471   if test $host_os = linux-gnu; then
 472     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 473     AC_CHECK_LIB(pthread, main)
 474   fi
 475 fi
 476
 477 ## If we're using GCC, ask for aggressive warnings.
 478 case "$GCC" in
 479   yes )
 480     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 481     ## much stuff with generic function pointers for that to really be
 482     ## less than exasperating.
 483     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 484     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 485     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 486 esac
 487
 488 AC_PROG_AWK
 489
 490 ## If we're creating a shared library (using libtool!), then we'll
 491 ## need to generate a list of .lo files corresponding to the .o files
 492 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 493 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 494
 495 AC_SUBST(GUILE_MAJOR_VERSION)
 496 AC_SUBST(GUILE_MINOR_VERSION)
 497 AC_SUBST(GUILE_VERSION)
 498
 499 dnl Tell guile-config what flags guile users should link against.
 500 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 501 AC_SUBST(GUILE_LIBS)
 502
 503 AC_SUBST(AWK)
 504 AC_SUBST(LIBLOBJS)
 505
 506 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check libguile/guile-snarf.awk libguile/versiondat.h ice-9/Makefile qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check])
 507
 508 dnl Local Variables:
 509 dnl comment-start: "dnl "
 510 dnl comment-end: ""
 511 dnl comment-start-skip: "\\bdnl\\b\\s *"
 512 dnl End: