configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 AC_INIT(Makefile.in)
   4 . $srcdir/GUILE-VERSION
   5 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
   6 AM_MAINTAINER_MODE
   7 AM_CONFIG_HEADER(libguile/scmconfig.h)
   8
   9 #--------------------------------------------------------------------
  10 #
  11 # User options
  12 #
  13 #--------------------------------------------------------------------
  14
  15 AC_ARG_ENABLE(dynamic-linking,
  16   [  --enable-dynamic-linking  Include support for dynamic linking],,
  17   enable_dynamic_linking=yes)
  18
  19 AC_ARG_ENABLE(guile-debug,
  20 [  --enable-guile-debug    Include internal debugging functions])
  21 if test "$enableval" = y || test "$enableval" = yes; then
  22   AC_DEFINE(GUILE_DEBUG)
  23 fi
  24
  25 dnl The --disable-debug used to control these two.  But now they are
  26 dnl a required part of the distribution.
  27 AC_DEFINE(DEBUG_EXTENSIONS)
  28 AC_DEFINE(READER_EXTENSIONS)
  29
  30 #--------------------------------------------------------------------
  31
  32 AC_PROG_CC
  33 AC_PROG_CPP
  34 AM_PROG_LIBTOOL
  35
  36 AC_AIX
  37 AC_ISC_POSIX
  38 AC_MINIX
  39
  40 AC_C_CONST
  41 AC_C_INLINE
  42
  43 AC_HEADER_STDC
  44 AC_HEADER_DIRENT
  45 AC_HEADER_TIME
  46 AC_HEADER_SYS_WAIT
  47 AC_CHECK_HEADERS(libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
  48 GUILE_HEADER_LIBC_WITH_UNISTD
  49
  50 AC_TYPE_GETGROUPS
  51 AC_TYPE_SIGNAL
  52 AC_TYPE_MODE_T
  53
  54 AC_CHECK_LIB(m, main)
  55 AC_CHECK_FUNCS(gethostbyname)
  56 if test $ac_cv_func_gethostbyname = no; then
  57     AC_CHECK_LIB(nsl, gethostbyname)
  58 fi
  59 AC_CHECK_FUNCS(connect)
  60 if test $ac_cv_func_connect = no; then
  61     AC_CHECK_LIB(socket, connect)
  62 fi
  63 AC_CHECK_LIB(termcap, tgoto)
  64 AC_CHECK_LIB(readline, readline)
  65 AC_CHECK_FUNCS(rl_clear_signals rl_cleanup_after_signal)
  66
  67 AC_CACHE_CHECK([for rl_getc_function pointer in readline],
  68                ac_cv_var_rl_getc_function,
  69                [AC_TRY_LINK([
  70 #include <stdio.h>
  71 #include <readline/readline.h>],
  72                             [rl_getc_function;],
  73                             [ac_cv_var_rl_getc_function=yes],
  74                             [ac_cv_var_rl_getc_function=no])])
  75 if test "$ac_cv_var_rl_getc_function" = "yes"; then
  76   AC_DEFINE(HAVE_RL_GETC_FUNCTION)
  77 fi
  78
  79 if test $ac_cv_lib_readline_readline = yes -a $ac_cv_var_rl_getc_function = no; then
  80   echo 'Warning: libreadline is too old on your system.  Need >= 2.1.'
  81 fi
  82
  83 # Checks for dynamic linking
  84
  85 if test "$enable_dynamic_linking" = "yes"; then
  86
  87 AC_CHECK_LIB(dl,dlopen)
  88 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
  89   AC_CHECK_FUNCS(dlopen)
  90   AC_DEFINE(DYNAMIC_LINKING)
  91 else
  92 AC_CHECK_LIB(dld,dld_link)
  93 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
  94   AC_DEFINE(DYNAMIC_LINKING)
  95 else
  96 AC_CHECK_FUNCS(shl_load)
  97 if test "$ac_cv_func_shl_load" = "yes"; then
  98   AC_DEFINE(DYNAMIC_LINKING)
  99 else
 100 AC_CHECK_FUNCS(dlopen)
 101 if test "$ac_cv_func_dlopen" = "yes"; then
 102   AC_DEFINE(DYNAMIC_LINKING)
 103 fi
 104 fi
 105 fi
 106 fi
 107
 108 fi
 109
 110 GUILE_DLSYM_USCORE
 111
 112 AC_CHECK_FUNCS(ctermid ftime getcwd geteuid gethostent gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep)
 113
 114 ### Some systems don't declare some functions.  On such systems, we
 115 ### need to at least provide our own K&R-style declarations.
 116
 117 ### GUILE_FUNC_DECLARED(function, headerfile)
 118
 119 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 120 ### not there, #define MISSING_FUNCTION_DECL.
 121 AC_DEFUN(GUILE_FUNC_DECLARED, [
 122   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 123     AC_EGREP_HEADER($1, $2,
 124                     guile_cv_func_$1_declared=yes,
 125                     guile_cv_func_$1_declared=no))
 126   if test [x$guile_cv_func_]$1[_declared] = xno; then
 127     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 128   fi
 129 ])
 130
 131 GUILE_FUNC_DECLARED(strptime, time.h)
 132 GUILE_FUNC_DECLARED(bzero, string.h)
 133 GUILE_FUNC_DECLARED(sleep, unistd.h)
 134 GUILE_FUNC_DECLARED(usleep, unistd.h)
 135
 136 ### On some systems usleep has no return value.  If it does have one,
 137 ### we'd like to return it; otherwise, we'll fake it.
 138 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 139   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 140                    /usr/include/unistd.h,
 141                    [guile_cv_func_usleep_return_type=void],
 142                    [guile_cv_func_usleep_return_type=int])])
 143 case "$guile_cv_func_usleep_return_type" in
 144   "void" )
 145     AC_DEFINE(USLEEP_RETURNS_VOID)
 146   ;;
 147 esac
 148
 149 dnl <GNU-WIN32 hacks>
 150
 151 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 152 if test -n "$have_sys_un_h" ; then
 153 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 154 fi
 155
 156 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 157
 158 dnl I don't know what this prefixing of cygwin32_ is for.
 159 dnl scmconfig.h wasn't updated with the test results.
 160 dnl so use AC_CHECK_FUNCS for now.
 161
 162 dnl how about:
 163 dnl save confdefs.h
 164 dnl if test $ac_cv_cigwin = yes; then
 165 dnl   modify confdefs.h
 166 dnl fi
 167 dnl AC_CHECK_FUNCS...
 168 dnl restore confdefs.h
 169
 170 dnl cp confdefs.h confdefs.h.bak
 171 dnl for func in sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof ; do
 172 dnl cp confdefs.h.bak confdefs.h
 173 dnl cat >> confdefs.h << EOF
 174 dnl #ifdef __CYGWIN32__
 175 dnl #define $func cygwin32_$func
 176 dnl #endif
 177 dnl EOF
 178 dnl AC_CHECK_FUNC($func)
 179 dnl done
 180 dnl cp confdefs.h.bak confdefs.h
 181
 182 AC_CHECK_FUNCS(sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof)
 183
 184 dnl </GNU-WIN32 hacks>
 185
 186 AC_CACHE_CHECK([for restartable system calls], scm_cv_restarts,
 187         if test $ac_cv_func_sigaction = yes; then
 188                 [AC_TRY_COMPILE([#include <signal.h>],
 189                                 [int a = SA_RESTART],
 190                                 scm_cv_restarts=yes,
 191                                 scm_cv_restarts=no)]
 192         else
 193                 scm_cv_restarts=no
 194         fi)
 195 if test $scm_cv_restarts = yes; then
 196         AC_DEFINE(HAVE_RESTARTS)
 197 fi
 198
 199 if test "$ac_cv_header_regex_h" = yes ||
 200    test "$ac_cv_header_rxposix_h" = yes ||
 201    test "$ac_cv_header_rx_rxposix_h" = yes; then
 202   GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 203   [AC_CHECK_LIB(rx, main)
 204    GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 205   )
 206   dnl The following should not be necessary, but for some reason
 207   dnl autoheader misses it if we don't include it!
 208   if test "$ac_cv_func_regcomp_norx" = yes ||
 209      test "$ac_cv_func_regcomp_rx" = yes; then
 210     AC_DEFINE(HAVE_REGCOMP)
 211   fi
 212 fi
 213
 214 AC_REPLACE_FUNCS(inet_aton putenv strerror)
 215
 216 # When testing for the presence of alloca, we need to add alloca.o
 217 # explicitly to LIBOBJS to make sure that it is translated to
 218 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 219 AC_FUNC_ALLOCA
 220 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 221
 222 AC_STRUCT_ST_RDEV
 223 AC_STRUCT_ST_BLKSIZE
 224
 225 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 226 # LIBOBJS, which we don't need.  This seems more direct.
 227 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 228 [AC_TRY_COMPILE([#include <sys/types.h>
 229 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 230 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 231 if test $ac_cv_struct_st_blocks = yes; then
 232   AC_DEFINE(HAVE_ST_BLOCKS)
 233 fi
 234
 235 AC_STRUCT_TIMEZONE
 236 GUILE_STRUCT_UTIMBUF
 237
 238 #--------------------------------------------------------------------
 239 #
 240 # Which way does the stack grow?
 241 #
 242 #--------------------------------------------------------------------
 243
 244 AC_TRY_RUN(aux (l) unsigned long l;
 245              { int x; exit (l >= ((unsigned long)&x)); }
 246            main () { int q; aux((unsigned long)&q); },
 247            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 248
 249 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 250     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 251                 [guile_cv_type_float_fits_long=yes],
 252                 [guile_cv_type_float_fits_long=no],
 253                 [guile_cv_type_float_fits_long=guess-yes])])
 254 case $guile_cv_type_float_fits_long in
 255   "yes" )
 256     AC_DEFINE(SCM_SINGLES)
 257   ;;
 258   "guess-yes" )
 259     AC_DEFINE(SCM_SINGLES)
 260     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 261     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 262   ;;
 263 esac
 264
 265
 266 AC_MSG_CHECKING(for struct linger)
 267 AC_CACHE_VAL(scm_cv_struct_linger,
 268         AC_TRY_COMPILE([
 269 #include <sys/types.h>
 270 #include <sys/socket.h>],
 271                         [struct linger lgr;  lgr.l_linger = 100],
 272                         scm_cv_struct_linger="yes",
 273                         scm_cv_struct_linger="no"))
 274 AC_MSG_RESULT($scm_cv_struct_linger)
 275 if test $scm_cv_struct_linger = yes; then
 276         AC_DEFINE(HAVE_STRUCT_LINGER)
 277 fi
 278
 279 #--------------------------------------------------------------------
 280 #
 281 # How can you violate a stdio abstraction by setting a stream's fd?
 282 #
 283 #--------------------------------------------------------------------
 284
 285 AC_MSG_CHECKING(how to set a stream file descriptor)
 286 AC_CACHE_VAL(scm_cv_fd_setter,
 287         AC_TRY_COMPILE([#include <stdio.h>],
 288                         [stdout->_file = 1],
 289                         scm_cv_fd_setter="_file",
 290         AC_TRY_COMPILE([#include <stdio.h>],
 291                         [stdout->__file = 1],
 292                         scm_cv_fd_setter="__file",
 293         AC_TRY_COMPILE([#include <stdio.h>],
 294                         [stdout->_fileno = 1],
 295                         scm_cv_fd_setter="_fileno",
 296                         scm_cv_fd_setter=""))))
 297
 298 if test "$scm_cv_fd_setter"; then
 299         AC_MSG_RESULT($scm_cv_fd_setter)
 300         AC_DEFINE_UNQUOTED(FD_SETTER, $scm_cv_fd_setter)
 301 else
 302         AC_MSG_RESULT(we couldn't do it!)
 303 fi
 304
 305 #--------------------------------------------------------------------
 306 # How to find out whether a FILE structure contains buffered data.
 307 # From Tk we have the following list:
 308 #               _cnt:           Most UNIX systems
 309 #               __cnt:          HPUX and SCO
 310 #               _r:             BSD
 311 #               readCount:      Sprite
 312 #       Or, in GNU libc there are two fields, _gptr and _egptr, which
 313 #       have to be compared.
 314 #       These can also be known as _IO_read_ptr and _IO_read_end.
 315 #--------------------------------------------------------------------
 316
 317 AC_MSG_CHECKING(how to get buffer char count from FILE structure)
 318 AC_CACHE_VAL(scm_cv_struct_file_count,
 319         AC_TRY_COMPILE([#include <stdio.h>],
 320                         [FILE *f = stdin; f->_cnt = 0],
 321                         scm_cv_struct_file_count="_cnt",
 322         AC_TRY_COMPILE([#include <stdio.h>],
 323                         [FILE *f = stdin; f->__cnt = 0],
 324                         scm_cv_struct_file_count="__cnt",
 325         AC_TRY_COMPILE([#include <stdio.h>],
 326                         [FILE *f = stdin; f->_r = 0],
 327                         scm_cv_struct_file_count="_r",
 328         AC_TRY_COMPILE([#include <stdio.h>],
 329                         [FILE *f = stdin; f->readCount = 0],
 330                         scm_cv_struct_file_count="readCount",
 331         scm_cv_struct_file_count="")))))
 332 if test "$scm_cv_struct_file_count"; then
 333         AC_MSG_RESULT($scm_cv_struct_file_count)
 334         AC_DEFINE_UNQUOTED(FILE_CNT_FIELD, $scm_cv_struct_file_count)
 335 else
 336 AC_CACHE_VAL(scm_cv_struct_file_gptr,
 337         AC_TRY_COMPILE([#include <stdio.h>],
 338                         [FILE *f = stdin; f->_gptr = f->egptr;],
 339                         scm_cv_struct_file_gptr=1,
 340         scm_cv_struct_file_gptr=""))
 341 if test "$scm_cv_struct_gptr"; then
 342         AC_MSG_RESULT(gptr)
 343         AC_DEFINE_UNQUOTED(FILE_CNT_GPTR, $scm_cv_struct_file_gptr)
 344 else
 345 AC_CACHE_VAL(scm_cv_struct_file_readptr,
 346         AC_TRY_COMPILE([#include <stdio.h>],
 347                         [FILE *f = stdin; f->_IO_read_ptr = f->_IO_read_end;],
 348                         scm_cv_struct_file_readptr=1))
 349 if test "$scm_cv_struct_file_readptr"; then
 350         AC_MSG_RESULT(read_ptr)
 351         AC_DEFINE_UNQUOTED(FILE_CNT_READPTR, $scm_cv_struct_file_readptr)
 352 else
 353         AC_MSG_RESULT(we couldn't do it!)
 354 fi
 355 fi
 356 fi
 357
 358 #--------------------------------------------------------------------
 359 #
 360 # Flags for thread support
 361 #
 362 #--------------------------------------------------------------------
 363
 364 ### What thread package has the user asked for?
 365 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 366             , with_threads=no)
 367
 368 ### Turn $with_threads into either the name of a threads package, like
 369 ### `qt', or `no', meaning that threads should not be supported.
 370 AC_MSG_CHECKING(whether to support threads)
 371 case "$with_threads" in
 372   "yes" | "qt" | "coop" | "")
 373     with_threads=qt
 374   ;;
 375   "no" )
 376   ;;
 377   * )
 378     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 379   ;;
 380 esac
 381 AC_MSG_RESULT($with_threads)
 382
 383 ## Make sure the threads package we've chosen is actually supported on
 384 ## the present platform.
 385 case "${with_threads}" in
 386   "qt" )
 387     ## This configures the QuickThreads package, and sets or clears
 388     ## the THREAD_PACKAGE variable if qthreads don't configure
 389     ## correctly.
 390     QTHREADS_CONFIGURE
 391    ;;
 392 esac
 393
 394 ## If we're using threads, bring in some other parts of Guile which
 395 ## work with them.
 396 if test "${THREAD_PACKAGE}" != "" ; then
 397   AC_DEFINE(USE_THREADS, 1)
 398
 399   ## Include the Guile thread interface in the library...
 400   LIBOBJS="$LIBOBJS threads.o"
 401
 402   ## ... and tell it which package to talk to.
 403   case "${THREAD_PACKAGE}" in
 404     "QT" )
 405       AC_DEFINE(USE_COOP_THREADS, 1)
 406     ;;
 407     * )
 408       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 409     ;;
 410   esac
 411
 412   ## Bring in scm_internal_select, if appropriate.
 413   if test $ac_cv_func_gettimeofday = yes &&
 414      test $ac_cv_func_select = yes; then
 415     LIBOBJS="$LIBOBJS iselect.o"
 416     AC_DEFINE(GUILE_ISELECT, 1)
 417   fi
 418 fi
 419
 420 ## If we're using GCC, ask for aggressive warnings.
 421 case "$GCC" in
 422   yes )
 423     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 424     ## much stuff with generic function pointers for that to really be
 425     ## less than exasperating.
 426     CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wmissing-prototypes" ;;
 427 esac
 428
 429 AC_PROG_AWK
 430
 431 ## If we're creating a shared library (using libtool!), then we'll
 432 ## need to generate a list of .lo files corresponding to the .o files
 433 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 434 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 435
 436 AC_SUBST(GUILE_MAJOR_VERSION)
 437 AC_SUBST(GUILE_MINOR_VERSION)
 438 AC_SUBST(GUILE_VERSION)
 439
 440 dnl Tell guile-config what flags guile users should link against.
 441 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 442 AC_SUBST(GUILE_LIBS)
 443
 444 dnl timestamping the interpreter and scheme libraries:
 445 dnl
 446 dnl Help us notice when we're running one version of the Guile
 447 dnl interpreter against a different version of the ice-9 Scheme code.
 448 dnl This will definitely detect version skew due to differing
 449 dnl snapshots and releases, but may not catch skew for the developers.
 450 dnl Hopefully it will not detect skew when there is none; if that
 451 dnl happens, the warnings will be useless, and we should remove this.
 452 GUILE_STAMP="`date`"
 453 AC_SUBST(GUILE_STAMP)
 454
 455 AC_SUBST(AWK)
 456 AC_SUBST(LIBLOBJS)
 457
 458 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/versiondat.h ice-9/Makefile ice-9/version.scm qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf])
 459
 460 dnl Local Variables:
 461 dnl comment-start: "dnl "
 462 dnl comment-end: ""
 463 dnl comment-start-skip: "\\bdnl\\b\\s *"
 464 dnl End: