configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 AC_INIT(Makefile.in)
   4 . $srcdir/GUILE-VERSION
   5 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
   6 AM_MAINTAINER_MODE
   7 AM_CONFIG_HEADER(libguile/scmconfig.h)
   8
   9 #--------------------------------------------------------------------
  10 #
  11 # User options
  12 #
  13 #--------------------------------------------------------------------
  14
  15 AC_ARG_ENABLE(dynamic-linking,
  16   [  --enable-dynamic-linking  Include support for dynamic linking],,
  17   enable_dynamic_linking=yes)
  18
  19 AC_ARG_ENABLE(guile-debug,
  20 [  --enable-guile-debug    Include internal debugging functions])
  21 if test "$enableval" = y || test "$enableval" = yes; then
  22   AC_DEFINE(GUILE_DEBUG)
  23 fi
  24
  25 dnl The --disable-debug used to control these two.  But now they are
  26 dnl a required part of the distribution.
  27 AC_DEFINE(DEBUG_EXTENSIONS)
  28 AC_DEFINE(READER_EXTENSIONS)
  29
  30 #--------------------------------------------------------------------
  31
  32 AC_PROG_CC
  33 AC_PROG_CPP
  34 AM_PROG_LIBTOOL
  35
  36 AC_AIX
  37 AC_ISC_POSIX
  38 AC_MINIX
  39
  40 AC_C_CONST
  41
  42 AC_HEADER_STDC
  43 AC_HEADER_DIRENT
  44 AC_HEADER_TIME
  45 AC_HEADER_SYS_WAIT
  46 AC_CHECK_HEADERS(libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
  47 GUILE_HEADER_LIBC_WITH_UNISTD
  48
  49 AC_TYPE_GETGROUPS
  50 AC_TYPE_SIGNAL
  51 AC_TYPE_MODE_T
  52
  53 AC_CHECK_LIB(m, main)
  54 AC_CHECK_FUNCS(gethostbyname)
  55 if test $ac_cv_func_gethostbyname = no; then
  56     AC_CHECK_LIB(nsl, gethostbyname)
  57 fi
  58 AC_CHECK_FUNCS(connect)
  59 if test $ac_cv_func_connect = no; then
  60     AC_CHECK_LIB(socket, connect)
  61 fi
  62 AC_CHECK_LIB(termcap, tgoto)
  63 AC_CHECK_LIB(readline, readline)
  64 AC_CHECK_FUNCS(rl_clear_signals rl_cleanup_after_signal)
  65
  66 AC_CACHE_CHECK([for rl_getc_function pointer in readline],
  67                ac_cv_var_rl_getc_function,
  68                [AC_TRY_LINK([
  69 #include <stdio.h>
  70 #include <readline/readline.h>],
  71                             [rl_getc_function;],
  72                             [ac_cv_var_rl_getc_function=yes],
  73                             [ac_cv_var_rl_getc_function=no])])
  74 if test "$ac_cv_var_rl_getc_function" = "yes"; then
  75   AC_DEFINE(HAVE_RL_GETC_FUNCTION)
  76 fi
  77
  78 if test $ac_cv_lib_readline_readline = yes -a $ac_cv_var_rl_getc_function = no; then
  79   echo 'Warning: libreadline is too old on your system.  Need >= 2.1.'
  80 fi
  81
  82 # Checks for dynamic linking
  83
  84 if test "$enable_dynamic_linking" = "yes"; then
  85
  86 AC_CHECK_LIB(dl,dlopen)
  87 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
  88   AC_CHECK_FUNCS(dlopen)
  89   AC_DEFINE(DYNAMIC_LINKING)
  90 else
  91 AC_CHECK_LIB(dld,dld_link)
  92 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
  93   AC_DEFINE(DYNAMIC_LINKING)
  94 else
  95 AC_CHECK_FUNCS(shl_load)
  96 if test "$ac_cv_func_shl_load" = "yes"; then
  97   AC_DEFINE(DYNAMIC_LINKING)
  98 else
  99 AC_CHECK_FUNCS(dlopen)
 100 if test "$ac_cv_func_dlopen" = "yes"; then
 101   AC_DEFINE(DYNAMIC_LINKING)
 102 fi
 103 fi
 104 fi
 105 fi
 106
 107 fi
 108
 109 GUILE_DLSYM_USCORE
 110
 111 AC_CHECK_FUNCS(ctermid ftime getcwd geteuid gethostent gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep)
 112
 113 ### Some systems don't declare some functions.  On such systems, we
 114 ### need to at least provide our own K&R-style declarations.
 115
 116 ### GUILE_FUNC_DECLARED(function, headerfile)
 117
 118 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 119 ### not there, #define MISSING_FUNCTION_DECL.
 120 AC_DEFUN(GUILE_FUNC_DECLARED, [
 121   AC_CACHE_CHECK(for $1 declaration, ac_cv_func_$1_declared,
 122     AC_EGREP_HEADER($1, $2,
 123                     ac_cv_func_$1_declared=yes,
 124                     ac_cv_func_$1_declared=no))
 125   if test [x$ac_cv_func_]$1[_declared] = xno; then
 126     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 127   fi
 128 ])
 129
 130 GUILE_FUNC_DECLARED(strptime, time.h)
 131 GUILE_FUNC_DECLARED(bzero, string.h)
 132 GUILE_FUNC_DECLARED(sleep, unistd.h)
 133 GUILE_FUNC_DECLARED(usleep, unistd.h)
 134
 135 # On some systems usleep has no return value
 136 AC_EGREP_HEADER(changequote(<, >)<void[         ][      ]*usleep>changequote([, ]),
 137   /usr/include/unistd.h,
 138   AC_DEFINE(USLEEP_RETURNS_VOID)
 139 )
 140
 141
 142 dnl <GNU-WIN32 hacks>
 143
 144 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 145 if test -n "$have_sys_un_h" ; then
 146 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 147 fi
 148
 149 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 150
 151 dnl I don't know what this prefixing of cygwin32_ is for.
 152 dnl scmconfig.h wasn't updated with the test results.
 153 dnl so use AC_CHECK_FUNCS for now.
 154
 155 dnl how about:
 156 dnl save confdefs.h
 157 dnl if test $ac_cv_cigwin = yes; then
 158 dnl   modify confdefs.h
 159 dnl fi
 160 dnl AC_CHECK_FUNCS...
 161 dnl restore confdefs.h
 162
 163 dnl cp confdefs.h confdefs.h.bak
 164 dnl for func in sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof ; do
 165 dnl cp confdefs.h.bak confdefs.h
 166 dnl cat >> confdefs.h << EOF
 167 dnl #ifdef __CYGWIN32__
 168 dnl #define $func cygwin32_$func
 169 dnl #endif
 170 dnl EOF
 171 dnl AC_CHECK_FUNC($func)
 172 dnl done
 173 dnl cp confdefs.h.bak confdefs.h
 174
 175 AC_CHECK_FUNCS(sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof)
 176
 177 dnl </GNU-WIN32 hacks>
 178
 179 AC_CACHE_CHECK([for restartable system calls], scm_cv_restarts,
 180         if test $ac_cv_func_sigaction = yes; then
 181                 [AC_TRY_COMPILE([#include <signal.h>],
 182                                 [int a = SA_RESTART],
 183                                 scm_cv_restarts=yes,
 184                                 scm_cv_restarts=no)]
 185         else
 186                 scm_cv_restarts=no
 187         fi)
 188 if test $scm_cv_restarts = yes; then
 189         AC_DEFINE(HAVE_RESTARTS)
 190 fi
 191
 192 if test "$ac_cv_header_regex_h" = yes ||
 193    test "$ac_cv_header_rxposix_h" = yes ||
 194    test "$ac_cv_header_rx_rxposix_h" = yes; then
 195   GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 196   [AC_CHECK_LIB(rx, main)
 197    GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 198   )
 199   dnl The following should not be necessary, but for some reason
 200   dnl autoheader misses it if we don't include it!
 201   if test "$ac_cv_func_regcomp_norx" = yes ||
 202      test "$ac_cv_func_regcomp_rx" = yes; then
 203     AC_DEFINE(HAVE_REGCOMP)
 204   fi
 205 fi
 206
 207 AC_REPLACE_FUNCS(inet_aton putenv strerror)
 208
 209 # When testing for the presence of alloca, we need to add alloca.o
 210 # explicitly to LIBOBJS to make sure that it is translated to
 211 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 212 AC_FUNC_ALLOCA
 213 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 214
 215 AC_STRUCT_ST_RDEV
 216 AC_STRUCT_ST_BLKSIZE
 217
 218 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 219 # LIBOBJS, which we don't need.  This seems more direct.
 220 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 221 [AC_TRY_COMPILE([#include <sys/types.h>
 222 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 223 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 224 if test $ac_cv_struct_st_blocks = yes; then
 225   AC_DEFINE(HAVE_ST_BLOCKS)
 226 fi
 227
 228 AC_STRUCT_TIMEZONE
 229 GUILE_STRUCT_UTIMBUF
 230
 231 #--------------------------------------------------------------------
 232 #
 233 # Which way does the stack grow?
 234 #
 235 #--------------------------------------------------------------------
 236
 237 AC_TRY_RUN(aux (l) unsigned long l;
 238              { int x; exit (l >= ((unsigned long)&x)); }
 239            main () { int q; aux((unsigned long)&q); },
 240            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 241
 242
 243 AC_TRY_RUN(main () { exit (sizeof(float) != sizeof(long)); },
 244            AC_DEFINE(SCM_SINGLES),,AC_DEFINE(SCM_SINGLES)
 245            AC_MSG_WARN(Guessing that sizeof(long) == sizeof(float) -- see scmconfig.h.in))
 246
 247 AC_MSG_CHECKING(for struct linger)
 248 AC_CACHE_VAL(scm_cv_struct_linger,
 249         AC_TRY_COMPILE([
 250 #include <sys/types.h>
 251 #include <sys/socket.h>],
 252                         [struct linger lgr;  lgr.l_linger = 100],
 253                         scm_cv_struct_linger="yes",
 254                         scm_cv_struct_linger="no"))
 255 AC_MSG_RESULT($scm_cv_struct_linger)
 256 if test $scm_cv_struct_linger = yes; then
 257         AC_DEFINE(HAVE_STRUCT_LINGER)
 258 fi
 259
 260 #--------------------------------------------------------------------
 261 #
 262 # How can you violate a stdio abstraction by setting a stream's fd?
 263 #
 264 #--------------------------------------------------------------------
 265
 266 AC_MSG_CHECKING(how to set a stream file descriptor)
 267 AC_CACHE_VAL(scm_cv_fd_setter,
 268         AC_TRY_COMPILE([#include <stdio.h>],
 269                         [stdout->_file = 1],
 270                         scm_cv_fd_setter="_file",
 271         AC_TRY_COMPILE([#include <stdio.h>],
 272                         [stdout->__file = 1],
 273                         scm_cv_fd_setter="__file",
 274         AC_TRY_COMPILE([#include <stdio.h>],
 275                         [stdout->_fileno = 1],
 276                         scm_cv_fd_setter="_fileno",
 277                         scm_cv_fd_setter=""))))
 278
 279 if test "$scm_cv_fd_setter"; then
 280         AC_MSG_RESULT($scm_cv_fd_setter)
 281         AC_DEFINE_UNQUOTED(FD_SETTER, $scm_cv_fd_setter)
 282 else
 283         AC_MSG_RESULT(we couldn't do it!)
 284 fi
 285
 286 #--------------------------------------------------------------------
 287 # How to find out whether a FILE structure contains buffered data.
 288 # From Tk we have the following list:
 289 #               _cnt:           Most UNIX systems
 290 #               __cnt:          HPUX and SCO
 291 #               _r:             BSD
 292 #               readCount:      Sprite
 293 #       Or, in GNU libc there are two fields, _gptr and _egptr, which
 294 #       have to be compared.
 295 #       These can also be known as _IO_read_ptr and _IO_read_end.
 296 #--------------------------------------------------------------------
 297
 298 AC_MSG_CHECKING(how to get buffer char count from FILE structure)
 299 AC_CACHE_VAL(scm_cv_struct_file_count,
 300         AC_TRY_COMPILE([#include <stdio.h>],
 301                         [FILE *f = stdin; f->_cnt = 0],
 302                         scm_cv_struct_file_count="_cnt",
 303         AC_TRY_COMPILE([#include <stdio.h>],
 304                         [FILE *f = stdin; f->__cnt = 0],
 305                         scm_cv_struct_file_count="__cnt",
 306         AC_TRY_COMPILE([#include <stdio.h>],
 307                         [FILE *f = stdin; f->_r = 0],
 308                         scm_cv_struct_file_count="_r",
 309         AC_TRY_COMPILE([#include <stdio.h>],
 310                         [FILE *f = stdin; f->readCount = 0],
 311                         scm_cv_struct_file_count="readCount",
 312         scm_cv_struct_file_count="")))))
 313 if test "$scm_cv_struct_file_count"; then
 314         AC_MSG_RESULT($scm_cv_struct_file_count)
 315         AC_DEFINE_UNQUOTED(FILE_CNT_FIELD, $scm_cv_struct_file_count)
 316 else
 317 AC_CACHE_VAL(scm_cv_struct_file_gptr,
 318         AC_TRY_COMPILE([#include <stdio.h>],
 319                         [FILE *f = stdin; f->_gptr = f->egptr;],
 320                         scm_cv_struct_file_gptr=1,
 321         scm_cv_struct_file_gptr=""))
 322 if test "$scm_cv_struct_gptr"; then
 323         AC_MSG_RESULT(gptr)
 324         AC_DEFINE_UNQUOTED(FILE_CNT_GPTR, $scm_cv_struct_file_gptr)
 325 else
 326 AC_CACHE_VAL(scm_cv_struct_file_readptr,
 327         AC_TRY_COMPILE([#include <stdio.h>],
 328                         [FILE *f = stdin; f->_IO_read_ptr = f->_IO_read_end;],
 329                         scm_cv_struct_file_readptr=1))
 330 if test "$scm_cv_struct_file_readptr"; then
 331         AC_MSG_RESULT(read_ptr)
 332         AC_DEFINE_UNQUOTED(FILE_CNT_READPTR, $scm_cv_struct_file_readptr)
 333 else
 334         AC_MSG_RESULT(we couldn't do it!)
 335 fi
 336 fi
 337 fi
 338
 339 #--------------------------------------------------------------------
 340 #
 341 # Flags for thread support
 342 #
 343 #--------------------------------------------------------------------
 344
 345 ### What thread package has the user asked for?
 346 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 347             , with_threads=no)
 348
 349 ### Turn $with_threads into either the name of a threads package, like
 350 ### `qt', or `no', meaning that threads should not be supported.
 351 AC_MSG_CHECKING(whether to support threads)
 352 case "$with_threads" in
 353   "yes" | "qt" | "coop" | "")
 354     with_threads=qt
 355   ;;
 356   "no" )
 357   ;;
 358   * )
 359     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 360   ;;
 361 esac
 362 AC_MSG_RESULT($with_threads)
 363
 364 ## Make sure the threads package we've chosen is actually supported on
 365 ## the present platform.
 366 case "${with_threads}" in
 367   "qt" )
 368     ## This configures the QuickThreads package, and sets or clears
 369     ## the THREAD_PACKAGE variable if qthreads don't configure
 370     ## correctly.
 371     QTHREADS_CONFIGURE
 372    ;;
 373 esac
 374
 375 ## If we're using threads, bring in some other parts of Guile which
 376 ## work with them.
 377 if test "${THREAD_PACKAGE}" != "" ; then
 378   AC_DEFINE(USE_THREADS, 1)
 379
 380   ## Include the Guile thread interface in the library...
 381   LIBOBJS="$LIBOBJS threads.o"
 382
 383   ## ... and tell it which package to talk to.
 384   case "${THREAD_PACKAGE}" in
 385     "QT" )
 386       AC_DEFINE(USE_COOP_THREADS, 1)
 387     ;;
 388     * )
 389       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 390     ;;
 391   esac
 392
 393   ## Bring in scm_internal_select, if appropriate.
 394   if test $ac_cv_func_gettimeofday = yes &&
 395      test $ac_cv_func_select = yes; then
 396     LIBOBJS="$LIBOBJS iselect.o"
 397     AC_DEFINE(GUILE_ISELECT, 1)
 398   fi
 399 fi
 400
 401 ## If we're using GCC, ask for aggressive warnings.
 402 case "$GCC" in
 403   yes )
 404     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 405     ## much stuff with generic function pointers for that to really be
 406     ## less than exasperating.
 407     CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wmissing-prototypes" ;;
 408 esac
 409
 410 AC_PROG_AWK
 411
 412 ## If we're creating a shared library (using libtool!), then we'll
 413 ## need to generate a list of .lo files corresponding to the .o files
 414 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 415 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 416
 417 AC_SUBST(GUILE_MAJOR_VERSION)
 418 AC_SUBST(GUILE_MINOR_VERSION)
 419 AC_SUBST(GUILE_VERSION)
 420
 421 dnl Tell guile-config what flags guile users should link against.
 422 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 423 AC_SUBST(GUILE_LIBS)
 424
 425 dnl timestamping the interpreter and scheme libraries:
 426 dnl
 427 dnl Help us notice when we're running one version of the Guile
 428 dnl interpreter against a different version of the ice-9 Scheme code.
 429 dnl This will definitely detect version skew due to differing
 430 dnl snapshots and releases, but may not catch skew for the developers.
 431 dnl Hopefully it will not detect skew when there is none; if that
 432 dnl happens, the warnings will be useless, and we should remove this.
 433 GUILE_STAMP="`date`"
 434 AC_SUBST(GUILE_STAMP)
 435
 436 AC_SUBST(AWK)
 437 AC_SUBST(LIBLOBJS)
 438
 439 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf ice-9/Makefile ice-9/version.scm qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf])
 440
 441 dnl Local Variables:
 442 dnl comment-start: "dnl "
 443 dnl comment-end: ""
 444 dnl comment-start-skip: "\\bdnl\\b\\s *"
 445 dnl End: