configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_PREREQ(2.50)
  24
  25 AC_INIT
  26 AC_CONFIG_SRCDIR([Makefile.in])
  27 . $srcdir/GUILE-VERSION
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  29 AM_MAINTAINER_MODE
  30 AM_CONFIG_HEADER(libguile/scmconfig.h)
  31
  32 #--------------------------------------------------------------------
  33 #
  34 # Independent Subdirectories
  35 #
  36 #--------------------------------------------------------------------
  37
  38 AC_CONFIG_SUBDIRS(guile-readline)
  39
  40 #--------------------------------------------------------------------
  41 #
  42 # User options
  43 #
  44 #--------------------------------------------------------------------
  45
  46 AC_ARG_ENABLE(error-on-warning,
  47   [  --enable-error-on-warning    treat compile warnings as errors],
  48   [case "${enableval}" in
  49      yes | y) CFLAGS="${CFLAGS} -Werror"; enable_compile_warnings=no ;;
  50      no | n)  ;;
  51      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  52    esac])
  53
  54 AC_ARG_ENABLE(debug-freelist,
  55   [  --enable-debug-freelist include garbage collector freelist debugging code],
  56   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  57     AC_DEFINE(GUILE_DEBUG_FREELIST)
  58   fi)
  59
  60 AC_ARG_ENABLE(debug-malloc,
  61   [  --enable-debug-malloc   include malloc debugging code],
  62   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  63     AC_DEFINE(GUILE_DEBUG_MALLOC)
  64   fi)
  65
  66 AC_ARG_ENABLE(guile-debug,
  67   [  --enable-guile-debug    include internal debugging functions],
  68   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  69     AC_DEFINE(GUILE_DEBUG)
  70   fi)
  71
  72 AC_ARG_ENABLE(arrays,
  73   [  --disable-arrays        omit array and uniform array support],,
  74   enable_arrays=yes)
  75
  76 AC_ARG_ENABLE(posix,
  77   [  --disable-posix         omit posix interfaces],,
  78   enable_posix=yes)
  79
  80 AC_ARG_ENABLE(networking,
  81   [  --disable-networking    omit networking interfaces],,
  82   enable_networking=yes)
  83
  84 AC_ARG_ENABLE(regex,
  85   [  --disable-regex         omit regular expression interfaces],,
  86   enable_regex=yes)
  87
  88 AC_ARG_ENABLE(htmldoc,
  89   [  --enable-htmldoc        build HTML documentation as well as Info],
  90   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  91      htmldoc_enabled=yes
  92      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  93      if test "$TEXI2HTML" = "not found"; then
  94        echo
  95        echo Building HTML documentation requires the \`texi2html\' program,
  96        echo which appears not to be present on your machine.
  97        echo
  98        echo \`texi2html\' is available from
  99        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
 100        echo
 101        echo In the meantime, to build the guile-doc distribution
 102        echo without HTML enabled, please rerun \`./configure\' without
 103        echo the \`--enable-htmldoc\' option.
 104        exit -1
 105      fi
 106    fi])
 107
 108 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
 109
 110 AC_ARG_ENABLE(deprecated,
 111   [  --disable-deprecated    omit deprecated features [no]])
 112
 113 if test "$enable_deprecated" = no; then
 114   AC_DEFINE(SCM_ENABLE_DEPRECATED, 0)
 115 else
 116   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 117     warn_default=summary
 118   elif test "$enable_deprecated" = shutup; then
 119     warn_default=no
 120   else
 121     warn_default=$enable_deprecated
 122   fi
 123   AC_DEFINE(SCM_ENABLE_DEPRECATED, 1)
 124   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default")
 125 fi
 126
 127 dnl The --disable-debug used to control these two.  But now they are
 128 dnl a required part of the distribution.
 129 AC_DEFINE(DEBUG_EXTENSIONS)
 130 AC_DEFINE(READER_EXTENSIONS)
 131
 132 AC_ARG_ENABLE(elisp,
 133   [  --disable-elisp         omit Emacs Lisp support],,
 134   enable_elisp=yes)
 135
 136 dnl files which are destined for separate modules.
 137
 138 if test "$enable_arrays" = yes; then
 139    LIBOBJS="$LIBOBJS ramap.o unif.o"
 140    AC_DEFINE(HAVE_ARRAYS)
 141 fi
 142
 143 if test "$enable_posix" = yes; then
 144    LIBOBJS="$LIBOBJS filesys.o posix.o"
 145    AC_DEFINE(HAVE_POSIX)
 146 fi
 147
 148 if test "$enable_networking" = yes; then
 149    LIBOBJS="$LIBOBJS net_db.o socket.o"
 150    AC_DEFINE(HAVE_NETWORKING)
 151 fi
 152
 153 if test "$enable_debug_malloc" = yes; then
 154    LIBOBJS="$LIBOBJS debug-malloc.o"
 155 fi
 156
 157 if test "$enable_elisp" = yes; then
 158    AC_DEFINE(SCM_ENABLE_ELISP)
 159 fi
 160
 161 #--------------------------------------------------------------------
 162
 163 dnl Some more checks for Win32
 164 AC_CYGWIN
 165 AC_MINGW32
 166 AC_LIBTOOL_WIN32_DLL
 167
 168 AC_LIBLTDL_INSTALLABLE
 169 AC_CONFIG_SUBDIRS(libltdl)
 170
 171 AC_PROG_INSTALL
 172 AC_PROG_CC
 173 AC_PROG_CPP
 174 AC_LIBTOOL_DLOPEN
 175
 176 AC_AIX
 177 AC_ISC_POSIX
 178 AC_MINIX
 179
 180 AM_PROG_CC_STDC
 181 AM_PROG_LIBTOOL
 182
 183 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
 184 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
 185
 186 AC_C_CONST
 187 AC_C_INLINE
 188 AC_C_BIGENDIAN
 189
 190 if test "$ac_cv_c_inline" != no; then
 191   AC_DEFINE(HAVE_INLINE)
 192 fi
 193
 194 AC_CHECK_SIZEOF(short)
 195 AC_CHECK_SIZEOF(int)
 196 AC_CHECK_SIZEOF(long)
 197 AC_CHECK_SIZEOF(size_t)
 198
 199 dnl Check for integral types that can represent the range of pointers.
 200 dnl If these types don't exist on this platform, they are replaced by
 201 dnl "unsigned long" and "long", respectively.
 202
 203 AC_CHECK_HEADERS(stdint.h)
 204 AC_CHECK_HEADERS(inttypes.h)
 205 AC_CHECK_SIZEOF(uintptr_t)
 206 AC_CHECK_SIZEOF(ptrdiff_t)
 207
 208 AC_CHECK_SIZEOF(long long)
 209
 210 AC_CHECK_SIZEOF(void *)
 211
 212 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 213   AC_MSG_ERROR(sizes of long and void* are not identical)
 214 fi
 215
 216 AC_HEADER_STDC
 217 AC_HEADER_DIRENT
 218 AC_HEADER_TIME
 219 AC_HEADER_SYS_WAIT
 220 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h direct.h)
 221 GUILE_HEADER_LIBC_WITH_UNISTD
 222
 223 AC_TYPE_GETGROUPS
 224 AC_TYPE_SIGNAL
 225 AC_TYPE_MODE_T
 226
 227 AC_CHECK_LIB(m, main)
 228 AC_CHECK_FUNCS(gethostbyname)
 229 if test $ac_cv_func_gethostbyname = no; then
 230     AC_CHECK_LIB(nsl, gethostbyname)
 231 fi
 232 AC_CHECK_FUNCS(connect)
 233 if test $ac_cv_func_connect = no; then
 234     AC_CHECK_LIB(socket, connect)
 235 fi
 236
 237 dnl
 238 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 239 dnl
 240 EXTRA_DEFS=""
 241 if test "$MINGW32" = "yes" ; then
 242     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 243       [Define if you have the <winsock2.h> header file.])])
 244     AC_CHECK_LIB(ws2_32, main)
 245     LIBOBJS="$LIBOBJS win32-uname.o win32-dirent.o"
 246     if test "$enable_networking" = yes ; then
 247       LIBOBJS="$LIBOBJS win32-socket.o"
 248     fi
 249     if test "$enable_shared" = yes ; then
 250       EXTRA_DEFS="-DSCM_IMPORT"
 251       AC_DEFINE(USE_DLL_IMPORT, 1,
 252         [Define if you need additional CPP macros on Win32 platforms.])
 253     fi
 254     if test x"$enable_ltdl_install" = x"yes" ; then
 255       INCLTDL="-DLIBLTDL_DLL_IMPORT $INCLTDL"
 256     fi
 257 fi
 258 AC_SUBST(EXTRA_DEFS)
 259
 260 dnl Check for dynamic linking
 261
 262 use_modules=yes
 263 AC_ARG_WITH(modules,
 264 [  --with-modules[=FILES]  Add support for dynamic modules],
 265 use_modules="$withval")
 266 test -z "$use_modules" && use_modules=yes
 267 DLPREOPEN=
 268 if test "$use_modules" != no; then
 269   AC_DEFINE(DYNAMIC_LINKING)
 270   if test "$use_modules" = yes; then
 271     DLPREOPEN="-dlpreopen force"
 272   else
 273     DLPREOPEN="-export-dynamic"
 274     for module in $use_modules; do
 275       DLPREOPEN="$DLPREOPEN -dlopen $module"
 276     done
 277   fi
 278 fi
 279
 280 AC_SUBST(INCLTDL)
 281 AC_SUBST(LIBLTDL)
 282 AC_SUBST(DLPREOPEN)
 283
 284 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer)
 285
 286 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 287 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 288 AC_CHECK_LIB(crypt, crypt)
 289
 290 ### Some systems don't declare some functions.  On such systems, we
 291 ### need to at least provide our own K&R-style declarations.
 292
 293 ### GUILE_FUNC_DECLARED(function, headerfile)
 294
 295 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 296 ### not there, #define MISSING_FUNCTION_DECL.
 297 AC_DEFUN(GUILE_FUNC_DECLARED, [
 298   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 299     AC_EGREP_HEADER($1, $2,
 300                     guile_cv_func_$1_declared=yes,
 301                     guile_cv_func_$1_declared=no))
 302   if test [x$guile_cv_func_]$1[_declared] = xno; then
 303     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 304   fi
 305 ])
 306
 307 GUILE_FUNC_DECLARED(strptime, time.h)
 308 GUILE_FUNC_DECLARED(sleep, unistd.h)
 309 GUILE_FUNC_DECLARED(usleep, unistd.h)
 310
 311 ### On some systems usleep has no return value.  If it does have one,
 312 ### we'd like to return it; otherwise, we'll fake it.
 313 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 314   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 315                    unistd.h,
 316                    [guile_cv_func_usleep_return_type=void],
 317                    [guile_cv_func_usleep_return_type=int])])
 318 case "$guile_cv_func_usleep_return_type" in
 319   "void" )
 320     AC_DEFINE(USLEEP_RETURNS_VOID)
 321   ;;
 322 esac
 323
 324 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 325 if test -n "$have_sys_un_h" ; then
 326 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 327 fi
 328
 329 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 330
 331 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 332                setnetent    getnetent    endnetent    dnl
 333                setprotoent  getprotoent  endprotoent  dnl
 334                setservent   getservent   endservent   dnl
 335                getnetbyaddr getnetbyname dnl
 336                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 337                inet_pton inet_ntop)
 338
 339 dnl Some systems do not declare this.  Some systems do declare it, as a
 340 dnl macro.  With cygwin it may be in a DLL.
 341
 342 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 343 AC_CACHE_VAL(guile_cv_have_h_errno,
 344 [AC_TRY_COMPILE([#include <netdb.h>],
 345 [int a = h_errno;],
 346 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 347 AC_MSG_RESULT($guile_cv_have_h_errno)
 348 if test $guile_cv_have_h_errno = yes; then
 349   AC_DEFINE(HAVE_H_ERRNO)
 350 fi
 351
 352 AC_MSG_CHECKING(whether uint32_t is defined)
 353 AC_CACHE_VAL(guile_cv_have_uint32_t,
 354   [AC_TRY_COMPILE([#include <sys/types.h>
 355                    #if HAVE_STDINT_H
 356                    #include <stdint.h>
 357                    #endif
 358                    #ifndef __MINGW32__
 359                    #include <netdb.h>
 360                    #endif],
 361                   [uint32_t a;],
 362                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 363 AC_MSG_RESULT($guile_cv_have_uint32_t)
 364 if test $guile_cv_have_uint32_t = yes; then
 365   AC_DEFINE(HAVE_UINT32_T)
 366 fi
 367
 368 AC_MSG_CHECKING(for working IPv6 support)
 369 AC_CACHE_VAL(guile_cv_have_ipv6,
 370 [AC_TRY_COMPILE([#include <netinet/in.h>
 371 #include <sys/socket.h>],
 372 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 373 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 374 AC_MSG_RESULT($guile_cv_have_ipv6)
 375 if test $guile_cv_have_ipv6 = yes; then
 376   AC_DEFINE(HAVE_IPV6)
 377 fi
 378
 379 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 380 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 381 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 382 [AC_TRY_COMPILE([#include <netinet/in.h>],
 383 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 384 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 385 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 386 if test $guile_cv_have_sin6_scope_id = yes; then
 387   AC_DEFINE(HAVE_SIN6_SCOPE_ID)
 388 fi
 389
 390 AC_MSG_CHECKING(whether localtime caches TZ)
 391 AC_CACHE_VAL(guile_cv_localtime_cache,
 392 [if test x$ac_cv_func_tzset = xyes; then
 393 AC_TRY_RUN([#include <time.h>
 394 #if STDC_HEADERS
 395 # include <stdlib.h>
 396 #endif
 397 extern char **environ;
 398 unset_TZ ()
 399 {
 400   char **from, **to;
 401   for (to = from = environ; (*to = *from); from++)
 402     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 403       to++;
 404 }
 405 char TZ_GMT0[] = "TZ=GMT0";
 406 char TZ_PST8[] = "TZ=PST8";
 407 main()
 408 {
 409   time_t now = time ((time_t *) 0);
 410   int hour_GMT0, hour_unset;
 411   if (putenv (TZ_GMT0) != 0)
 412     exit (1);
 413   hour_GMT0 = localtime (&now)->tm_hour;
 414   unset_TZ ();
 415   hour_unset = localtime (&now)->tm_hour;
 416   if (putenv (TZ_PST8) != 0)
 417     exit (1);
 418   if (localtime (&now)->tm_hour == hour_GMT0)
 419     exit (1);
 420   unset_TZ ();
 421   if (localtime (&now)->tm_hour != hour_unset)
 422     exit (1);
 423   exit (0);
 424 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 425 [# If we have tzset, assume the worst when cross-compiling.
 426 guile_cv_localtime_cache=yes])
 427 else
 428         # If we lack tzset, report that localtime does not cache TZ,
 429         # since we can't invalidate the cache if we don't have tzset.
 430         guile_cv_localtime_cache=no
 431 fi])dnl
 432 AC_MSG_RESULT($guile_cv_localtime_cache)
 433 if test $guile_cv_localtime_cache = yes; then
 434   AC_DEFINE(LOCALTIME_CACHE)
 435 fi
 436
 437 dnl Test whether system calls are restartable by default on the
 438 dnl current system.  If they are not, we put a loop around every system
 439 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 440 dnl change from the default behaviour.  On the other hand, if signals
 441 dnl are restartable then the loop is not installed and when libguile
 442 dnl initialises it also resets the behaviour of each signal to cause a
 443 dnl restart (in case a different runtime had a different default
 444 dnl behaviour for some reason: e.g., different versions of linux seem
 445 dnl to behave differently.)
 446
 447 AC_SYS_RESTARTABLE_SYSCALLS
 448
 449 if test "$enable_regex" = yes; then
 450    if test "$ac_cv_header_regex_h" = yes ||
 451       test "$ac_cv_header_rxposix_h" = yes ||
 452       test "$ac_cv_header_rx_rxposix_h" = yes; then
 453      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 454      [AC_CHECK_LIB(rx, main)
 455       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 456      [AC_CHECK_LIB(regex, main)
 457       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [LIBOBJS="regex-posix.o $LIBOBJS"])])]
 458      )
 459      dnl The following should not be necessary, but for some reason
 460      dnl autoheader misses it if we don't include it!
 461      if test "$ac_cv_func_regcomp_norx" = yes ||
 462         test "$ac_cv_func_regcomp_regex" = yes ||
 463         test "$ac_cv_func_regcomp_rx" = yes; then
 464        AC_DEFINE(HAVE_REGCOMP)
 465      fi
 466    fi
 467 fi
 468
 469 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 470
 471 # When testing for the presence of alloca, we need to add alloca.o
 472 # explicitly to LIBOBJS to make sure that it is translated to
 473 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 474 AC_FUNC_ALLOCA
 475 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 476
 477 AC_CHECK_MEMBERS([struct stat.st_rdev])
 478 AC_CHECK_MEMBERS([struct stat.st_blksize])
 479
 480 AC_STRUCT_ST_BLOCKS
 481
 482 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 483   [AC_TRY_CPP([#include <sys/stat.h>
 484                #ifndef S_ISLNK
 485                #error no S_ISLNK
 486                #endif],
 487                ac_cv_macro_S_ISLNK=yes,
 488                ac_cv_macro_S_ISLNK=no)])
 489 if test $ac_cv_macro_S_ISLNK = yes; then
 490   AC_DEFINE(HAVE_S_ISLNK)
 491 fi
 492
 493 AC_STRUCT_TIMEZONE
 494 GUILE_STRUCT_UTIMBUF
 495
 496 #--------------------------------------------------------------------
 497 #
 498 # Which way does the stack grow?
 499 #
 500 #--------------------------------------------------------------------
 501
 502 AC_TRY_RUN(aux (l) unsigned long l;
 503              { int x; exit (l >= ((unsigned long)&x)); }
 504            main () { int q; aux((unsigned long)&q); },
 505            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 506
 507 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 508     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 509                 [guile_cv_type_float_fits_long=yes],
 510                 [guile_cv_type_float_fits_long=no],
 511                 [guile_cv_type_float_fits_long=guess-yes])])
 512 case $guile_cv_type_float_fits_long in
 513   "yes" )
 514     AC_DEFINE(SCM_SINGLES)
 515   ;;
 516   "guess-yes" )
 517     AC_DEFINE(SCM_SINGLES)
 518     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 519     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 520   ;;
 521 esac
 522
 523
 524 AC_MSG_CHECKING(for struct linger)
 525 AC_CACHE_VAL(scm_cv_struct_linger,
 526         AC_TRY_COMPILE([
 527 #include <sys/types.h>
 528 #include <sys/socket.h>],
 529                         [struct linger lgr;  lgr.l_linger = 100],
 530                         scm_cv_struct_linger="yes",
 531                         scm_cv_struct_linger="no"))
 532 AC_MSG_RESULT($scm_cv_struct_linger)
 533 if test $scm_cv_struct_linger = yes; then
 534         AC_DEFINE(HAVE_STRUCT_LINGER)
 535 fi
 536
 537
 538 AC_MSG_CHECKING(for struct timespec)
 539 AC_CACHE_VAL(scm_cv_struct_timespec,
 540         AC_TRY_COMPILE([
 541 #include <time.h>],
 542                         [struct timespec t;  t.tv_nsec = 100],
 543                         scm_cv_struct_timespec="yes",
 544                         scm_cv_struct_timespec="no"))
 545 AC_MSG_RESULT($scm_cv_struct_timespec)
 546 if test $scm_cv_struct_timespec = yes; then
 547         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 548 fi
 549
 550 #--------------------------------------------------------------------
 551 #
 552 # Flags for thread support
 553 #
 554 #--------------------------------------------------------------------
 555
 556 ### What thread package has the user asked for?
 557 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 558             , with_threads=no)
 559
 560 ### Turn $with_threads into either the name of a threads package, like
 561 ### `qt', or `no', meaning that threads should not be supported.
 562 AC_MSG_CHECKING(whether to support threads)
 563 case "$with_threads" in
 564   "yes" | "qt" | "coop" | "")
 565     with_threads=qt
 566   ;;
 567   "no" )
 568   ;;
 569   * )
 570     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 571   ;;
 572 esac
 573 AC_MSG_RESULT($with_threads)
 574
 575 ## Make sure the threads package we've chosen is actually supported on
 576 ## the present platform.
 577 case "${with_threads}" in
 578   "qt" )
 579     ## This configures the QuickThreads package, and sets or clears
 580     ## the THREAD_PACKAGE variable if qthreads don't configure
 581     ## correctly.
 582     QTHREADS_CONFIGURE
 583    ;;
 584 esac
 585
 586 ## If we're using threads, bring in some other parts of Guile which
 587 ## work with them.
 588 if test "${THREAD_PACKAGE}" != "" ; then
 589   AC_DEFINE(USE_THREADS, 1)
 590
 591   ## Include the Guile thread interface in the library...
 592   LIBOBJS="$LIBOBJS threads.o"
 593
 594   ## ... and tell it which package to talk to.
 595   case "${THREAD_PACKAGE}" in
 596     "QT" )
 597       AC_DEFINE(USE_COOP_THREADS, 1)
 598     ;;
 599     * )
 600       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 601     ;;
 602   esac
 603
 604   ## Bring in scm_internal_select, if appropriate.
 605   if test $ac_cv_func_gettimeofday = yes &&
 606      test $ac_cv_func_select = yes; then
 607     AC_DEFINE(GUILE_ISELECT, 1)
 608   fi
 609
 610   AC_ARG_ENABLE(linuxthreads,
 611   [  --disable-linuxthreads  disable linuxthreads workaround],,
 612   enable_linuxthreads=yes)
 613
 614   ## Workaround for linuxthreads (optionally disabled)
 615   if test $host_os = linux-gnu -a "$enable_linuxthreads" = yes; then
 616     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 617     AC_CHECK_LIB(pthread, main)
 618   fi
 619 fi
 620
 621 ## If we're using GCC, ask for aggressive warnings.
 622 case "$GCC" in
 623   yes )
 624     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 625     ## much stuff with generic function pointers for that to really be
 626     ## less than exasperating.
 627     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 628     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 629     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 630 esac
 631
 632 AC_PROG_AWK
 633
 634 ## Remove fileblocks.o from the object list.  This file gets added by
 635 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
 636 LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
 637
 638 ## If we're creating a shared library (using libtool!), then we'll
 639 ## need to generate a list of .lo files corresponding to the .o files
 640 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 641 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 642
 643 ## We also need to create corresponding .doc and .x files
 644 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 645 EXTRA_DOT_X_FILES="`echo ${LIBOBJS} | sed 's/\.o/.x/g'`"
 646
 647 AC_SUBST(GUILE_MAJOR_VERSION)
 648 AC_SUBST(GUILE_MINOR_VERSION)
 649 AC_SUBST(GUILE_MICRO_VERSION)
 650 AC_SUBST(GUILE_VERSION)
 651
 652 #######################################################################
 653 # library versioning
 654
 655 AC_SUBST(LIBQTHREADS_INTERFACE_CURRENT)
 656 AC_SUBST(LIBQTHREADS_INTERFACE_REVISION)
 657 AC_SUBST(LIBQTHREADS_INTERFACE_AGE)
 658 AC_SUBST(LIBQTHREADS_INTERFACE)
 659
 660 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
 661 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
 662 AC_SUBST(LIBGUILE_INTERFACE_AGE)
 663 AC_SUBST(LIBGUILE_INTERFACE)
 664
 665 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
 666 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
 667 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
 668 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
 669
 670 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
 671 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
 672 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
 673 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
 674
 675 #######################################################################
 676
 677 dnl Tell guile-config what flags guile users should link against.
 678 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 679 AC_SUBST(GUILE_LIBS)
 680
 681 AC_SUBST(AWK)
 682 AC_SUBST(LIBLOBJS)
 683 AC_SUBST(EXTRA_DOT_DOC_FILES)
 684 AC_SUBST(EXTRA_DOT_X_FILES)
 685
 686 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
 687 top_builddir_absolute=`pwd`
 688 AC_SUBST(top_builddir_absolute)
 689
 690 AC_CONFIG_FILES([
 691   Makefile
 692   am/Makefile
 693   libguile/Makefile
 694   libguile/guile-snarf
 695   libguile/guile-doc-snarf
 696   libguile/guile-func-name-check
 697   libguile/guile-snarf-docs
 698   libguile/version.h
 699   ice-9/Makefile
 700   lang/Makefile
 701   lang/elisp/Makefile
 702   lang/elisp/internals/Makefile
 703   lang/elisp/primitives/Makefile
 704   oop/Makefile
 705   oop/goops/Makefile
 706   scripts/Makefile
 707   srfi/Makefile
 708   qt/Makefile
 709   qt/qt.h
 710   qt/md/Makefile
 711   qt/time/Makefile
 712   guile-config/Makefile
 713   doc/Makefile
 714   doc/ref/Makefile
 715   doc/tutorial/Makefile
 716   doc/goops/Makefile
 717   doc/r5rs/Makefile
 718   examples/Makefile
 719   examples/scripts/Makefile
 720   examples/box/Makefile
 721   examples/box-module/Makefile
 722   examples/box-dynamic/Makefile
 723   examples/box-dynamic-module/Makefile
 724   examples/modules/Makefile
 725   examples/safe/Makefile
 726   test-suite/Makefile
 727   check-guile
 728   guile-tools
 729   pre-inst-guile])
 730
 731 AC_CONFIG_COMMANDS(default,
 732   [ chmod +x libguile/guile-snarf \
 733              libguile/guile-doc-snarf \
 734              libguile/guile-func-name-check \
 735              libguile/guile-snarf-docs \
 736              check-guile \
 737              guile-tools \
 738              pre-inst-guile])
 739
 740 AC_OUTPUT
 741
 742 dnl Local Variables:
 743 dnl comment-start: "dnl "
 744 dnl comment-end: ""
 745 dnl comment-start-skip: "\\bdnl\\b\\s *"
 746 dnl End: