configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 Boston, MA 02111-1307, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT
  31 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  32 AC_CONFIG_SRCDIR([GUILE-VERSION])
  33 . $srcdir/GUILE-VERSION
  34 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  35 AM_MAINTAINER_MODE
  36 AM_CONFIG_HEADER([config.h])
  37 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  38
  39 #--------------------------------------------------------------------
  40 #
  41 # Independent Subdirectories
  42 #
  43 #--------------------------------------------------------------------
  44
  45 AC_CONFIG_SUBDIRS(guile-readline)
  46
  47 #--------------------------------------------------------------------
  48
  49 dnl Some more checks for Win32
  50 AC_CYGWIN
  51 AC_MINGW32
  52 AC_LIBTOOL_WIN32_DLL
  53
  54 AC_PROG_INSTALL
  55 AC_PROG_CC
  56 AC_PROG_CPP
  57 AC_PROG_AWK
  58
  59 AC_AIX
  60 AC_ISC_POSIX
  61 AC_MINIX
  62
  63 AM_PROG_CC_STDC
  64
  65 AC_LIBTOOL_DLOPEN
  66 AC_PROG_LIBTOOL
  67 AC_LIB_LTDL
  68
  69 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  70 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  71
  72 AM_PATH_LISPDIR
  73
  74 #--------------------------------------------------------------------
  75 #
  76 # User options (after above tests that may set default CFLAGS etc.)
  77 #
  78 #--------------------------------------------------------------------
  79
  80 GUILE_ERROR_ON_WARNING="yes"
  81
  82 AC_ARG_ENABLE(error-on-warning,
  83   [  --enable-error-on-warning    treat compile warnings as errors],
  84   [case "${enableval}" in
  85      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  86      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  87      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  88    esac])
  89
  90 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
  91 AC_ARG_ENABLE(debug-freelist,
  92   [  --enable-debug-freelist include garbage collector freelist debugging code],
  93   if test "$enable_debug_freelist" = y \
  94      || test "$enable_debug_freelist" = yes; then
  95     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
  96   fi)
  97
  98 AC_ARG_ENABLE(debug-malloc,
  99   [  --enable-debug-malloc   include malloc debugging code],
 100   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 101     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 102       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 103   fi)
 104
 105 SCM_I_GSC_GUILE_DEBUG=0
 106 AC_ARG_ENABLE(guile-debug,
 107   [AC_HELP_STRING([--enable-guile-debug],
 108                   [include internal debugging functions])],
 109   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 110     SCM_I_GSC_GUILE_DEBUG=1
 111   fi)
 112
 113 AC_ARG_ENABLE(arrays,
 114   [AC_HELP_STRING([--disable-arrays],[omit array and uniform array support])],
 115   ,
 116   enable_arrays=yes)
 117
 118 AC_ARG_ENABLE(posix,
 119   [  --disable-posix         omit posix interfaces],,
 120   enable_posix=yes)
 121
 122 AC_ARG_ENABLE(networking,
 123   [  --disable-networking    omit networking interfaces],,
 124   enable_networking=yes)
 125
 126 AC_ARG_ENABLE(regex,
 127   [  --disable-regex         omit regular expression interfaces],,
 128   enable_regex=yes)
 129
 130 AC_ARG_ENABLE(htmldoc,
 131   [  --enable-htmldoc        build HTML documentation as well as Info],
 132   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
 133      htmldoc_enabled=yes
 134      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
 135      if test "$TEXI2HTML" = "not found"; then
 136        echo
 137        echo Building HTML documentation requires the \`texi2html\' program,
 138        echo which appears not to be present on your machine.
 139        echo
 140        echo \`texi2html\' is available from
 141        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
 142        echo
 143        echo In the meantime, to build the guile-doc distribution
 144        echo without HTML enabled, please rerun \`./configure\' without
 145        echo the \`--enable-htmldoc\' option.
 146        exit -1
 147      fi
 148    fi])
 149
 150 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
 151
 152 AC_ARG_ENABLE([deprecated],
 153   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 154
 155 if test "$enable_deprecated" = no; then
 156   SCM_I_GSC_ENABLE_DEPRECATED=0
 157 else
 158   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 159     warn_default=summary
 160   elif test "$enable_deprecated" = shutup; then
 161     warn_default=no
 162   else
 163     warn_default=$enable_deprecated
 164   fi
 165   SCM_I_GSC_ENABLE_DEPRECATED=1
 166   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 167   [Define this to control the default warning level for deprecated features.])
 168 fi
 169
 170 AC_ARG_ENABLE(elisp,
 171   [  --disable-elisp         omit Emacs Lisp support],,
 172   enable_elisp=yes)
 173
 174 #--------------------------------------------------------------------
 175
 176 dnl Check for dynamic linking
 177
 178 use_modules=yes
 179 AC_ARG_WITH(modules,
 180 [  --with-modules[=FILES]  Add support for dynamic modules],
 181 use_modules="$withval")
 182 test -z "$use_modules" && use_modules=yes
 183 DLPREOPEN=
 184 if test "$use_modules" != no; then
 185   if test "$use_modules" = yes; then
 186     DLPREOPEN="-dlpreopen force"
 187   else
 188     DLPREOPEN="-export-dynamic"
 189     for module in $use_modules; do
 190       DLPREOPEN="$DLPREOPEN -dlopen $module"
 191     done
 192   fi
 193 fi
 194
 195 dnl files which are destined for separate modules.
 196
 197 if test "$use_modules" != no; then
 198    AC_LIBOBJ([dynl])
 199 fi
 200
 201 SCM_I_GSC_HAVE_ARRAYS=0
 202 if test "$enable_arrays" = yes; then
 203    AC_LIBOBJ([ramap])
 204    AC_LIBOBJ([unif])
 205    SCM_I_GSC_HAVE_ARRAYS=1
 206 fi
 207
 208 if test "$enable_posix" = yes; then
 209    AC_LIBOBJ([filesys])
 210    AC_LIBOBJ([posix])
 211    AC_DEFINE(HAVE_POSIX, 1,
 212      [Define this if you want support for POSIX system calls in Guile.])
 213 fi
 214
 215 if test "$enable_networking" = yes; then
 216    AC_LIBOBJ([net_db])
 217    AC_LIBOBJ([socket])
 218    AC_DEFINE(HAVE_NETWORKING, 1,
 219      [Define this if you want support for networking in Guile.])
 220 fi
 221
 222 if test "$enable_debug_malloc" = yes; then
 223    AC_LIBOBJ([debug-malloc])
 224 fi
 225
 226 if test "$enable_elisp" = yes; then
 227   SCM_I_GSC_ENABLE_ELISP=1
 228 else
 229   SCM_I_GSC_ENABLE_ELISP=0
 230 fi
 231
 232 AC_C_CONST
 233
 234 AC_C_INLINE
 235 if test "$ac_cv_c_inline" != no; then
 236   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 237 else
 238   SCM_I_GSC_C_INLINE=NULL
 239 fi
 240
 241 AC_C_BIGENDIAN
 242
 243 AC_CHECK_SIZEOF(char)
 244 AC_CHECK_SIZEOF(unsigned char)
 245 AC_CHECK_SIZEOF(short)
 246 AC_CHECK_SIZEOF(unsigned short)
 247 AC_CHECK_SIZEOF(int)
 248 AC_CHECK_SIZEOF(unsigned int)
 249 AC_CHECK_SIZEOF(long)
 250 AC_CHECK_SIZEOF(unsigned long)
 251 AC_CHECK_SIZEOF(size_t)
 252 AC_CHECK_SIZEOF(long long)
 253 AC_CHECK_SIZEOF(unsigned long long)
 254 AC_CHECK_SIZEOF(__int64)
 255 AC_CHECK_SIZEOF(unsigned __int64)
 256 AC_CHECK_SIZEOF(void *)
 257 AC_CHECK_SIZEOF(intptr_t)
 258 AC_CHECK_SIZEOF(uintptr_t)
 259 AC_CHECK_SIZEOF(ptrdiff_t)
 260
 261 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 262   AC_MSG_ERROR(sizes of long and void* are not identical)
 263 fi
 264
 265 if test "$ac_cv_sizeof_ptrdiff_t" -eq 0; then
 266   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 267 else
 268   SCM_I_GSC_T_PTRDIFF='"long"'
 269 fi
 270 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 271
 272 AC_CHECK_HEADERS([stdint.h])
 273 AC_CHECK_HEADERS([inttypes.h])
 274
 275 SCM_I_GSC_NEEDS_STDINT_H=0
 276 SCM_I_GSC_NEEDS_INTTYPES_H=0
 277
 278 ### intptr and uintptr (try not to use inttypes if we don't have to)
 279 if test "$ac_cv_header_inttypes_h" = yes; then
 280   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 281     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 282 #include <stdio.h>])
 283     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 284       SCM_I_GSC_NEEDS_INTTYPES_H=1
 285     fi
 286   fi
 287   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 288     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 289 #include <stdio.h>])
 290     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 291       SCM_I_GSC_NEEDS_INTTYPES_H=1
 292     fi
 293   fi
 294 fi
 295
 296 ### See what's provided by stdint.h
 297 if test "$ac_cv_header_stdint_h" = yes; then
 298    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 299    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 300    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 301    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 302    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 303    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 304    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 305    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 306    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 307    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 308 fi
 309
 310 # so we don't get confused by the cache (wish there was a better way
 311 # to check particular headers for the same type...)
 312
 313 unset ac_cv_type_int8_t
 314 unset ac_cv_type_uint8_t
 315 unset ac_cv_type_int16_t
 316 unset ac_cv_type_uint16_t
 317 unset ac_cv_type_int32_t
 318 unset ac_cv_type_uint32_t
 319 unset ac_cv_type_int64_t
 320 unset ac_cv_type_uint64_t
 321 unset ac_cv_type_intmax_t
 322 unset ac_cv_type_uintmax_t
 323
 324 ### See what's provided by inttypes.h
 325 if test "$ac_cv_header_inttypes_h" = yes; then
 326   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 327   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 328   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 329   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 330   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 331   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 332   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 333   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 334   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 335   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 336 fi
 337
 338 # Try hard to find definitions for some required scm_t_*int* types.
 339
 340 ### Required type scm_t_int8
 341 if test "$ac_cv_sizeof_char" -eq 1; then
 342   SCM_I_GSC_T_INT8='"char"'
 343 elif test "$scm_stdint_has_int8"; then
 344   SCM_I_GSC_T_INT8='"int8_t"'
 345   SCM_I_GSC_NEEDS_STDINT_H=1
 346 elif test "$scm_inttypes_has_int8"; then
 347   SCM_I_GSC_T_INT8='"int8_t"'
 348   SCM_I_GSC_NEEDS_INTTYPES_H=1
 349 else
 350   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 351 fi
 352 AC_SUBST([SCM_I_GSC_T_INT8])
 353
 354 ### Required type scm_t_uint8
 355 if test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 356   SCM_I_GSC_T_UINT8='"unsigned char"'
 357 elif test "$scm_stdint_has_uint8"; then
 358   SCM_I_GSC_T_UINT8='"uint8_t"'
 359   SCM_I_GSC_NEEDS_STDINT_H=1
 360 elif test "$scm_inttypes_has_uint8"; then
 361   SCM_I_GSC_T_UINT8='"uint8_t"'
 362   SCM_I_GSC_NEEDS_INTTYPES_H=1
 363 else
 364   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 365 fi
 366 AC_SUBST([SCM_I_GSC_T_UINT8])
 367
 368
 369 ### Required type scm_t_int16 (ANSI C says int or short might work)
 370 if test "$ac_cv_sizeof_int" -eq 2; then
 371   SCM_I_GSC_T_INT16='"int"'
 372 elif test "$ac_cv_sizeof_short" -eq 2; then
 373   SCM_I_GSC_T_INT16='"short"'
 374 elif test "$scm_stdint_has_int16"; then
 375   SCM_I_GSC_T_INT16='"int16_t"'
 376   SCM_I_GSC_NEEDS_STDINT_H=1
 377 elif test "$scm_inttypes_has_int16"; then
 378   SCM_I_GSC_T_INT16='"int16_t"'
 379   SCM_I_GSC_NEEDS_INTTYPES_H=1
 380 else
 381   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 382 fi
 383 AC_SUBST([SCM_I_GSC_T_INT16])
 384
 385 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 386 if test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 387   SCM_I_GSC_T_UINT16='"unsigned int"'
 388 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 389   SCM_I_GSC_T_UINT16='"unsigned short"'
 390 elif test "$scm_stdint_has_uint16"; then
 391   SCM_I_GSC_T_UINT16='"uint16_t"'
 392   SCM_I_GSC_NEEDS_STDINT_H=1
 393 elif test "$scm_inttypes_has_uint16"; then
 394   SCM_I_GSC_T_UINT16='"uint16_t"'
 395   SCM_I_GSC_NEEDS_INTTYPES_H=1
 396 else
 397   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 398 fi
 399 AC_SUBST([SCM_I_GSC_T_UINT16])
 400
 401
 402 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 403 if test "$ac_cv_sizeof_int" -eq 4; then
 404   SCM_I_GSC_T_INT32='"int"'
 405 elif test "$ac_cv_sizeof_long" -eq 4; then
 406   SCM_I_GSC_T_INT32='"long"'
 407 elif test "$ac_cv_sizeof_short" -eq 4; then
 408   SCM_I_GSC_T_INT32='"short"'
 409 elif test "$scm_stdint_has_int32"; then
 410   SCM_I_GSC_T_INT32='"int32_t"'
 411   SCM_I_GSC_NEEDS_STDINT_H=1
 412 elif test "$scm_inttypes_has_int32"; then
 413   SCM_I_GSC_T_INT32='"int32_t"'
 414   SCM_I_GSC_NEEDS_INTTYPES_H=1
 415 else
 416   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 417 fi
 418 AC_SUBST([SCM_I_GSC_T_INT32])
 419
 420 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 421 if test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 422   SCM_I_GSC_T_UINT32='"unsigned int"'
 423 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 424   SCM_I_GSC_T_UINT32='"unsigned long"'
 425 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 426   SCM_I_GSC_T_UINT32='"unsigned short"'
 427 elif test "$scm_stdint_has_uint32"; then
 428   SCM_I_GSC_T_UINT32='"uint32_t"'
 429   SCM_I_GSC_NEEDS_STDINT_H=1
 430 elif test "$scm_inttypes_has_uint32"; then
 431   SCM_I_GSC_T_UINT32='"uint32_t"'
 432   SCM_I_GSC_NEEDS_INTTYPES_H=1
 433 else
 434   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 435 fi
 436 AC_SUBST([SCM_I_GSC_T_UINT32])
 437
 438 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 439 ### Also try 'long long' and '__int64' if we have it.
 440 SCM_I_GSC_T_INT64=0
 441 if test "$ac_cv_sizeof_int" -eq 8; then
 442   SCM_I_GSC_T_INT64='"int"'
 443 elif test "$ac_cv_sizeof_long" -eq 8; then
 444   SCM_I_GSC_T_INT64='"long"'
 445 elif test "$ac_cv_sizeof_short" -eq 8; then
 446   SCM_I_GSC_T_INT64='"short"'
 447 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 448   SCM_I_GSC_T_INT64='"long long"'
 449 elif test "$ac_cv_sizeof___int64" -eq 8; then
 450   SCM_I_GSC_T_INT64='"__int64"'
 451 elif test "$scm_stdint_has_int64"; then
 452   SCM_I_GSC_T_INT64='"int64_t"'
 453   SCM_I_GSC_NEEDS_STDINT_H=1
 454 elif test "$scm_inttypes_has_int64"; then
 455   SCM_I_GSC_T_INT64='"int64_t"'
 456   SCM_I_GSC_NEEDS_INTTYPES_H=1
 457 else
 458   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 459 fi
 460 AC_SUBST([SCM_I_GSC_T_INT64])
 461
 462 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 463 ### Also try 'long long' and '__int64' if we have it.
 464 SCM_I_GSC_T_UINT64=0
 465 if test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 466   SCM_I_GSC_T_UINT64='"unsigned int"'
 467 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 468   SCM_I_GSC_T_UINT64='"unsigned long"'
 469 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 470   SCM_I_GSC_T_UINT64='"unsigned short"'
 471 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 472   SCM_I_GSC_T_UINT64='"unsigned long long"'
 473 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 474   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 475 elif test "$scm_stdint_has_uint64"; then
 476   SCM_I_GSC_T_UINT64='"uint64_t"'
 477   SCM_I_GSC_NEEDS_STDINT_H=1
 478 elif test "$scm_inttypes_has_uint64"; then
 479   SCM_I_GSC_T_UINT64='"uint64_t"'
 480   SCM_I_GSC_NEEDS_INTTYPES_H=1
 481 else
 482   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 483 fi
 484 AC_SUBST([SCM_I_GSC_T_UINT64])
 485
 486 ### Required type scm_t_intmax
 487 ###
 488 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 489 ### none of them is available, we use 'long'.
 490 ###
 491 SCM_I_GSC_T_INTMAX=0
 492 if test "$scm_stdint_has_intmax"; then
 493   SCM_I_GSC_T_INTMAX='"intmax_t"'
 494   SCM_I_GSC_NEEDS_STDINT_H=1
 495 elif test "$scm_inttypes_has_intmax"; then
 496   SCM_I_GSC_T_INTMAX='"intmax_t"'
 497   SCM_I_GSC_NEEDS_INTTYPES_H=1
 498 elif test "$ac_cv_sizeof___int64" -ne 0; then
 499   SCM_I_GSC_T_INTMAX='"__int64"'
 500 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 501   SCM_I_GSC_T_INTMAX='"long long"'
 502 else
 503   SCM_I_GSC_T_INTMAX='"long"'
 504 fi
 505 AC_SUBST([SCM_I_GSC_T_INTMAX])
 506
 507 ### Required type scm_t_uintmax
 508 ###
 509 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 510 ### this order.  When none of them is available, we use 'unsigned long'.
 511 ###
 512 SCM_I_GSC_T_UINTMAX=0
 513 if test "$scm_stdint_has_uintmax"; then
 514   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 515   SCM_I_GSC_NEEDS_STDINT_H=1
 516 elif test "$scm_inttypes_has_uintmax"; then
 517   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 518   SCM_I_GSC_NEEDS_INTTYPES_H=1
 519 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 520   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 521 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 522   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 523 else
 524   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 525 fi
 526 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 527
 528
 529 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 530 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 531
 532 AC_HEADER_STDC
 533 AC_HEADER_DIRENT
 534 AC_HEADER_TIME
 535 AC_HEADER_SYS_WAIT
 536
 537 AC_CHECK_HEADERS([io.h libc.h limits.h malloc.h memory.h string.h \
 538 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 539 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 540 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 541 direct.h])
 542
 543 GUILE_HEADER_LIBC_WITH_UNISTD
 544
 545 AC_TYPE_GETGROUPS
 546 AC_TYPE_SIGNAL
 547 AC_TYPE_MODE_T
 548
 549 if test $MINGW32 = no; then
 550         AC_CHECK_LIB(m, main)
 551 fi
 552 AC_CHECK_FUNCS(gethostbyname)
 553 if test $ac_cv_func_gethostbyname = no; then
 554     AC_CHECK_LIB(nsl, gethostbyname)
 555 fi
 556
 557 AC_CHECK_FUNCS(connect)
 558 if test $ac_cv_func_connect = no; then
 559     AC_CHECK_LIB(socket, connect)
 560 fi
 561
 562 dnl
 563 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 564 dnl
 565 EXTRA_DEFS=""
 566 if test "$MINGW32" = "yes" ; then
 567     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 568       [Define if you have the <winsock2.h> header file.])])
 569     AC_CHECK_LIB(ws2_32, main)
 570     AC_LIBOBJ([win32-uname])
 571     AC_LIBOBJ([win32-dirent])
 572     if test "$enable_networking" = yes ; then
 573       AC_LIBOBJ([win32-socket])
 574     fi
 575     if test "$enable_shared" = yes ; then
 576       EXTRA_DEFS="-DSCM_IMPORT"
 577       AC_DEFINE(USE_DLL_IMPORT, 1,
 578         [Define if you need additional CPP macros on Win32 platforms.])
 579     fi
 580     if test x"$enable_ltdl_install" = x"yes" ; then
 581       INCLTDL="-DLIBLTDL_DLL_IMPORT $INCLTDL"
 582     fi
 583 fi
 584 AC_SUBST(EXTRA_DEFS)
 585
 586 # FIXME: check to see if we still need these.
 587 #AC_SUBST(INCLTDL)
 588 #AC_SUBST(LIBLTDL)
 589
 590 AC_SUBST(DLPREOPEN)
 591
 592 # Reasons for testing:
 593 #   crt_externs.h - Darwin specific
 594 #
 595 AC_CHECK_HEADERS([assert.h crt_externs.h])
 596
 597 # Reasons for testing:
 598 #   DINFINITY - OSF specific
 599 #   DQNAN - OSF specific
 600 #       (DINFINITY and DQNAN are actually global variables, not functions)
 601 #   gmtime_r - recent posix, not on old systems
 602 #   sysconf - not on old systems
 603 #   _NSGetEnviron - Darwin specific
 604 #
 605 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid ftime fchown getcwd geteuid gettimeofday gmtime_r lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv _NSGetEnviron])
 606
 607 # Reasons for testing:
 608 #   netdb.h - not in mingw
 609 #   sys/param.h - not in mingw
 610 #
 611 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 612 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 613
 614 # crypt() may or may not be available, for instance in some countries there
 615 # are restrictions on cryptography.
 616 #
 617 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 618 # -lcrypt library (eg. Debian GNU/Linux).
 619 #
 620 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 621 # be careful to avoid -lcrypt in this case, since libtool will see there's
 622 # only a static libcrypt and decide to build only a static libguile.
 623 #
 624 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 625 # libraries already in that list.
 626 #
 627 AC_SEARCH_LIBS(crypt, crypt,
 628   [AC_DEFINE(HAVE_CRYPT,1,
 629              [Define to 1 if you have the `crypt' function.])])
 630
 631 dnl GMP tests
 632 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 633   [AC_MSG_ERROR([GNU MP not found, see http://swox.com/gmp])])
 634
 635 # mpz_import is a macro so we need to include <gmp.h>
 636 AC_TRY_LINK([#include <gmp.h>],
 637             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 638   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see http://swox.com/gmp])])
 639
 640 ### Some systems don't declare some functions.  On such systems, we
 641 ### need to at least provide our own K&R-style declarations.
 642
 643 ### GUILE_FUNC_DECLARED(function, headerfile)
 644
 645 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 646 ### not there, #define MISSING_FUNCTION_DECL.
 647 AC_DEFUN([GUILE_FUNC_DECLARED], [
 648   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 649     AC_EGREP_HEADER($1, $2,
 650                     guile_cv_func_$1_declared=yes,
 651                     guile_cv_func_$1_declared=no))
 652   if test [x$guile_cv_func_]$1[_declared] = xno; then
 653     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 654       [Define if the operating system supplies $1 without declaring it.])
 655   fi
 656 ])
 657
 658 GUILE_FUNC_DECLARED(sleep, unistd.h)
 659 GUILE_FUNC_DECLARED(usleep, unistd.h)
 660
 661 AC_CHECK_DECLS([strptime],,,
 662 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 663 #include <time.h>])
 664
 665 ### On some systems usleep has no return value.  If it does have one,
 666 ### we'd like to return it; otherwise, we'll fake it.
 667 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 668   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 669                    unistd.h,
 670                    [guile_cv_func_usleep_return_type=void],
 671                    [guile_cv_func_usleep_return_type=int])])
 672 case "$guile_cv_func_usleep_return_type" in
 673   "void" )
 674     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 675       [Define if the system headers declare usleep to return void.])
 676   ;;
 677 esac
 678
 679 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 680 if test -n "$have_sys_un_h" ; then
 681   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 682     [Define if the system supports Unix-domain (file-domain) sockets.])
 683 fi
 684
 685 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 686
 687 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 688                setnetent    getnetent    endnetent    dnl
 689                setprotoent  getprotoent  endprotoent  dnl
 690                setservent   getservent   endservent   dnl
 691                getnetbyaddr getnetbyname dnl
 692                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 693                inet_pton inet_ntop)
 694
 695 AC_MSG_CHECKING(for __libc_stack_end)
 696 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 697 [AC_TRY_LINK([#include <stdio.h>
 698 extern char *__libc_stack_end;],
 699              [printf("%p", (char*) __libc_stack_end);],
 700              guile_cv_have_libc_stack_end=yes,
 701              guile_cv_have_libc_stack_end=no)])
 702 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 703
 704 if test $guile_cv_have_libc_stack_end = yes; then
 705   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 706            [Define if you have the __libc_stack_end variable.])
 707 fi
 708
 709 dnl Some systems do not declare this.  Some systems do declare it, as a
 710 dnl macro.  With cygwin it may be in a DLL.
 711
 712 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 713 AC_CACHE_VAL(guile_cv_have_h_errno,
 714 [AC_TRY_COMPILE([#include <netdb.h>],
 715 [int a = h_errno;],
 716 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 717 AC_MSG_RESULT($guile_cv_have_h_errno)
 718 if test $guile_cv_have_h_errno = yes; then
 719   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 720 fi
 721
 722 AC_MSG_CHECKING(whether uint32_t is defined)
 723 AC_CACHE_VAL(guile_cv_have_uint32_t,
 724   [AC_TRY_COMPILE([#include <sys/types.h>
 725                    #if HAVE_STDINT_H
 726                    #include <stdint.h>
 727                    #endif
 728                    #ifndef __MINGW32__
 729                    #include <netdb.h>
 730                    #endif],
 731                   [uint32_t a;],
 732                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 733 AC_MSG_RESULT($guile_cv_have_uint32_t)
 734 if test $guile_cv_have_uint32_t = yes; then
 735   AC_DEFINE(HAVE_UINT32_T, 1,
 736     [Define if uint32_t typedef is defined when netdb.h is include.])
 737 fi
 738
 739 AC_MSG_CHECKING(for working IPv6 support)
 740 AC_CACHE_VAL(guile_cv_have_ipv6,
 741 [AC_TRY_COMPILE([
 742 #ifdef HAVE_SYS_TYPES_H
 743 #include <sys/types.h>
 744 #endif
 745 #include <netinet/in.h>
 746 #include <sys/socket.h>],
 747 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 748 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 749 AC_MSG_RESULT($guile_cv_have_ipv6)
 750 if test $guile_cv_have_ipv6 = yes; then
 751   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 752 fi
 753
 754 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 755 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 756 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 757 [AC_TRY_COMPILE([
 758 #ifdef HAVE_SYS_TYPES_H
 759 #include <sys/types.h>
 760 #endif
 761 #include <netinet/in.h>],
 762 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 763 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 764 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 765 if test $guile_cv_have_sin6_scope_id = yes; then
 766   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 767     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 768 fi
 769
 770 AC_MSG_CHECKING(whether localtime caches TZ)
 771 AC_CACHE_VAL(guile_cv_localtime_cache,
 772 [if test x$ac_cv_func_tzset = xyes; then
 773 AC_TRY_RUN([#include <time.h>
 774 #if STDC_HEADERS
 775 # include <stdlib.h>
 776 #endif
 777 extern char **environ;
 778 unset_TZ ()
 779 {
 780   char **from, **to;
 781   for (to = from = environ; (*to = *from); from++)
 782     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 783       to++;
 784 }
 785 char TZ_GMT0[] = "TZ=GMT0";
 786 char TZ_PST8[] = "TZ=PST8";
 787 main()
 788 {
 789   time_t now = time ((time_t *) 0);
 790   int hour_GMT0, hour_unset;
 791   if (putenv (TZ_GMT0) != 0)
 792     exit (1);
 793   hour_GMT0 = localtime (&now)->tm_hour;
 794   unset_TZ ();
 795   hour_unset = localtime (&now)->tm_hour;
 796   if (putenv (TZ_PST8) != 0)
 797     exit (1);
 798   if (localtime (&now)->tm_hour == hour_GMT0)
 799     exit (1);
 800   unset_TZ ();
 801   if (localtime (&now)->tm_hour != hour_unset)
 802     exit (1);
 803   exit (0);
 804 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 805 [# If we have tzset, assume the worst when cross-compiling.
 806 guile_cv_localtime_cache=yes])
 807 else
 808         # If we lack tzset, report that localtime does not cache TZ,
 809         # since we can't invalidate the cache if we don't have tzset.
 810         guile_cv_localtime_cache=no
 811 fi])dnl
 812 AC_MSG_RESULT($guile_cv_localtime_cache)
 813 if test $guile_cv_localtime_cache = yes; then
 814   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 815 fi
 816
 817 dnl Test whether system calls are restartable by default on the
 818 dnl current system.  If they are not, we put a loop around every system
 819 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 820 dnl change from the default behaviour.  On the other hand, if signals
 821 dnl are restartable then the loop is not installed and when libguile
 822 dnl initialises it also resets the behaviour of each signal to cause a
 823 dnl restart (in case a different runtime had a different default
 824 dnl behaviour for some reason: e.g., different versions of linux seem
 825 dnl to behave differently.)
 826
 827 AC_SYS_RESTARTABLE_SYSCALLS
 828
 829 if test "$enable_regex" = yes; then
 830    if test "$ac_cv_header_regex_h" = yes ||
 831       test "$ac_cv_header_rxposix_h" = yes ||
 832       test "$ac_cv_header_rx_rxposix_h" = yes; then
 833      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 834      [AC_CHECK_LIB(rx, main)
 835       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 836      [AC_CHECK_LIB(regex, main)
 837       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 838      )
 839      dnl The following should not be necessary, but for some reason
 840      dnl autoheader misses it if we don't include it!
 841      if test "$ac_cv_func_regcomp_norx" = yes ||
 842         test "$ac_cv_func_regcomp_regex" = yes ||
 843         test "$ac_cv_func_regcomp_rx" = yes; then
 844        AC_DEFINE(HAVE_REGCOMP, 1,
 845          [This is included as part of a workaround for a autoheader bug.])
 846      fi
 847    fi
 848 fi
 849
 850 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 851
 852 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 853
 854 # Reasons for testing:
 855 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 856 #                                older systems
 857 #   sincos - GLIBC extension
 858 #
 859 AC_CHECK_FUNCS(asinh acosh atanh copysign finite isinf isnan sincos trunc)
 860
 861 # When testing for the presence of alloca, we need to add alloca.o
 862 # explicitly to LIBOBJS to make sure that it is translated to
 863 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 864 AC_FUNC_ALLOCA
 865 if test "$ALLOCA" = "alloca.o"
 866 then
 867   AC_LIBOBJ([alloca])
 868 fi
 869
 870 AC_CHECK_MEMBERS([struct stat.st_rdev])
 871 AC_CHECK_MEMBERS([struct stat.st_blksize])
 872
 873 AC_STRUCT_ST_BLOCKS
 874
 875 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 876   [AC_TRY_CPP([#include <sys/stat.h>
 877                #ifndef S_ISLNK
 878                #error no S_ISLNK
 879                #endif],
 880                ac_cv_macro_S_ISLNK=yes,
 881                ac_cv_macro_S_ISLNK=no)])
 882 if test $ac_cv_macro_S_ISLNK = yes; then
 883   AC_DEFINE(HAVE_S_ISLNK, 1,
 884     [Define this if your system defines S_ISLNK in sys/stat.h.])
 885 fi
 886
 887 AC_STRUCT_TIMEZONE
 888 GUILE_STRUCT_UTIMBUF
 889
 890 #--------------------------------------------------------------------
 891 #
 892 # Which way does the stack grow?
 893 #
 894 #--------------------------------------------------------------------
 895
 896 SCM_I_GSC_STACK_GROWS_UP=0
 897 AC_TRY_RUN(aux (l) unsigned long l;
 898              { int x; exit (l >= ((unsigned long)&x)); }
 899            main () { int q; aux((unsigned long)&q); },
 900            [SCM_I_GSC_STACK_GROWS_UP=1],
 901            [],
 902            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
 903
 904 AC_CHECK_SIZEOF(float)
 905 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
 906     AC_DEFINE(SCM_SINGLES, 1,
 907               [Define this if floats are the same size as longs.])
 908 fi
 909
 910 AC_MSG_CHECKING(for struct linger)
 911 AC_CACHE_VAL(scm_cv_struct_linger,
 912         AC_TRY_COMPILE([
 913 #include <sys/types.h>
 914 #include <sys/socket.h>],
 915                         [struct linger lgr;  lgr.l_linger = 100],
 916                         scm_cv_struct_linger="yes",
 917                         scm_cv_struct_linger="no"))
 918 AC_MSG_RESULT($scm_cv_struct_linger)
 919 if test $scm_cv_struct_linger = yes; then
 920         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 921           [Define this if your system defines struct linger, for use with the
 922            getsockopt and setsockopt system calls.])
 923 fi
 924
 925
 926 AC_MSG_CHECKING(for struct timespec)
 927 AC_CACHE_VAL(scm_cv_struct_timespec,
 928         AC_TRY_COMPILE([
 929 #include <time.h>],
 930                         [struct timespec t;  t.tv_nsec = 100],
 931                         scm_cv_struct_timespec="yes",
 932                         scm_cv_struct_timespec="no"))
 933 AC_MSG_RESULT($scm_cv_struct_timespec)
 934 if test $scm_cv_struct_timespec = yes; then
 935   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 936     [Define this if your system defines struct timespec via <time.h>.])
 937 fi
 938
 939 #--------------------------------------------------------------------
 940 #
 941 # Flags for thread support
 942 #
 943 #--------------------------------------------------------------------
 944
 945 SCM_I_GSC_USE_PTHREAD_THREADS=0
 946 SCM_I_GSC_USE_NULL_THREADS=0
 947 SCM_I_GSC_USE_COOP_THREADS=0
 948 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
 949 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
 950 AC_SUBST([SCM_I_GSC_USE_COOP_THREADS])
 951
 952 ### What thread package has the user asked for?
 953 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 954             , with_threads=yes)
 955
 956 case "$with_threads" in
 957   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
 958     AC_CHECK_LIB(pthread, main,
 959       LIBS="-lpthread $LIBS"
 960       SCM_I_GSC_USE_PTHREAD_THREADS=1
 961       with_threads="pthreads",
 962       with_threads="null")
 963
 964     if test $GCC = yes; then
 965     AC_DEFINE(_THREAD_SAFE, 1,
 966       [Use thread safe versions of GNU Libc functions.])
 967     fi
 968
 969     AC_MSG_CHECKING(if pthread_mutexattr_settype is declared)
 970     AC_CACHE_VAL(guile_cv_mutexattr_settype_declared,
 971       [AC_TRY_COMPILE([#include <pthread.h>],
 972           [int pthread_mutexattr_settype (int, int);],
 973           guile_cv_mutexattr_settype_declared=no,
 974           guile_cv_mutexattr_settype_declared=yes)])
 975     AC_MSG_RESULT($guile_cv_mutexattr_settype_declared)
 976     if test $guile_cv_mutexattr_settype_declared = yes; then
 977       AC_DEFINE(SCM_MUTEXATTR_SETTYPE_DECLARED, 1,
 978           [Define if pthread.h declares pthread_mutexattr_settype.])
 979     fi
 980
 981     AC_MSG_CHECKING(how to get a fast mutex)
 982     AC_CACHE_VAL(guile_cv_have_mutex_fast,
 983       [AC_TRY_COMPILE([#include <pthread.h>],
 984           [int a = PTHREAD_MUTEX_ADAPTIVE_NP;],
 985           guile_cv_have_mutex_fast=PTHREAD_MUTEX_ADAPTIVE_NP,
 986           guile_cv_have_mutex_fast=none)])
 987     AC_MSG_RESULT($guile_cv_have_mutex_fast)
 988     if test ! $guile_cv_have_mutex_fast = none; then
 989       AC_DEFINE_UNQUOTED(SCM_MUTEX_FAST, $guile_cv_have_mutex_fast,
 990           [The mutex kind enum for fast mutexes.])
 991     fi
 992
 993     AC_MSG_CHECKING(how to get a recursive mutex)
 994     AC_CACHE_VAL(guile_cv_have_mutex_recursive,
 995       [AC_TRY_COMPILE([#include <pthread.h>],
 996         [int a = PTHREAD_MUTEX_RECURSIVE_NP;],
 997          guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE_NP)
 998       if test -z "$guile_cv_have_mutex_recursive"; then
 999           AC_TRY_COMPILE([#include <pthread.h>],
1000             [int a = PTHREAD_MUTEX_RECURSIVE;],
1001             guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE,
1002             guile_cv_have_mutex_recursive=none)
1003         fi])
1004     AC_MSG_RESULT($guile_cv_have_mutex_recursive)
1005     if test ! $guile_cv_have_mutex_recursive = none; then
1006       AC_DEFINE_UNQUOTED(SCM_MUTEX_RECURSIVE, $guile_cv_have_mutex_recursive,
1007          [The mutex kind enum for recursive mutexes.])
1008     fi
1009
1010     # On Solaris, sched_yield lives in -lrt.
1011     AC_SEARCH_LIBS(sched_yield, rt)
1012
1013   ;;
1014 esac
1015
1016 case "$with_threads" in
1017   "pthreads")
1018   ;;
1019   "no" | "null")
1020     SCM_I_GSC_USE_NULL_THREADS=1
1021     with_threads="null-threads"
1022   ;;
1023   * )
1024     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1025   ;;
1026 esac
1027
1028 AC_MSG_CHECKING(what kind of threads to support)
1029 AC_MSG_RESULT($with_threads)
1030
1031 ## Cross building
1032 if test "$cross_compiling" = "yes"; then
1033   AC_MSG_CHECKING(cc for build)
1034   ## /usr/bin/cc still uses wrong assembler
1035   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1036   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1037 else
1038   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1039 fi
1040
1041 ## AC_MSG_CHECKING("if we are cross compiling")
1042 ## AC_MSG_RESULT($cross_compiling)
1043 if test "$cross_compiling" = "yes"; then
1044    AC_MSG_RESULT($CC_FOR_BUILD)
1045 fi
1046
1047 ## No need as yet to be more elaborate
1048 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1049
1050 AC_SUBST(cross_compiling)
1051 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1052 AC_SUBST(CCLD_FOR_BUILD)
1053
1054 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1055 ## --HOST is the platform that PACKAGE is compiled for.
1056 HOST_CC="$CC_FOR_BUILD"
1057 AC_SUBST(HOST_CC)
1058
1059 if test "$cross_compiling" = "yes"; then
1060   AC_MSG_CHECKING(guile for build)
1061   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1062 else
1063   GUILE_FOR_BUILD='$(preinstguile)'
1064 fi
1065
1066 ## AC_MSG_CHECKING("if we are cross compiling")
1067 ## AC_MSG_RESULT($cross_compiling)
1068 if test "$cross_compiling" = "yes"; then
1069    AC_MSG_RESULT($GUILE_FOR_BUILD)
1070 fi
1071 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1072 AC_SUBST(GUILE_FOR_BUILD)
1073
1074 ## If we're using GCC, ask for aggressive warnings.
1075 case "$GCC" in
1076   yes )
1077     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1078     ## much stuff with generic function pointers for that to really be
1079     ## less than exasperating.
1080     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1081     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1082     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1083     # Do this here so we don't screw up any of the tests above that might
1084     # not be "warning free"
1085     if test "${GUILE_ERROR_ON_WARNING}" = yes
1086     then
1087         CFLAGS="${CFLAGS} -Werror"
1088         enable_compile_warnings=no
1089     fi
1090     ;;
1091 esac
1092
1093 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
1094 ## -- I'm disabling it for now in the hopes that the newer autoconf
1095 ## will DTRT -- if not, we need to fix up the sed command to match the
1096 ## others...
1097 ##
1098 ## Remove fileblocks.o from the object list.  This file gets added by
1099 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
1100 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
1101
1102 ## If we're creating a shared library (using libtool!), then we'll
1103 ## need to generate a list of .lo files corresponding to the .o files
1104 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1105 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1106
1107 ## We also need to create corresponding .doc and .x files
1108 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1109 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1110
1111 AC_SUBST(GUILE_MAJOR_VERSION)
1112 AC_SUBST(GUILE_MINOR_VERSION)
1113 AC_SUBST(GUILE_MICRO_VERSION)
1114 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1115 AC_SUBST(GUILE_VERSION)
1116
1117 #######################################################################
1118 # library versioning
1119
1120 AC_SUBST(LIBQTHREADS_INTERFACE_CURRENT)
1121 AC_SUBST(LIBQTHREADS_INTERFACE_REVISION)
1122 AC_SUBST(LIBQTHREADS_INTERFACE_AGE)
1123 AC_SUBST(LIBQTHREADS_INTERFACE)
1124
1125 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1126 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1127 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1128 AC_SUBST(LIBGUILE_INTERFACE)
1129
1130 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1131 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1132 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1133 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1134
1135 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1136 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1137 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1138 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1139
1140 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1141 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1142 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1143 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1144
1145 #######################################################################
1146
1147 dnl Tell guile-config what flags guile users should link against.
1148 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
1149 AC_SUBST(GUILE_LIBS)
1150
1151 AC_SUBST(AWK)
1152 AC_SUBST(LIBLOBJS)
1153 AC_SUBST(EXTRA_DOT_DOC_FILES)
1154 AC_SUBST(EXTRA_DOT_X_FILES)
1155
1156 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1157 top_builddir_absolute=`pwd`
1158 AC_SUBST(top_builddir_absolute)
1159 top_srcdir_absolute=`(cd $srcdir && pwd)`
1160 AC_SUBST(top_srcdir_absolute)
1161
1162 # Additional SCM_I_GSC definitions are above.
1163 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1164 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1165 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1166 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1167 AC_SUBST([SCM_I_GSC_HAVE_ARRAYS])
1168 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1169 AC_SUBST([SCM_I_GSC_C_INLINE])
1170 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1171
1172 AC_CONFIG_FILES([
1173   Makefile
1174   am/Makefile
1175   benchmark-suite/Makefile
1176   doc/Makefile
1177   doc/goops/Makefile
1178   doc/r5rs/Makefile
1179   doc/ref/Makefile
1180   doc/tutorial/Makefile
1181   emacs/Makefile
1182   examples/Makefile
1183   examples/box-dynamic-module/Makefile
1184   examples/box-dynamic/Makefile
1185   examples/box-module/Makefile
1186   examples/box/Makefile
1187   examples/modules/Makefile
1188   examples/safe/Makefile
1189   examples/scripts/Makefile
1190   guile-config/Makefile
1191   ice-9/Makefile
1192   ice-9/debugger/Makefile
1193   ice-9/debugger/breakpoints/Makefile
1194   lang/Makefile
1195   lang/elisp/Makefile
1196   lang/elisp/internals/Makefile
1197   lang/elisp/primitives/Makefile
1198   libguile-ltdl/Makefile
1199   libguile-ltdl/upstream/Makefile
1200   libguile/Makefile
1201   oop/Makefile
1202   oop/goops/Makefile
1203   scripts/Makefile
1204   srfi/Makefile
1205   test-suite/Makefile
1206   test-suite/standalone/Makefile
1207 ])
1208
1209 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1210 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1211 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1212 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1213 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1214 AC_CONFIG_FILES([libguile/guile-snarf],
1215                 [chmod +x libguile/guile-snarf])
1216 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1217                 [chmod +x libguile/guile-doc-snarf])
1218 AC_CONFIG_FILES([libguile/guile-func-name-check],
1219                 [chmod +x libguile/guile-func-name-check])
1220 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1221                 [chmod +x libguile/guile-snarf-docs])
1222
1223 AC_OUTPUT
1224
1225 dnl Local Variables:
1226 dnl comment-start: "dnl "
1227 dnl comment-end: ""
1228 dnl comment-start-skip: "\\bdnl\\b\\s *"
1229 dnl End: