configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_PREREQ(2.50)
  24
  25 AC_INIT
  26 AC_CONFIG_SRCDIR([Makefile.in])
  27 . $srcdir/GUILE-VERSION
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  29 AM_MAINTAINER_MODE
  30 AM_CONFIG_HEADER(libguile/scmconfig.h)
  31
  32 #--------------------------------------------------------------------
  33 #
  34 # Independent Subdirectories
  35 #
  36 #--------------------------------------------------------------------
  37
  38 AC_CONFIG_SUBDIRS(guile-readline)
  39
  40 #--------------------------------------------------------------------
  41 #
  42 # User options
  43 #
  44 #--------------------------------------------------------------------
  45
  46 AC_ARG_ENABLE(error-on-warning,
  47   [  --enable-error-on-warning    treat compile warnings as errors],
  48   [case "${enableval}" in
  49      yes | y) CFLAGS="${CFLAGS} -Werror"; enable_compile_warnings=no ;;
  50      no | n)  ;;
  51      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  52    esac])
  53
  54 AC_ARG_ENABLE(debug-freelist,
  55   [  --enable-debug-freelist include garbage collector freelist debugging code],
  56   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  57     AC_DEFINE(GUILE_DEBUG_FREELIST)
  58   fi)
  59
  60 AC_ARG_ENABLE(debug-malloc,
  61   [  --enable-debug-malloc   include malloc debugging code],
  62   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  63     AC_DEFINE(GUILE_DEBUG_MALLOC)
  64   fi)
  65
  66 AC_ARG_ENABLE(guile-debug,
  67   [  --enable-guile-debug    include internal debugging functions],
  68   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  69     AC_DEFINE(GUILE_DEBUG)
  70   fi)
  71
  72 AC_ARG_ENABLE(arrays,
  73   [  --disable-arrays        omit array and uniform array support],,
  74   enable_arrays=yes)
  75
  76 AC_ARG_ENABLE(posix,
  77   [  --disable-posix         omit posix interfaces],,
  78   enable_posix=yes)
  79
  80 AC_ARG_ENABLE(networking,
  81   [  --disable-networking    omit networking interfaces],,
  82   enable_networking=yes)
  83
  84 AC_ARG_ENABLE(regex,
  85   [  --disable-regex         omit regular expression interfaces],,
  86   enable_regex=yes)
  87
  88 AC_ARG_ENABLE(htmldoc,
  89   [  --enable-htmldoc        build HTML documentation as well as Info],
  90   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  91      htmldoc_enabled=yes
  92      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  93      if test "$TEXI2HTML" = "not found"; then
  94        echo
  95        echo Building HTML documentation requires the \`texi2html\' program,
  96        echo which appears not to be present on your machine.
  97        echo
  98        echo \`texi2html\' is available from
  99        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
 100        echo
 101        echo In the meantime, to build the guile-doc distribution
 102        echo without HTML enabled, please rerun \`./configure\' without
 103        echo the \`--enable-htmldoc\' option.
 104        exit -1
 105      fi
 106    fi])
 107
 108 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
 109
 110 AC_ARG_ENABLE(deprecated,
 111   [  --disable-deprecated    omit deprecated features [no]])
 112
 113 if test "$enable_deprecated" = no; then
 114   AC_DEFINE(SCM_ENABLE_DEPRECATED, 0)
 115 else
 116   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 117     warn_default=summary
 118   elif test "$enable_deprecated" = shutup; then
 119     warn_default=no
 120   else
 121     warn_default=$enable_deprecated
 122   fi
 123   AC_DEFINE(SCM_ENABLE_DEPRECATED, 1)
 124   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default")
 125 fi
 126
 127 dnl The --disable-debug used to control these two.  But now they are
 128 dnl a required part of the distribution.
 129 AC_DEFINE(DEBUG_EXTENSIONS)
 130 AC_DEFINE(READER_EXTENSIONS)
 131
 132 dnl files which are destined for separate modules.
 133
 134 if test "$enable_arrays" = yes; then
 135    LIBOBJS="$LIBOBJS ramap.o unif.o"
 136    AC_DEFINE(HAVE_ARRAYS)
 137 fi
 138
 139 if test "$enable_posix" = yes; then
 140    LIBOBJS="$LIBOBJS filesys.o posix.o"
 141    AC_DEFINE(HAVE_POSIX)
 142 fi
 143
 144 if test "$enable_networking" = yes; then
 145    LIBOBJS="$LIBOBJS net_db.o socket.o"
 146    AC_DEFINE(HAVE_NETWORKING)
 147 fi
 148
 149 if test "$enable_debug_malloc" = yes; then
 150    LIBOBJS="$LIBOBJS debug-malloc.o"
 151 fi
 152
 153 #--------------------------------------------------------------------
 154
 155 AC_LIBLTDL_CONVENIENCE
 156 AC_CONFIG_SUBDIRS(libltdl)
 157
 158 AC_PROG_CC
 159 AC_PROG_CPP
 160 AC_LIBTOOL_DLOPEN
 161
 162 AC_AIX
 163 AC_ISC_POSIX
 164 AC_MINIX
 165
 166 AM_PROG_CC_STDC
 167 AM_PROG_LIBTOOL
 168
 169 AC_C_CONST
 170 AC_C_INLINE
 171 AC_C_BIGENDIAN
 172
 173 AC_CHECK_SIZEOF(int)
 174 AC_CHECK_SIZEOF(long)
 175
 176 dnl Check for integral types that can represent the range of pointers.
 177 dnl If these types don't exist on this platform, they are replaced by
 178 dnl "unsigned long" and "long", respectively.
 179
 180 AC_CHECK_HEADERS(stdint.h)
 181 AC_CHECK_HEADERS(inttypes.h)
 182 AC_CHECK_TYPES([uintptr_t, ptrdiff_t])
 183
 184 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 185                AC_TRY_COMPILE(,
 186                               [long long a],
 187                               scm_cv_long_longs=yes,
 188                               scm_cv_long_longs=no))
 189 if test "$scm_cv_long_longs" = yes; then
 190   AC_DEFINE(HAVE_LONG_LONGS)
 191   AC_CHECK_SIZEOF(long long)
 192 fi
 193
 194 AC_CHECK_SIZEOF(void *)
 195
 196 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 197   AC_MSG_ERROR(sizes of long and void* are not identical)
 198 fi
 199
 200 AC_HEADER_STDC
 201 AC_HEADER_DIRENT
 202 AC_HEADER_TIME
 203 AC_HEADER_SYS_WAIT
 204 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h sys/utime.h time.h unistd.h utime.h pwd.h winsock2.h grp.h sys/utsname.h)
 205 GUILE_HEADER_LIBC_WITH_UNISTD
 206
 207 AC_TYPE_GETGROUPS
 208 AC_TYPE_SIGNAL
 209 AC_TYPE_MODE_T
 210
 211 AC_CHECK_LIB(m, main)
 212 AC_CHECK_FUNCS(gethostbyname)
 213 if test $ac_cv_func_gethostbyname = no; then
 214     AC_CHECK_LIB(nsl, gethostbyname)
 215 fi
 216 AC_CHECK_FUNCS(connect)
 217 if test $ac_cv_func_connect = no; then
 218     AC_CHECK_LIB(socket, connect)
 219 fi
 220
 221 # Check for dynamic linking
 222
 223 use_modules=yes
 224 AC_ARG_WITH(modules,
 225 [  --with-modules[=FILES]  Add support for dynamic modules],
 226 use_modules="$withval")
 227 test -z "$use_modules" && use_modules=yes
 228 DLPREOPEN=
 229 if test "$use_modules" != no; then
 230   AC_DEFINE(DYNAMIC_LINKING)
 231   if test "$use_modules" = yes; then
 232     DLPREOPEN="-dlpreopen force"
 233   else
 234     DLPREOPEN="-export-dynamic"
 235     for module in $use_modules; do
 236       DLPREOPEN="$DLPREOPEN -dlopen $module"
 237     done
 238   fi
 239 fi
 240 AC_SUBST(INCLTDL)
 241 AC_SUBST(LIBLTDL)
 242 AC_SUBST(DLPREOPEN)
 243
 244 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer)
 245
 246 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 247 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 248 AC_CHECK_LIB(crypt, crypt)
 249
 250 ### Some systems don't declare some functions.  On such systems, we
 251 ### need to at least provide our own K&R-style declarations.
 252
 253 ### GUILE_FUNC_DECLARED(function, headerfile)
 254
 255 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 256 ### not there, #define MISSING_FUNCTION_DECL.
 257 AC_DEFUN(GUILE_FUNC_DECLARED, [
 258   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 259     AC_EGREP_HEADER($1, $2,
 260                     guile_cv_func_$1_declared=yes,
 261                     guile_cv_func_$1_declared=no))
 262   if test [x$guile_cv_func_]$1[_declared] = xno; then
 263     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 264   fi
 265 ])
 266
 267 GUILE_FUNC_DECLARED(strptime, time.h)
 268 GUILE_FUNC_DECLARED(sleep, unistd.h)
 269 GUILE_FUNC_DECLARED(usleep, unistd.h)
 270
 271 ### On some systems usleep has no return value.  If it does have one,
 272 ### we'd like to return it; otherwise, we'll fake it.
 273 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 274   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 275                    unistd.h,
 276                    [guile_cv_func_usleep_return_type=void],
 277                    [guile_cv_func_usleep_return_type=int])])
 278 case "$guile_cv_func_usleep_return_type" in
 279   "void" )
 280     AC_DEFINE(USLEEP_RETURNS_VOID)
 281   ;;
 282 esac
 283
 284 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 285 if test -n "$have_sys_un_h" ; then
 286 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 287 fi
 288
 289 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 290
 291 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 292                setnetent    getnetent    endnetent    dnl
 293                setprotoent  getprotoent  endprotoent  dnl
 294                setservent   getservent   endservent   dnl
 295                getnetbyaddr getnetbyname dnl
 296                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 297                inet_pton inet_ntop)
 298
 299 dnl Some systems do not declare this.  Some systems do declare it, as a
 300 dnl macro.  With cygwin it may be in a DLL.
 301
 302 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 303 AC_CACHE_VAL(guile_cv_have_h_errno,
 304 [AC_TRY_COMPILE([#include <netdb.h>],
 305 [int a = h_errno;],
 306 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 307 AC_MSG_RESULT($guile_cv_have_h_errno)
 308 if test $guile_cv_have_h_errno = yes; then
 309   AC_DEFINE(HAVE_H_ERRNO)
 310 fi
 311
 312 AC_MSG_CHECKING(whether uint32_t is defined)
 313 AC_CACHE_VAL(guile_cv_have_uint32_t,
 314   [AC_TRY_COMPILE([#include <sys/types.h>
 315                    #include <netdb.h>],
 316                   [uint32_t a;],
 317                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 318 AC_MSG_RESULT($guile_cv_have_uint32_t)
 319 if test $guile_cv_have_uint32_t = yes; then
 320   AC_DEFINE(HAVE_UINT32_T)
 321 fi
 322
 323 AC_MSG_CHECKING(for working IPv6 support)
 324 AC_CACHE_VAL(guile_cv_have_ipv6,
 325 [AC_TRY_COMPILE([#include <netinet/in.h>
 326 #include <sys/socket.h>],
 327 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 328 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 329 AC_MSG_RESULT($guile_cv_have_ipv6)
 330 if test $guile_cv_have_ipv6 = yes; then
 331   AC_DEFINE(HAVE_IPV6)
 332 fi
 333
 334 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 335 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 336 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 337 [AC_TRY_COMPILE([#include <netinet/in.h>],
 338 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 339 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 340 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 341 if test $guile_cv_have_sin6_scope_id = yes; then
 342   AC_DEFINE(HAVE_SIN6_SCOPE_ID)
 343 fi
 344
 345 AC_MSG_CHECKING(whether localtime caches TZ)
 346 AC_CACHE_VAL(guile_cv_localtime_cache,
 347 [if test x$ac_cv_func_tzset = xyes; then
 348 AC_TRY_RUN([#include <time.h>
 349 #if STDC_HEADERS
 350 # include <stdlib.h>
 351 #endif
 352 extern char **environ;
 353 unset_TZ ()
 354 {
 355   char **from, **to;
 356   for (to = from = environ; (*to = *from); from++)
 357     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 358       to++;
 359 }
 360 char TZ_GMT0[] = "TZ=GMT0";
 361 char TZ_PST8[] = "TZ=PST8";
 362 main()
 363 {
 364   time_t now = time ((time_t *) 0);
 365   int hour_GMT0, hour_unset;
 366   if (putenv (TZ_GMT0) != 0)
 367     exit (1);
 368   hour_GMT0 = localtime (&now)->tm_hour;
 369   unset_TZ ();
 370   hour_unset = localtime (&now)->tm_hour;
 371   if (putenv (TZ_PST8) != 0)
 372     exit (1);
 373   if (localtime (&now)->tm_hour == hour_GMT0)
 374     exit (1);
 375   unset_TZ ();
 376   if (localtime (&now)->tm_hour != hour_unset)
 377     exit (1);
 378   exit (0);
 379 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 380 [# If we have tzset, assume the worst when cross-compiling.
 381 guile_cv_localtime_cache=yes])
 382 else
 383         # If we lack tzset, report that localtime does not cache TZ,
 384         # since we can't invalidate the cache if we don't have tzset.
 385         guile_cv_localtime_cache=no
 386 fi])dnl
 387 AC_MSG_RESULT($guile_cv_localtime_cache)
 388 if test $guile_cv_localtime_cache = yes; then
 389   AC_DEFINE(LOCALTIME_CACHE)
 390 fi
 391
 392 dnl Test whether system calls are restartable by default on the
 393 dnl current system.  If they are not, we put a loop around every system
 394 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 395 dnl change from the default behaviour.  On the other hand, if signals
 396 dnl are restartable then the loop is not installed and when libguile
 397 dnl initialises it also resets the behaviour of each signal to cause a
 398 dnl restart (in case a different runtime had a different default
 399 dnl behaviour for some reason: e.g., different versions of linux seem
 400 dnl to behave differently.)
 401
 402 AC_SYS_RESTARTABLE_SYSCALLS
 403
 404 if test "$enable_regex" = yes; then
 405    if test "$ac_cv_header_regex_h" = yes ||
 406       test "$ac_cv_header_rxposix_h" = yes ||
 407       test "$ac_cv_header_rx_rxposix_h" = yes; then
 408      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 409      [AC_CHECK_LIB(rx, main)
 410       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 411      )
 412      dnl The following should not be necessary, but for some reason
 413      dnl autoheader misses it if we don't include it!
 414      if test "$ac_cv_func_regcomp_norx" = yes ||
 415         test "$ac_cv_func_regcomp_rx" = yes; then
 416        AC_DEFINE(HAVE_REGCOMP)
 417      fi
 418    fi
 419 fi
 420
 421 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 422
 423 # When testing for the presence of alloca, we need to add alloca.o
 424 # explicitly to LIBOBJS to make sure that it is translated to
 425 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 426 AC_FUNC_ALLOCA
 427 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 428
 429 AC_CHECK_MEMBERS([struct stat.st_rdev])
 430 AC_CHECK_MEMBERS([struct stat.st_blksize])
 431
 432 AC_STRUCT_ST_BLOCKS
 433
 434 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 435   [AC_TRY_CPP([#include <sys/stat.h>
 436                #ifndef S_ISLNK
 437                #error no S_ISLNK
 438                #endif],
 439                ac_cv_macro_S_ISLNK=yes,
 440                ac_cv_macro_S_ISLNK=no)])
 441 if test $ac_cv_macro_S_ISLNK = yes; then
 442   AC_DEFINE(HAVE_S_ISLNK)
 443 fi
 444
 445 AC_STRUCT_TIMEZONE
 446 GUILE_STRUCT_UTIMBUF
 447
 448 #--------------------------------------------------------------------
 449 #
 450 # Which way does the stack grow?
 451 #
 452 #--------------------------------------------------------------------
 453
 454 AC_TRY_RUN(aux (l) unsigned long l;
 455              { int x; exit (l >= ((unsigned long)&x)); }
 456            main () { int q; aux((unsigned long)&q); },
 457            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 458
 459 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 460     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 461                 [guile_cv_type_float_fits_long=yes],
 462                 [guile_cv_type_float_fits_long=no],
 463                 [guile_cv_type_float_fits_long=guess-yes])])
 464 case $guile_cv_type_float_fits_long in
 465   "yes" )
 466     AC_DEFINE(SCM_SINGLES)
 467   ;;
 468   "guess-yes" )
 469     AC_DEFINE(SCM_SINGLES)
 470     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 471     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 472   ;;
 473 esac
 474
 475
 476 AC_MSG_CHECKING(for struct linger)
 477 AC_CACHE_VAL(scm_cv_struct_linger,
 478         AC_TRY_COMPILE([
 479 #include <sys/types.h>
 480 #include <sys/socket.h>],
 481                         [struct linger lgr;  lgr.l_linger = 100],
 482                         scm_cv_struct_linger="yes",
 483                         scm_cv_struct_linger="no"))
 484 AC_MSG_RESULT($scm_cv_struct_linger)
 485 if test $scm_cv_struct_linger = yes; then
 486         AC_DEFINE(HAVE_STRUCT_LINGER)
 487 fi
 488
 489
 490 AC_MSG_CHECKING(for struct timespec)
 491 AC_CACHE_VAL(scm_cv_struct_timespec,
 492         AC_TRY_COMPILE([
 493 #include <time.h>],
 494                         [struct timespec t;  t.tv_nsec = 100],
 495                         scm_cv_struct_timespec="yes",
 496                         scm_cv_struct_timespec="no"))
 497 AC_MSG_RESULT($scm_cv_struct_timespec)
 498 if test $scm_cv_struct_timespec = yes; then
 499         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 500 fi
 501
 502 #--------------------------------------------------------------------
 503 #
 504 # Flags for thread support
 505 #
 506 #--------------------------------------------------------------------
 507
 508 ### What thread package has the user asked for?
 509 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 510             , with_threads=no)
 511
 512 ### Turn $with_threads into either the name of a threads package, like
 513 ### `qt', or `no', meaning that threads should not be supported.
 514 AC_MSG_CHECKING(whether to support threads)
 515 case "$with_threads" in
 516   "yes" | "qt" | "coop" | "")
 517     with_threads=qt
 518   ;;
 519   "no" )
 520   ;;
 521   * )
 522     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 523   ;;
 524 esac
 525 AC_MSG_RESULT($with_threads)
 526
 527 ## Make sure the threads package we've chosen is actually supported on
 528 ## the present platform.
 529 case "${with_threads}" in
 530   "qt" )
 531     ## This configures the QuickThreads package, and sets or clears
 532     ## the THREAD_PACKAGE variable if qthreads don't configure
 533     ## correctly.
 534     QTHREADS_CONFIGURE
 535    ;;
 536 esac
 537
 538 ## If we're using threads, bring in some other parts of Guile which
 539 ## work with them.
 540 if test "${THREAD_PACKAGE}" != "" ; then
 541   AC_DEFINE(USE_THREADS, 1)
 542
 543   ## Include the Guile thread interface in the library...
 544   LIBOBJS="$LIBOBJS threads.o"
 545
 546   ## ... and tell it which package to talk to.
 547   case "${THREAD_PACKAGE}" in
 548     "QT" )
 549       AC_DEFINE(USE_COOP_THREADS, 1)
 550     ;;
 551     * )
 552       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 553     ;;
 554   esac
 555
 556   ## Bring in scm_internal_select, if appropriate.
 557   if test $ac_cv_func_gettimeofday = yes &&
 558      test $ac_cv_func_select = yes; then
 559     AC_DEFINE(GUILE_ISELECT, 1)
 560   fi
 561
 562   AC_ARG_ENABLE(linuxthreads,
 563   [  --disable-linuxthreads  disable linuxthreads workaround],,
 564   enable_linuxthreads=yes)
 565
 566   ## Workaround for linuxthreads (optionally disabled)
 567   if test $host_os = linux-gnu -a "$enable_linuxthreads" = yes; then
 568     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 569     AC_CHECK_LIB(pthread, main)
 570   fi
 571 fi
 572 AC_SUBST(LIBGUILEQTHREADS_INTERFACE_CURRENT)
 573 AC_SUBST(LIBGUILEQTHREADS_INTERFACE_REVISION)
 574 AC_SUBST(LIBGUILEQTHREADS_INTERFACE_AGE)
 575 AC_SUBST(LIBGUILEQTHREADS_INTERFACE)
 576
 577 ## If we're using GCC, ask for aggressive warnings.
 578 case "$GCC" in
 579   yes )
 580     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 581     ## much stuff with generic function pointers for that to really be
 582     ## less than exasperating.
 583     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 584     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 585     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 586 esac
 587
 588 AC_PROG_AWK
 589
 590 ## If we're creating a shared library (using libtool!), then we'll
 591 ## need to generate a list of .lo files corresponding to the .o files
 592 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 593 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 594
 595 ## We also need to create corresponding .doc and .x files
 596 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 597 EXTRA_DOT_X_FILES="`echo ${LIBOBJS} | sed 's/\.o/.x/g'`"
 598
 599 AC_SUBST(GUILE_MAJOR_VERSION)
 600 AC_SUBST(GUILE_MINOR_VERSION)
 601 AC_SUBST(GUILE_MICRO_VERSION)
 602 AC_SUBST(GUILE_VERSION)
 603
 604 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
 605 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
 606 AC_SUBST(LIBGUILE_INTERFACE_AGE)
 607 AC_SUBST(LIBGUILE_INTERFACE)
 608
 609 dnl Tell guile-config what flags guile users should link against.
 610 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 611 AC_SUBST(GUILE_LIBS)
 612
 613 AC_SUBST(AWK)
 614 AC_SUBST(LIBLOBJS)
 615 AC_SUBST(EXTRA_DOT_DOC_FILES)
 616 AC_SUBST(EXTRA_DOT_X_FILES)
 617
 618 AC_CONFIG_FILES([
 619   Makefile
 620   libguile/Makefile
 621   libguile/guile-snarf
 622   libguile/guile-doc-snarf
 623   libguile/guile-func-name-check
 624   libguile/guile-snarf-docs
 625   libguile/guile-snarf-docs-texi
 626   libguile/version.h
 627   ice-9/Makefile
 628   oop/Makefile
 629   oop/goops/Makefile
 630   scripts/Makefile
 631   srfi/Makefile
 632   qt/Makefile
 633   qt/qt.h
 634   qt/md/Makefile
 635   qt/time/Makefile
 636   guile-config/Makefile
 637   doc/Makefile
 638   doc/ref/Makefile
 639   doc/tutorial/Makefile
 640   doc/goops/Makefile
 641   doc/r5rs/Makefile
 642   examples/Makefile
 643   examples/scripts/Makefile
 644   examples/box/Makefile
 645   examples/box-module/Makefile
 646   examples/box-dynamic/Makefile
 647   examples/box-dynamic-module/Makefile
 648   examples/modules/Makefile
 649   examples/safe/Makefile
 650   test-suite/Makefile
 651   check-guile
 652   guile-tools])
 653
 654 AC_CONFIG_COMMANDS(default,
 655   [ chmod +x libguile/guile-snarf \
 656              libguile/guile-doc-snarf \
 657              libguile/guile-func-name-check \
 658              libguile/guile-snarf-docs \
 659              libguile/guile-snarf-docs-texi \
 660              check-guile \
 661              guile-tools])
 662
 663 AC_OUTPUT
 664
 665 dnl Local Variables:
 666 dnl comment-start: "dnl "
 667 dnl comment-end: ""
 668 dnl comment-start-skip: "\\bdnl\\b\\s *"
 669 dnl End: