module/statprof.scm

   1 ;;;; (statprof) -- a statistical profiler for Guile
   2 ;;;; -*-scheme-*-
   3 ;;;;
   4 ;;;;    Copyright (C) 2009, 2010, 2011, 2013, 2014  Free Software Foundation, Inc.
   5 ;;;;    Copyright (C) 2004, 2009 Andy Wingo <wingo at pobox dot com>
   6 ;;;;    Copyright (C) 2001 Rob Browning <rlb at defaultvalue dot org>
   7 ;;;;
   8 ;;;; This library is free software; you can redistribute it and/or
   9 ;;;; modify it under the terms of the GNU Lesser General Public
  10 ;;;; License as published by the Free Software Foundation; either
  11 ;;;; version 3 of the License, or (at your option) any later version.
  12 ;;;;
  13 ;;;; This library is distributed in the hope that it will be useful,
  14 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;;;; Lesser General Public License for more details.
  17 ;;;;
  18 ;;;; You should have received a copy of the GNU Lesser General Public
  19 ;;;; License along with this library; if not, write to the Free Software
  20 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  21 ;;;;
  22 \f
  23
  24 ;;; Commentary:
  25 ;;;
  26 ;;; @code{(statprof)} is a statistical profiler for Guile.
  27 ;;;
  28 ;;; A simple use of statprof would look like this:
  29 ;;;
  30 ;;; @example
  31 ;;;   (statprof-reset 0 50000 #t)
  32 ;;;   (statprof-start)
  33 ;;;   (do-something)
  34 ;;;   (statprof-stop)
  35 ;;;   (statprof-display)
  36 ;;; @end example
  37 ;;;
  38 ;;; This would reset statprof, clearing all accumulated statistics, then
  39 ;;; start profiling, run some code, stop profiling, and finally display a
  40 ;;; gprof flat-style table of statistics which will look something like
  41 ;;; this:
  42 ;;;
  43 ;;; @example
  44 ;;;   %   cumulative      self              self    total
  45 ;;;  time    seconds   seconds    calls  ms/call  ms/call  name
  46 ;;;  35.29      0.23      0.23     2002     0.11     0.11  -
  47 ;;;  23.53      0.15      0.15     2001     0.08     0.08  positive?
  48 ;;;  23.53      0.15      0.15     2000     0.08     0.08  +
  49 ;;;  11.76      0.23      0.08     2000     0.04     0.11  do-nothing
  50 ;;;   5.88      0.64      0.04     2001     0.02     0.32  loop
  51 ;;;   0.00      0.15      0.00        1     0.00   150.59  do-something
  52 ;;;  ...
  53 ;;; @end example
  54 ;;;
  55 ;;; All of the numerical data with the exception of the calls column is
  56 ;;; statistically approximate. In the following column descriptions, and
  57 ;;; in all of statprof, "time" refers to execution time (both user and
  58 ;;; system), not wall clock time.
  59 ;;;
  60 ;;; @table @asis
  61 ;;; @item % time
  62 ;;; The percent of the time spent inside the procedure itself
  63 ;;; (not counting children).
  64 ;;; @item cumulative seconds
  65 ;;; The total number of seconds spent in the procedure, including
  66 ;;; children.
  67 ;;; @item self seconds
  68 ;;; The total number of seconds spent in the procedure itself (not counting
  69 ;;; children).
  70 ;;; @item calls
  71 ;;; The total number of times the procedure was called.
  72 ;;; @item self ms/call
  73 ;;; The average time taken by the procedure itself on each call, in ms.
  74 ;;; @item total ms/call
  75 ;;; The average time taken by each call to the procedure, including time
  76 ;;; spent in child functions.
  77 ;;; @item name
  78 ;;; The name of the procedure.
  79 ;;; @end table
  80 ;;;
  81 ;;; The profiler uses @code{eq?} and the procedure object itself to
  82 ;;; identify the procedures, so it won't confuse different procedures with
  83 ;;; the same name. They will show up as two different rows in the output.
  84 ;;;
  85 ;;; Right now the profiler is quite simplistic.  I cannot provide
  86 ;;; call-graphs or other higher level information.  What you see in the
  87 ;;; table is pretty much all there is. Patches are welcome :-)
  88 ;;;
  89 ;;; @section Implementation notes
  90 ;;;
  91 ;;; The profiler works by setting the unix profiling signal
  92 ;;; @code{ITIMER_PROF} to go off after the interval you define in the call
  93 ;;; to @code{statprof-reset}. When the signal fires, a sampling routine is
  94 ;;; run which looks at the current procedure that's executing, and then
  95 ;;; crawls up the stack, and for each procedure encountered, increments
  96 ;;; that procedure's sample count. Note that if a procedure is encountered
  97 ;;; multiple times on a given stack, it is only counted once. After the
  98 ;;; sampling is complete, the profiler resets profiling timer to fire
  99 ;;; again after the appropriate interval.
 100 ;;;
 101 ;;; Meanwhile, the profiler keeps track, via @code{get-internal-run-time},
 102 ;;; how much CPU time (system and user -- which is also what
 103 ;;; @code{ITIMER_PROF} tracks), has elapsed while code has been executing
 104 ;;; within a statprof-start/stop block.
 105 ;;;
 106 ;;; The profiler also tries to avoid counting or timing its own code as
 107 ;;; much as possible.
 108 ;;;
 109 ;;; Code:
 110
 111 (define-module (statprof)
 112   #:use-module (srfi srfi-1)
 113   #:use-module (srfi srfi-9)
 114   #:autoload   (ice-9 format) (format)
 115   #:use-module (system vm vm)
 116   #:use-module (system vm frame)
 117   #:use-module (system vm program)
 118   #:export (statprof-active?
 119             statprof-start
 120             statprof-stop
 121             statprof-reset
 122
 123             statprof-accumulated-time
 124             statprof-sample-count
 125             statprof-fold-call-data
 126             statprof-proc-call-data
 127             statprof-call-data-name
 128             statprof-call-data-calls
 129             statprof-call-data-cum-samples
 130             statprof-call-data-self-samples
 131             statprof-call-data->stats
 132
 133             statprof-stats-proc-name
 134             statprof-stats-%-time-in-proc
 135             statprof-stats-cum-secs-in-proc
 136             statprof-stats-self-secs-in-proc
 137             statprof-stats-calls
 138             statprof-stats-self-secs-per-call
 139             statprof-stats-cum-secs-per-call
 140
 141             statprof-display
 142             statprof-display-anomolies
 143
 144             statprof-fetch-stacks
 145             statprof-fetch-call-tree
 146
 147             statprof
 148             with-statprof
 149
 150             gcprof))
 151
 152
 153 ;; This profiler tracks two numbers for every function called while
 154 ;; it's active.  It tracks the total number of calls, and the number
 155 ;; of times the function was active when the sampler fired.
 156 ;;
 157 ;; Globally the profiler tracks the total time elapsed and the number
 158 ;; of times the sampler was fired.
 159 ;;
 160 ;; Right now, this profiler is not per-thread and is not thread safe.
 161
 162 (define-record-type <state>
 163   (make-state accumulated-time last-start-time sample-count
 164               sampling-frequency remaining-prof-time profile-level
 165               count-calls? gc-time-taken record-full-stacks?
 166               stacks procedure-data inside-profiler?)
 167   state?
 168   ;; Total time so far.
 169   (accumulated-time accumulated-time set-accumulated-time!)
 170   ;; Start-time when timer is active.
 171   (last-start-time last-start-time set-last-start-time!)
 172   ;; Total count of sampler calls.
 173   (sample-count sample-count set-sample-count!)
 174   ;; (seconds . microseconds)
 175   (sampling-frequency sampling-frequency set-sampling-frequency!)
 176   ;; Time remaining when prof suspended.
 177   (remaining-prof-time remaining-prof-time set-remaining-prof-time!)
 178   ;; For user start/stop nesting.
 179   (profile-level profile-level set-profile-level!)
 180   ;; Whether to catch apply-frame.
 181   (count-calls? count-calls? set-count-calls?!)
 182   ;; GC time between statprof-start and statprof-stop.
 183   (gc-time-taken gc-time-taken set-gc-time-taken!)
 184   ;; If #t, stash away the stacks for future analysis.
 185   (record-full-stacks? record-full-stacks? set-record-full-stacks?!)
 186   ;; If record-full-stacks?, the stashed full stacks.
 187   (stacks stacks set-stacks!)
 188   ;; A hash where the key is the function object itself and the value is
 189   ;; the data. The data will be a vector like this:
 190   ;;   #(name call-count cum-sample-count self-sample-count)
 191   (procedure-data procedure-data set-procedure-data!)
 192   ;; True if we are inside the profiler.
 193   (inside-profiler? inside-profiler? set-inside-profiler?!))
 194
 195 (define profiler-state (make-parameter #f))
 196
 197 (define* (fresh-profiler-state #:key (count-calls? #f)
 198                                (sampling-frequency '(0 . 10000))
 199                                (full-stacks? #f))
 200   (make-state 0.0 #f 0 sampling-frequency #f 0 count-calls? 0.0 #f '()
 201               (make-hash-table) #f))
 202
 203 (define (ensure-profiler-state)
 204   (or (profiler-state)
 205       (let ((state (fresh-profiler-state)))
 206         (profiler-state state)
 207         state)))
 208
 209 (define (existing-profiler-state)
 210   (or (profiler-state)
 211       (error "expected there to be a profiler state")))
 212
 213 ;; If you change the call-data data structure, you need to also change
 214 ;; sample-uncount-frame.
 215 (define (make-call-data proc call-count cum-sample-count self-sample-count)
 216   (vector proc call-count cum-sample-count self-sample-count))
 217 (define (call-data-proc cd) (vector-ref cd 0))
 218 (define (call-data-name cd) (procedure-name (call-data-proc cd)))
 219 (define (call-data-printable cd)
 220   (or (call-data-name cd)
 221       (with-output-to-string (lambda () (write (call-data-proc cd))))))
 222 (define (call-data-call-count cd) (vector-ref cd 1))
 223 (define (call-data-cum-sample-count cd) (vector-ref cd 2))
 224 (define (call-data-self-sample-count cd) (vector-ref cd 3))
 225
 226 (define (inc-call-data-call-count! cd)
 227   (vector-set! cd 1 (1+ (vector-ref cd 1))))
 228 (define (inc-call-data-cum-sample-count! cd)
 229   (vector-set! cd 2 (1+ (vector-ref cd 2))))
 230 (define (inc-call-data-self-sample-count! cd)
 231   (vector-set! cd 3 (1+ (vector-ref cd 3))))
 232
 233 (define (accumulate-time state stop-time)
 234   (set-accumulated-time! state
 235                          (+ (accumulated-time state)
 236                             (- stop-time (last-start-time state)))))
 237
 238 (define (get-call-data proc)
 239   (define state (ensure-profiler-state))
 240   (let ((k (cond
 241             ((program? proc) (program-code proc))
 242             (else proc))))
 243     (or (hashv-ref (procedure-data state) k)
 244         (let ((call-data (make-call-data proc 0 0 0)))
 245           (hashv-set! (procedure-data state) k call-data)
 246           call-data))))
 247
 248 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 249 ;; SIGPROF handler
 250
 251 (define (sample-stack-procs stack)
 252   (let ((stacklen (stack-length stack))
 253         (hit-count-call? #f)
 254         (state (existing-profiler-state)))
 255
 256     (if (record-full-stacks? state)
 257         (set-stacks! state (cons stack (stacks state))))
 258
 259     (set-sample-count! state (+ (sample-count state) 1))
 260     ;; Now accumulate stats for the whole stack.
 261     (let loop ((frame (stack-ref stack 0))
 262                (procs-seen (make-hash-table 13))
 263                (self #f))
 264       (cond
 265        ((not frame)
 266         (hash-fold
 267          (lambda (proc val accum)
 268            (inc-call-data-cum-sample-count!
 269             (get-call-data proc)))
 270          #f
 271          procs-seen)
 272         (and=> (and=> self get-call-data)
 273                inc-call-data-self-sample-count!))
 274        ((frame-procedure frame)
 275         => (lambda (proc)
 276              (cond
 277               ((eq? proc count-call)
 278                ;; We're not supposed to be sampling count-call and
 279                ;; its sub-functions, so loop again with a clean
 280                ;; slate.
 281                (set! hit-count-call? #t)
 282                (loop (frame-previous frame) (make-hash-table 13) #f))
 283               (else
 284                (hashq-set! procs-seen proc #t)
 285                (loop (frame-previous frame)
 286                      procs-seen
 287                      (or self proc))))))
 288        (else
 289         (loop (frame-previous frame) procs-seen self))))
 290     hit-count-call?))
 291
 292 (define (profile-signal-handler sig)
 293   (define state (existing-profiler-state))
 294
 295   (set-inside-profiler?! state #t)
 296
 297   ;; FIXME: with-statprof should be able to set an outer frame for the
 298   ;; stack cut
 299   (if (positive? (profile-level state))
 300       (let* ((stop-time (get-internal-run-time))
 301              ;; cut down to the signal handler. note that this will only
 302              ;; work if statprof.scm is compiled; otherwise we get
 303              ;; `eval' on the stack instead, because if it's not
 304              ;; compiled, profile-signal-handler is a thunk that
 305              ;; tail-calls eval. perhaps we should always compile the
 306              ;; signal handler instead...
 307              (stack (or (make-stack #t profile-signal-handler)
 308                         (pk 'what! (make-stack #t))))
 309              (inside-apply-trap? (sample-stack-procs stack)))
 310
 311         (if (not inside-apply-trap?)
 312             (begin
 313               ;; disabling here is just a little more efficient, but
 314               ;; not necessary given inside-profiler?.  We can't just
 315               ;; disable unconditionally at the top of this function
 316               ;; and eliminate inside-profiler? because it seems to
 317               ;; confuse guile wrt re-enabling the trap when
 318               ;; count-call finishes.
 319               (if (count-calls? state)
 320                   (set-vm-trace-level! (1- (vm-trace-level))))
 321               (accumulate-time state stop-time)))
 322
 323         (setitimer ITIMER_PROF
 324                    0 0
 325                    (car (sampling-frequency state))
 326                    (cdr (sampling-frequency state)))
 327
 328         (if (not inside-apply-trap?)
 329             (begin
 330               (set-last-start-time! state (get-internal-run-time))
 331               (if (count-calls? state)
 332                   (set-vm-trace-level! (1+ (vm-trace-level))))))))
 333
 334   (set-inside-profiler?! state #f))
 335
 336 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 337 ;; Count total calls.
 338
 339 (define (count-call frame)
 340   (define state (existing-profiler-state))
 341
 342   (if (not (inside-profiler? state))
 343       (begin
 344         (accumulate-time state (get-internal-run-time))
 345
 346         (and=> (frame-procedure frame)
 347                (lambda (proc)
 348                  (inc-call-data-call-count!
 349                   (get-call-data proc))))
 350
 351         (set-last-start-time! state (get-internal-run-time)))))
 352
 353 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 354
 355 (define (statprof-active?)
 356   "Returns @code{#t} if @code{statprof-start} has been called more times
 357 than @code{statprof-stop}, @code{#f} otherwise."
 358   (define state (profiler-state))
 359   (and state (positive? (profile-level state))))
 360
 361 ;; Do not call this from statprof internal functions -- user only.
 362 (define (statprof-start)
 363   "Start the profiler.@code{}"
 364   ;; After some head-scratching, I don't *think* I need to mask/unmask
 365   ;; signals here, but if I'm wrong, please let me know.
 366   (define state (ensure-profiler-state))
 367   (set-profile-level! state (+ (profile-level state) 1))
 368   (if (= (profile-level state) 1)
 369       (let* ((rpt (remaining-prof-time state))
 370              (use-rpt? (and rpt
 371                             (or (positive? (car rpt))
 372                                 (positive? (cdr rpt))))))
 373         (set-remaining-prof-time! state #f)
 374         (set-last-start-time! state (get-internal-run-time))
 375         (set-gc-time-taken! state
 376                             (cdr (assq 'gc-time-taken (gc-stats))))
 377         (if use-rpt?
 378             (setitimer ITIMER_PROF 0 0 (car rpt) (cdr rpt))
 379             (setitimer ITIMER_PROF
 380                        0 0
 381                        (car (sampling-frequency state))
 382                        (cdr (sampling-frequency state))))
 383         (if (count-calls? state)
 384             (add-hook! (vm-apply-hook) count-call))
 385         (set-vm-trace-level! (1+ (vm-trace-level)))
 386         #t)))
 387
 388 ;; Do not call this from statprof internal functions -- user only.
 389 (define (statprof-stop)
 390   "Stop the profiler.@code{}"
 391   ;; After some head-scratching, I don't *think* I need to mask/unmask
 392   ;; signals here, but if I'm wrong, please let me know.
 393   (define state (ensure-profiler-state))
 394   (set-profile-level! state (- (profile-level state) 1))
 395   (if (zero? (profile-level state))
 396       (begin
 397         (set-gc-time-taken! state
 398                             (- (cdr (assq 'gc-time-taken (gc-stats)))
 399                                (gc-time-taken state)))
 400         (set-vm-trace-level! (1- (vm-trace-level)))
 401         (if (count-calls? state)
 402             (remove-hook! (vm-apply-hook) count-call))
 403         ;; I believe that we need to do this before getting the time
 404         ;; (unless we want to make things even more complicated).
 405         (set-remaining-prof-time! state (setitimer ITIMER_PROF 0 0 0 0))
 406         (accumulate-time state (get-internal-run-time))
 407         (set-last-start-time! state #f))))
 408
 409 (define* (statprof-reset sample-seconds sample-microseconds count-calls?
 410                          #:optional full-stacks?)
 411   "Reset the statprof sampler interval to @var{sample-seconds} and
 412 @var{sample-microseconds}. If @var{count-calls?} is true, arrange to
 413 instrument procedure calls as well as collecting statistical profiling
 414 data. If @var{full-stacks?} is true, collect all sampled stacks into a
 415 list for later analysis.
 416
 417 Enables traps and debugging as necessary."
 418   (when (statprof-active?)
 419     (error "Can't reset profiler while profiler is running."))
 420   (let ((state (fresh-profiler-state #:count-calls? count-calls?
 421                                      #:sampling-frequency
 422                                      (cons sample-seconds sample-microseconds)
 423                                      #:full-stacks? full-stacks?)))
 424     (profiler-state state)
 425     (sigaction SIGPROF profile-signal-handler)
 426     #t))
 427
 428 (define (statprof-fold-call-data proc init)
 429   "Fold @var{proc} over the call-data accumulated by statprof. Cannot be
 430 called while statprof is active. @var{proc} should take two arguments,
 431 @code{(@var{call-data} @var{prior-result})}.
 432
 433 Note that a given proc-name may appear multiple times, but if it does,
 434 it represents different functions with the same name."
 435   (when (statprof-active?)
 436     (error "Can't call statprof-fold-call-data while profiler is running."))
 437   (hash-fold
 438    (lambda (key value prior-result)
 439      (proc value prior-result))
 440    init
 441    (procedure-data (existing-profiler-state))))
 442
 443 (define (statprof-proc-call-data proc)
 444   "Returns the call-data associated with @var{proc}, or @code{#f} if
 445 none is available."
 446   (when (statprof-active?)
 447     (error "Can't call statprof-proc-call-data while profiler is running."))
 448   (get-call-data proc))
 449
 450 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 451 ;; Stats
 452
 453 (define (statprof-call-data->stats call-data)
 454   "Returns an object of type @code{statprof-stats}."
 455   ;; returns (vector proc-name
 456   ;;                 %-time-in-proc
 457   ;;                 cum-seconds-in-proc
 458   ;;                 self-seconds-in-proc
 459   ;;                 num-calls
 460   ;;                 self-secs-per-call
 461   ;;                 total-secs-per-call)
 462
 463   (define state (existing-profiler-state))
 464
 465   (let* ((proc-name (call-data-printable call-data))
 466          (self-samples (call-data-self-sample-count call-data))
 467          (cum-samples (call-data-cum-sample-count call-data))
 468          (all-samples (statprof-sample-count))
 469          (secs-per-sample (/ (statprof-accumulated-time)
 470                              (statprof-sample-count)))
 471          (num-calls (and (count-calls? state) (statprof-call-data-calls call-data))))
 472
 473     (vector proc-name
 474             (* (/ self-samples all-samples) 100.0)
 475             (* cum-samples secs-per-sample 1.0)
 476             (* self-samples secs-per-sample 1.0)
 477             num-calls
 478             (and num-calls ;; maybe we only sampled in children
 479                  (if (zero? self-samples) 0.0
 480                      (/ (* self-samples secs-per-sample) 1.0 num-calls)))
 481             (and num-calls ;; cum-samples must be positive
 482                  (/ (* cum-samples secs-per-sample)
 483                     1.0
 484                     ;; num-calls might be 0 if we entered statprof during the
 485                     ;; dynamic extent of the call
 486                     (max num-calls 1))))))
 487
 488 (define (statprof-stats-proc-name stats) (vector-ref stats 0))
 489 (define (statprof-stats-%-time-in-proc stats) (vector-ref stats 1))
 490 (define (statprof-stats-cum-secs-in-proc stats) (vector-ref stats 2))
 491 (define (statprof-stats-self-secs-in-proc stats) (vector-ref stats 3))
 492 (define (statprof-stats-calls stats) (vector-ref stats 4))
 493 (define (statprof-stats-self-secs-per-call stats) (vector-ref stats 5))
 494 (define (statprof-stats-cum-secs-per-call stats) (vector-ref stats 6))
 495
 496 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 497
 498 (define (stats-sorter x y)
 499   (let ((diff (- (statprof-stats-self-secs-in-proc x)
 500                  (statprof-stats-self-secs-in-proc y))))
 501     (positive?
 502      (if (= diff 0)
 503          (- (statprof-stats-cum-secs-in-proc x)
 504             (statprof-stats-cum-secs-in-proc y))
 505          diff))))
 506
 507 (define* (statprof-display #:optional (port (current-output-port)))
 508   "Displays a gprof-like summary of the statistics collected. Unless an
 509 optional @var{port} argument is passed, uses the current output port."
 510   (define state (existing-profiler-state))
 511
 512   (cond
 513    ((zero? (statprof-sample-count))
 514     (format port "No samples recorded.\n"))
 515    (else
 516     (let* ((stats-list (statprof-fold-call-data
 517                         (lambda (data prior-value)
 518                           (cons (statprof-call-data->stats data)
 519                                 prior-value))
 520                         '()))
 521            (sorted-stats (sort stats-list stats-sorter)))
 522
 523       (define (display-stats-line stats)
 524         (if (count-calls? state)
 525             (format  port "~6,2f ~9,2f ~9,2f ~7d ~8,2f ~8,2f  "
 526                      (statprof-stats-%-time-in-proc stats)
 527                      (statprof-stats-cum-secs-in-proc stats)
 528                      (statprof-stats-self-secs-in-proc stats)
 529                      (statprof-stats-calls stats)
 530                      (* 1000 (statprof-stats-self-secs-per-call stats))
 531                      (* 1000 (statprof-stats-cum-secs-per-call stats)))
 532             (format  port "~6,2f ~9,2f ~9,2f  "
 533                      (statprof-stats-%-time-in-proc stats)
 534                      (statprof-stats-cum-secs-in-proc stats)
 535                      (statprof-stats-self-secs-in-proc stats)))
 536         (display (statprof-stats-proc-name stats) port)
 537         (newline port))
 538
 539       (if (count-calls? state)
 540           (begin
 541             (format  port "~5a ~10a   ~7a ~8a ~8a ~8a  ~8@a\n"
 542                      "%  " "cumulative" "self" "" "self" "total" "")
 543             (format  port "~5a  ~9a  ~8a ~8a ~8a ~8a  ~8@a\n"
 544                      "time" "seconds" "seconds" "calls" "ms/call" "ms/call" "name"))
 545           (begin
 546             (format  port "~5a ~10a   ~7a  ~8@a\n"
 547                      "%" "cumulative" "self" "")
 548             (format  port "~5a  ~10a  ~7a  ~8@a\n"
 549                      "time" "seconds" "seconds" "name")))
 550
 551       (for-each display-stats-line sorted-stats)
 552
 553       (display "---\n" port)
 554       (simple-format #t "Sample count: ~A\n" (statprof-sample-count))
 555       (simple-format #t "Total time: ~A seconds (~A seconds in GC)\n"
 556                      (statprof-accumulated-time)
 557                      (/ (gc-time-taken state) 1.0 internal-time-units-per-second))))))
 558
 559 (define (statprof-display-anomolies)
 560   "A sanity check that attempts to detect anomolies in statprof's
 561 statistics.@code{}"
 562   (define state (existing-profiler-state))
 563
 564   (statprof-fold-call-data
 565    (lambda (data prior-value)
 566      (if (and (count-calls? state)
 567               (zero? (call-data-call-count data))
 568               (positive? (call-data-cum-sample-count data)))
 569          (simple-format #t
 570                         "==[~A ~A ~A]\n"
 571                         (call-data-name data)
 572                         (call-data-call-count data)
 573                         (call-data-cum-sample-count data))))
 574    #f)
 575   (simple-format #t "Total time: ~A\n" (statprof-accumulated-time))
 576   (simple-format #t "Sample count: ~A\n" (statprof-sample-count)))
 577
 578 (define (statprof-accumulated-time)
 579   "Returns the time accumulated during the last statprof run.@code{}"
 580   (when (statprof-active?)
 581     (error "Can't get accumulated time while profiler is running."))
 582   (/ (accumulated-time (existing-profiler-state)) internal-time-units-per-second))
 583
 584 (define (statprof-sample-count)
 585   "Returns the number of samples taken during the last statprof run.@code{}"
 586   (when (statprof-active?)
 587     (error "Can't get sample count while profiler is running."))
 588   (sample-count (existing-profiler-state)))
 589
 590 (define statprof-call-data-name call-data-name)
 591 (define statprof-call-data-calls call-data-call-count)
 592 (define statprof-call-data-cum-samples call-data-cum-sample-count)
 593 (define statprof-call-data-self-samples call-data-self-sample-count)
 594
 595 (define (statprof-fetch-stacks)
 596   "Returns a list of stacks, as they were captured since the last call
 597 to @code{statprof-reset}.
 598
 599 Note that stacks are only collected if the @var{full-stacks?} argument
 600 to @code{statprof-reset} is true."
 601   (define state (existing-profiler-state))
 602   (stacks state))
 603
 604 (define procedure=?
 605   (lambda (a b)
 606     (cond
 607      ((eq? a b))
 608      ((and (program? a) (program? b))
 609       (eq? (program-code a) (program-code b)))
 610      (else
 611       #f))))
 612
 613 ;; tree ::= (car n . tree*)
 614
 615 (define (lists->trees lists equal?)
 616   (let lp ((in lists) (n-terminal 0) (tails '()))
 617     (cond
 618      ((null? in)
 619       (let ((trees (map (lambda (tail)
 620                           (cons (car tail)
 621                                 (lists->trees (cdr tail) equal?)))
 622                         tails)))
 623         (cons (apply + n-terminal (map cadr trees))
 624               (sort trees
 625                     (lambda (a b) (> (cadr a) (cadr b)))))))
 626      ((null? (car in))
 627       (lp (cdr in) (1+ n-terminal) tails))
 628      ((find (lambda (x) (equal? (car x) (caar in)))
 629             tails)
 630       => (lambda (tail)
 631            (lp (cdr in)
 632                n-terminal
 633                (assq-set! tails
 634                           (car tail)
 635                           (cons (cdar in) (cdr tail))))))
 636      (else
 637       (lp (cdr in)
 638           n-terminal
 639           (acons (caar in) (list (cdar in)) tails))))))
 640
 641 (define (stack->procedures stack)
 642   (filter identity
 643           (unfold-right (lambda (x) (not x))
 644                         frame-procedure
 645                         frame-previous
 646                         (stack-ref stack 0))))
 647
 648 (define (statprof-fetch-call-tree)
 649   "Return a call tree for the previous statprof run.
 650
 651 The return value is a list of nodes, each of which is of the type:
 652 @code
 653  node ::= (@var{proc} @var{count} . @var{nodes})
 654 @end code"
 655   (define state (existing-profiler-state))
 656   (cons #t (lists->trees (map stack->procedures (stacks state)) procedure=?)))
 657
 658 (define* (statprof thunk #:key (loop 1) (hz 100) (count-calls? #f)
 659                    (full-stacks? #f))
 660   "Profiles the execution of @var{thunk}.
 661
 662 The stack will be sampled @var{hz} times per second, and the thunk itself will
 663 be called @var{loop} times.
 664
 665 If @var{count-calls?} is true, all procedure calls will be recorded. This
 666 operation is somewhat expensive.
 667
 668 If @var{full-stacks?} is true, at each sample, statprof will store away the
 669 whole call tree, for later analysis. Use @code{statprof-fetch-stacks} or
 670 @code{statprof-fetch-call-tree} to retrieve the last-stored stacks."
 671
 672   (define state (ensure-profiler-state))
 673
 674   (dynamic-wind
 675     (lambda ()
 676       (statprof-reset (inexact->exact (floor (/ 1 hz)))
 677                       (inexact->exact (* 1e6 (- (/ 1 hz)
 678                                                 (floor (/ 1 hz)))))
 679                       count-calls?
 680                       full-stacks?)
 681       (statprof-start))
 682     (lambda ()
 683       (let lp ((i loop))
 684         (if (not (zero? i))
 685             (begin
 686               (thunk)
 687               (lp (1- i))))))
 688     (lambda ()
 689       (statprof-stop)
 690       (statprof-display)
 691       (set-procedure-data! state #f))))
 692
 693 (define-macro (with-statprof . args)
 694   "Profiles the expressions in its body.
 695
 696 Keyword arguments:
 697
 698 @table @code
 699 @item #:loop
 700 Execute the body @var{loop} number of times, or @code{#f} for no looping
 701
 702 default: @code{#f}
 703 @item #:hz
 704 Sampling rate
 705
 706 default: @code{20}
 707 @item #:count-calls?
 708 Whether to instrument each function call (expensive)
 709
 710 default: @code{#f}
 711 @item #:full-stacks?
 712 Whether to collect away all sampled stacks into a list
 713
 714 default: @code{#f}
 715 @end table"
 716   (define (kw-arg-ref kw args def)
 717     (cond
 718      ((null? args) (error "Invalid macro body"))
 719      ((keyword? (car args))
 720       (if (eq? (car args) kw)
 721           (cadr args)
 722           (kw-arg-ref kw (cddr args) def)))
 723      ((eq? kw #f def) ;; asking for the body
 724       args)
 725      (else def))) ;; kw not found
 726   `((@ (statprof) statprof)
 727     (lambda () ,@(kw-arg-ref #f args #f))
 728     #:loop ,(kw-arg-ref #:loop args 1)
 729     #:hz ,(kw-arg-ref #:hz args 100)
 730     #:count-calls? ,(kw-arg-ref #:count-calls? args #f)
 731     #:full-stacks? ,(kw-arg-ref #:full-stacks? args #f)))
 732
 733 (define* (gcprof thunk #:key (loop 1) (full-stacks? #f))
 734   "Do an allocation profile of the execution of @var{thunk}.
 735
 736 The stack will be sampled soon after every garbage collection, yielding
 737 an approximate idea of what is causing allocation in your program.
 738
 739 Since GC does not occur very frequently, you may need to use the
 740 @var{loop} parameter, to cause @var{thunk} to be called @var{loop}
 741 times.
 742
 743 If @var{full-stacks?} is true, at each sample, statprof will store away the
 744 whole call tree, for later analysis. Use @code{statprof-fetch-stacks} or
 745 @code{statprof-fetch-call-tree} to retrieve the last-stored stacks."
 746
 747   (define state (ensure-profiler-state))
 748
 749   (define (reset)
 750     (if (positive? (profile-level state))
 751         (error "Can't reset profiler while profiler is running."))
 752     (set-accumulated-time! state 0)
 753     (set-last-start-time! state #f)
 754     (set-sample-count! state 0)
 755     (set-count-calls?! state #f)
 756     (set-procedure-data! state (make-hash-table 131))
 757     (set-record-full-stacks?! state full-stacks?)
 758     (set-stacks! state '()))
 759
 760   (define (gc-callback)
 761     (cond
 762      ((inside-profiler? state))
 763      (else
 764       (set-inside-profiler?! state #t)
 765
 766       ;; FIXME: should be able to set an outer frame for the stack cut
 767       (let ((stop-time (get-internal-run-time))
 768             ;; Cut down to gc-callback, and then one before (the
 769             ;; after-gc async).  See the note in profile-signal-handler
 770             ;; also.
 771             (stack (or (make-stack #t gc-callback 0 1)
 772                        (pk 'what! (make-stack #t)))))
 773         (sample-stack-procs stack)
 774         (accumulate-time state stop-time)
 775         (set-last-start-time! state (get-internal-run-time)))
 776
 777       (set-inside-profiler?! state #f))))
 778
 779   (define (start)
 780     (set-profile-level! state (+ (profile-level state) 1))
 781     (if (= (profile-level state) 1)
 782         (begin
 783           (set-remaining-prof-time! state #f)
 784           (set-last-start-time! state (get-internal-run-time))
 785           (set-gc-time-taken! state (cdr (assq 'gc-time-taken (gc-stats))))
 786           (add-hook! after-gc-hook gc-callback)
 787           (set-vm-trace-level! (1+ (vm-trace-level)))
 788           #t)))
 789
 790   (define (stop)
 791     (set-profile-level! state (- (profile-level state) 1))
 792     (if (zero? (profile-level state))
 793         (begin
 794           (set-gc-time-taken! state
 795                               (- (cdr (assq 'gc-time-taken (gc-stats)))
 796                                  (gc-time-taken state)))
 797           (remove-hook! after-gc-hook gc-callback)
 798           (accumulate-time state (get-internal-run-time))
 799           (set-last-start-time! state #f))))
 800
 801   (dynamic-wind
 802     (lambda ()
 803       (reset)
 804       (start))
 805     (lambda ()
 806       (let lp ((i loop))
 807         (if (not (zero? i))
 808             (begin
 809               (thunk)
 810               (lp (1- i))))))
 811     (lambda ()
 812       (stop)
 813       (statprof-display)
 814       (set-procedure-data! state #f))))