configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # User options
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_ARG_ENABLE(dynamic-linking,
  36   [  --enable-dynamic-linking  Include support for dynamic linking],,
  37   enable_dynamic_linking=yes)
  38
  39 AC_ARG_ENABLE(guile-debug,
  40 [  --enable-guile-debug    Include internal debugging functions])
  41 if test "$enableval" = y || test "$enableval" = yes; then
  42   AC_DEFINE(GUILE_DEBUG)
  43 fi
  44
  45 dnl The --disable-debug used to control these two.  But now they are
  46 dnl a required part of the distribution.
  47 AC_DEFINE(DEBUG_EXTENSIONS)
  48 AC_DEFINE(READER_EXTENSIONS)
  49
  50 #--------------------------------------------------------------------
  51
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AM_PROG_LIBTOOL
  55
  56 AC_AIX
  57 AC_ISC_POSIX
  58 AC_MINIX
  59
  60 AC_C_CONST
  61 AC_C_INLINE
  62
  63 AC_HEADER_STDC
  64 AC_HEADER_DIRENT
  65 AC_HEADER_TIME
  66 AC_HEADER_SYS_WAIT
  67 AC_CHECK_HEADERS(libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
  68 GUILE_HEADER_LIBC_WITH_UNISTD
  69
  70 AC_TYPE_GETGROUPS
  71 AC_TYPE_SIGNAL
  72 AC_TYPE_MODE_T
  73
  74 AC_CHECK_LIB(m, main)
  75 AC_CHECK_FUNCS(gethostbyname)
  76 if test $ac_cv_func_gethostbyname = no; then
  77     AC_CHECK_LIB(nsl, gethostbyname)
  78 fi
  79 AC_CHECK_FUNCS(connect)
  80 if test $ac_cv_func_connect = no; then
  81     AC_CHECK_LIB(socket, connect)
  82 fi
  83 AC_CHECK_LIB(termcap, tgoto)
  84 AC_CHECK_LIB(readline, readline)
  85 AC_CHECK_FUNCS(rl_clear_signals rl_cleanup_after_signal)
  86
  87 AC_CACHE_CHECK([for rl_getc_function pointer in readline],
  88                ac_cv_var_rl_getc_function,
  89                [AC_TRY_LINK([
  90 #include <stdio.h>
  91 #include <readline/readline.h>],
  92                             [rl_getc_function;],
  93                             [ac_cv_var_rl_getc_function=yes],
  94                             [ac_cv_var_rl_getc_function=no])])
  95 if test "$ac_cv_var_rl_getc_function" = "yes"; then
  96   AC_DEFINE(HAVE_RL_GETC_FUNCTION)
  97 fi
  98
  99 if test $ac_cv_lib_readline_readline = yes -a $ac_cv_var_rl_getc_function = no; then
 100   echo 'Warning: libreadline is too old on your system.  Need >= 2.1.'
 101 fi
 102
 103 # Checks for dynamic linking
 104
 105 if test "$enable_dynamic_linking" = "yes"; then
 106
 107 AC_CHECK_LIB(dl,dlopen)
 108 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 109   AC_CHECK_FUNCS(dlopen)
 110   AC_DEFINE(DYNAMIC_LINKING)
 111 else
 112 AC_CHECK_LIB(dld,dld_link)
 113 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
 114   AC_DEFINE(DYNAMIC_LINKING)
 115 else
 116 AC_CHECK_FUNCS(shl_load)
 117 if test "$ac_cv_func_shl_load" = "yes"; then
 118   AC_DEFINE(DYNAMIC_LINKING)
 119 else
 120 AC_CHECK_FUNCS(dlopen)
 121 if test "$ac_cv_func_dlopen" = "yes"; then
 122   AC_DEFINE(DYNAMIC_LINKING)
 123 fi
 124 fi
 125 fi
 126 fi
 127
 128 fi
 129
 130 GUILE_DLSYM_USCORE
 131
 132 AC_CHECK_FUNCS(ctermid ftime getcwd geteuid gethostent gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep)
 133
 134 ### Some systems don't declare some functions.  On such systems, we
 135 ### need to at least provide our own K&R-style declarations.
 136
 137 ### GUILE_FUNC_DECLARED(function, headerfile)
 138
 139 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 140 ### not there, #define MISSING_FUNCTION_DECL.
 141 AC_DEFUN(GUILE_FUNC_DECLARED, [
 142   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 143     AC_EGREP_HEADER($1, $2,
 144                     guile_cv_func_$1_declared=yes,
 145                     guile_cv_func_$1_declared=no))
 146   if test [x$guile_cv_func_]$1[_declared] = xno; then
 147     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 148   fi
 149 ])
 150
 151 GUILE_FUNC_DECLARED(strptime, time.h)
 152 GUILE_FUNC_DECLARED(bzero, string.h)
 153 GUILE_FUNC_DECLARED(sleep, unistd.h)
 154 GUILE_FUNC_DECLARED(usleep, unistd.h)
 155
 156 ### On some systems usleep has no return value.  If it does have one,
 157 ### we'd like to return it; otherwise, we'll fake it.
 158 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 159   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 160                    /usr/include/unistd.h,
 161                    [guile_cv_func_usleep_return_type=void],
 162                    [guile_cv_func_usleep_return_type=int])])
 163 case "$guile_cv_func_usleep_return_type" in
 164   "void" )
 165     AC_DEFINE(USLEEP_RETURNS_VOID)
 166   ;;
 167 esac
 168
 169 dnl <GNU-WIN32 hacks>
 170
 171 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 172 if test -n "$have_sys_un_h" ; then
 173 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 174 fi
 175
 176 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 177
 178 dnl I don't know what this prefixing of cygwin32_ is for.
 179 dnl scmconfig.h wasn't updated with the test results.
 180 dnl so use AC_CHECK_FUNCS for now.
 181
 182 dnl how about:
 183 dnl save confdefs.h
 184 dnl if test $ac_cv_cigwin = yes; then
 185 dnl   modify confdefs.h
 186 dnl fi
 187 dnl AC_CHECK_FUNCS...
 188 dnl restore confdefs.h
 189
 190 dnl cp confdefs.h confdefs.h.bak
 191 dnl for func in sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof ; do
 192 dnl cp confdefs.h.bak confdefs.h
 193 dnl cat >> confdefs.h << EOF
 194 dnl #ifdef __CYGWIN32__
 195 dnl #define $func cygwin32_$func
 196 dnl #endif
 197 dnl EOF
 198 dnl AC_CHECK_FUNC($func)
 199 dnl done
 200 dnl cp confdefs.h.bak confdefs.h
 201
 202 AC_CHECK_FUNCS(sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof)
 203
 204 dnl </GNU-WIN32 hacks>
 205
 206 AC_CACHE_CHECK([for restartable system calls], scm_cv_restarts,
 207         if test $ac_cv_func_sigaction = yes; then
 208                 [AC_TRY_COMPILE([#include <signal.h>],
 209                                 [int a = SA_RESTART],
 210                                 scm_cv_restarts=yes,
 211                                 scm_cv_restarts=no)]
 212         else
 213                 scm_cv_restarts=no
 214         fi)
 215 if test $scm_cv_restarts = yes; then
 216         AC_DEFINE(HAVE_RESTARTS)
 217 fi
 218
 219 if test "$ac_cv_header_regex_h" = yes ||
 220    test "$ac_cv_header_rxposix_h" = yes ||
 221    test "$ac_cv_header_rx_rxposix_h" = yes; then
 222   GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 223   [AC_CHECK_LIB(rx, main)
 224    GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 225   )
 226   dnl The following should not be necessary, but for some reason
 227   dnl autoheader misses it if we don't include it!
 228   if test "$ac_cv_func_regcomp_norx" = yes ||
 229      test "$ac_cv_func_regcomp_rx" = yes; then
 230     AC_DEFINE(HAVE_REGCOMP)
 231   fi
 232 fi
 233
 234 AC_REPLACE_FUNCS(inet_aton putenv strerror)
 235
 236 # When testing for the presence of alloca, we need to add alloca.o
 237 # explicitly to LIBOBJS to make sure that it is translated to
 238 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 239 AC_FUNC_ALLOCA
 240 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 241
 242 AC_STRUCT_ST_RDEV
 243 AC_STRUCT_ST_BLKSIZE
 244
 245 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 246 # LIBOBJS, which we don't need.  This seems more direct.
 247 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 248 [AC_TRY_COMPILE([#include <sys/types.h>
 249 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 250 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 251 if test $ac_cv_struct_st_blocks = yes; then
 252   AC_DEFINE(HAVE_ST_BLOCKS)
 253 fi
 254
 255 AC_STRUCT_TIMEZONE
 256 GUILE_STRUCT_UTIMBUF
 257
 258 #--------------------------------------------------------------------
 259 #
 260 # Which way does the stack grow?
 261 #
 262 #--------------------------------------------------------------------
 263
 264 AC_TRY_RUN(aux (l) unsigned long l;
 265              { int x; exit (l >= ((unsigned long)&x)); }
 266            main () { int q; aux((unsigned long)&q); },
 267            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 268
 269 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 270     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 271                 [guile_cv_type_float_fits_long=yes],
 272                 [guile_cv_type_float_fits_long=no],
 273                 [guile_cv_type_float_fits_long=guess-yes])])
 274 case $guile_cv_type_float_fits_long in
 275   "yes" )
 276     AC_DEFINE(SCM_SINGLES)
 277   ;;
 278   "guess-yes" )
 279     AC_DEFINE(SCM_SINGLES)
 280     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 281     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 282   ;;
 283 esac
 284
 285
 286 AC_MSG_CHECKING(for struct linger)
 287 AC_CACHE_VAL(scm_cv_struct_linger,
 288         AC_TRY_COMPILE([
 289 #include <sys/types.h>
 290 #include <sys/socket.h>],
 291                         [struct linger lgr;  lgr.l_linger = 100],
 292                         scm_cv_struct_linger="yes",
 293                         scm_cv_struct_linger="no"))
 294 AC_MSG_RESULT($scm_cv_struct_linger)
 295 if test $scm_cv_struct_linger = yes; then
 296         AC_DEFINE(HAVE_STRUCT_LINGER)
 297 fi
 298
 299 #--------------------------------------------------------------------
 300 #
 301 # How can you violate a stdio abstraction by setting a stream's fd?
 302 #
 303 #--------------------------------------------------------------------
 304
 305 AC_MSG_CHECKING(how to set a stream file descriptor)
 306 AC_CACHE_VAL(scm_cv_fd_setter,
 307         AC_TRY_COMPILE([#include <stdio.h>],
 308                         [stdout->_file = 1],
 309                         scm_cv_fd_setter="_file",
 310         AC_TRY_COMPILE([#include <stdio.h>],
 311                         [stdout->__file = 1],
 312                         scm_cv_fd_setter="__file",
 313         AC_TRY_COMPILE([#include <stdio.h>],
 314                         [stdout->_fileno = 1],
 315                         scm_cv_fd_setter="_fileno",
 316                         scm_cv_fd_setter=""))))
 317
 318 if test "$scm_cv_fd_setter"; then
 319         AC_MSG_RESULT($scm_cv_fd_setter)
 320         AC_DEFINE_UNQUOTED(FD_SETTER, $scm_cv_fd_setter)
 321 else
 322         AC_MSG_RESULT(we couldn't do it!)
 323 fi
 324
 325 #--------------------------------------------------------------------
 326 # How to find out whether a FILE structure contains buffered data.
 327 # From Tk we have the following list:
 328 #               _cnt:           Most UNIX systems
 329 #               __cnt:          HPUX and SCO
 330 #               _r:             BSD
 331 #               readCount:      Sprite
 332 #       Or, in GNU libc there are two fields, _gptr and _egptr, which
 333 #       have to be compared.
 334 #       These can also be known as _IO_read_ptr and _IO_read_end.
 335 #--------------------------------------------------------------------
 336
 337 AC_MSG_CHECKING(how to get buffer char count from FILE structure)
 338 AC_CACHE_VAL(scm_cv_struct_file_count,
 339         AC_TRY_COMPILE([#include <stdio.h>],
 340                         [FILE *f = stdin; f->_cnt = 0],
 341                         scm_cv_struct_file_count="_cnt",
 342         AC_TRY_COMPILE([#include <stdio.h>],
 343                         [FILE *f = stdin; f->__cnt = 0],
 344                         scm_cv_struct_file_count="__cnt",
 345         AC_TRY_COMPILE([#include <stdio.h>],
 346                         [FILE *f = stdin; f->_r = 0],
 347                         scm_cv_struct_file_count="_r",
 348         AC_TRY_COMPILE([#include <stdio.h>],
 349                         [FILE *f = stdin; f->readCount = 0],
 350                         scm_cv_struct_file_count="readCount",
 351         scm_cv_struct_file_count="")))))
 352 if test "$scm_cv_struct_file_count"; then
 353         AC_MSG_RESULT($scm_cv_struct_file_count)
 354         AC_DEFINE_UNQUOTED(FILE_CNT_FIELD, $scm_cv_struct_file_count)
 355 else
 356 AC_CACHE_VAL(scm_cv_struct_file_gptr,
 357         AC_TRY_COMPILE([#include <stdio.h>],
 358                         [FILE *f = stdin; f->_gptr = f->egptr;],
 359                         scm_cv_struct_file_gptr=1,
 360         scm_cv_struct_file_gptr=""))
 361 if test "$scm_cv_struct_gptr"; then
 362         AC_MSG_RESULT(gptr)
 363         AC_DEFINE_UNQUOTED(FILE_CNT_GPTR, $scm_cv_struct_file_gptr)
 364 else
 365 AC_CACHE_VAL(scm_cv_struct_file_readptr,
 366         AC_TRY_COMPILE([#include <stdio.h>],
 367                         [FILE *f = stdin; f->_IO_read_ptr = f->_IO_read_end;],
 368                         scm_cv_struct_file_readptr=1))
 369 if test "$scm_cv_struct_file_readptr"; then
 370         AC_MSG_RESULT(read_ptr)
 371         AC_DEFINE_UNQUOTED(FILE_CNT_READPTR, $scm_cv_struct_file_readptr)
 372 else
 373         AC_MSG_RESULT(we couldn't do it!)
 374 fi
 375 fi
 376 fi
 377
 378 #--------------------------------------------------------------------
 379 #
 380 # Flags for thread support
 381 #
 382 #--------------------------------------------------------------------
 383
 384 ### What thread package has the user asked for?
 385 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 386             , with_threads=no)
 387
 388 ### Turn $with_threads into either the name of a threads package, like
 389 ### `qt', or `no', meaning that threads should not be supported.
 390 AC_MSG_CHECKING(whether to support threads)
 391 case "$with_threads" in
 392   "yes" | "qt" | "coop" | "")
 393     with_threads=qt
 394   ;;
 395   "no" )
 396   ;;
 397   * )
 398     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 399   ;;
 400 esac
 401 AC_MSG_RESULT($with_threads)
 402
 403 ## Make sure the threads package we've chosen is actually supported on
 404 ## the present platform.
 405 case "${with_threads}" in
 406   "qt" )
 407     ## This configures the QuickThreads package, and sets or clears
 408     ## the THREAD_PACKAGE variable if qthreads don't configure
 409     ## correctly.
 410     QTHREADS_CONFIGURE
 411    ;;
 412 esac
 413
 414 ## If we're using threads, bring in some other parts of Guile which
 415 ## work with them.
 416 if test "${THREAD_PACKAGE}" != "" ; then
 417   AC_DEFINE(USE_THREADS, 1)
 418
 419   ## Include the Guile thread interface in the library...
 420   LIBOBJS="$LIBOBJS threads.o"
 421
 422   ## ... and tell it which package to talk to.
 423   case "${THREAD_PACKAGE}" in
 424     "QT" )
 425       AC_DEFINE(USE_COOP_THREADS, 1)
 426     ;;
 427     * )
 428       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 429     ;;
 430   esac
 431
 432   ## Bring in scm_internal_select, if appropriate.
 433   if test $ac_cv_func_gettimeofday = yes &&
 434      test $ac_cv_func_select = yes; then
 435     LIBOBJS="$LIBOBJS iselect.o"
 436     AC_DEFINE(GUILE_ISELECT, 1)
 437   fi
 438 fi
 439
 440 ## If we're using GCC, ask for aggressive warnings.
 441 case "$GCC" in
 442   yes )
 443     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 444     ## much stuff with generic function pointers for that to really be
 445     ## less than exasperating.
 446     CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wmissing-prototypes" ;;
 447 esac
 448
 449 AC_PROG_AWK
 450
 451 ## If we're creating a shared library (using libtool!), then we'll
 452 ## need to generate a list of .lo files corresponding to the .o files
 453 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 454 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 455
 456 AC_SUBST(GUILE_MAJOR_VERSION)
 457 AC_SUBST(GUILE_MINOR_VERSION)
 458 AC_SUBST(GUILE_VERSION)
 459
 460 dnl Tell guile-config what flags guile users should link against.
 461 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 462 AC_SUBST(GUILE_LIBS)
 463
 464 dnl timestamping the interpreter and scheme libraries:
 465 dnl
 466 dnl Help us notice when we're running one version of the Guile
 467 dnl interpreter against a different version of the ice-9 Scheme code.
 468 dnl This will definitely detect version skew due to differing
 469 dnl snapshots and releases, but may not catch skew for the developers.
 470 dnl Hopefully it will not detect skew when there is none; if that
 471 dnl happens, the warnings will be useless, and we should remove this.
 472 GUILE_STAMP="`date`"
 473 AC_SUBST(GUILE_STAMP)
 474
 475 AC_SUBST(AWK)
 476 AC_SUBST(LIBLOBJS)
 477
 478 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/versiondat.h ice-9/Makefile ice-9/version.scm qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf])
 479
 480 dnl Local Variables:
 481 dnl comment-start: "dnl "
 482 dnl comment-end: ""
 483 dnl comment-start-skip: "\\bdnl\\b\\s *"
 484 dnl End: