configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # Independent Subdirectories
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_CONFIG_SUBDIRS(guile-readline)
  36
  37 #--------------------------------------------------------------------
  38 #
  39 # User options
  40 #
  41 #--------------------------------------------------------------------
  42
  43 AC_ARG_ENABLE(debug-freelist,
  44   [  --enable-debug-freelist include garbage collector freelist debugging code],
  45   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  46     AC_DEFINE(GUILE_DEBUG_FREELIST)
  47   fi)
  48
  49 AC_ARG_ENABLE(debug-malloc,
  50   [  --enable-debug-malloc   include malloc debugging code],
  51   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  52     AC_DEFINE(GUILE_DEBUG_MALLOC)
  53   fi)
  54
  55 AC_ARG_ENABLE(guile-debug,
  56   [  --enable-guile-debug    include internal debugging functions],
  57   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  58     AC_DEFINE(GUILE_DEBUG)
  59   fi)
  60
  61 AC_ARG_ENABLE(arrays,
  62   [  --disable-arrays        omit array and uniform array support],,
  63   enable_arrays=yes)
  64
  65 AC_ARG_ENABLE(posix,
  66   [  --disable-posix         omit posix interfaces],,
  67   enable_posix=yes)
  68
  69 AC_ARG_ENABLE(networking,
  70   [  --disable-networking    omit networking interfaces],,
  71   enable_networking=yes)
  72
  73 AC_ARG_ENABLE(regex,
  74   [  --disable-regex         omit regular expression interfaces],,
  75   enable_regex=yes)
  76
  77 AC_ARG_ENABLE(htmldoc,
  78   [  --enable-htmldoc        build HTML documentation as well as Info],
  79   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  80      htmldoc_enabled=yes
  81      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  82      if test "$TEXI2HTML" = "not found"; then
  83        echo
  84        echo Building HTML documentation requires the \`texi2html\' program,
  85        echo which appears not to be present on your machine.
  86        echo
  87        echo \`texi2html\' is available from
  88        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
  89        echo
  90        echo In the meantime, to build the guile-doc distribution
  91        echo without HTML enabled, please rerun \`./configure\' without
  92        echo the \`--enable-htmldoc\' option.
  93        exit -1
  94      fi
  95    fi])
  96
  97 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
  98
  99 AC_ARG_ENABLE(deprecated,
 100   [  --disable-deprecated    omit deprecated features [no]])
 101
 102 if test "$enable_deprecated" = no; then
 103   AC_DEFINE(SCM_DEBUG_DEPRECATED, 1)
 104 else
 105   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 106     warn_default=summary
 107   elif test "$enable_deprecated" = shutup; then
 108     warn_default=no
 109   else
 110     warn_default=$enable_deprecated
 111   fi
 112   AC_DEFINE(SCM_DEBUG_DEPRECATED, 0)
 113   AC_DEFINE_UNQUOTED(GUILE_WARN_DEPRECATED_DEFAULT, "$warn_default")
 114 fi
 115
 116 dnl The --disable-debug used to control these two.  But now they are
 117 dnl a required part of the distribution.
 118 AC_DEFINE(DEBUG_EXTENSIONS)
 119 AC_DEFINE(READER_EXTENSIONS)
 120
 121 dnl files which are destined for separate modules.
 122
 123 if test "$enable_arrays" = yes; then
 124    LIBOBJS="$LIBOBJS ramap.o unif.o"
 125    AC_DEFINE(HAVE_ARRAYS)
 126 fi
 127
 128 if test "$enable_posix" = yes; then
 129    LIBOBJS="$LIBOBJS filesys.o posix.o"
 130    AC_DEFINE(HAVE_POSIX)
 131 fi
 132
 133 if test "$enable_networking" = yes; then
 134    LIBOBJS="$LIBOBJS net_db.o socket.o"
 135    AC_DEFINE(HAVE_NETWORKING)
 136 fi
 137
 138 if test "$enable_debug_malloc" = yes; then
 139    LIBOBJS="$LIBOBJS debug-malloc.o"
 140 fi
 141
 142 #--------------------------------------------------------------------
 143
 144 AC_LIBLTDL_CONVENIENCE
 145 AC_CONFIG_SUBDIRS(libltdl)
 146
 147 AC_PROG_CC
 148 AC_PROG_CPP
 149 AC_LIBTOOL_DLOPEN
 150
 151 AC_AIX
 152 AC_ISC_POSIX
 153 AC_MINIX
 154
 155 AM_PROG_CC_STDC
 156 AM_PROG_LIBTOOL
 157
 158 AC_C_CONST
 159 AC_C_INLINE
 160 AC_C_BIGENDIAN
 161
 162 AC_CHECK_SIZEOF(int)
 163 AC_CHECK_SIZEOF(long)
 164 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 165                AC_TRY_COMPILE(,
 166                               [long long a],
 167                               scm_cv_long_longs=yes,
 168                               scm_cv_long_longs=no))
 169 if test "$scm_cv_long_longs" = yes; then
 170   AC_DEFINE(HAVE_LONG_LONGS)
 171 fi
 172
 173 AC_HEADER_STDC
 174 AC_HEADER_DIRENT
 175 AC_HEADER_TIME
 176 AC_HEADER_SYS_WAIT
 177 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
 178 GUILE_HEADER_LIBC_WITH_UNISTD
 179
 180 AC_TYPE_GETGROUPS
 181 AC_TYPE_SIGNAL
 182 AC_TYPE_MODE_T
 183
 184 AC_CHECK_LIB(m, main)
 185 AC_CHECK_FUNCS(gethostbyname)
 186 if test $ac_cv_func_gethostbyname = no; then
 187     AC_CHECK_LIB(nsl, gethostbyname)
 188 fi
 189 AC_CHECK_FUNCS(connect)
 190 if test $ac_cv_func_connect = no; then
 191     AC_CHECK_LIB(socket, connect)
 192 fi
 193
 194 # Check for dynamic linking
 195
 196 use_modules=yes
 197 AC_ARG_WITH(modules,
 198 [  --with-modules[=FILES]  Add support for dynamic modules],
 199 use_modules="$withval")
 200 test -z "$use_modules" && use_modules=yes
 201 DLPREOPEN=
 202 if test "$use_modules" != no; then
 203   AC_DEFINE(DYNAMIC_LINKING)
 204   if test "$use_modules" = yes; then
 205     DLPREOPEN="-dlpreopen force"
 206   else
 207     DLPREOPEN="-export-dynamic"
 208     for module in $use_modules; do
 209       DLPREOPEN="$DLPREOPEN -dlopen $module"
 210     done
 211   fi
 212 fi
 213 AC_SUBST(INCLTDL)
 214 AC_SUBST(LIBLTDL)
 215 AC_SUBST(DLPREOPEN)
 216
 217 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit)
 218
 219 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 220 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 221 AC_CHECK_LIB(crypt, crypt)
 222
 223 ### Some systems don't declare some functions.  On such systems, we
 224 ### need to at least provide our own K&R-style declarations.
 225
 226 ### GUILE_FUNC_DECLARED(function, headerfile)
 227
 228 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 229 ### not there, #define MISSING_FUNCTION_DECL.
 230 AC_DEFUN(GUILE_FUNC_DECLARED, [
 231   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 232     AC_EGREP_HEADER($1, $2,
 233                     guile_cv_func_$1_declared=yes,
 234                     guile_cv_func_$1_declared=no))
 235   if test [x$guile_cv_func_]$1[_declared] = xno; then
 236     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 237   fi
 238 ])
 239
 240 GUILE_FUNC_DECLARED(strptime, time.h)
 241 GUILE_FUNC_DECLARED(sleep, unistd.h)
 242 GUILE_FUNC_DECLARED(usleep, unistd.h)
 243
 244 ### On some systems usleep has no return value.  If it does have one,
 245 ### we'd like to return it; otherwise, we'll fake it.
 246 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 247   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 248                    /usr/include/unistd.h,
 249                    [guile_cv_func_usleep_return_type=void],
 250                    [guile_cv_func_usleep_return_type=int])])
 251 case "$guile_cv_func_usleep_return_type" in
 252   "void" )
 253     AC_DEFINE(USLEEP_RETURNS_VOID)
 254   ;;
 255 esac
 256
 257 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 258 if test -n "$have_sys_un_h" ; then
 259 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 260 fi
 261
 262 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 263
 264 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 265                setnetent    getnetent    endnetent    dnl
 266                setprotoent  getprotoent  endprotoent  dnl
 267                setservent   getservent   endservent   dnl
 268                getnetbyaddr getnetbyname dnl
 269                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 270                inet_pton inet_ntop)
 271
 272 dnl Some systems do not declare this.  Some systems do declare it, as a
 273 dnl macro.  With cygwin it may be in a DLL.
 274
 275 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 276 AC_CACHE_VAL(guile_cv_have_h_errno,
 277 [AC_TRY_COMPILE([#include <netdb.h>],
 278 [int a = h_errno;],
 279 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 280 AC_MSG_RESULT($guile_cv_have_h_errno)
 281 if test $guile_cv_have_h_errno = yes; then
 282   AC_DEFINE(HAVE_H_ERRNO)
 283 fi
 284
 285 AC_MSG_CHECKING(whether netdb.h defines uint32_t)
 286 AC_CACHE_VAL(guile_cv_have_uint32_t,
 287 [AC_TRY_COMPILE([#include <netdb.h>],
 288 [uint32_t a;],
 289 guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 290 AC_MSG_RESULT($guile_cv_have_uint32_t)
 291 if test $guile_cv_have_uint32_t = yes; then
 292   AC_DEFINE(HAVE_UINT32_T)
 293 fi
 294
 295 AC_MSG_CHECKING(for working IPv6 support)
 296 AC_CACHE_VAL(guile_cv_have_ipv6,
 297 [AC_TRY_COMPILE([#include <netinet/in.h>
 298 #include <sys/socket.h>],
 299 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 300 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 301 AC_MSG_RESULT($guile_cv_have_ipv6)
 302 if test $guile_cv_have_ipv6 = yes; then
 303   AC_DEFINE(HAVE_IPV6)
 304 fi
 305
 306 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 307 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 308 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 309 [AC_TRY_COMPILE([#include <netinet/in.h>],
 310 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 311 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 312 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 313 if test $guile_cv_have_sin6_scope_id = yes; then
 314   AC_DEFINE(HAVE_SIN6_SCOPE_ID)
 315 fi
 316
 317 AC_MSG_CHECKING(whether localtime caches TZ)
 318 AC_CACHE_VAL(guile_cv_localtime_cache,
 319 [if test x$ac_cv_func_tzset = xyes; then
 320 AC_TRY_RUN([#include <time.h>
 321 #if STDC_HEADERS
 322 # include <stdlib.h>
 323 #endif
 324 extern char **environ;
 325 unset_TZ ()
 326 {
 327   char **from, **to;
 328   for (to = from = environ; (*to = *from); from++)
 329     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 330       to++;
 331 }
 332 char TZ_GMT0[] = "TZ=GMT0";
 333 char TZ_PST8[] = "TZ=PST8";
 334 main()
 335 {
 336   time_t now = time ((time_t *) 0);
 337   int hour_GMT0, hour_unset;
 338   if (putenv (TZ_GMT0) != 0)
 339     exit (1);
 340   hour_GMT0 = localtime (&now)->tm_hour;
 341   unset_TZ ();
 342   hour_unset = localtime (&now)->tm_hour;
 343   if (putenv (TZ_PST8) != 0)
 344     exit (1);
 345   if (localtime (&now)->tm_hour == hour_GMT0)
 346     exit (1);
 347   unset_TZ ();
 348   if (localtime (&now)->tm_hour != hour_unset)
 349     exit (1);
 350   exit (0);
 351 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 352 [# If we have tzset, assume the worst when cross-compiling.
 353 guile_cv_localtime_cache=yes])
 354 else
 355         # If we lack tzset, report that localtime does not cache TZ,
 356         # since we can't invalidate the cache if we don't have tzset.
 357         guile_cv_localtime_cache=no
 358 fi])dnl
 359 AC_MSG_RESULT($guile_cv_localtime_cache)
 360 if test $guile_cv_localtime_cache = yes; then
 361   AC_DEFINE(LOCALTIME_CACHE)
 362 fi
 363
 364 dnl Test whether system calls are restartable by default on the
 365 dnl current system.  If they are not, we put a loop around every system
 366 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 367 dnl change from the default behaviour.  On the other hand, if signals
 368 dnl are restartable then the loop is not installed and when libguile
 369 dnl initialises it also resets the behaviour of each signal to cause a
 370 dnl restart (in case a different runtime had a different default
 371 dnl behaviour for some reason: e.g., different versions of linux seem
 372 dnl to behave differently.)
 373
 374 AC_SYS_RESTARTABLE_SYSCALLS
 375
 376 if test "$enable_regex" = yes; then
 377    if test "$ac_cv_header_regex_h" = yes ||
 378       test "$ac_cv_header_rxposix_h" = yes ||
 379       test "$ac_cv_header_rx_rxposix_h" = yes; then
 380      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 381      [AC_CHECK_LIB(rx, main)
 382       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 383      )
 384      dnl The following should not be necessary, but for some reason
 385      dnl autoheader misses it if we don't include it!
 386      if test "$ac_cv_func_regcomp_norx" = yes ||
 387         test "$ac_cv_func_regcomp_rx" = yes; then
 388        AC_DEFINE(HAVE_REGCOMP)
 389      fi
 390    fi
 391 fi
 392
 393 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
 394
 395 # When testing for the presence of alloca, we need to add alloca.o
 396 # explicitly to LIBOBJS to make sure that it is translated to
 397 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 398 AC_FUNC_ALLOCA
 399 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 400
 401 AC_STRUCT_ST_RDEV
 402 AC_STRUCT_ST_BLKSIZE
 403
 404 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 405 # LIBOBJS, which we don't need.  This seems more direct.
 406 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 407 [AC_TRY_COMPILE([#include <sys/types.h>
 408 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 409 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 410 if test $ac_cv_struct_st_blocks = yes; then
 411   AC_DEFINE(HAVE_ST_BLOCKS)
 412 fi
 413
 414 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 415   [AC_TRY_CPP([#include <sys/stat.h>
 416                #ifndef S_ISLNK
 417                #error no S_ISLNK
 418                #endif],
 419                ac_cv_macro_S_ISLNK=yes,
 420                ac_cv_macro_S_ISLNK=no)])
 421 if test $ac_cv_macro_S_ISLNK = yes; then
 422   AC_DEFINE(HAVE_S_ISLNK)
 423 fi
 424
 425 AC_STRUCT_TIMEZONE
 426 GUILE_STRUCT_UTIMBUF
 427
 428 #--------------------------------------------------------------------
 429 #
 430 # Which way does the stack grow?
 431 #
 432 #--------------------------------------------------------------------
 433
 434 AC_TRY_RUN(aux (l) unsigned long l;
 435              { int x; exit (l >= ((unsigned long)&x)); }
 436            main () { int q; aux((unsigned long)&q); },
 437            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 438
 439 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 440     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 441                 [guile_cv_type_float_fits_long=yes],
 442                 [guile_cv_type_float_fits_long=no],
 443                 [guile_cv_type_float_fits_long=guess-yes])])
 444 case $guile_cv_type_float_fits_long in
 445   "yes" )
 446     AC_DEFINE(SCM_SINGLES)
 447   ;;
 448   "guess-yes" )
 449     AC_DEFINE(SCM_SINGLES)
 450     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 451     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 452   ;;
 453 esac
 454
 455
 456 AC_MSG_CHECKING(for struct linger)
 457 AC_CACHE_VAL(scm_cv_struct_linger,
 458         AC_TRY_COMPILE([
 459 #include <sys/types.h>
 460 #include <sys/socket.h>],
 461                         [struct linger lgr;  lgr.l_linger = 100],
 462                         scm_cv_struct_linger="yes",
 463                         scm_cv_struct_linger="no"))
 464 AC_MSG_RESULT($scm_cv_struct_linger)
 465 if test $scm_cv_struct_linger = yes; then
 466         AC_DEFINE(HAVE_STRUCT_LINGER)
 467 fi
 468
 469
 470 AC_MSG_CHECKING(for struct timespec)
 471 AC_CACHE_VAL(scm_cv_struct_timespec,
 472         AC_TRY_COMPILE([
 473 #include <time.h>],
 474                         [struct timespec t;  t.tv_nsec = 100],
 475                         scm_cv_struct_timespec="yes",
 476                         scm_cv_struct_timespec="no"))
 477 AC_MSG_RESULT($scm_cv_struct_timespec)
 478 if test $scm_cv_struct_timespec = yes; then
 479         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 480 fi
 481
 482 #--------------------------------------------------------------------
 483 #
 484 # Flags for thread support
 485 #
 486 #--------------------------------------------------------------------
 487
 488 ### What thread package has the user asked for?
 489 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 490             , with_threads=no)
 491
 492 ### Turn $with_threads into either the name of a threads package, like
 493 ### `qt', or `no', meaning that threads should not be supported.
 494 AC_MSG_CHECKING(whether to support threads)
 495 case "$with_threads" in
 496   "yes" | "qt" | "coop" | "")
 497     with_threads=qt
 498   ;;
 499   "no" )
 500   ;;
 501   * )
 502     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 503   ;;
 504 esac
 505 AC_MSG_RESULT($with_threads)
 506
 507 ## Make sure the threads package we've chosen is actually supported on
 508 ## the present platform.
 509 case "${with_threads}" in
 510   "qt" )
 511     ## This configures the QuickThreads package, and sets or clears
 512     ## the THREAD_PACKAGE variable if qthreads don't configure
 513     ## correctly.
 514     QTHREADS_CONFIGURE
 515    ;;
 516 esac
 517
 518 ## If we're using threads, bring in some other parts of Guile which
 519 ## work with them.
 520 if test "${THREAD_PACKAGE}" != "" ; then
 521   AC_DEFINE(USE_THREADS, 1)
 522
 523   ## Include the Guile thread interface in the library...
 524   LIBOBJS="$LIBOBJS threads.o"
 525
 526   ## ... and tell it which package to talk to.
 527   case "${THREAD_PACKAGE}" in
 528     "QT" )
 529       AC_DEFINE(USE_COOP_THREADS, 1)
 530     ;;
 531     * )
 532       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 533     ;;
 534   esac
 535
 536   ## Bring in scm_internal_select, if appropriate.
 537   if test $ac_cv_func_gettimeofday = yes &&
 538      test $ac_cv_func_select = yes; then
 539     AC_DEFINE(GUILE_ISELECT, 1)
 540   fi
 541
 542   ## Workaround for linuxthreads (currently disabled)
 543   if test $host_os = linux-gnu; then
 544     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 545     AC_CHECK_LIB(pthread, main)
 546   fi
 547 fi
 548 AC_SUBST(LIBGUILEQTHREADS_MAJOR_VERSION)
 549 AC_SUBST(LIBGUILEQTHREADS_MINOR_VERSION)
 550 AC_SUBST(LIBGUILEQTHREADS_REVISION_VERSION)
 551 AC_SUBST(LIBGUILEQTHREADS_VERSION)
 552
 553 ## If we're using GCC, ask for aggressive warnings.
 554 case "$GCC" in
 555   yes )
 556     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 557     ## much stuff with generic function pointers for that to really be
 558     ## less than exasperating.
 559     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 560     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 561     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 562 esac
 563
 564 AC_PROG_AWK
 565
 566 ## If we're creating a shared library (using libtool!), then we'll
 567 ## need to generate a list of .lo files corresponding to the .o files
 568 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 569 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 570
 571 ## We also need to create corresponding .doc and .x files
 572 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 573 EXTRA_DOT_X_FILES="`echo ${LIBOBJS} | sed 's/\.o/.x/g'`"
 574
 575 AC_SUBST(GUILE_MAJOR_VERSION)
 576 AC_SUBST(GUILE_MINOR_VERSION)
 577 AC_SUBST(GUILE_VERSION)
 578 AC_SUBST(LIBGUILE_MAJOR_VERSION)
 579 AC_SUBST(LIBGUILE_MINOR_VERSION)
 580 AC_SUBST(LIBGUILE_REVISION_VERSION)
 581 AC_SUBST(LIBGUILE_VERSION)
 582
 583 dnl Tell guile-config what flags guile users should link against.
 584 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 585 AC_SUBST(GUILE_LIBS)
 586
 587 AC_SUBST(AWK)
 588 AC_SUBST(LIBLOBJS)
 589 AC_SUBST(EXTRA_DOT_DOC_FILES)
 590 AC_SUBST(EXTRA_DOT_X_FILES)
 591
 592 AC_OUTPUT([Makefile
 593            libguile/Makefile
 594            libguile/guile-snarf
 595            libguile/guile-doc-snarf
 596            libguile/guile-func-name-check
 597            libguile/guile-snarf.awk
 598            libguile/versiondat.h
 599            ice-9/Makefile
 600            oop/Makefile
 601            oop/goops/Makefile
 602            scripts/Makefile
 603            srfi/Makefile
 604            qt/Makefile
 605            qt/qt.h
 606            qt/md/Makefile
 607            qt/time/Makefile
 608            guile-config/Makefile
 609            doc/Makefile
 610            check-guile
 611            guile-tools],
 612           [chmod +x libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check check-guile guile-tools])
 613
 614 dnl Local Variables:
 615 dnl comment-start: "dnl "
 616 dnl comment-end: ""
 617 dnl comment-start-skip: "\\bdnl\\b\\s *"
 618 dnl End: