configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 Boston, MA 02111-1307, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT(m4_esyscmd(. ./GUILE-VERSION && echo -n ${PACKAGE}),
  31         m4_esyscmd(. ./GUILE-VERSION && echo -n ${GUILE_VERSION}))
  32 AC_CONFIG_SRCDIR(GUILE-VERSION)
  33 AM_INIT_AUTOMAKE([no-define])
  34
  35 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  36 AC_CONFIG_SRCDIR([GUILE-VERSION])
  37
  38 . $srcdir/GUILE-VERSION
  39
  40 AM_MAINTAINER_MODE
  41 AM_CONFIG_HEADER([config.h])
  42 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  43
  44 #--------------------------------------------------------------------
  45 #
  46 # Independent Subdirectories
  47 #
  48 #--------------------------------------------------------------------
  49
  50 AC_CONFIG_SUBDIRS(libltdl)
  51 AC_CONFIG_SUBDIRS(guile-readline)
  52
  53 #--------------------------------------------------------------------
  54
  55 dnl Some more checks for Win32
  56 AC_CYGWIN
  57 AC_MINGW32
  58 AC_LIBTOOL_WIN32_DLL
  59
  60 AC_PROG_INSTALL
  61 AC_PROG_CC
  62 AC_PROG_CPP
  63 AC_PROG_AWK
  64
  65 AC_AIX
  66 AC_ISC_POSIX
  67 AC_MINIX
  68
  69 AM_PROG_CC_STDC
  70
  71 AC_LIBTOOL_DLOPEN
  72 AC_LIBLTDL_INSTALLABLE
  73 AC_PROG_LIBTOOL
  74
  75 AC_SUBST(DLPREOPEN)
  76 AC_SUBST(LTDLINCL)
  77 AC_SUBST(LIBLTDL)
  78
  79 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  80 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  81
  82 AM_PATH_LISPDIR
  83
  84 #--------------------------------------------------------------------
  85 #
  86 # User options (after above tests that may set default CFLAGS etc.)
  87 #
  88 #--------------------------------------------------------------------
  89
  90 GUILE_ERROR_ON_WARNING="yes"
  91
  92 AC_ARG_ENABLE(error-on-warning,
  93   [  --enable-error-on-warning    treat compile warnings as errors],
  94   [case "${enableval}" in
  95      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  96      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  97      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  98    esac])
  99
 100 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
 101 AC_ARG_ENABLE(debug-freelist,
 102   [  --enable-debug-freelist include garbage collector freelist debugging code],
 103   if test "$enable_debug_freelist" = y \
 104      || test "$enable_debug_freelist" = yes; then
 105     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 106   fi)
 107
 108 AC_ARG_ENABLE(debug-malloc,
 109   [  --enable-debug-malloc   include malloc debugging code],
 110   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 111     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 112       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 113   fi)
 114
 115 SCM_I_GSC_GUILE_DEBUG=0
 116 AC_ARG_ENABLE(guile-debug,
 117   [AC_HELP_STRING([--enable-guile-debug],
 118                   [include internal debugging functions])],
 119   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 120     SCM_I_GSC_GUILE_DEBUG=1
 121   fi)
 122
 123 AC_ARG_ENABLE(arrays,
 124   [AC_HELP_STRING([--disable-arrays],[omit array and uniform array support])],
 125   ,
 126   enable_arrays=yes)
 127
 128 AC_ARG_ENABLE(posix,
 129   [  --disable-posix         omit posix interfaces],,
 130   enable_posix=yes)
 131
 132 AC_ARG_ENABLE(networking,
 133   [  --disable-networking    omit networking interfaces],,
 134   enable_networking=yes)
 135
 136 AC_ARG_ENABLE(regex,
 137   [  --disable-regex         omit regular expression interfaces],,
 138   enable_regex=yes)
 139
 140 AC_ARG_ENABLE([discouraged],
 141   AC_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 142
 143 if test "$enable_discouraged" = no; then
 144   SCM_I_GSC_ENABLE_DISCOURAGED=0
 145 else
 146   SCM_I_GSC_ENABLE_DISCOURAGED=1
 147 fi
 148
 149 AC_ARG_ENABLE([deprecated],
 150   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 151
 152 if test "$enable_deprecated" = no; then
 153   SCM_I_GSC_ENABLE_DEPRECATED=0
 154 else
 155   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 156     warn_default=summary
 157   elif test "$enable_deprecated" = shutup; then
 158     warn_default=no
 159   else
 160     warn_default=$enable_deprecated
 161   fi
 162   SCM_I_GSC_ENABLE_DEPRECATED=1
 163   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 164   [Define this to control the default warning level for deprecated features.])
 165 fi
 166
 167 AC_ARG_ENABLE(elisp,
 168   [  --disable-elisp         omit Emacs Lisp support],,
 169   enable_elisp=yes)
 170
 171 #--------------------------------------------------------------------
 172
 173 dnl Check for dynamic linking
 174
 175 use_modules=yes
 176 AC_ARG_WITH(modules,
 177 [  --with-modules[=FILES]  Add support for dynamic modules],
 178 use_modules="$withval")
 179 test -z "$use_modules" && use_modules=yes
 180 DLPREOPEN=
 181 if test "$use_modules" != no; then
 182   if test "$use_modules" = yes; then
 183     DLPREOPEN="-dlpreopen force"
 184   else
 185     DLPREOPEN="-export-dynamic"
 186     for module in $use_modules; do
 187       DLPREOPEN="$DLPREOPEN -dlopen $module"
 188     done
 189   fi
 190 fi
 191
 192 dnl files which are destined for separate modules.
 193
 194 if test "$use_modules" != no; then
 195    AC_LIBOBJ([dynl])
 196 fi
 197
 198 if test "$enable_posix" = yes; then
 199    AC_LIBOBJ([filesys])
 200    AC_LIBOBJ([posix])
 201    AC_DEFINE(HAVE_POSIX, 1,
 202      [Define this if you want support for POSIX system calls in Guile.])
 203 fi
 204
 205 if test "$enable_networking" = yes; then
 206    AC_LIBOBJ([net_db])
 207    AC_LIBOBJ([socket])
 208    AC_DEFINE(HAVE_NETWORKING, 1,
 209      [Define this if you want support for networking in Guile.])
 210 fi
 211
 212 if test "$enable_debug_malloc" = yes; then
 213    AC_LIBOBJ([debug-malloc])
 214 fi
 215
 216 if test "$enable_elisp" = yes; then
 217   SCM_I_GSC_ENABLE_ELISP=1
 218 else
 219   SCM_I_GSC_ENABLE_ELISP=0
 220 fi
 221
 222 AC_C_CONST
 223
 224 AC_C_INLINE
 225 if test "$ac_cv_c_inline" != no; then
 226   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 227 else
 228   SCM_I_GSC_C_INLINE=NULL
 229 fi
 230
 231 AC_C_BIGENDIAN
 232
 233 AC_CHECK_SIZEOF(char)
 234 AC_CHECK_SIZEOF(unsigned char)
 235 AC_CHECK_SIZEOF(short)
 236 AC_CHECK_SIZEOF(unsigned short)
 237 AC_CHECK_SIZEOF(int)
 238 AC_CHECK_SIZEOF(unsigned int)
 239 AC_CHECK_SIZEOF(long)
 240 AC_CHECK_SIZEOF(unsigned long)
 241 AC_CHECK_SIZEOF(size_t)
 242 AC_CHECK_SIZEOF(long long)
 243 AC_CHECK_SIZEOF(unsigned long long)
 244 AC_CHECK_SIZEOF(__int64)
 245 AC_CHECK_SIZEOF(unsigned __int64)
 246 AC_CHECK_SIZEOF(void *)
 247 AC_CHECK_SIZEOF(intptr_t)
 248 AC_CHECK_SIZEOF(uintptr_t)
 249 AC_CHECK_SIZEOF(ptrdiff_t)
 250 AC_CHECK_SIZEOF(size_t)
 251
 252 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 253   AC_MSG_ERROR(sizes of long and void* are not identical)
 254 fi
 255
 256 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 257   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 258 else
 259   SCM_I_GSC_T_PTRDIFF='"long"'
 260 fi
 261 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 262
 263 AC_CHECK_HEADERS([stdint.h])
 264 AC_CHECK_HEADERS([inttypes.h])
 265
 266 AC_CHECK_SIZEOF(intmax_t)
 267
 268 SCM_I_GSC_NEEDS_STDINT_H=0
 269 SCM_I_GSC_NEEDS_INTTYPES_H=0
 270
 271 ### intptr and uintptr (try not to use inttypes if we don't have to)
 272 if test "$ac_cv_header_inttypes_h" = yes; then
 273   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 274     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 275 #include <stdio.h>])
 276     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 277       SCM_I_GSC_NEEDS_INTTYPES_H=1
 278     fi
 279   fi
 280   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 281     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 282 #include <stdio.h>])
 283     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 284       SCM_I_GSC_NEEDS_INTTYPES_H=1
 285     fi
 286   fi
 287 fi
 288
 289 ### See what's provided by stdint.h
 290 if test "$ac_cv_header_stdint_h" = yes; then
 291    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 292    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 293    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 294    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 295    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 296    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 297    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 298    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 299    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 300    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 301 fi
 302
 303 # so we don't get confused by the cache (wish there was a better way
 304 # to check particular headers for the same type...)
 305
 306 unset ac_cv_type_int8_t
 307 unset ac_cv_type_uint8_t
 308 unset ac_cv_type_int16_t
 309 unset ac_cv_type_uint16_t
 310 unset ac_cv_type_int32_t
 311 unset ac_cv_type_uint32_t
 312 unset ac_cv_type_int64_t
 313 unset ac_cv_type_uint64_t
 314 unset ac_cv_type_intmax_t
 315 unset ac_cv_type_uintmax_t
 316
 317 ### See what's provided by inttypes.h
 318 if test "$ac_cv_header_inttypes_h" = yes; then
 319   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 320   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 321   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 322   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 323   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 324   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 325   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 326   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 327   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 328   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 329 fi
 330
 331 # Try hard to find definitions for some required scm_t_*int* types.
 332
 333 ### Required type scm_t_int8
 334 if test "$scm_stdint_has_int8"; then
 335   SCM_I_GSC_T_INT8='"int8_t"'
 336   SCM_I_GSC_NEEDS_STDINT_H=1
 337 elif test "$scm_inttypes_has_int8"; then
 338   SCM_I_GSC_T_INT8='"int8_t"'
 339   SCM_I_GSC_NEEDS_INTTYPES_H=1
 340 elif test "$ac_cv_sizeof_char" -eq 1; then
 341   SCM_I_GSC_T_INT8='"signed char"'
 342 else
 343   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 344 fi
 345 AC_SUBST([SCM_I_GSC_T_INT8])
 346
 347 ### Required type scm_t_uint8
 348 if test "$scm_stdint_has_uint8"; then
 349   SCM_I_GSC_T_UINT8='"uint8_t"'
 350   SCM_I_GSC_NEEDS_STDINT_H=1
 351 elif test "$scm_inttypes_has_uint8"; then
 352   SCM_I_GSC_T_UINT8='"uint8_t"'
 353   SCM_I_GSC_NEEDS_INTTYPES_H=1
 354 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 355   SCM_I_GSC_T_UINT8='"unsigned char"'
 356 else
 357   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 358 fi
 359 AC_SUBST([SCM_I_GSC_T_UINT8])
 360
 361 ### Required type scm_t_int16 (ANSI C says int or short might work)
 362 if test "$scm_stdint_has_int16"; then
 363   SCM_I_GSC_T_INT16='"int16_t"'
 364   SCM_I_GSC_NEEDS_STDINT_H=1
 365 elif test "$scm_inttypes_has_int16"; then
 366   SCM_I_GSC_T_INT16='"int16_t"'
 367   SCM_I_GSC_NEEDS_INTTYPES_H=1
 368 elif test "$ac_cv_sizeof_int" -eq 2; then
 369   SCM_I_GSC_T_INT16='"int"'
 370 elif test "$ac_cv_sizeof_short" -eq 2; then
 371   SCM_I_GSC_T_INT16='"short"'
 372 else
 373   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 374 fi
 375 AC_SUBST([SCM_I_GSC_T_INT16])
 376
 377 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 378 if test "$scm_stdint_has_uint16"; then
 379   SCM_I_GSC_T_UINT16='"uint16_t"'
 380   SCM_I_GSC_NEEDS_STDINT_H=1
 381 elif test "$scm_inttypes_has_uint16"; then
 382   SCM_I_GSC_T_UINT16='"uint16_t"'
 383   SCM_I_GSC_NEEDS_INTTYPES_H=1
 384 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 385   SCM_I_GSC_T_UINT16='"unsigned int"'
 386 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 387   SCM_I_GSC_T_UINT16='"unsigned short"'
 388 else
 389   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 390 fi
 391 AC_SUBST([SCM_I_GSC_T_UINT16])
 392
 393
 394 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 395 if test "$scm_stdint_has_int32"; then
 396   SCM_I_GSC_T_INT32='"int32_t"'
 397   SCM_I_GSC_NEEDS_STDINT_H=1
 398 elif test "$scm_inttypes_has_int32"; then
 399   SCM_I_GSC_T_INT32='"int32_t"'
 400   SCM_I_GSC_NEEDS_INTTYPES_H=1
 401 elif test "$ac_cv_sizeof_int" -eq 4; then
 402   SCM_I_GSC_T_INT32='"int"'
 403 elif test "$ac_cv_sizeof_long" -eq 4; then
 404   SCM_I_GSC_T_INT32='"long"'
 405 elif test "$ac_cv_sizeof_short" -eq 4; then
 406   SCM_I_GSC_T_INT32='"short"'
 407 else
 408   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 409 fi
 410 AC_SUBST([SCM_I_GSC_T_INT32])
 411
 412 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 413 if test "$scm_stdint_has_uint32"; then
 414   SCM_I_GSC_T_UINT32='"uint32_t"'
 415   SCM_I_GSC_NEEDS_STDINT_H=1
 416 elif test "$scm_inttypes_has_uint32"; then
 417   SCM_I_GSC_T_UINT32='"uint32_t"'
 418   SCM_I_GSC_NEEDS_INTTYPES_H=1
 419 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 420   SCM_I_GSC_T_UINT32='"unsigned int"'
 421 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 422   SCM_I_GSC_T_UINT32='"unsigned long"'
 423 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 424   SCM_I_GSC_T_UINT32='"unsigned short"'
 425 else
 426   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 427 fi
 428 AC_SUBST([SCM_I_GSC_T_UINT32])
 429
 430 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 431 ### Also try 'long long' and '__int64' if we have it.
 432 SCM_I_GSC_T_INT64=0
 433 if test "$scm_stdint_has_int64"; then
 434   SCM_I_GSC_T_INT64='"int64_t"'
 435   SCM_I_GSC_NEEDS_STDINT_H=1
 436 elif test "$scm_inttypes_has_int64"; then
 437   SCM_I_GSC_T_INT64='"int64_t"'
 438   SCM_I_GSC_NEEDS_INTTYPES_H=1
 439 elif test "$ac_cv_sizeof_int" -eq 8; then
 440   SCM_I_GSC_T_INT64='"int"'
 441 elif test "$ac_cv_sizeof_long" -eq 8; then
 442   SCM_I_GSC_T_INT64='"long"'
 443 elif test "$ac_cv_sizeof_short" -eq 8; then
 444   SCM_I_GSC_T_INT64='"short"'
 445 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 446   SCM_I_GSC_T_INT64='"long long"'
 447 elif test "$ac_cv_sizeof___int64" -eq 8; then
 448   SCM_I_GSC_T_INT64='"__int64"'
 449 else
 450   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 451 fi
 452 AC_SUBST([SCM_I_GSC_T_INT64])
 453
 454
 455 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 456 ### Also try 'long long' and '__int64' if we have it.
 457 SCM_I_GSC_T_UINT64=0
 458 if test "$scm_stdint_has_uint64"; then
 459   SCM_I_GSC_T_UINT64='"uint64_t"'
 460   SCM_I_GSC_NEEDS_STDINT_H=1
 461 elif test "$scm_inttypes_has_uint64"; then
 462   SCM_I_GSC_T_UINT64='"uint64_t"'
 463   SCM_I_GSC_NEEDS_INTTYPES_H=1
 464 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 465   SCM_I_GSC_T_UINT64='"unsigned int"'
 466 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 467   SCM_I_GSC_T_UINT64='"unsigned long"'
 468 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 469   SCM_I_GSC_T_UINT64='"unsigned short"'
 470 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 471   SCM_I_GSC_T_UINT64='"unsigned long long"'
 472 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 473   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 474 else
 475   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 476 fi
 477 AC_SUBST([SCM_I_GSC_T_UINT64])
 478
 479 ### Required type scm_t_intmax
 480 ###
 481 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 482 ### none of them is available, we use 'long'.
 483 ###
 484 SCM_I_GSC_T_INTMAX=0
 485 if test "$scm_stdint_has_intmax"; then
 486   SCM_I_GSC_T_INTMAX='"intmax_t"'
 487   SCM_I_GSC_NEEDS_STDINT_H=1
 488 elif test "$scm_inttypes_has_intmax"; then
 489   SCM_I_GSC_T_INTMAX='"intmax_t"'
 490   SCM_I_GSC_NEEDS_INTTYPES_H=1
 491 elif test "$ac_cv_sizeof___int64" -ne 0; then
 492   SCM_I_GSC_T_INTMAX='"__int64"'
 493 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 494   SCM_I_GSC_T_INTMAX='"long long"'
 495 else
 496   SCM_I_GSC_T_INTMAX='"long"'
 497 fi
 498 AC_SUBST([SCM_I_GSC_T_INTMAX])
 499
 500 ### Required type scm_t_uintmax
 501 ###
 502 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 503 ### this order.  When none of them is available, we use 'unsigned long'.
 504 ###
 505 SCM_I_GSC_T_UINTMAX=0
 506 if test "$scm_stdint_has_uintmax"; then
 507   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 508   SCM_I_GSC_NEEDS_STDINT_H=1
 509 elif test "$scm_inttypes_has_uintmax"; then
 510   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 511   SCM_I_GSC_NEEDS_INTTYPES_H=1
 512 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 513   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 514 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 515   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 516 else
 517   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 518 fi
 519 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 520
 521
 522 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 523 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 524
 525 AC_HEADER_STDC
 526 AC_HEADER_DIRENT
 527 AC_HEADER_TIME
 528 AC_HEADER_SYS_WAIT
 529
 530 # Reasons for testing:
 531 #   fenv.h - available in C99, but not older systems
 532 #
 533 AC_CHECK_HEADERS([fenv.h io.h libc.h limits.h malloc.h memory.h string.h \
 534 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 535 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 536 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 537 direct.h])
 538
 539 GUILE_HEADER_LIBC_WITH_UNISTD
 540
 541 AC_TYPE_GETGROUPS
 542 AC_TYPE_SIGNAL
 543 AC_TYPE_MODE_T
 544
 545 if test $MINGW32 = no; then
 546         AC_CHECK_LIB(m, main)
 547 fi
 548 AC_CHECK_FUNCS(gethostbyname)
 549 if test $ac_cv_func_gethostbyname = no; then
 550     AC_CHECK_LIB(nsl, gethostbyname)
 551 fi
 552
 553 AC_CHECK_FUNCS(connect)
 554 if test $ac_cv_func_connect = no; then
 555     AC_CHECK_LIB(socket, connect)
 556 fi
 557
 558 dnl
 559 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 560 dnl
 561 EXTRA_DEFS=""
 562 if test "$MINGW32" = "yes" ; then
 563     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 564       [Define if you have the <winsock2.h> header file.])])
 565     AC_CHECK_LIB(ws2_32, main)
 566     AC_LIBOBJ([win32-uname])
 567     AC_LIBOBJ([win32-dirent])
 568     if test "$enable_networking" = yes ; then
 569       AC_LIBOBJ([win32-socket])
 570     fi
 571     if test "$enable_shared" = yes ; then
 572       EXTRA_DEFS="-DSCM_IMPORT"
 573       AC_DEFINE(USE_DLL_IMPORT, 1,
 574         [Define if you need additional CPP macros on Win32 platforms.])
 575     fi
 576     if test x"$enable_ltdl_install" = x"yes" ; then
 577       INCLTDL="-DLIBLTDL_DLL_IMPORT $INCLTDL"
 578     fi
 579 fi
 580 AC_SUBST(EXTRA_DEFS)
 581
 582 # Reasons for testing:
 583 #   crt_externs.h - Darwin specific
 584 #
 585 AC_CHECK_HEADERS([assert.h crt_externs.h])
 586
 587 # Reasons for testing:
 588 #   DINFINITY - OSF specific
 589 #   DQNAN - OSF specific
 590 #       (DINFINITY and DQNAN are actually global variables, not functions)
 591 #   fesetround - available in C99, but not older systems
 592 #   gmtime_r - recent posix, not on old systems
 593 #   readdir_r - recent posix, not on old systems
 594 #   sysconf - not on old systems
 595 #   _NSGetEnviron - Darwin specific
 596 #
 597 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid fesetround ftime fchown getcwd geteuid gettimeofday gmtime_r lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv _NSGetEnviron])
 598
 599 # Reasons for testing:
 600 #   netdb.h - not in mingw
 601 #   sys/param.h - not in mingw
 602 #
 603 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 604 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 605
 606 # crypt() may or may not be available, for instance in some countries there
 607 # are restrictions on cryptography.
 608 #
 609 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 610 # -lcrypt library (eg. Debian GNU/Linux).
 611 #
 612 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 613 # be careful to avoid -lcrypt in this case, since libtool will see there's
 614 # only a static libcrypt and decide to build only a static libguile.
 615 #
 616 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 617 # libraries already in that list.
 618 #
 619 AC_SEARCH_LIBS(crypt, crypt,
 620   [AC_DEFINE(HAVE_CRYPT,1,
 621              [Define to 1 if you have the `crypt' function.])])
 622
 623 dnl GMP tests
 624 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 625   [AC_MSG_ERROR([GNU MP not found, see http://swox.com/gmp])])
 626
 627 # mpz_import is a macro so we need to include <gmp.h>
 628 AC_TRY_LINK([#include <gmp.h>],
 629             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 630   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see http://swox.com/gmp])])
 631
 632 dnl i18n tests
 633 #AC_CHECK_HEADERS([libintl.h])
 634 #AC_CHECK_FUNCS(gettext)
 635 #if test $ac_cv_func_gettext = no; then
 636 #   AC_CHECK_LIB(intl, gettext)
 637 #fi
 638 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 639 AM_GNU_GETTEXT([external], [need-ngettext])
 640
 641 ### Some systems don't declare some functions.  On such systems, we
 642 ### need to at least provide our own K&R-style declarations.
 643
 644 ### GUILE_FUNC_DECLARED(function, headerfile)
 645
 646 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 647 ### not there, #define MISSING_FUNCTION_DECL.
 648 AC_DEFUN([GUILE_FUNC_DECLARED], [
 649   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 650     AC_EGREP_HEADER($1, $2,
 651                     guile_cv_func_$1_declared=yes,
 652                     guile_cv_func_$1_declared=no))
 653   if test [x$guile_cv_func_]$1[_declared] = xno; then
 654     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 655       [Define if the operating system supplies $1 without declaring it.])
 656   fi
 657 ])
 658
 659 GUILE_FUNC_DECLARED(sleep, unistd.h)
 660 GUILE_FUNC_DECLARED(usleep, unistd.h)
 661
 662 AC_CHECK_DECLS([strptime],,,
 663 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 664 #include <time.h>])
 665
 666 ### On some systems usleep has no return value.  If it does have one,
 667 ### we'd like to return it; otherwise, we'll fake it.
 668 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 669   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 670                    unistd.h,
 671                    [guile_cv_func_usleep_return_type=void],
 672                    [guile_cv_func_usleep_return_type=int])])
 673 case "$guile_cv_func_usleep_return_type" in
 674   "void" )
 675     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 676       [Define if the system headers declare usleep to return void.])
 677   ;;
 678 esac
 679
 680 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 681 if test -n "$have_sys_un_h" ; then
 682   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 683     [Define if the system supports Unix-domain (file-domain) sockets.])
 684 fi
 685
 686 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 687
 688 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 689                setnetent    getnetent    endnetent    dnl
 690                setprotoent  getprotoent  endprotoent  dnl
 691                setservent   getservent   endservent   dnl
 692                getnetbyaddr getnetbyname dnl
 693                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 694                inet_pton inet_ntop)
 695
 696 # struct sockaddr field sin_len is only present on BSD systems.
 697 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 698 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 699 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 700 [#ifdef HAVE_SYS_TYPES_H
 701 #include <sys/types.h>
 702 #endif
 703 #include <netinet/in.h>])
 704
 705 AC_MSG_CHECKING(for __libc_stack_end)
 706 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 707 [AC_TRY_LINK([#include <stdio.h>
 708 extern char *__libc_stack_end;],
 709              [printf("%p", (char*) __libc_stack_end);],
 710              guile_cv_have_libc_stack_end=yes,
 711              guile_cv_have_libc_stack_end=no)])
 712 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 713
 714 if test $guile_cv_have_libc_stack_end = yes; then
 715   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 716            [Define if you have the __libc_stack_end variable.])
 717 fi
 718
 719 dnl Some systems do not declare this.  Some systems do declare it, as a
 720 dnl macro.  With cygwin it may be in a DLL.
 721
 722 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 723 AC_CACHE_VAL(guile_cv_have_h_errno,
 724 [AC_TRY_COMPILE([#include <netdb.h>],
 725 [int a = h_errno;],
 726 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 727 AC_MSG_RESULT($guile_cv_have_h_errno)
 728 if test $guile_cv_have_h_errno = yes; then
 729   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 730 fi
 731
 732 AC_MSG_CHECKING(whether uint32_t is defined)
 733 AC_CACHE_VAL(guile_cv_have_uint32_t,
 734   [AC_TRY_COMPILE([#include <sys/types.h>
 735                    #if HAVE_STDINT_H
 736                    #include <stdint.h>
 737                    #endif
 738                    #ifndef __MINGW32__
 739                    #include <netdb.h>
 740                    #endif],
 741                   [uint32_t a;],
 742                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 743 AC_MSG_RESULT($guile_cv_have_uint32_t)
 744 if test $guile_cv_have_uint32_t = yes; then
 745   AC_DEFINE(HAVE_UINT32_T, 1,
 746     [Define if uint32_t typedef is defined when netdb.h is include.])
 747 fi
 748
 749 AC_MSG_CHECKING(for working IPv6 support)
 750 AC_CACHE_VAL(guile_cv_have_ipv6,
 751 [AC_TRY_COMPILE([
 752 #ifdef HAVE_SYS_TYPES_H
 753 #include <sys/types.h>
 754 #endif
 755 #include <netinet/in.h>
 756 #include <sys/socket.h>],
 757 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 758 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 759 AC_MSG_RESULT($guile_cv_have_ipv6)
 760 if test $guile_cv_have_ipv6 = yes; then
 761   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 762 fi
 763
 764 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 765 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 766 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 767 [AC_TRY_COMPILE([
 768 #ifdef HAVE_SYS_TYPES_H
 769 #include <sys/types.h>
 770 #endif
 771 #include <netinet/in.h>],
 772 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 773 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 774 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 775 if test $guile_cv_have_sin6_scope_id = yes; then
 776   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 777     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 778 fi
 779
 780 # struct sockaddr_in6 field sin_len is only present on BSD systems
 781 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 782 [#ifdef HAVE_SYS_TYPES_H
 783 #include <sys/types.h>
 784 #endif
 785 #include <netinet/in.h>])
 786
 787 AC_MSG_CHECKING(whether localtime caches TZ)
 788 AC_CACHE_VAL(guile_cv_localtime_cache,
 789 [if test x$ac_cv_func_tzset = xyes; then
 790 AC_TRY_RUN([#include <time.h>
 791 #if STDC_HEADERS
 792 # include <stdlib.h>
 793 #endif
 794 extern char **environ;
 795 unset_TZ ()
 796 {
 797   char **from, **to;
 798   for (to = from = environ; (*to = *from); from++)
 799     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 800       to++;
 801 }
 802 char TZ_GMT0[] = "TZ=GMT0";
 803 char TZ_PST8[] = "TZ=PST8";
 804 main()
 805 {
 806   time_t now = time ((time_t *) 0);
 807   int hour_GMT0, hour_unset;
 808   if (putenv (TZ_GMT0) != 0)
 809     exit (1);
 810   hour_GMT0 = localtime (&now)->tm_hour;
 811   unset_TZ ();
 812   hour_unset = localtime (&now)->tm_hour;
 813   if (putenv (TZ_PST8) != 0)
 814     exit (1);
 815   if (localtime (&now)->tm_hour == hour_GMT0)
 816     exit (1);
 817   unset_TZ ();
 818   if (localtime (&now)->tm_hour != hour_unset)
 819     exit (1);
 820   exit (0);
 821 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 822 [# If we have tzset, assume the worst when cross-compiling.
 823 guile_cv_localtime_cache=yes])
 824 else
 825         # If we lack tzset, report that localtime does not cache TZ,
 826         # since we can't invalidate the cache if we don't have tzset.
 827         guile_cv_localtime_cache=no
 828 fi])dnl
 829 AC_MSG_RESULT($guile_cv_localtime_cache)
 830 if test $guile_cv_localtime_cache = yes; then
 831   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 832 fi
 833
 834 dnl Test whether system calls are restartable by default on the
 835 dnl current system.  If they are not, we put a loop around every system
 836 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 837 dnl change from the default behaviour.  On the other hand, if signals
 838 dnl are restartable then the loop is not installed and when libguile
 839 dnl initialises it also resets the behaviour of each signal to cause a
 840 dnl restart (in case a different runtime had a different default
 841 dnl behaviour for some reason: e.g., different versions of linux seem
 842 dnl to behave differently.)
 843
 844 AC_SYS_RESTARTABLE_SYSCALLS
 845
 846 if test "$enable_regex" = yes; then
 847    if test "$ac_cv_header_regex_h" = yes ||
 848       test "$ac_cv_header_rxposix_h" = yes ||
 849       test "$ac_cv_header_rx_rxposix_h" = yes; then
 850      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 851      [AC_CHECK_LIB(rx, main)
 852       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 853      [AC_CHECK_LIB(regex, main)
 854       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 855      )
 856      dnl The following should not be necessary, but for some reason
 857      dnl autoheader misses it if we don't include it!
 858      if test "$ac_cv_func_regcomp_norx" = yes ||
 859         test "$ac_cv_func_regcomp_regex" = yes ||
 860         test "$ac_cv_func_regcomp_rx" = yes; then
 861        AC_DEFINE(HAVE_REGCOMP, 1,
 862          [This is included as part of a workaround for a autoheader bug.])
 863      fi
 864    fi
 865 fi
 866
 867 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 868
 869 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 870
 871 # Reasons for testing:
 872 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 873 #                                older systems
 874 #   sincos - GLIBC extension
 875 #
 876 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
 877
 878 # C99 specifies isinf and isnan as macros.
 879 # HP-UX provides only macros, no functions.
 880 # glibc 2.3.2 provides both macros and functions.
 881 # IRIX 6.5 and Solaris 8 only provide functions.
 882 #
 883 # The following tests detect isinf and isnan either as functions or as
 884 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
 885 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
 886 #
 887 AC_MSG_CHECKING([for isinf])
 888 AC_LINK_IFELSE(
 889 [#include <math.h>
 890 int main () { return (isinf(0.0) != 0); }],
 891   [AC_MSG_RESULT([yes])
 892    AC_DEFINE(HAVE_ISINF, 1,
 893              [Define to 1 if you have the `isinf' macro or function.])],
 894   [AC_MSG_RESULT([no])])
 895 AC_MSG_CHECKING([for isnan])
 896 AC_LINK_IFELSE(
 897 [#include <math.h>
 898 #ifdef __MINGW32__
 899 #define isnan _isnan
 900 #endif
 901 int main () { return (isnan(0.0) != 0); }],
 902   [AC_MSG_RESULT([yes])
 903    AC_DEFINE(HAVE_ISNAN, 1,
 904              [Define to 1 if you have the `isnan' macro or function.])],
 905   [AC_MSG_RESULT([no])])
 906
 907 # We must have a proper stack-using alloca in order for stack-copying
 908 # continuations to work properly.  If we don't find a native one,
 909 # abort.
 910
 911 AC_FUNC_ALLOCA
 912 if test "$ALLOCA" = "alloca.o"
 913 then
 914   AC_ERROR([No native alloca found.])
 915 fi
 916
 917 AC_CHECK_MEMBERS([struct stat.st_rdev])
 918 AC_CHECK_MEMBERS([struct stat.st_blksize])
 919
 920 AC_STRUCT_ST_BLOCKS
 921
 922 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 923   [AC_TRY_CPP([#include <sys/stat.h>
 924                #ifndef S_ISLNK
 925                #error no S_ISLNK
 926                #endif],
 927                ac_cv_macro_S_ISLNK=yes,
 928                ac_cv_macro_S_ISLNK=no)])
 929 if test $ac_cv_macro_S_ISLNK = yes; then
 930   AC_DEFINE(HAVE_S_ISLNK, 1,
 931     [Define this if your system defines S_ISLNK in sys/stat.h.])
 932 fi
 933
 934 AC_STRUCT_TIMEZONE
 935 GUILE_STRUCT_UTIMBUF
 936
 937 #--------------------------------------------------------------------
 938 #
 939 # Which way does the stack grow?
 940 #
 941 #--------------------------------------------------------------------
 942
 943 SCM_I_GSC_STACK_GROWS_UP=0
 944 AC_TRY_RUN(aux (l) unsigned long l;
 945              { int x; exit (l >= ((unsigned long)&x)); }
 946            main () { int q; aux((unsigned long)&q); },
 947            [SCM_I_GSC_STACK_GROWS_UP=1],
 948            [],
 949            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
 950
 951 AC_CHECK_SIZEOF(float)
 952 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
 953     AC_DEFINE(SCM_SINGLES, 1,
 954               [Define this if floats are the same size as longs.])
 955 fi
 956
 957 AC_MSG_CHECKING(for struct linger)
 958 AC_CACHE_VAL(scm_cv_struct_linger,
 959         AC_TRY_COMPILE([
 960 #include <sys/types.h>
 961 #include <sys/socket.h>],
 962                         [struct linger lgr;  lgr.l_linger = 100],
 963                         scm_cv_struct_linger="yes",
 964                         scm_cv_struct_linger="no"))
 965 AC_MSG_RESULT($scm_cv_struct_linger)
 966 if test $scm_cv_struct_linger = yes; then
 967         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 968           [Define this if your system defines struct linger, for use with the
 969            getsockopt and setsockopt system calls.])
 970 fi
 971
 972
 973 AC_MSG_CHECKING(for struct timespec)
 974 AC_CACHE_VAL(scm_cv_struct_timespec,
 975         AC_TRY_COMPILE([
 976 #include <time.h>],
 977                         [struct timespec t;  t.tv_nsec = 100],
 978                         scm_cv_struct_timespec="yes",
 979                         scm_cv_struct_timespec="no"))
 980 AC_MSG_RESULT($scm_cv_struct_timespec)
 981 if test $scm_cv_struct_timespec = yes; then
 982   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 983     [Define this if your system defines struct timespec via <time.h>.])
 984 fi
 985
 986 #--------------------------------------------------------------------
 987 #
 988 # Flags for thread support
 989 #
 990 #--------------------------------------------------------------------
 991
 992 SCM_I_GSC_USE_PTHREAD_THREADS=0
 993 SCM_I_GSC_USE_NULL_THREADS=0
 994 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
 995 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
 996
 997 ### What thread package has the user asked for?
 998 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 999             , with_threads=yes)
1000
1001 case "$with_threads" in
1002   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1003     ACX_PTHREAD(CC="$PTHREAD_CC"
1004       LIBS="$PTHREAD_LIBS $LIBS"
1005       SCM_I_GSC_USE_PTHREAD_THREADS=1
1006       with_threads="pthreads",
1007       with_threads="null")
1008
1009     old_CFLAGS="$CFLAGS"
1010     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1011     AC_CHECK_FUNCS(pthread_attr_getstack)
1012     CFLAGS="$old_CFLAGS"
1013
1014     # On Solaris, sched_yield lives in -lrt.
1015     AC_SEARCH_LIBS(sched_yield, rt)
1016
1017   ;;
1018 esac
1019
1020 case "$with_threads" in
1021   "pthreads")
1022   ;;
1023   "no" | "null")
1024     SCM_I_GSC_USE_NULL_THREADS=1
1025     with_threads="null-threads"
1026   ;;
1027   * )
1028     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1029   ;;
1030 esac
1031
1032 AC_MSG_CHECKING(what kind of threads to support)
1033 AC_MSG_RESULT($with_threads)
1034
1035 ## Cross building
1036 if test "$cross_compiling" = "yes"; then
1037   AC_MSG_CHECKING(cc for build)
1038   ## /usr/bin/cc still uses wrong assembler
1039   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1040   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1041 else
1042   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1043 fi
1044
1045 ## AC_MSG_CHECKING("if we are cross compiling")
1046 ## AC_MSG_RESULT($cross_compiling)
1047 if test "$cross_compiling" = "yes"; then
1048    AC_MSG_RESULT($CC_FOR_BUILD)
1049 fi
1050
1051 ## No need as yet to be more elaborate
1052 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1053
1054 AC_SUBST(cross_compiling)
1055 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1056 AC_SUBST(CCLD_FOR_BUILD)
1057
1058 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1059 ## --HOST is the platform that PACKAGE is compiled for.
1060 HOST_CC="$CC_FOR_BUILD"
1061 AC_SUBST(HOST_CC)
1062
1063 if test "$cross_compiling" = "yes"; then
1064   AC_MSG_CHECKING(guile for build)
1065   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1066 else
1067   GUILE_FOR_BUILD='$(preinstguile)'
1068 fi
1069
1070 ## AC_MSG_CHECKING("if we are cross compiling")
1071 ## AC_MSG_RESULT($cross_compiling)
1072 if test "$cross_compiling" = "yes"; then
1073    AC_MSG_RESULT($GUILE_FOR_BUILD)
1074 fi
1075 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1076 AC_SUBST(GUILE_FOR_BUILD)
1077
1078 ## If we're using GCC, ask for aggressive warnings.
1079 case "$GCC" in
1080   yes )
1081     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1082     ## much stuff with generic function pointers for that to really be
1083     ## less than exasperating.
1084     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1085     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1086     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1087     # Do this here so we don't screw up any of the tests above that might
1088     # not be "warning free"
1089     if test "${GUILE_ERROR_ON_WARNING}" = yes
1090     then
1091         CFLAGS="${CFLAGS} -Werror"
1092         enable_compile_warnings=no
1093     fi
1094     ;;
1095 esac
1096
1097 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
1098 ## -- I'm disabling it for now in the hopes that the newer autoconf
1099 ## will DTRT -- if not, we need to fix up the sed command to match the
1100 ## others...
1101 ##
1102 ## Remove fileblocks.o from the object list.  This file gets added by
1103 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
1104 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
1105
1106 ## If we're creating a shared library (using libtool!), then we'll
1107 ## need to generate a list of .lo files corresponding to the .o files
1108 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1109 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1110
1111 ## We also need to create corresponding .doc and .x files
1112 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1113 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1114
1115 AC_SUBST(GUILE_MAJOR_VERSION)
1116 AC_SUBST(GUILE_MINOR_VERSION)
1117 AC_SUBST(GUILE_MICRO_VERSION)
1118 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1119 AC_SUBST(GUILE_VERSION)
1120
1121 #######################################################################
1122 # library versioning
1123
1124 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1125 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1126 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1127 AC_SUBST(LIBGUILE_INTERFACE)
1128
1129 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1130 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1131 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1132 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1133 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1134
1135 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1136 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1137 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1138 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1139 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1140
1141 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1142 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1143 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1144 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1145 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1146
1147 #######################################################################
1148
1149 dnl Tell guile-config what flags guile users should compile and link with.
1150 GUILE_LIBS="$LDFLAGS $LIBS"
1151 GUILE_CFLAGS="$PTHREAD_CFLAGS"
1152 AC_SUBST(GUILE_LIBS)
1153 AC_SUBST(GUILE_CFLAGS)
1154
1155 AC_SUBST(AWK)
1156 AC_SUBST(LIBLOBJS)
1157 AC_SUBST(EXTRA_DOT_DOC_FILES)
1158 AC_SUBST(EXTRA_DOT_X_FILES)
1159
1160 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1161 top_builddir_absolute=`pwd`
1162 AC_SUBST(top_builddir_absolute)
1163 top_srcdir_absolute=`(cd $srcdir && pwd)`
1164 AC_SUBST(top_srcdir_absolute)
1165
1166 # Additional SCM_I_GSC definitions are above.
1167 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1168 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1169 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1170 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1171 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1172 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1173 AC_SUBST([SCM_I_GSC_C_INLINE])
1174 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1175
1176 AC_CONFIG_FILES([
1177   Makefile
1178   am/Makefile
1179   benchmark-suite/Makefile
1180   doc/Makefile
1181   doc/goops/Makefile
1182   doc/r5rs/Makefile
1183   doc/ref/Makefile
1184   doc/tutorial/Makefile
1185   emacs/Makefile
1186   examples/Makefile
1187   examples/box-dynamic-module/Makefile
1188   examples/box-dynamic/Makefile
1189   examples/box-module/Makefile
1190   examples/box/Makefile
1191   examples/modules/Makefile
1192   examples/safe/Makefile
1193   examples/scripts/Makefile
1194   guile-config/Makefile
1195   ice-9/Makefile
1196   ice-9/debugger/Makefile
1197   ice-9/debugger/breakpoints/Makefile
1198   lang/Makefile
1199   lang/elisp/Makefile
1200   lang/elisp/internals/Makefile
1201   lang/elisp/primitives/Makefile
1202   libguile/Makefile
1203   oop/Makefile
1204   oop/goops/Makefile
1205   scripts/Makefile
1206   srfi/Makefile
1207   test-suite/Makefile
1208   test-suite/standalone/Makefile
1209 ])
1210
1211 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1212 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1213 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1214 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1215 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1216 AC_CONFIG_FILES([libguile/guile-snarf],
1217                 [chmod +x libguile/guile-snarf])
1218 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1219                 [chmod +x libguile/guile-doc-snarf])
1220 AC_CONFIG_FILES([libguile/guile-func-name-check],
1221                 [chmod +x libguile/guile-func-name-check])
1222 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1223                 [chmod +x libguile/guile-snarf-docs])
1224
1225 AC_OUTPUT
1226
1227 dnl Local Variables:
1228 dnl comment-start: "dnl "
1229 dnl comment-end: ""
1230 dnl comment-start-skip: "\\bdnl\\b\\s *"
1231 dnl End: