configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000, 2001 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_PREREQ(2.50)
  24
  25 AC_INIT
  26 AC_CONFIG_SRCDIR([Makefile.in])
  27 . $srcdir/GUILE-VERSION
  28 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  29 AM_MAINTAINER_MODE
  30 AM_CONFIG_HEADER(libguile/scmconfig.h)
  31
  32 #--------------------------------------------------------------------
  33 #
  34 # Independent Subdirectories
  35 #
  36 #--------------------------------------------------------------------
  37
  38 AC_CONFIG_SUBDIRS(guile-readline)
  39
  40 #--------------------------------------------------------------------
  41 #
  42 # User options
  43 #
  44 #--------------------------------------------------------------------
  45
  46 AC_ARG_ENABLE(error-on-warning,
  47   [  --enable-error-on-warning    treat compile warnings as errors],
  48   [case "${enableval}" in
  49      yes | y) CFLAGS="${CFLAGS} -Werror"; enable_compile_warnings=no ;;
  50      no | n)  ;;
  51      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  52    esac])
  53
  54 AC_ARG_ENABLE(debug-freelist,
  55   [  --enable-debug-freelist include garbage collector freelist debugging code],
  56   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  57     AC_DEFINE(GUILE_DEBUG_FREELIST)
  58   fi)
  59
  60 AC_ARG_ENABLE(debug-malloc,
  61   [  --enable-debug-malloc   include malloc debugging code],
  62   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  63     AC_DEFINE(GUILE_DEBUG_MALLOC)
  64   fi)
  65
  66 AC_ARG_ENABLE(guile-debug,
  67   [  --enable-guile-debug    include internal debugging functions],
  68   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  69     AC_DEFINE(GUILE_DEBUG)
  70   fi)
  71
  72 AC_ARG_ENABLE(arrays,
  73   [  --disable-arrays        omit array and uniform array support],,
  74   enable_arrays=yes)
  75
  76 AC_ARG_ENABLE(posix,
  77   [  --disable-posix         omit posix interfaces],,
  78   enable_posix=yes)
  79
  80 AC_ARG_ENABLE(networking,
  81   [  --disable-networking    omit networking interfaces],,
  82   enable_networking=yes)
  83
  84 AC_ARG_ENABLE(regex,
  85   [  --disable-regex         omit regular expression interfaces],,
  86   enable_regex=yes)
  87
  88 AC_ARG_ENABLE(htmldoc,
  89   [  --enable-htmldoc        build HTML documentation as well as Info],
  90   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  91      htmldoc_enabled=yes
  92      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  93      if test "$TEXI2HTML" = "not found"; then
  94        echo
  95        echo Building HTML documentation requires the \`texi2html\' program,
  96        echo which appears not to be present on your machine.
  97        echo
  98        echo \`texi2html\' is available from
  99        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
 100        echo
 101        echo In the meantime, to build the guile-doc distribution
 102        echo without HTML enabled, please rerun \`./configure\' without
 103        echo the \`--enable-htmldoc\' option.
 104        exit -1
 105      fi
 106    fi])
 107
 108 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
 109
 110 AC_ARG_ENABLE(deprecated,
 111   [  --disable-deprecated    omit deprecated features [no]])
 112
 113 if test "$enable_deprecated" = no; then
 114   AC_DEFINE(SCM_ENABLE_DEPRECATED, 0)
 115 else
 116   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 117     warn_default=summary
 118   elif test "$enable_deprecated" = shutup; then
 119     warn_default=no
 120   else
 121     warn_default=$enable_deprecated
 122   fi
 123   AC_DEFINE(SCM_ENABLE_DEPRECATED, 1)
 124   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default")
 125 fi
 126
 127 dnl The --disable-debug used to control these two.  But now they are
 128 dnl a required part of the distribution.
 129 AC_DEFINE(DEBUG_EXTENSIONS)
 130 AC_DEFINE(READER_EXTENSIONS)
 131
 132 AC_ARG_ENABLE(elisp,
 133   [  --disable-elisp         omit Emacs Lisp support],,
 134   enable_elisp=yes)
 135
 136 dnl files which are destined for separate modules.
 137
 138 if test "$enable_arrays" = yes; then
 139    LIBOBJS="$LIBOBJS ramap.o unif.o"
 140    AC_DEFINE(HAVE_ARRAYS)
 141 fi
 142
 143 if test "$enable_posix" = yes; then
 144    LIBOBJS="$LIBOBJS filesys.o posix.o"
 145    AC_DEFINE(HAVE_POSIX)
 146 fi
 147
 148 if test "$enable_networking" = yes; then
 149    LIBOBJS="$LIBOBJS net_db.o socket.o"
 150    AC_DEFINE(HAVE_NETWORKING)
 151 fi
 152
 153 if test "$enable_debug_malloc" = yes; then
 154    LIBOBJS="$LIBOBJS debug-malloc.o"
 155 fi
 156
 157 if test "$enable_elisp" = yes; then
 158    AC_DEFINE(SCM_ENABLE_ELISP)
 159 fi
 160
 161 #--------------------------------------------------------------------
 162
 163 dnl Some more checks for Win32
 164 AC_CYGWIN
 165 AC_MINGW32
 166 AC_LIBTOOL_WIN32_DLL
 167
 168 AC_LIBLTDL_INSTALLABLE
 169 AC_CONFIG_SUBDIRS(libltdl)
 170
 171 AC_PROG_INSTALL
 172 AC_PROG_CC
 173 AC_PROG_CPP
 174 AC_LIBTOOL_DLOPEN
 175
 176 AC_AIX
 177 AC_ISC_POSIX
 178 AC_MINIX
 179
 180 AM_PROG_CC_STDC
 181 AM_PROG_LIBTOOL
 182
 183 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
 184 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
 185
 186 AC_C_CONST
 187 AC_C_INLINE
 188 AC_C_BIGENDIAN
 189
 190 if test "$ac_cv_c_inline" != no; then
 191   AC_DEFINE(HAVE_INLINE)
 192 fi
 193
 194 AC_CHECK_SIZEOF(short)
 195 AC_CHECK_SIZEOF(int)
 196 AC_CHECK_SIZEOF(long)
 197 AC_CHECK_SIZEOF(size_t)
 198
 199 dnl Check for integral types that can represent the range of pointers.
 200 dnl If these types don't exist on this platform, they are replaced by
 201 dnl "unsigned long" and "long", respectively.
 202
 203 AC_CHECK_HEADERS(stdint.h)
 204 AC_CHECK_HEADERS(inttypes.h)
 205 AC_CHECK_SIZEOF(uintptr_t)
 206 AC_CHECK_SIZEOF(ptrdiff_t)
 207
 208 AC_CHECK_SIZEOF(long long)
 209
 210 AC_CHECK_SIZEOF(void *)
 211
 212 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 213   AC_MSG_ERROR(sizes of long and void* are not identical)
 214 fi
 215
 216 AC_HEADER_STDC
 217 AC_HEADER_DIRENT
 218 AC_HEADER_TIME
 219 AC_HEADER_SYS_WAIT
 220 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h direct.h)
 221 GUILE_HEADER_LIBC_WITH_UNISTD
 222
 223 AC_TYPE_GETGROUPS
 224 AC_TYPE_SIGNAL
 225 AC_TYPE_MODE_T
 226
 227 AC_CHECK_LIB(m, main)
 228 AC_CHECK_FUNCS(gethostbyname)
 229 if test $ac_cv_func_gethostbyname = no; then
 230     AC_CHECK_LIB(nsl, gethostbyname)
 231 fi
 232 AC_CHECK_FUNCS(connect)
 233 if test $ac_cv_func_connect = no; then
 234     AC_CHECK_LIB(socket, connect)
 235 fi
 236
 237 dnl
 238 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 239 dnl
 240 EXTRA_DEFS=""
 241 if test "$MINGW32" = "yes" ; then
 242     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 243       [Define if you have the <winsock2.h> header file.])])
 244     AC_CHECK_LIB(ws2_32, main)
 245     LIBOBJS="$LIBOBJS win32-uname.o win32-dirent.o"
 246     if test "$enable_networking" = yes ; then
 247       LIBOBJS="$LIBOBJS win32-socket.o"
 248     fi
 249     if test "$enable_shared" = yes ; then
 250       EXTRA_DEFS="-DSCM_IMPORT"
 251       AC_DEFINE(USE_DLL_IMPORT, 1,
 252         [Define if you need additional CPP macros on Win32 platforms.])
 253     fi
 254 fi
 255 AC_SUBST(EXTRA_DEFS)
 256
 257 dnl Check for dynamic linking
 258
 259 use_modules=yes
 260 AC_ARG_WITH(modules,
 261 [  --with-modules[=FILES]  Add support for dynamic modules],
 262 use_modules="$withval")
 263 test -z "$use_modules" && use_modules=yes
 264 DLPREOPEN=
 265 if test "$use_modules" != no; then
 266   AC_DEFINE(DYNAMIC_LINKING)
 267   if test "$use_modules" = yes; then
 268     DLPREOPEN="-dlpreopen force"
 269   else
 270     DLPREOPEN="-export-dynamic"
 271     for module in $use_modules; do
 272       DLPREOPEN="$DLPREOPEN -dlopen $module"
 273     done
 274   fi
 275 fi
 276 AC_SUBST(INCLTDL)
 277 AC_SUBST(LIBLTDL)
 278 AC_SUBST(DLPREOPEN)
 279
 280 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer)
 281
 282 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 283 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 284 AC_CHECK_LIB(crypt, crypt)
 285
 286 ### Some systems don't declare some functions.  On such systems, we
 287 ### need to at least provide our own K&R-style declarations.
 288
 289 ### GUILE_FUNC_DECLARED(function, headerfile)
 290
 291 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 292 ### not there, #define MISSING_FUNCTION_DECL.
 293 AC_DEFUN(GUILE_FUNC_DECLARED, [
 294   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 295     AC_EGREP_HEADER($1, $2,
 296                     guile_cv_func_$1_declared=yes,
 297                     guile_cv_func_$1_declared=no))
 298   if test [x$guile_cv_func_]$1[_declared] = xno; then
 299     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 300   fi
 301 ])
 302
 303 GUILE_FUNC_DECLARED(strptime, time.h)
 304 GUILE_FUNC_DECLARED(sleep, unistd.h)
 305 GUILE_FUNC_DECLARED(usleep, unistd.h)
 306
 307 ### On some systems usleep has no return value.  If it does have one,
 308 ### we'd like to return it; otherwise, we'll fake it.
 309 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 310   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 311                    unistd.h,
 312                    [guile_cv_func_usleep_return_type=void],
 313                    [guile_cv_func_usleep_return_type=int])])
 314 case "$guile_cv_func_usleep_return_type" in
 315   "void" )
 316     AC_DEFINE(USLEEP_RETURNS_VOID)
 317   ;;
 318 esac
 319
 320 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 321 if test -n "$have_sys_un_h" ; then
 322 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 323 fi
 324
 325 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 326
 327 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 328                setnetent    getnetent    endnetent    dnl
 329                setprotoent  getprotoent  endprotoent  dnl
 330                setservent   getservent   endservent   dnl
 331                getnetbyaddr getnetbyname dnl
 332                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 333                inet_pton inet_ntop)
 334
 335 dnl Some systems do not declare this.  Some systems do declare it, as a
 336 dnl macro.  With cygwin it may be in a DLL.
 337
 338 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 339 AC_CACHE_VAL(guile_cv_have_h_errno,
 340 [AC_TRY_COMPILE([#include <netdb.h>],
 341 [int a = h_errno;],
 342 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 343 AC_MSG_RESULT($guile_cv_have_h_errno)
 344 if test $guile_cv_have_h_errno = yes; then
 345   AC_DEFINE(HAVE_H_ERRNO)
 346 fi
 347
 348 AC_MSG_CHECKING(whether uint32_t is defined)
 349 AC_CACHE_VAL(guile_cv_have_uint32_t,
 350   [AC_TRY_COMPILE([#include <sys/types.h>
 351                    #include <netdb.h>],
 352                   [uint32_t a;],
 353                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 354 AC_MSG_RESULT($guile_cv_have_uint32_t)
 355 if test $guile_cv_have_uint32_t = yes; then
 356   AC_DEFINE(HAVE_UINT32_T)
 357 fi
 358
 359 AC_MSG_CHECKING(for working IPv6 support)
 360 AC_CACHE_VAL(guile_cv_have_ipv6,
 361 [AC_TRY_COMPILE([#include <netinet/in.h>
 362 #include <sys/socket.h>],
 363 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 364 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 365 AC_MSG_RESULT($guile_cv_have_ipv6)
 366 if test $guile_cv_have_ipv6 = yes; then
 367   AC_DEFINE(HAVE_IPV6)
 368 fi
 369
 370 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 371 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 372 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 373 [AC_TRY_COMPILE([#include <netinet/in.h>],
 374 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 375 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 376 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 377 if test $guile_cv_have_sin6_scope_id = yes; then
 378   AC_DEFINE(HAVE_SIN6_SCOPE_ID)
 379 fi
 380
 381 AC_MSG_CHECKING(whether localtime caches TZ)
 382 AC_CACHE_VAL(guile_cv_localtime_cache,
 383 [if test x$ac_cv_func_tzset = xyes; then
 384 AC_TRY_RUN([#include <time.h>
 385 #if STDC_HEADERS
 386 # include <stdlib.h>
 387 #endif
 388 extern char **environ;
 389 unset_TZ ()
 390 {
 391   char **from, **to;
 392   for (to = from = environ; (*to = *from); from++)
 393     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 394       to++;
 395 }
 396 char TZ_GMT0[] = "TZ=GMT0";
 397 char TZ_PST8[] = "TZ=PST8";
 398 main()
 399 {
 400   time_t now = time ((time_t *) 0);
 401   int hour_GMT0, hour_unset;
 402   if (putenv (TZ_GMT0) != 0)
 403     exit (1);
 404   hour_GMT0 = localtime (&now)->tm_hour;
 405   unset_TZ ();
 406   hour_unset = localtime (&now)->tm_hour;
 407   if (putenv (TZ_PST8) != 0)
 408     exit (1);
 409   if (localtime (&now)->tm_hour == hour_GMT0)
 410     exit (1);
 411   unset_TZ ();
 412   if (localtime (&now)->tm_hour != hour_unset)
 413     exit (1);
 414   exit (0);
 415 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 416 [# If we have tzset, assume the worst when cross-compiling.
 417 guile_cv_localtime_cache=yes])
 418 else
 419         # If we lack tzset, report that localtime does not cache TZ,
 420         # since we can't invalidate the cache if we don't have tzset.
 421         guile_cv_localtime_cache=no
 422 fi])dnl
 423 AC_MSG_RESULT($guile_cv_localtime_cache)
 424 if test $guile_cv_localtime_cache = yes; then
 425   AC_DEFINE(LOCALTIME_CACHE)
 426 fi
 427
 428 dnl Test whether system calls are restartable by default on the
 429 dnl current system.  If they are not, we put a loop around every system
 430 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 431 dnl change from the default behaviour.  On the other hand, if signals
 432 dnl are restartable then the loop is not installed and when libguile
 433 dnl initialises it also resets the behaviour of each signal to cause a
 434 dnl restart (in case a different runtime had a different default
 435 dnl behaviour for some reason: e.g., different versions of linux seem
 436 dnl to behave differently.)
 437
 438 AC_SYS_RESTARTABLE_SYSCALLS
 439
 440 if test "$enable_regex" = yes; then
 441    if test "$ac_cv_header_regex_h" = yes ||
 442       test "$ac_cv_header_rxposix_h" = yes ||
 443       test "$ac_cv_header_rx_rxposix_h" = yes; then
 444      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 445      [AC_CHECK_LIB(rx, main)
 446       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 447      [AC_CHECK_LIB(regex, main)
 448       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [LIBOBJS="regex-posix.o $LIBOBJS"])])]
 449      )
 450      dnl The following should not be necessary, but for some reason
 451      dnl autoheader misses it if we don't include it!
 452      if test "$ac_cv_func_regcomp_norx" = yes ||
 453         test "$ac_cv_func_regcomp_regex" = yes ||
 454         test "$ac_cv_func_regcomp_rx" = yes; then
 455        AC_DEFINE(HAVE_REGCOMP)
 456      fi
 457    fi
 458 fi
 459
 460 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 461
 462 # When testing for the presence of alloca, we need to add alloca.o
 463 # explicitly to LIBOBJS to make sure that it is translated to
 464 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 465 AC_FUNC_ALLOCA
 466 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 467
 468 AC_CHECK_MEMBERS([struct stat.st_rdev])
 469 AC_CHECK_MEMBERS([struct stat.st_blksize])
 470
 471 AC_STRUCT_ST_BLOCKS
 472
 473 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 474   [AC_TRY_CPP([#include <sys/stat.h>
 475                #ifndef S_ISLNK
 476                #error no S_ISLNK
 477                #endif],
 478                ac_cv_macro_S_ISLNK=yes,
 479                ac_cv_macro_S_ISLNK=no)])
 480 if test $ac_cv_macro_S_ISLNK = yes; then
 481   AC_DEFINE(HAVE_S_ISLNK)
 482 fi
 483
 484 AC_STRUCT_TIMEZONE
 485 GUILE_STRUCT_UTIMBUF
 486
 487 #--------------------------------------------------------------------
 488 #
 489 # Which way does the stack grow?
 490 #
 491 #--------------------------------------------------------------------
 492
 493 AC_TRY_RUN(aux (l) unsigned long l;
 494              { int x; exit (l >= ((unsigned long)&x)); }
 495            main () { int q; aux((unsigned long)&q); },
 496            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 497
 498 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 499     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 500                 [guile_cv_type_float_fits_long=yes],
 501                 [guile_cv_type_float_fits_long=no],
 502                 [guile_cv_type_float_fits_long=guess-yes])])
 503 case $guile_cv_type_float_fits_long in
 504   "yes" )
 505     AC_DEFINE(SCM_SINGLES)
 506   ;;
 507   "guess-yes" )
 508     AC_DEFINE(SCM_SINGLES)
 509     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 510     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 511   ;;
 512 esac
 513
 514
 515 AC_MSG_CHECKING(for struct linger)
 516 AC_CACHE_VAL(scm_cv_struct_linger,
 517         AC_TRY_COMPILE([
 518 #include <sys/types.h>
 519 #include <sys/socket.h>],
 520                         [struct linger lgr;  lgr.l_linger = 100],
 521                         scm_cv_struct_linger="yes",
 522                         scm_cv_struct_linger="no"))
 523 AC_MSG_RESULT($scm_cv_struct_linger)
 524 if test $scm_cv_struct_linger = yes; then
 525         AC_DEFINE(HAVE_STRUCT_LINGER)
 526 fi
 527
 528
 529 AC_MSG_CHECKING(for struct timespec)
 530 AC_CACHE_VAL(scm_cv_struct_timespec,
 531         AC_TRY_COMPILE([
 532 #include <time.h>],
 533                         [struct timespec t;  t.tv_nsec = 100],
 534                         scm_cv_struct_timespec="yes",
 535                         scm_cv_struct_timespec="no"))
 536 AC_MSG_RESULT($scm_cv_struct_timespec)
 537 if test $scm_cv_struct_timespec = yes; then
 538         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 539 fi
 540
 541 #--------------------------------------------------------------------
 542 #
 543 # Flags for thread support
 544 #
 545 #--------------------------------------------------------------------
 546
 547 ### What thread package has the user asked for?
 548 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 549             , with_threads=no)
 550
 551 ### Turn $with_threads into either the name of a threads package, like
 552 ### `qt', or `no', meaning that threads should not be supported.
 553 AC_MSG_CHECKING(whether to support threads)
 554 case "$with_threads" in
 555   "yes" | "qt" | "coop" | "")
 556     with_threads=qt
 557   ;;
 558   "no" )
 559   ;;
 560   * )
 561     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 562   ;;
 563 esac
 564 AC_MSG_RESULT($with_threads)
 565
 566 ## Make sure the threads package we've chosen is actually supported on
 567 ## the present platform.
 568 case "${with_threads}" in
 569   "qt" )
 570     ## This configures the QuickThreads package, and sets or clears
 571     ## the THREAD_PACKAGE variable if qthreads don't configure
 572     ## correctly.
 573     QTHREADS_CONFIGURE
 574    ;;
 575 esac
 576
 577 ## If we're using threads, bring in some other parts of Guile which
 578 ## work with them.
 579 if test "${THREAD_PACKAGE}" != "" ; then
 580   AC_DEFINE(USE_THREADS, 1)
 581
 582   ## Include the Guile thread interface in the library...
 583   LIBOBJS="$LIBOBJS threads.o"
 584
 585   ## ... and tell it which package to talk to.
 586   case "${THREAD_PACKAGE}" in
 587     "QT" )
 588       AC_DEFINE(USE_COOP_THREADS, 1)
 589     ;;
 590     * )
 591       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 592     ;;
 593   esac
 594
 595   ## Bring in scm_internal_select, if appropriate.
 596   if test $ac_cv_func_gettimeofday = yes &&
 597      test $ac_cv_func_select = yes; then
 598     AC_DEFINE(GUILE_ISELECT, 1)
 599   fi
 600
 601   AC_ARG_ENABLE(linuxthreads,
 602   [  --disable-linuxthreads  disable linuxthreads workaround],,
 603   enable_linuxthreads=yes)
 604
 605   ## Workaround for linuxthreads (optionally disabled)
 606   if test $host_os = linux-gnu -a "$enable_linuxthreads" = yes; then
 607     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 608     AC_CHECK_LIB(pthread, main)
 609   fi
 610 fi
 611 AC_SUBST(LIBGUILEQTHREADS_INTERFACE_CURRENT)
 612 AC_SUBST(LIBGUILEQTHREADS_INTERFACE_REVISION)
 613 AC_SUBST(LIBGUILEQTHREADS_INTERFACE_AGE)
 614 AC_SUBST(LIBGUILEQTHREADS_INTERFACE)
 615
 616 ## If we're using GCC, ask for aggressive warnings.
 617 case "$GCC" in
 618   yes )
 619     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 620     ## much stuff with generic function pointers for that to really be
 621     ## less than exasperating.
 622     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 623     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 624     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 625 esac
 626
 627 AC_PROG_AWK
 628
 629 ## Remove fileblocks.o from the object list.  This file gets added by
 630 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
 631 LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
 632
 633 ## If we're creating a shared library (using libtool!), then we'll
 634 ## need to generate a list of .lo files corresponding to the .o files
 635 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 636 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 637
 638 ## We also need to create corresponding .doc and .x files
 639 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 640 EXTRA_DOT_X_FILES="`echo ${LIBOBJS} | sed 's/\.o/.x/g'`"
 641
 642 AC_SUBST(GUILE_MAJOR_VERSION)
 643 AC_SUBST(GUILE_MINOR_VERSION)
 644 AC_SUBST(GUILE_MICRO_VERSION)
 645 AC_SUBST(GUILE_VERSION)
 646
 647 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
 648 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
 649 AC_SUBST(LIBGUILE_INTERFACE_AGE)
 650 AC_SUBST(LIBGUILE_INTERFACE)
 651
 652 dnl Tell guile-config what flags guile users should link against.
 653 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 654 AC_SUBST(GUILE_LIBS)
 655
 656 AC_SUBST(AWK)
 657 AC_SUBST(LIBLOBJS)
 658 AC_SUBST(EXTRA_DOT_DOC_FILES)
 659 AC_SUBST(EXTRA_DOT_X_FILES)
 660
 661 AC_CONFIG_FILES([
 662   Makefile
 663   libguile/Makefile
 664   libguile/guile-snarf
 665   libguile/guile-doc-snarf
 666   libguile/guile-func-name-check
 667   libguile/guile-snarf-docs
 668   libguile/guile-snarf-docs-texi
 669   libguile/version.h
 670   ice-9/Makefile
 671   lang/Makefile
 672   lang/elisp/Makefile
 673   lang/elisp/internals/Makefile
 674   lang/elisp/primitives/Makefile
 675   oop/Makefile
 676   oop/goops/Makefile
 677   scripts/Makefile
 678   srfi/Makefile
 679   qt/Makefile
 680   qt/qt.h
 681   qt/md/Makefile
 682   qt/time/Makefile
 683   guile-config/Makefile
 684   doc/Makefile
 685   doc/ref/Makefile
 686   doc/tutorial/Makefile
 687   doc/goops/Makefile
 688   doc/r5rs/Makefile
 689   examples/Makefile
 690   examples/scripts/Makefile
 691   examples/box/Makefile
 692   examples/box-module/Makefile
 693   examples/box-dynamic/Makefile
 694   examples/box-dynamic-module/Makefile
 695   examples/modules/Makefile
 696   examples/safe/Makefile
 697   test-suite/Makefile
 698   check-guile
 699   guile-tools])
 700
 701 AC_CONFIG_COMMANDS(default,
 702   [ chmod +x libguile/guile-snarf \
 703              libguile/guile-doc-snarf \
 704              libguile/guile-func-name-check \
 705              libguile/guile-snarf-docs \
 706              libguile/guile-snarf-docs-texi \
 707              check-guile \
 708              guile-tools])
 709
 710 AC_OUTPUT
 711
 712 dnl Local Variables:
 713 dnl comment-start: "dnl "
 714 dnl comment-end: ""
 715 dnl comment-start-skip: "\\bdnl\\b\\s *"
 716 dnl End: