configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   8   2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   9
  10 This file is part of GUILE
  11
  12 GUILE is free software; you can redistribute it and/or modify it under
  13 the terms of the GNU Lesser General Public License as published by the
  14 Free Software Foundation; either version 3, or (at your option) any
  15 later version.
  16
  17 GUILE is distributed in the hope that it will be useful, but WITHOUT
  18 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  19 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  20 License for more details.
  21
  22 You should have received a copy of the GNU Lesser General Public
  23 License along with GUILE; see the file COPYING.LESSER.  If not, write
  24 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  25 Floor, Boston, MA 02110-1301, USA.
  26
  27 ]])
  28
  29 AC_PREREQ(2.61)
  30
  31 AC_INIT([GNU Guile],
  32         m4_esyscmd([build-aux/git-version-gen                                   \
  33           .tarball-version                                                      \
  34           's/^release_\([0-9][0-9]*\)-\([0-9][0-9]*\)-\([0-9][0-9]*\)/v\1.\2\.\3/g']),
  35         [bug-guile@gnu.org])
  36 AC_CONFIG_AUX_DIR([build-aux])
  37 AC_CONFIG_MACRO_DIR([m4])
  38 AC_CONFIG_SRCDIR(GUILE-VERSION)
  39
  40 AM_INIT_AUTOMAKE([gnu no-define -Wall -Wno-override])
  41 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  42
  43 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  44 AC_CONFIG_SRCDIR([GUILE-VERSION])
  45
  46 . $srcdir/GUILE-VERSION
  47 GUILE_VERSION="$PACKAGE_VERSION"
  48
  49 AC_CONFIG_HEADERS([config.h])
  50 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  51
  52 #--------------------------------------------------------------------
  53
  54 AC_LANG([C])
  55
  56 dnl Some more checks for Win32
  57 AC_CANONICAL_HOST
  58
  59 AC_LIBTOOL_WIN32_DLL
  60
  61 AC_PROG_INSTALL
  62 AC_PROG_CC
  63 gl_EARLY
  64 AC_PROG_CPP
  65 AC_PROG_SED
  66 AC_PROG_AWK
  67
  68 dnl Gnulib.
  69 gl_INIT
  70
  71 AC_PROG_CC_C89
  72
  73 # for per-target cflags in the libguile subdir
  74 AM_PROG_CC_C_O
  75
  76 AC_LIBTOOL_DLOPEN
  77 AC_PROG_LIBTOOL
  78
  79 AM_CONDITIONAL([HAVE_SHARED_LIBRARIES], [test "x$enable_shared" = "xyes"])
  80
  81 dnl Check for libltdl.
  82 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  83   [lt_dlopenext ("foo");])
  84 if test "x$HAVE_LIBLTDL" != "xyes"; then
  85   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
  86 fi
  87
  88 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  89 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  90
  91 AM_PATH_LISPDIR
  92
  93 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
  94   [Define to the host's GNU triplet.])
  95
  96 #--------------------------------------------------------------------
  97 #
  98 # User options (after above tests that may set default CFLAGS etc.)
  99 #
 100 #--------------------------------------------------------------------
 101
 102 GUILE_ERROR_ON_WARNING="no"
 103
 104 AC_ARG_ENABLE(error-on-warning,
 105   [  --enable-error-on-warning    treat compile warnings as errors],
 106   [case "${enableval}" in
 107      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 108      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 109      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 110    esac])
 111
 112 AC_ARG_ENABLE(debug-malloc,
 113   [  --enable-debug-malloc   include malloc debugging code],
 114   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 115     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 116       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 117   fi)
 118
 119 SCM_I_GSC_GUILE_DEBUG=0
 120 AC_ARG_ENABLE(guile-debug,
 121   [AS_HELP_STRING([--enable-guile-debug],
 122                   [include internal debugging functions])],
 123   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 124     SCM_I_GSC_GUILE_DEBUG=1
 125   fi)
 126
 127 AC_ARG_ENABLE(posix,
 128   [  --disable-posix         omit posix interfaces],,
 129   enable_posix=yes)
 130
 131 AC_ARG_ENABLE(networking,
 132   [  --disable-networking    omit networking interfaces],,
 133   enable_networking=yes)
 134
 135 AC_ARG_ENABLE(regex,
 136   [  --disable-regex         omit regular expression interfaces],,
 137   enable_regex=yes)
 138
 139 AC_ARG_ENABLE([deprecated],
 140   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 141
 142 if test "$enable_deprecated" = no; then
 143   SCM_I_GSC_ENABLE_DEPRECATED=0
 144   warn_default=no
 145 else
 146   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 147     warn_default=summary
 148   elif test "$enable_deprecated" = shutup; then
 149     warn_default=no
 150   else
 151     warn_default=$enable_deprecated
 152   fi
 153   SCM_I_GSC_ENABLE_DEPRECATED=1
 154 fi
 155 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 156 [Define this to control the default warning level for deprecated features.])
 157
 158 dnl  Added the following configure option in January 2008 following
 159 dnl  investigation of problems with "64" system and library calls on
 160 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 161 dnl  system has stat64, it will have all the other 64 APIs too; but on
 162 dnl  Darwin, stat64 is there but other APIs are missing.
 163 dnl
 164 dnl  It also appears, from the Darwin docs, that most system call APIs
 165 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 166 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 167 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 168 dnl
 169 dnl  A similar problem has been reported for HP-UX:
 170 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 171 dnl
 172 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 173 dnl  better than no Guile at all, we provide this option to suppress
 174 dnl  trying to use "64" calls.
 175 dnl
 176 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 177 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 178 dnl  missing out on that.  If so, someone can work on that in the future.
 179 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 180 dnl  wasn't building before.
 181 AC_MSG_CHECKING([whether to use system and library "64" calls])
 182 AC_ARG_WITH([64-calls],
 183   AS_HELP_STRING([--without-64-calls],
 184                  [don't attempt to use system and library calls with "64" in their names]),
 185   [use_64_calls=$withval],
 186   [use_64_calls=yes
 187    case $host in
 188      *-apple-darwin* )
 189        use_64_calls=no
 190        ;;
 191      powerpc-ibm-aix* )
 192        use_64_calls=no
 193        ;;
 194    esac])
 195 AC_MSG_RESULT($use_64_calls)
 196 case "$use_64_calls" in
 197   y* )
 198     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 199       [Define to 1 in order to try to use "64" versions of system and library calls.])
 200     ;;
 201 esac
 202
 203 #--------------------------------------------------------------------
 204
 205 dnl Check for dynamic linking
 206
 207 use_modules=yes
 208 AC_ARG_WITH(modules,
 209 [  --with-modules[=FILES]  Add support for dynamic modules],
 210 use_modules="$withval")
 211 test -z "$use_modules" && use_modules=yes
 212 DLPREOPEN=
 213 if test "$use_modules" != no; then
 214   if test "$use_modules" = yes; then
 215     DLPREOPEN="-dlpreopen force"
 216   else
 217     DLPREOPEN="-export-dynamic"
 218     for module in $use_modules; do
 219       DLPREOPEN="$DLPREOPEN -dlopen $module"
 220     done
 221   fi
 222 fi
 223
 224 dnl files which are destined for separate modules.
 225
 226 if test "$use_modules" != no; then
 227    AC_LIBOBJ([dynl])
 228 fi
 229
 230 if test "$enable_posix" = yes; then
 231    AC_LIBOBJ([filesys])
 232    AC_LIBOBJ([posix])
 233    AC_DEFINE([HAVE_POSIX], 1,
 234      [Define this if you want support for POSIX system calls in Guile.])
 235 fi
 236
 237 if test "$enable_networking" = yes; then
 238    AC_LIBOBJ([net_db])
 239    AC_LIBOBJ([socket])
 240    AC_DEFINE([HAVE_NETWORKING], 1,
 241      [Define this if you want support for networking in Guile.])
 242 fi
 243
 244 if test "$enable_debug_malloc" = yes; then
 245    AC_LIBOBJ([debug-malloc])
 246 fi
 247
 248 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 249
 250 AC_C_CONST
 251
 252 # "volatile" is used in a couple of tests below.
 253 AC_C_VOLATILE
 254
 255 AC_C_INLINE
 256 if test "$ac_cv_c_inline" != no; then
 257   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 258 else
 259   SCM_I_GSC_C_INLINE=NULL
 260 fi
 261 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 262
 263 AC_C_BIGENDIAN
 264
 265 AC_C_LABELS_AS_VALUES
 266
 267 AC_CHECK_SIZEOF(char)
 268 AC_CHECK_SIZEOF(unsigned char)
 269 AC_CHECK_SIZEOF(short)
 270 AC_CHECK_SIZEOF(unsigned short)
 271 AC_CHECK_SIZEOF(int)
 272 AC_CHECK_SIZEOF(unsigned int)
 273 AC_CHECK_SIZEOF(long)
 274 AC_CHECK_SIZEOF(unsigned long)
 275 AC_CHECK_SIZEOF(size_t)
 276 AC_CHECK_SIZEOF(long long)
 277 AC_CHECK_SIZEOF(unsigned long long)
 278 AC_CHECK_SIZEOF(__int64)
 279 AC_CHECK_SIZEOF(unsigned __int64)
 280 AC_CHECK_SIZEOF(void *)
 281 AC_CHECK_SIZEOF(intptr_t)
 282 AC_CHECK_SIZEOF(uintptr_t)
 283 AC_CHECK_SIZEOF(ptrdiff_t)
 284 AC_CHECK_SIZEOF(size_t)
 285 AC_CHECK_SIZEOF(off_t)
 286
 287 if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then
 288   AC_MSG_ERROR(long does not fit into a void*)
 289 fi
 290
 291 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 292   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 293 else
 294   SCM_I_GSC_T_PTRDIFF='"long"'
 295 fi
 296 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 297
 298 AC_CHECK_HEADERS([stdint.h])
 299 AC_CHECK_HEADERS([inttypes.h])
 300
 301 AC_CHECK_SIZEOF(intmax_t)
 302
 303 SCM_I_GSC_NEEDS_STDINT_H=0
 304 SCM_I_GSC_NEEDS_INTTYPES_H=0
 305
 306 ### intptr and uintptr (try not to use inttypes if we don't have to)
 307 if test "$ac_cv_header_inttypes_h" = yes; then
 308   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 309     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 310 #include <stdio.h>])
 311     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 312       SCM_I_GSC_NEEDS_INTTYPES_H=1
 313     fi
 314   fi
 315   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 316     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 317 #include <stdio.h>])
 318     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 319       SCM_I_GSC_NEEDS_INTTYPES_H=1
 320     fi
 321   fi
 322 fi
 323
 324 ### See what's provided by stdint.h
 325 if test "$ac_cv_header_stdint_h" = yes; then
 326    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 327    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 328    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 329    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 330    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 331    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 332    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 333    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 334    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 335    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 336    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 337    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 338 fi
 339
 340 # so we don't get confused by the cache (wish there was a better way
 341 # to check particular headers for the same type...)
 342
 343 unset ac_cv_type_int8_t
 344 unset ac_cv_type_uint8_t
 345 unset ac_cv_type_int16_t
 346 unset ac_cv_type_uint16_t
 347 unset ac_cv_type_int32_t
 348 unset ac_cv_type_uint32_t
 349 unset ac_cv_type_int64_t
 350 unset ac_cv_type_uint64_t
 351 unset ac_cv_type_intmax_t
 352 unset ac_cv_type_uintmax_t
 353
 354 ### See what's provided by inttypes.h
 355 if test "$ac_cv_header_inttypes_h" = yes; then
 356   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 357   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 358   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 359   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 360   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 361   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 362   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 363   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 364   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 365   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 366   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 367   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 368 fi
 369
 370 # Try hard to find definitions for some required scm_t_*int* types.
 371
 372 ### Required type scm_t_int8
 373 if test "$scm_stdint_has_int8"; then
 374   SCM_I_GSC_T_INT8='"int8_t"'
 375   SCM_I_GSC_NEEDS_STDINT_H=1
 376 elif test "$scm_inttypes_has_int8"; then
 377   SCM_I_GSC_T_INT8='"int8_t"'
 378   SCM_I_GSC_NEEDS_INTTYPES_H=1
 379 elif test "$ac_cv_sizeof_char" -eq 1; then
 380   SCM_I_GSC_T_INT8='"signed char"'
 381 else
 382   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 383 fi
 384 AC_SUBST([SCM_I_GSC_T_INT8])
 385
 386 ### Required type scm_t_uint8
 387 if test "$scm_stdint_has_uint8"; then
 388   SCM_I_GSC_T_UINT8='"uint8_t"'
 389   SCM_I_GSC_NEEDS_STDINT_H=1
 390 elif test "$scm_inttypes_has_uint8"; then
 391   SCM_I_GSC_T_UINT8='"uint8_t"'
 392   SCM_I_GSC_NEEDS_INTTYPES_H=1
 393 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 394   SCM_I_GSC_T_UINT8='"unsigned char"'
 395 else
 396   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 397 fi
 398 AC_SUBST([SCM_I_GSC_T_UINT8])
 399
 400 ### Required type scm_t_int16 (ANSI C says int or short might work)
 401 if test "$scm_stdint_has_int16"; then
 402   SCM_I_GSC_T_INT16='"int16_t"'
 403   SCM_I_GSC_NEEDS_STDINT_H=1
 404 elif test "$scm_inttypes_has_int16"; then
 405   SCM_I_GSC_T_INT16='"int16_t"'
 406   SCM_I_GSC_NEEDS_INTTYPES_H=1
 407 elif test "$ac_cv_sizeof_int" -eq 2; then
 408   SCM_I_GSC_T_INT16='"int"'
 409 elif test "$ac_cv_sizeof_short" -eq 2; then
 410   SCM_I_GSC_T_INT16='"short"'
 411 else
 412   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 413 fi
 414 AC_SUBST([SCM_I_GSC_T_INT16])
 415
 416 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 417 if test "$scm_stdint_has_uint16"; then
 418   SCM_I_GSC_T_UINT16='"uint16_t"'
 419   SCM_I_GSC_NEEDS_STDINT_H=1
 420 elif test "$scm_inttypes_has_uint16"; then
 421   SCM_I_GSC_T_UINT16='"uint16_t"'
 422   SCM_I_GSC_NEEDS_INTTYPES_H=1
 423 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 424   SCM_I_GSC_T_UINT16='"unsigned int"'
 425 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 426   SCM_I_GSC_T_UINT16='"unsigned short"'
 427 else
 428   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 429 fi
 430 AC_SUBST([SCM_I_GSC_T_UINT16])
 431
 432
 433 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 434 if test "$scm_stdint_has_int32"; then
 435   SCM_I_GSC_T_INT32='"int32_t"'
 436   SCM_I_GSC_NEEDS_STDINT_H=1
 437 elif test "$scm_inttypes_has_int32"; then
 438   SCM_I_GSC_T_INT32='"int32_t"'
 439   SCM_I_GSC_NEEDS_INTTYPES_H=1
 440 elif test "$ac_cv_sizeof_int" -eq 4; then
 441   SCM_I_GSC_T_INT32='"int"'
 442 elif test "$ac_cv_sizeof_long" -eq 4; then
 443   SCM_I_GSC_T_INT32='"long"'
 444 elif test "$ac_cv_sizeof_short" -eq 4; then
 445   SCM_I_GSC_T_INT32='"short"'
 446 else
 447   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 448 fi
 449 AC_SUBST([SCM_I_GSC_T_INT32])
 450
 451 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 452 if test "$scm_stdint_has_uint32"; then
 453   SCM_I_GSC_T_UINT32='"uint32_t"'
 454   SCM_I_GSC_NEEDS_STDINT_H=1
 455 elif test "$scm_inttypes_has_uint32"; then
 456   SCM_I_GSC_T_UINT32='"uint32_t"'
 457   SCM_I_GSC_NEEDS_INTTYPES_H=1
 458 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 459   SCM_I_GSC_T_UINT32='"unsigned int"'
 460 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 461   SCM_I_GSC_T_UINT32='"unsigned long"'
 462 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 463   SCM_I_GSC_T_UINT32='"unsigned short"'
 464 else
 465   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 466 fi
 467 AC_SUBST([SCM_I_GSC_T_UINT32])
 468
 469 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 470 ### Also try 'long long' and '__int64' if we have it.
 471 SCM_I_GSC_T_INT64=0
 472 if test "$scm_stdint_has_int64"; then
 473   SCM_I_GSC_T_INT64='"int64_t"'
 474   SCM_I_GSC_NEEDS_STDINT_H=1
 475 elif test "$scm_inttypes_has_int64"; then
 476   SCM_I_GSC_T_INT64='"int64_t"'
 477   SCM_I_GSC_NEEDS_INTTYPES_H=1
 478 elif test "$ac_cv_sizeof_int" -eq 8; then
 479   SCM_I_GSC_T_INT64='"int"'
 480 elif test "$ac_cv_sizeof_long" -eq 8; then
 481   SCM_I_GSC_T_INT64='"long"'
 482 elif test "$ac_cv_sizeof_short" -eq 8; then
 483   SCM_I_GSC_T_INT64='"short"'
 484 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 485   SCM_I_GSC_T_INT64='"long long"'
 486 elif test "$ac_cv_sizeof___int64" -eq 8; then
 487   SCM_I_GSC_T_INT64='"__int64"'
 488 else
 489   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 490 fi
 491 AC_SUBST([SCM_I_GSC_T_INT64])
 492
 493
 494 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 495 ### Also try 'long long' and '__int64' if we have it.
 496 SCM_I_GSC_T_UINT64=0
 497 if test "$scm_stdint_has_uint64"; then
 498   SCM_I_GSC_T_UINT64='"uint64_t"'
 499   SCM_I_GSC_NEEDS_STDINT_H=1
 500 elif test "$scm_inttypes_has_uint64"; then
 501   SCM_I_GSC_T_UINT64='"uint64_t"'
 502   SCM_I_GSC_NEEDS_INTTYPES_H=1
 503 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 504   SCM_I_GSC_T_UINT64='"unsigned int"'
 505 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 506   SCM_I_GSC_T_UINT64='"unsigned long"'
 507 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 508   SCM_I_GSC_T_UINT64='"unsigned short"'
 509 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 510   SCM_I_GSC_T_UINT64='"unsigned long long"'
 511 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 512   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 513 else
 514   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 515 fi
 516 AC_SUBST([SCM_I_GSC_T_UINT64])
 517
 518 ### Required type scm_t_intmax
 519 ###
 520 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 521 ### none of them is available, we use 'long'.
 522 ###
 523 SCM_I_GSC_T_INTMAX=0
 524 if test "$scm_stdint_has_intmax"; then
 525   SCM_I_GSC_T_INTMAX='"intmax_t"'
 526   SCM_I_GSC_NEEDS_STDINT_H=1
 527 elif test "$scm_inttypes_has_intmax"; then
 528   SCM_I_GSC_T_INTMAX='"intmax_t"'
 529   SCM_I_GSC_NEEDS_INTTYPES_H=1
 530 elif test "$ac_cv_sizeof___int64" -ne 0; then
 531   SCM_I_GSC_T_INTMAX='"__int64"'
 532 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 533   SCM_I_GSC_T_INTMAX='"long long"'
 534 else
 535   SCM_I_GSC_T_INTMAX='"long"'
 536 fi
 537 AC_SUBST([SCM_I_GSC_T_INTMAX])
 538
 539 ### Required type scm_t_uintmax
 540 ###
 541 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 542 ### this order.  When none of them is available, we use 'unsigned long'.
 543 ###
 544 SCM_I_GSC_T_UINTMAX=0
 545 if test "$scm_stdint_has_uintmax"; then
 546   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 547   SCM_I_GSC_NEEDS_STDINT_H=1
 548 elif test "$scm_inttypes_has_uintmax"; then
 549   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 550   SCM_I_GSC_NEEDS_INTTYPES_H=1
 551 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 552   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 553 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 554   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 555 else
 556   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 557 fi
 558 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 559
 560 ### Required type scm_t_intptr
 561 ###
 562 SCM_I_GSC_T_INTPTR=0
 563 if test "$scm_stdint_has_intptr"; then
 564   SCM_I_GSC_T_INTPTR='"intptr_t"'
 565   SCM_I_GSC_NEEDS_STDINT_H=1
 566 elif test "$scm_inttypes_has_intptr"; then
 567   SCM_I_GSC_T_INTPTR='"intptr_t"'
 568   SCM_I_GSC_NEEDS_INTTYPES_H=1
 569 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 570   SCM_I_GSC_T_INTPTR='"int"'
 571 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 572   SCM_I_GSC_T_INTPTR='"long"'
 573 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 574   SCM_I_GSC_T_INTPTR='"long long"'
 575 else
 576   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 577 fi
 578 AC_SUBST([SCM_I_GSC_T_INTPTR])
 579
 580 ### Required type scm_t_uintptr
 581 ###
 582 SCM_I_GSC_T_UINTPTR=0
 583 if test "$scm_stdint_has_uintptr"; then
 584   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 585   SCM_I_GSC_NEEDS_STDINT_H=1
 586 elif test "$scm_inttypes_has_uintptr"; then
 587   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 588   SCM_I_GSC_NEEDS_INTTYPES_H=1
 589 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 590   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 591 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 592   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 593 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 594   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 595 else
 596   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 597 fi
 598 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 599
 600
 601 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 602 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 603
 604 AC_HEADER_STDC
 605 AC_HEADER_TIME
 606 AC_HEADER_SYS_WAIT
 607 AC_HEADER_DIRENT
 608
 609 # Reason for checking:
 610 #
 611 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 612 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 613 #
 614 AC_CHECK_MEMBER([struct dirent64.d_name],
 615   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 616   [ #ifndef _LARGEFILE64_SOURCE
 617     # define _LARGEFILE64_SOURCE
 618     #endif
 619
 620     /* Per Autoconf manual.  */
 621     #include <sys/types.h>
 622     #ifdef HAVE_DIRENT_H
 623     # include <dirent.h>
 624     #else
 625     # define dirent direct
 626     # ifdef HAVE_SYS_NDIR_H
 627     #  include <sys/ndir.h>
 628     # endif
 629     # ifdef HAVE_SYS_DIR_H
 630     #  include <sys/dir.h>
 631     # endif
 632     # ifdef HAVE_NDIR_H
 633     #  include <ndir.h>
 634     # endif
 635     #endif ])
 636 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 637
 638 # Reasons for testing:
 639 #   complex.h - new in C99
 640 #   fenv.h - available in C99, but not older systems
 641 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 642 #     this file instead of <fenv.h>
 643 #   process.h - mingw specific
 644 #   langinfo.h, nl_types.h - SuS v2
 645 #
 646 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 647 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 648 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 649 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 650 direct.h langinfo.h nl_types.h machine/fpu.h poll.h])
 651
 652 # Reasons for testing:
 653 #   nl_item - lacking on Cygwin
 654 AC_CHECK_TYPES([nl_item], [], [],
 655   [[#ifdef HAVE_LANGINFO_H
 656     # include <langinfo.h>
 657     #endif
 658     #ifdef HAVE_NL_TYPES_H
 659     # include <nl_types.h>
 660     #endif]])
 661
 662 # "complex double" is new in C99, and "complex" is only a keyword if
 663 # <complex.h> is included
 664 AC_CHECK_TYPES(complex double,,,
 665 [#if HAVE_COMPLEX_H
 666 #include <complex.h>
 667 #endif])
 668
 669 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 670 # when testing.
 671 AC_CHECK_TYPE(socklen_t, ,
 672   [AC_DEFINE_UNQUOTED([socklen_t], int,
 673                       [Define to `int' if <sys/socket.h> does not define.])],
 674   [#if HAVE_SYS_TYPES_H
 675 #include <sys/types.h>
 676 #endif
 677 #include <sys/socket.h>
 678 ])
 679
 680 AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>])
 681
 682 GUILE_HEADER_LIBC_WITH_UNISTD
 683
 684 AC_TYPE_GETGROUPS
 685 AC_TYPE_SIGNAL
 686 AC_TYPE_MODE_T
 687
 688 # On mingw -lm is empty, so this test is unnecessary, but it's
 689 # harmless so we don't hard-code to suppress it.
 690 #
 691 AC_CHECK_LIB(m, cos)
 692
 693 AC_CHECK_FUNCS(gethostbyname)
 694 if test $ac_cv_func_gethostbyname = no; then
 695     AC_CHECK_LIB(nsl, gethostbyname)
 696 fi
 697
 698 AC_CHECK_FUNCS(connect)
 699 if test $ac_cv_func_connect = no; then
 700     AC_CHECK_LIB(socket, connect)
 701 fi
 702
 703 dnl
 704 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 705 dnl
 706 EXTRA_DEFS=""
 707 case $host in
 708   *-*-mingw*)
 709     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 710       [Define if you have the <winsock2.h> header file.])])
 711     AC_CHECK_LIB(ws2_32, main)
 712     AC_LIBOBJ([win32-uname])
 713     AC_LIBOBJ([win32-dirent])
 714     if test "$enable_networking" = yes ; then
 715       AC_LIBOBJ([win32-socket])
 716     fi
 717     if test "$enable_shared" = yes ; then
 718       EXTRA_DEFS="-DSCM_IMPORT"
 719       AC_DEFINE([USE_DLL_IMPORT], 1,
 720         [Define if you need additional CPP macros on Win32 platforms.])
 721     fi
 722     ;;
 723 esac
 724 AC_SUBST(EXTRA_DEFS)
 725
 726 # Reasons for testing:
 727 #   crt_externs.h - Darwin specific
 728 #
 729 AC_CHECK_HEADERS([assert.h crt_externs.h])
 730
 731 # Reasons for testing:
 732 #   DINFINITY - OSF specific
 733 #   DQNAN - OSF specific
 734 #       (DINFINITY and DQNAN are actually global variables, not functions)
 735 #   chsize - an MS-DOS-ism, found in mingw
 736 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 737 #       for gcc to provide the "complex double" type but the system to not
 738 #       have functions like cexp and clog
 739 #   clog10 - not in mingw (though others like clog and csqrt are)
 740 #   fesetround - available in C99, but not older systems
 741 #   ftruncate - posix, but probably not older systems (current mingw
 742 #               has it as an inline for chsize)
 743 #   ioctl - not in mingw.
 744 #   gmtime_r - recent posix, not on old systems
 745 #   pipe - not in mingw
 746 #   _pipe - specific to mingw, taking 3 args
 747 #   poll - since posix 2001
 748 #   readdir_r - recent posix, not on old systems
 749 #   readdir64_r - not available on HP-UX 11.11
 750 #   stat64 - SuS largefile stuff, not on old systems
 751 #   sysconf - not on old systems
 752 #   truncate - not in mingw
 753 #   isblank - available as a GNU extension or in C99
 754 #   _NSGetEnviron - Darwin specific
 755 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 756 #   nl_langinfo - X/Open, not available on Windows.
 757 #   utimensat: posix.1-2008
 758 #   sched_getaffinity, sched_setaffinity: GNU extensions (glibc)
 759 #
 760 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe poll readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat sched_getaffinity sched_setaffinity])
 761
 762 # Reasons for testing:
 763 #   netdb.h - not in mingw
 764 #   sys/param.h - not in mingw
 765 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 766 #       check this specifically, we need it for the timespec test below.
 767 #   sethostname - the function itself check because it's not in mingw,
 768 #       the DECL is checked because Solaris 10 doens't have in any header
 769 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 770 #       declaration isn't anywhere.
 771 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 772 #       only with `_XOPEN_SOURCE' or some such.
 773 #
 774 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h])
 775 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 776 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 777
 778 # crypt() may or may not be available, for instance in some countries there
 779 # are restrictions on cryptography.
 780 #
 781 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 782 # -lcrypt library (eg. Debian GNU/Linux).
 783 #
 784 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 785 # be careful to avoid -lcrypt in this case, since libtool will see there's
 786 # only a static libcrypt and decide to build only a static libguile.
 787 #
 788 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 789 # libraries already in that list.
 790 #
 791 AC_SEARCH_LIBS(crypt, crypt,
 792   [AC_DEFINE([HAVE_CRYPT],1,
 793              [Define to 1 if you have the `crypt' function.])])
 794
 795 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 796 # work; in the reported cases so far, 1.0fi works well instead.  According
 797 # to the C99 spec, the complex.h header must provide a working definition
 798 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 799 # is a workaround for the failure of some systems to conform to C99.
 800 if test "$ac_cv_type_complex_double" = yes; then
 801   AC_MSG_CHECKING([for i])
 802   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 803 #if HAVE_COMPLEX_H
 804 #include <complex.h>
 805 #endif
 806 complex double z;
 807 ]], [[
 808 z = _Complex_I;
 809 ]])],
 810     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 811      AC_MSG_RESULT([_Complex_I])],
 812     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 813 #if HAVE_COMPLEX_H
 814 #include <complex.h>
 815 #endif
 816 complex double z;
 817 ]],[[
 818 z = 1.0fi;
 819 ]])],
 820   [AC_DEFINE([GUILE_I],1.0fi)
 821    AC_MSG_RESULT([1.0fi])],
 822   [ac_cv_type_complex_double=no
 823    AC_MSG_RESULT([not available])])])
 824 fi
 825
 826 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 827 # csqrt(-i) returned a negative real part, when it should be positive
 828 # for the principal root.
 829 #
 830 if test "$ac_cv_type_complex_double" = yes; then
 831
 832   AC_CACHE_CHECK([whether csqrt is usable],
 833     guile_cv_use_csqrt,
 834     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 835 #include <complex.h>
 836 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 837    constant, we want to test libc. */
 838 volatile complex double z = - _Complex_I;
 839 int
 840 main (void)
 841 {
 842   z = csqrt (z);
 843   if (creal (z) > 0.0)
 844     return 0;  /* good */
 845   else
 846     return 1;  /* bad */
 847 }]])],
 848     [guile_cv_use_csqrt=yes],
 849     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 850     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 851   case $guile_cv_use_csqrt in
 852     yes*)
 853       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 854       ;;
 855   esac
 856 fi
 857
 858
 859 dnl GMP tests
 860 AC_LIB_HAVE_LINKFLAGS([gmp],
 861   [],
 862   [#include <gmp.h>],
 863   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 864
 865 if test "x$HAVE_LIBGMP" != "xyes"; then
 866   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 867 fi
 868
 869 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 870 if test "x$LTLIBUNISTRING" = "x"; then
 871   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 872 fi
 873
 874 dnl Libffi is needed to compile Guile's foreign function interface, but its
 875 dnl interface isn't exposed in Guile's API.
 876 PKG_CHECK_MODULES(LIBFFI, libffi)
 877 AC_SUBST(LIBFFI_CFLAGS)
 878 AC_SUBST(LIBFFI_LIBS)
 879
 880 dnl figure out approriate ffi type for size_t
 881 AC_CHECK_SIZEOF(size_t)
 882 AC_CHECK_SIZEOF(ssize_t)
 883 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 884 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 885 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 886                    [ffi type for size_t])
 887 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 888                    [ffi type for ssize_t])
 889
 890 dnl i18n tests
 891 #AC_CHECK_HEADERS([libintl.h])
 892 #AC_CHECK_FUNCS(gettext)
 893 #if test $ac_cv_func_gettext = no; then
 894 #   AC_CHECK_LIB(intl, gettext)
 895 #fi
 896 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 897 AM_GNU_GETTEXT([external], [need-ngettext])
 898
 899 ### Some systems don't declare some functions.  On such systems, we
 900 ### need to at least provide our own K&R-style declarations.
 901
 902 ### GUILE_FUNC_DECLARED(function, headerfile)
 903
 904 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 905 ### not there, #define MISSING_FUNCTION_DECL.
 906 AC_DEFUN([GUILE_FUNC_DECLARED], [
 907   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 908     AC_EGREP_HEADER($1, $2,
 909                     guile_cv_func_$1_declared=yes,
 910                     guile_cv_func_$1_declared=no))
 911   if test [x$guile_cv_func_]$1[_declared] = xno; then
 912     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 913       [Define if the operating system supplies $1 without declaring it.])
 914   fi
 915 ])
 916
 917 GUILE_FUNC_DECLARED(sleep, unistd.h)
 918 GUILE_FUNC_DECLARED(usleep, unistd.h)
 919
 920 AC_CHECK_DECLS([strptime],,,
 921 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 922 #include <time.h>])
 923
 924 ### On some systems usleep has no return value.  If it does have one,
 925 ### we'd like to return it; otherwise, we'll fake it.
 926 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 927   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 928                    unistd.h,
 929                    [guile_cv_func_usleep_return_type=void],
 930                    [guile_cv_func_usleep_return_type=int])])
 931 case "$guile_cv_func_usleep_return_type" in
 932   "void" )
 933     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 934       [Define if the system headers declare usleep to return void.])
 935   ;;
 936 esac
 937
 938 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 939 if test -n "$have_sys_un_h" ; then
 940   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 941     [Define if the system supports Unix-domain (file-domain) sockets.])
 942 fi
 943
 944 AC_CHECK_FUNCS(getrlimit setrlimit)
 945
 946 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 947
 948 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 949                setnetent    getnetent    endnetent    dnl
 950                setprotoent  getprotoent  endprotoent  dnl
 951                setservent   getservent   endservent   dnl
 952                getnetbyaddr getnetbyname dnl
 953                inet_lnaof inet_makeaddr inet_netof hstrerror)
 954
 955 # struct sockaddr field sin_len is only present on BSD systems.
 956 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 957 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 958 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 959 [#ifdef HAVE_SYS_TYPES_H
 960 #include <sys/types.h>
 961 #endif
 962 #include <netinet/in.h>])
 963
 964 AC_MSG_CHECKING(for __libc_stack_end)
 965 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 966 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 967 extern char *__libc_stack_end;]],
 968    [[printf("%p", (char*) __libc_stack_end);]])],
 969    [guile_cv_have_libc_stack_end=yes],
 970    [guile_cv_have_libc_stack_end=no])])
 971 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 972
 973 if test $guile_cv_have_libc_stack_end = yes; then
 974   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 975            [Define if you have the __libc_stack_end variable.])
 976 fi
 977
 978 dnl Some systems do not declare this.  Some systems do declare it, as a
 979 dnl macro.  With cygwin it may be in a DLL.
 980
 981 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 982 AC_CACHE_VAL(guile_cv_have_h_errno,
 983   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 984                                       [[int a = h_errno;]])],
 985   [guile_cv_have_h_errno=yes],
 986   [guile_cv_have_h_errno=no])])
 987 AC_MSG_RESULT($guile_cv_have_h_errno)
 988 if test $guile_cv_have_h_errno = yes; then
 989   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
 990 fi
 991
 992 AC_MSG_CHECKING(whether uint32_t is defined)
 993 AC_CACHE_VAL(guile_cv_have_uint32_t,
 994   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 995                    #if HAVE_STDINT_H
 996                    #include <stdint.h>
 997                    #endif
 998                    #ifndef HAVE_NETDB_H
 999                    #include <netdb.h>
1000                    #endif]],
1001                    [[uint32_t a;]])],
1002                    [guile_cv_have_uint32_t=yes],
1003                    [guile_cv_have_uint32_t=no])])
1004 AC_MSG_RESULT($guile_cv_have_uint32_t)
1005 if test $guile_cv_have_uint32_t = yes; then
1006   AC_DEFINE([HAVE_UINT32_T], 1,
1007     [Define if uint32_t typedef is defined when netdb.h is include.])
1008 fi
1009
1010 AC_MSG_CHECKING(for working IPv6 support)
1011 AC_CACHE_VAL(guile_cv_have_ipv6,
1012 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1013 #ifdef HAVE_SYS_TYPES_H
1014 #include <sys/types.h>
1015 #endif
1016 #include <netinet/in.h>
1017 #include <sys/socket.h>]],
1018 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1019 [guile_cv_have_ipv6=yes],
1020 [guile_cv_have_ipv6=no])])
1021 AC_MSG_RESULT($guile_cv_have_ipv6)
1022 if test $guile_cv_have_ipv6 = yes; then
1023   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1024 fi
1025
1026 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1027 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1028 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1029 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1030 #ifdef HAVE_SYS_TYPES_H
1031 #include <sys/types.h>
1032 #endif
1033 #include <netinet/in.h>]],
1034 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1035 [guile_cv_have_sin6_scope_id=yes],
1036 [guile_cv_have_sin6_scope_id=no])])
1037 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1038 if test $guile_cv_have_sin6_scope_id = yes; then
1039   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1040     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1041 fi
1042
1043 # struct sockaddr_in6 field sin_len is only present on BSD systems
1044 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1045 [#ifdef HAVE_SYS_TYPES_H
1046 #include <sys/types.h>
1047 #endif
1048 #include <netinet/in.h>])
1049
1050 AC_MSG_CHECKING(whether localtime caches TZ)
1051 AC_CACHE_VAL(guile_cv_localtime_cache,
1052 [if test x$ac_cv_func_tzset = xyes; then
1053 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1054 #if STDC_HEADERS
1055 # include <stdlib.h>
1056 #endif
1057 extern char **environ;
1058 unset_TZ ()
1059 {
1060   char **from, **to;
1061   for (to = from = environ; (*to = *from); from++)
1062     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1063       to++;
1064 }
1065 char TZ_GMT0[] = "TZ=GMT0";
1066 char TZ_PST8[] = "TZ=PST8";
1067 main()
1068 {
1069   time_t now = time ((time_t *) 0);
1070   int hour_GMT0, hour_unset;
1071   if (putenv (TZ_GMT0) != 0)
1072     exit (1);
1073   hour_GMT0 = localtime (&now)->tm_hour;
1074   unset_TZ ();
1075   hour_unset = localtime (&now)->tm_hour;
1076   if (putenv (TZ_PST8) != 0)
1077     exit (1);
1078   if (localtime (&now)->tm_hour == hour_GMT0)
1079     exit (1);
1080   unset_TZ ();
1081   if (localtime (&now)->tm_hour != hour_unset)
1082     exit (1);
1083   exit (0);
1084 }]])],
1085 [guile_cv_localtime_cache=no],
1086 [guile_cv_localtime_cache=yes],
1087 [# If we have tzset, assume the worst when cross-compiling.
1088 guile_cv_localtime_cache=yes])
1089 else
1090         # If we lack tzset, report that localtime does not cache TZ,
1091         # since we can't invalidate the cache if we don't have tzset.
1092         guile_cv_localtime_cache=no
1093 fi])dnl
1094 AC_MSG_RESULT($guile_cv_localtime_cache)
1095 if test $guile_cv_localtime_cache = yes; then
1096   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1097 fi
1098
1099 if test "$enable_regex" = yes; then
1100    if test "$ac_cv_header_regex_h" = yes ||
1101       test "$ac_cv_header_rxposix_h" = yes ||
1102       test "$ac_cv_header_rx_rxposix_h" = yes; then
1103      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1104      [AC_CHECK_LIB(rx, main)
1105       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1106      [AC_CHECK_LIB(regex, main)
1107       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1108      )
1109      dnl The following should not be necessary, but for some reason
1110      dnl autoheader misses it if we don't include it!
1111      if test "$ac_cv_func_regcomp_norx" = yes ||
1112         test "$ac_cv_func_regcomp_regex" = yes ||
1113         test "$ac_cv_func_regcomp_rx" = yes; then
1114        AC_DEFINE([HAVE_REGCOMP], 1,
1115          [This is included as part of a workaround for a autoheader bug.])
1116      fi
1117    fi
1118 fi
1119
1120 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1121
1122 # Reasons for testing:
1123 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1124 #                                older systems
1125 #   sincos - GLIBC extension
1126 #
1127 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1128
1129 # C99 specifies isinf and isnan as macros.
1130 # HP-UX provides only macros, no functions.
1131 # glibc 2.3.2 provides both macros and functions.
1132 # IRIX 6.5 and Solaris 8 only provide functions.
1133 #
1134 # The following tests detect isinf and isnan either as functions or as
1135 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1136 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1137 #
1138 AC_MSG_CHECKING([for isinf])
1139 AC_LINK_IFELSE(AC_LANG_SOURCE(
1140 [[#include <math.h>
1141 volatile double x = 0.0;
1142 int main () { return (isinf(x) != 0); }]]),
1143   [AC_MSG_RESULT([yes])
1144    AC_DEFINE([HAVE_ISINF], 1,
1145              [Define to 1 if you have the `isinf' macro or function.])],
1146   [AC_MSG_RESULT([no])])
1147 AC_MSG_CHECKING([for isnan])
1148 AC_LINK_IFELSE(AC_LANG_SOURCE(
1149 [[#include <math.h>
1150 volatile double x = 0.0;
1151 int main () { return (isnan(x) != 0); }]]),
1152   [AC_MSG_RESULT([yes])
1153    AC_DEFINE([HAVE_ISNAN], 1,
1154              [Define to 1 if you have the `isnan' macro or function.])],
1155   [AC_MSG_RESULT([no])])
1156
1157 # Reasons for checking:
1158 #
1159 #     st_rdev
1160 #     st_blksize
1161 #     st_blocks   not in mingw
1162 #     tm_gmtoff   BSD+GNU, not in C99
1163 #
1164 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1165 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1166 #
1167 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1168                  [#define _GNU_SOURCE
1169 AC_INCLUDES_DEFAULT
1170 ])
1171
1172 AC_STRUCT_TIMEZONE
1173 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1174 [#include <time.h>
1175 #ifdef TIME_WITH_SYS_TIME
1176 # include <sys/time.h>
1177 # include <time.h>
1178 #else
1179 # if HAVE_SYS_TIME_H
1180 #  include <sys/time.h>
1181 # else
1182 #  include <time.h>
1183 # endif
1184 #endif
1185 ])
1186 GUILE_STRUCT_UTIMBUF
1187
1188
1189 #--------------------------------------------------------------------
1190 #
1191 # Which way does the stack grow?
1192 #
1193 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1194 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1195 # very similar code, so in future we could look at using that.
1196 #
1197 # An important detail is that the code involves find_stack_direction
1198 # calling _itself_ - which means that find_stack_direction (or at
1199 # least the second find_stack_direction() call) cannot be inlined.
1200 # If the code could be inlined, that might cause the test to give
1201 # an incorrect answer.
1202 #--------------------------------------------------------------------
1203
1204 SCM_I_GSC_STACK_GROWS_UP=0
1205 AC_RUN_IFELSE([AC_LANG_SOURCE(
1206 [AC_INCLUDES_DEFAULT
1207 int
1208 find_stack_direction ()
1209 {
1210   static char *addr = 0;
1211   auto char dummy;
1212   if (addr == 0)
1213     {
1214       addr = &dummy;
1215       return find_stack_direction ();
1216     }
1217   else
1218     return (&dummy > addr) ? 1 : -1;
1219 }
1220
1221 int
1222 main ()
1223 {
1224   return find_stack_direction () < 0;
1225 }])],
1226                [SCM_I_GSC_STACK_GROWS_UP=1],
1227                [],
1228                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1229
1230 #--------------------------------------------------------------------
1231 #
1232 # Boehm's GC library
1233 #
1234 #--------------------------------------------------------------------
1235 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1236
1237 save_LIBS="$LIBS"
1238 LIBS="$BDW_GC_LIBS $LIBS"
1239 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1240
1241 AC_CHECK_FUNCS([GC_do_blocking GC_call_with_gc_active])
1242
1243 # Though the `GC_do_blocking ()' symbol is present in GC 7.1, it is not
1244 # declared, and has a different type (returning void instead of
1245 # void*).
1246 AC_CHECK_DECL([GC_do_blocking],
1247   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1248     [Define this if the `GC_do_blocking ()' function is declared])],
1249   [],
1250   [#include <gc/gc.h>])
1251
1252 # `GC_fn_type' is not available in GC 7.1 and earlier.
1253 AC_CHECK_TYPE([GC_fn_type],
1254   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1255     [Define this if the `GC_fn_type' type is available.])],
1256   [],
1257   [#include <gc/gc.h>])
1258
1259 LIBS="$save_LIBS"
1260
1261
1262 AC_CHECK_SIZEOF(float)
1263 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1264     AC_DEFINE([SCM_SINGLES], 1,
1265               [Define this if floats are the same size as longs.])
1266 fi
1267
1268 AC_MSG_CHECKING(for struct linger)
1269 AC_CACHE_VAL(scm_cv_struct_linger,
1270         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1271 #include <sys/types.h>
1272 #include <sys/socket.h>]],
1273                           [[struct linger lgr;  lgr.l_linger = 100]])],
1274                           [scm_cv_struct_linger="yes"],
1275                           [scm_cv_struct_linger="no"]))
1276 AC_MSG_RESULT($scm_cv_struct_linger)
1277 if test $scm_cv_struct_linger = yes; then
1278         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1279           [Define this if your system defines struct linger, for use with the
1280            getsockopt and setsockopt system calls.])
1281 fi
1282
1283
1284 # On mingw, struct timespec is in <pthread.h>.
1285 #
1286 AC_MSG_CHECKING(for struct timespec)
1287 AC_CACHE_VAL(scm_cv_struct_timespec,
1288         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1289 #include <time.h>
1290 #if HAVE_PTHREAD_H
1291 #include <pthread.h>
1292 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1293           [scm_cv_struct_timespec="yes"],
1294           [scm_cv_struct_timespec="no"]))
1295 AC_MSG_RESULT($scm_cv_struct_timespec)
1296 if test $scm_cv_struct_timespec = yes; then
1297   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1298     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1299 fi
1300
1301 #--------------------------------------------------------------------
1302 #
1303 # Flags for thread support
1304 #
1305 #--------------------------------------------------------------------
1306
1307 SCM_I_GSC_USE_PTHREAD_THREADS=0
1308 SCM_I_GSC_USE_NULL_THREADS=0
1309 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1310 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1311
1312 ### What thread package has the user asked for?
1313 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1314             , with_threads=yes)
1315
1316 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1317 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1318
1319 case "$with_threads" in
1320   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1321
1322     build_pthread_support="yes"
1323
1324     ACX_PTHREAD([CC="$PTHREAD_CC"
1325        LIBS="$PTHREAD_LIBS $LIBS"
1326        SCM_I_GSC_USE_PTHREAD_THREADS=1
1327        with_threads="pthreads"],
1328       [with_threads="null"
1329        build_pthread_support="no"])
1330
1331     old_CFLAGS="$CFLAGS"
1332     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1333
1334     # Reasons for testing:
1335     #     pthread_getattr_np - "np" meaning "non portable" says it
1336     #         all; not present on MacOS X or Solaris 10
1337     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1338     #         all; specific to MacOS X
1339     #     pthread_sigmask - not available on mingw
1340     #
1341     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1342
1343     # On past versions of Solaris, believe 8 through 10 at least, you
1344     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1345     # This is contrary to POSIX:
1346     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1347     # Check here if this style is required.
1348     #
1349     # glibc (2.3.6 at least) works both with or without braces, so the
1350     # test checks whether it works without.
1351     #
1352
1353     if test "$GCC" = "yes"; then
1354       # Since GCC only issues a warning for missing braces, so we need
1355       # `-Werror' to catch it.
1356       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1357     fi
1358
1359     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1360       guile_cv_need_braces_on_pthread_once_init,
1361       [AC_COMPILE_IFELSE([#include <pthread.h>
1362          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1363         [guile_cv_need_braces_on_pthread_once_init=no],
1364         [guile_cv_need_braces_on_pthread_once_init=yes])])
1365     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1366       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1367     fi
1368
1369     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1370     # 6.5.30m with GCC 3.3.
1371     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1372       guile_cv_need_braces_on_pthread_mutex_initializer,
1373       [AC_COMPILE_IFELSE([#include <pthread.h>
1374          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1375         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1376         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1377     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1378       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1379     fi
1380
1381     CFLAGS="$old_CFLAGS"
1382
1383     # On Solaris, sched_yield lives in -lrt.
1384     AC_SEARCH_LIBS(sched_yield, rt)
1385
1386   ;;
1387 esac
1388
1389 case "$with_threads" in
1390   "pthreads")
1391   ;;
1392   "no" | "null")
1393     SCM_I_GSC_USE_NULL_THREADS=1
1394     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1395     with_threads="null-threads"
1396   ;;
1397   * )
1398     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1399   ;;
1400 esac
1401
1402 AC_MSG_CHECKING(what kind of threads to support)
1403 AC_MSG_RESULT($with_threads)
1404
1405 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1406   [test "x$build_pthread_support" = "xyes"])
1407
1408
1409 ## Check whether pthread_attr_getstack works for the main thread
1410
1411 if test "$with_threads" = pthreads; then
1412
1413 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1414 old_CFLAGS="$CFLAGS"
1415 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1416 if test "$cross_compiling" = "no"; then
1417   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1418   #if HAVE_PTHREAD_ATTR_GETSTACK
1419   #include <pthread.h>
1420
1421   int main ()
1422   {
1423     pthread_attr_t attr;
1424     void *start, *end;
1425     size_t size;
1426
1427     pthread_getattr_np (pthread_self (), &attr);
1428     pthread_attr_getstack (&attr, &start, &size);
1429     end = (char *)start + size;
1430
1431     if ((void *)&attr < start || (void *)&attr >= end)
1432       return 1;
1433     else
1434       return 0;
1435   }
1436   #else
1437   int main ()
1438   {
1439     return 1;
1440   }
1441   #endif
1442   ]])],
1443   [works=yes
1444    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1445   [works=no],
1446   [])
1447 else
1448   works="assuming it doesn't"
1449 fi
1450 CFLAGS="$old_CFLAGS"
1451 AC_MSG_RESULT($works)
1452
1453 GUILE_THREAD_LOCAL_STORAGE
1454
1455 fi # with_threads=pthreads
1456
1457
1458 ## Cross building
1459 if test "$cross_compiling" = "yes"; then
1460   AC_MSG_CHECKING(cc for build)
1461   ## /usr/bin/cc still uses wrong assembler
1462   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1463   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1464 else
1465   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1466 fi
1467
1468 ## AC_MSG_CHECKING("if we are cross compiling")
1469 ## AC_MSG_RESULT($cross_compiling)
1470 if test "$cross_compiling" = "yes"; then
1471    AC_MSG_RESULT($CC_FOR_BUILD)
1472 fi
1473
1474 ## No need as yet to be more elaborate
1475 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1476
1477 AC_SUBST(cross_compiling)
1478 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1479 AC_SUBST(CCLD_FOR_BUILD)
1480
1481 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1482 ## --HOST is the platform that PACKAGE is compiled for.
1483 HOST_CC="$CC_FOR_BUILD"
1484 AC_SUBST(HOST_CC)
1485
1486 if test "$cross_compiling" = "yes"; then
1487   AC_MSG_CHECKING(guile for build)
1488   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1489 else
1490   GUILE_FOR_BUILD='$(preinstguile)'
1491 fi
1492
1493 ## AC_MSG_CHECKING("if we are cross compiling")
1494 ## AC_MSG_RESULT($cross_compiling)
1495 if test "$cross_compiling" = "yes"; then
1496    AC_MSG_RESULT($GUILE_FOR_BUILD)
1497 fi
1498 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1499 AC_SUBST(GUILE_FOR_BUILD)
1500
1501 ## If we're using GCC, ask for aggressive warnings.
1502 GCC_CFLAGS=""
1503 case "$GCC" in
1504   yes )
1505     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1506     ## much stuff with generic function pointers for that to really be
1507     ## less than exasperating.
1508     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1509     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1510     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1511       -Wdeclaration-after-statement -Wundef \
1512       -Wswitch-enum"
1513     # Do this here so we don't screw up any of the tests above that might
1514     # not be "warning free"
1515     if test "${GUILE_ERROR_ON_WARNING}" = yes
1516     then
1517         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1518         enable_compile_warnings=no
1519     fi
1520
1521     for flag in $POTENTIAL_GCC_CFLAGS
1522     do
1523         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1524     done
1525     ;;
1526 esac
1527
1528 AC_SUBST(GCC_CFLAGS)
1529
1530 # Check for GNU ld's "-z relro".
1531 GUILE_GNU_LD_RELRO
1532
1533
1534 ## If we're creating a shared library (using libtool!), then we'll
1535 ## need to generate a list of .lo files corresponding to the .o files
1536 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1537 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1538
1539 ## We also need to create corresponding .doc and .x files
1540 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1541 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1542
1543 # GNU Readline bindings.
1544 GUILE_READLINE
1545
1546 AC_SUBST(GUILE_MAJOR_VERSION)
1547 AC_SUBST(GUILE_MINOR_VERSION)
1548 AC_SUBST(GUILE_MICRO_VERSION)
1549 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1550 AC_SUBST(GUILE_VERSION)
1551
1552 #######################################################################
1553 # library versioning
1554
1555 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1556 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1557 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1558 AC_SUBST(LIBGUILE_INTERFACE)
1559
1560 AC_SUBST(LIBGUILE_I18N_MAJOR)
1561 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1562 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1563 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1564 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1565
1566
1567 #######################################################################
1568
1569 dnl Tell guile-config what flags guile users should compile and link with.
1570 GUILE_LIBS="$LDFLAGS $LIBS"
1571 GUILE_CFLAGS="$CPPFLAGS $PTHREAD_CFLAGS"
1572 AC_SUBST(GUILE_LIBS)
1573 AC_SUBST(GUILE_CFLAGS)
1574
1575 AC_SUBST(AWK)
1576 AC_SUBST(LIBLOBJS)
1577 AC_SUBST(EXTRA_DOT_DOC_FILES)
1578 AC_SUBST(EXTRA_DOT_X_FILES)
1579
1580 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1581 top_builddir_absolute=`pwd`
1582 AC_SUBST(top_builddir_absolute)
1583 top_srcdir_absolute=`(cd $srcdir && pwd)`
1584 AC_SUBST(top_srcdir_absolute)
1585
1586 dnl `sitedir' goes into libpath.h and the pkg-config file.
1587 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1588 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1589 AC_SUBST([sitedir])
1590
1591 # Additional SCM_I_GSC definitions are above.
1592 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1593 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1594 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1595 AC_SUBST([SCM_I_GSC_C_INLINE])
1596 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1597
1598 AC_CONFIG_FILES([
1599   Makefile
1600   am/Makefile
1601   lib/Makefile
1602   benchmark-suite/Makefile
1603   doc/Makefile
1604   doc/r5rs/Makefile
1605   doc/ref/Makefile
1606   emacs/Makefile
1607   examples/Makefile
1608   libguile/Makefile
1609   libguile/version.h
1610   guile-readline/Makefile
1611   test-suite/Makefile
1612   test-suite/standalone/Makefile
1613   test-suite/vm/Makefile
1614   meta/Makefile
1615   module/Makefile
1616 ])
1617
1618 AC_CONFIG_FILES([meta/guile-2.0.pc])
1619 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1620 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1621
1622 GUILE_CONFIG_SCRIPT([check-guile])
1623 GUILE_CONFIG_SCRIPT([benchmark-guile])
1624 GUILE_CONFIG_SCRIPT([meta/guile])
1625 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1626 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1627 GUILE_CONFIG_SCRIPT([meta/guile-tools])
1628 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1629 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1630 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1631 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1632
1633 AC_OUTPUT
1634
1635 dnl Local Variables:
1636 dnl comment-start: "dnl "
1637 dnl comment-end: ""
1638 dnl comment-start-skip: "\\bdnl\\b\\s *"
1639 dnl End: