module/language/tree-il/primitives.scm

   1 ;;; open-coding primitive procedures
   2
   3 ;; Copyright (C) 2009, 2010, 2011, 2012, 2013 Free Software Foundation, Inc.
   4
   5 ;;;; This library is free software; you can redistribute it and/or
   6 ;;;; modify it under the terms of the GNU Lesser General Public
   7 ;;;; License as published by the Free Software Foundation; either
   8 ;;;; version 3 of the License, or (at your option) any later version.
   9 ;;;;
  10 ;;;; This library is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 ;;;; Lesser General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU Lesser General Public
  16 ;;;; License along with this library; if not, write to the Free Software
  17 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  18
  19 ;;; Code:
  20
  21 (define-module (language tree-il primitives)
  22   #:use-module (system base pmatch)
  23   #:use-module (ice-9 match)
  24   #:use-module (rnrs bytevectors)
  25   #:use-module (system base syntax)
  26   #:use-module (language tree-il)
  27   #:use-module (srfi srfi-4)
  28   #:use-module (srfi srfi-16)
  29   #:export (resolve-primitives add-interesting-primitive!
  30             expand-primitives
  31             effect-free-primitive? effect+exception-free-primitive?
  32             constructor-primitive? accessor-primitive?
  33             singly-valued-primitive? equality-primitive?
  34             bailout-primitive?
  35             negate-primitive))
  36
  37 ;; When adding to this, be sure to update *multiply-valued-primitives*
  38 ;; if appropriate.
  39 (define *interesting-primitive-names*
  40   '(apply
  41     call-with-values
  42     call-with-current-continuation
  43     call/cc
  44     dynamic-wind
  45     values
  46     eq? eqv? equal?
  47     memq memv
  48     = < > <= >= zero?
  49     + * - / 1- 1+ quotient remainder modulo
  50     ash logand logior logxor lognot
  51     not
  52     pair? null? list? symbol? vector? string? struct? number? char? nil?
  53
  54     procedure? thunk?
  55
  56     complex? real? rational? inf? nan? integer? exact? inexact? even? odd?
  57
  58     char<? char<=? char>=? char>?
  59
  60     integer->char char->integer number->string string->number
  61
  62     acons cons cons*
  63
  64     list vector
  65
  66     car cdr
  67     set-car! set-cdr!
  68
  69     caar cadr cdar cddr
  70
  71     caaar caadr cadar caddr cdaar cdadr cddar cdddr
  72
  73     caaaar caaadr caadar caaddr cadaar cadadr caddar cadddr
  74     cdaaar cdaadr cdadar cdaddr cddaar cddadr cdddar cddddr
  75
  76     vector-length vector-ref vector-set!
  77     variable-ref variable-set!
  78     variable-bound?
  79
  80     fluid-ref fluid-set! with-fluid*
  81
  82     call-with-prompt
  83     abort-to-prompt* abort-to-prompt
  84     make-prompt-tag
  85
  86     throw error scm-error
  87
  88     string-length string-ref string-set!
  89
  90     struct-vtable make-struct struct-ref struct-set!
  91
  92     bytevector-u8-ref bytevector-u8-set!
  93     bytevector-s8-ref bytevector-s8-set!
  94     u8vector-ref u8vector-set! s8vector-ref s8vector-set!
  95
  96     bytevector-u16-ref bytevector-u16-set!
  97     bytevector-u16-native-ref bytevector-u16-native-set!
  98     bytevector-s16-ref bytevector-s16-set!
  99     bytevector-s16-native-ref bytevector-s16-native-set!
 100     u16vector-ref u16vector-set! s16vector-ref s16vector-set!
 101
 102     bytevector-u32-ref bytevector-u32-set!
 103     bytevector-u32-native-ref bytevector-u32-native-set!
 104     bytevector-s32-ref bytevector-s32-set!
 105     bytevector-s32-native-ref bytevector-s32-native-set!
 106     u32vector-ref u32vector-set! s32vector-ref s32vector-set!
 107
 108     bytevector-u64-ref bytevector-u64-set!
 109     bytevector-u64-native-ref bytevector-u64-native-set!
 110     bytevector-s64-ref bytevector-s64-set!
 111     bytevector-s64-native-ref bytevector-s64-native-set!
 112     u64vector-ref u64vector-set! s64vector-ref s64vector-set!
 113
 114     bytevector-ieee-single-ref bytevector-ieee-single-set!
 115     bytevector-ieee-single-native-ref bytevector-ieee-single-native-set!
 116     bytevector-ieee-double-ref bytevector-ieee-double-set!
 117     bytevector-ieee-double-native-ref bytevector-ieee-double-native-set!
 118     f32vector-ref f32vector-set! f64vector-ref f64vector-set!))
 119
 120 (define (add-interesting-primitive! name)
 121   (hashq-set! *interesting-primitive-vars*
 122               (or (module-variable (current-module) name)
 123                   (error "unbound interesting primitive" name))
 124               name))
 125
 126 (define *interesting-primitive-vars* (make-hash-table))
 127
 128 (for-each add-interesting-primitive! *interesting-primitive-names*)
 129
 130 (define *primitive-constructors*
 131   ;; Primitives that return a fresh object.
 132   '(acons cons cons* list vector make-struct make-struct/no-tail
 133     make-prompt-tag))
 134
 135 (define *primitive-accessors*
 136   ;; Primitives that are pure, but whose result depends on the mutable
 137   ;; memory pointed to by their operands.
 138   '(vector-ref
 139     car cdr
 140     memq memv
 141     struct-ref
 142     string-ref
 143     bytevector-u8-ref bytevector-s8-ref
 144     bytevector-u16-ref bytevector-u16-native-ref
 145     bytevector-s16-ref bytevector-s16-native-ref
 146     bytevector-u32-ref bytevector-u32-native-ref
 147     bytevector-s32-ref bytevector-s32-native-ref
 148     bytevector-u64-ref bytevector-u64-native-ref
 149     bytevector-s64-ref bytevector-s64-native-ref
 150     bytevector-ieee-single-ref bytevector-ieee-single-native-ref
 151     bytevector-ieee-double-ref bytevector-ieee-double-native-ref))
 152
 153 (define *effect-free-primitives*
 154   `(values
 155     eq? eqv? equal?
 156     = < > <= >= zero?
 157     ash logand logior logxor lognot
 158     + * - / 1- 1+ quotient remainder modulo
 159     not
 160     pair? null? list? symbol? vector? struct? string? number? char? nil
 161     complex? real? rational? inf? nan? integer? exact? inexact? even? odd?
 162     char<? char<=? char>=? char>?
 163     integer->char char->integer number->string string->number
 164     struct-vtable
 165     string-length vector-length
 166     ;; These all should get expanded out by expand-primitives.
 167     caar cadr cdar cddr
 168     caaar caadr cadar caddr cdaar cdadr cddar cdddr
 169     caaaar caaadr caadar caaddr cadaar cadadr caddar cadddr
 170     cdaaar cdaadr cdadar cdaddr cddaar cddadr cdddar cddddr
 171     ,@*primitive-constructors*
 172     ,@*primitive-accessors*))
 173
 174 ;; Like *effect-free-primitives* above, but further restricted in that they
 175 ;; cannot raise exceptions.
 176 (define *effect+exception-free-primitives*
 177   '(values
 178     eq? eqv? equal?
 179     not
 180     pair? null? list? symbol? vector? struct? string? number? char?
 181     procedure? thunk?
 182     acons cons cons* list vector))
 183
 184 ;; Primitives that don't always return one value.
 185 (define *multiply-valued-primitives*
 186   '(apply
 187     call-with-values
 188     call-with-current-continuation
 189     call/cc
 190     dynamic-wind
 191     values
 192     call-with-prompt
 193     @abort abort-to-prompt))
 194
 195 ;; Procedures that cause a nonlocal, non-resumable abort.
 196 (define *bailout-primitives*
 197   '(throw error scm-error))
 198
 199 ;; Negatable predicates.
 200 (define *negatable-primitives*
 201   '((even? . odd?)
 202     (exact? . inexact?)
 203     ;; (< <= > >=) are not negatable because of NaNs.
 204     (char<? . char>=?)
 205     (char>? . char<=?)))
 206
 207 (define *equality-primitives*
 208   '(eq? eqv? equal?))
 209
 210 (define *effect-free-primitive-table* (make-hash-table))
 211 (define *effect+exceptions-free-primitive-table* (make-hash-table))
 212 (define *equality-primitive-table* (make-hash-table))
 213 (define *multiply-valued-primitive-table* (make-hash-table))
 214 (define *bailout-primitive-table* (make-hash-table))
 215 (define *negatable-primitive-table* (make-hash-table))
 216
 217 (for-each (lambda (x)
 218             (hashq-set! *effect-free-primitive-table* x #t))
 219           *effect-free-primitives*)
 220 (for-each (lambda (x)
 221             (hashq-set! *effect+exceptions-free-primitive-table* x #t))
 222           *effect+exception-free-primitives*)
 223 (for-each (lambda (x)
 224             (hashq-set! *equality-primitive-table* x #t))
 225           *equality-primitives*)
 226 (for-each (lambda (x)
 227             (hashq-set! *multiply-valued-primitive-table* x #t))
 228           *multiply-valued-primitives*)
 229 (for-each (lambda (x)
 230             (hashq-set! *bailout-primitive-table* x #t))
 231           *bailout-primitives*)
 232 (for-each (lambda (x)
 233             (hashq-set! *negatable-primitive-table* (car x) (cdr x))
 234             (hashq-set! *negatable-primitive-table* (cdr x) (car x)))
 235           *negatable-primitives*)
 236
 237 (define (constructor-primitive? prim)
 238   (memq prim *primitive-constructors*))
 239 (define (accessor-primitive? prim)
 240   (memq prim *primitive-accessors*))
 241 (define (effect-free-primitive? prim)
 242   (hashq-ref *effect-free-primitive-table* prim))
 243 (define (effect+exception-free-primitive? prim)
 244   (hashq-ref *effect+exceptions-free-primitive-table* prim))
 245 (define (equality-primitive? prim)
 246   (hashq-ref *equality-primitive-table* prim))
 247 (define (singly-valued-primitive? prim)
 248   (not (hashq-ref *multiply-valued-primitive-table* prim)))
 249 (define (bailout-primitive? prim)
 250   (hashq-ref *bailout-primitive-table* prim))
 251 (define (negate-primitive prim)
 252   (hashq-ref *negatable-primitive-table* prim))
 253
 254 (define (resolve-primitives x mod)
 255   (define local-definitions
 256     (make-hash-table))
 257
 258   ;; Assume that any definitions with primitive names in the root module
 259   ;; have the same semantics as the primitives.
 260   (unless (eq? mod the-root-module)
 261     (let collect-local-definitions ((x x))
 262       (record-case x
 263         ((<toplevel-define> name)
 264          (hashq-set! local-definitions name #t))
 265         ((<seq> head tail)
 266          (collect-local-definitions head)
 267          (collect-local-definitions tail))
 268         (else #f))))
 269
 270   (post-order
 271    (lambda (x)
 272      (or
 273       (record-case x
 274         ((<toplevel-ref> src name)
 275          (and=> (and (not (hashq-ref local-definitions name))
 276                      (hashq-ref *interesting-primitive-vars*
 277                                 (module-variable mod name)))
 278                 (lambda (name) (make-primitive-ref src name))))
 279         ((<module-ref> src mod name public?)
 280          ;; for the moment, we're disabling primitive resolution for
 281          ;; public refs because resolve-interface can raise errors.
 282          (and=> (and=> (resolve-module mod)
 283                        (if public?
 284                            module-public-interface
 285                            identity))
 286                 (lambda (m)
 287                   (and=> (hashq-ref *interesting-primitive-vars*
 288                                     (module-variable m name))
 289                          (lambda (name)
 290                            (make-primitive-ref src name))))))
 291         ((<call> src proc args)
 292          (and (primitive-ref? proc)
 293               (make-primcall src (primitive-ref-name proc) args)))
 294         (else #f))
 295       x))
 296    x))
 297
 298 \f
 299
 300 (define *primitive-expand-table* (make-hash-table))
 301
 302 (define (expand-primitives x)
 303   (pre-order
 304    (lambda (x)
 305      (record-case x
 306        ((<primcall> src name args)
 307         (let ((expand (hashq-ref *primitive-expand-table* name)))
 308           (or (and expand (apply expand src args))
 309               x)))
 310        (else x)))
 311    x))
 312
 313 ;;; I actually did spend about 10 minutes trying to redo this with
 314 ;;; syntax-rules. Patches appreciated.
 315 ;;;
 316 (define-macro (define-primitive-expander sym . clauses)
 317   (define (inline-args args)
 318     (let lp ((in args) (out '()))
 319       (cond ((null? in) `(list ,@(reverse out)))
 320             ((symbol? in) `(cons* ,@(reverse out) ,in))
 321             ((pair? (car in))
 322              (lp (cdr in)
 323                  (cons (if (eq? (caar in) 'quote)
 324                            `(make-const src ,@(cdar in))
 325                            `(make-primcall src ',(caar in)
 326                                            ,(inline-args (cdar in))))
 327                        out)))
 328             ((symbol? (car in))
 329              ;; assume it's locally bound
 330              (lp (cdr in) (cons (car in) out)))
 331             ((self-evaluating? (car in))
 332              (lp (cdr in) (cons `(make-const src ,(car in)) out)))
 333             (else
 334              (error "what what" (car in))))))
 335   (define (consequent exp)
 336     (cond
 337      ((pair? exp)
 338       (pmatch exp
 339         ((if ,test ,then ,else)
 340          `(if ,test
 341               ,(consequent then)
 342               ,(consequent else)))
 343         (else
 344          `(make-primcall src ',(car exp)
 345                          ,(inline-args (cdr exp))))))
 346      ((symbol? exp)
 347       ;; assume locally bound
 348       exp)
 349      ((number? exp)
 350       `(make-const src ,exp))
 351      ((not exp)
 352       ;; failed match
 353       #f)
 354      (else (error "bad consequent yall" exp))))
 355   `(hashq-set! *primitive-expand-table*
 356                ',sym
 357                (match-lambda*
 358                 ,@(let lp ((in clauses) (out '()))
 359                     (if (null? in)
 360                         (reverse (cons '(_ #f) out))
 361                         (lp (cddr in)
 362                             (cons `((src . ,(car in))
 363                                     ,(consequent (cadr in)))
 364                                   out)))))))
 365
 366 (define-primitive-expander zero? (x)
 367   (= x 0))
 368
 369 ;; FIXME: All the code that uses `const?' is redundant with `peval'.
 370
 371 (define-primitive-expander +
 372   () 0
 373   (x) (values x)
 374   (x y) (if (and (const? y) (eqv? (const-exp y) 1))
 375             (1+ x)
 376             (if (and (const? y) (eqv? (const-exp y) -1))
 377                 (1- x)
 378                 (if (and (const? x) (eqv? (const-exp x) 1))
 379                     (1+ y)
 380                     (if (and (const? x) (eqv? (const-exp x) -1))
 381                         (1- y)
 382                         (+ x y)))))
 383   (x y z ... last) (+ (+ x y . z) last))
 384
 385 (define-primitive-expander *
 386   () 1
 387   (x) (values x)
 388   (x y z ... last) (* (* x y . z) last))
 389
 390 (define-primitive-expander -
 391   (x) (- 0 x)
 392   (x y) (if (and (const? y) (eqv? (const-exp y) 1))
 393             (1- x)
 394             (- x y))
 395   (x y z ... last) (- (- x y . z) last))
 396
 397 (define-primitive-expander /
 398   (x) (/ 1 x)
 399   (x y z ... last) (/ (/ x y . z) last))
 400
 401 (define-primitive-expander logior
 402   () 0
 403   (x) (logior x 0)
 404   (x y) (logior x y)
 405   (x y z ... last) (logior (logior x y . z) last))
 406
 407 (define-primitive-expander logand
 408   () -1
 409   (x) (logand x -1)
 410   (x y) (logand x y)
 411   (x y z ... last) (logand (logand x y . z) last))
 412
 413 (define-primitive-expander caar (x) (car (car x)))
 414 (define-primitive-expander cadr (x) (car (cdr x)))
 415 (define-primitive-expander cdar (x) (cdr (car x)))
 416 (define-primitive-expander cddr (x) (cdr (cdr x)))
 417 (define-primitive-expander caaar (x) (car (car (car x))))
 418 (define-primitive-expander caadr (x) (car (car (cdr x))))
 419 (define-primitive-expander cadar (x) (car (cdr (car x))))
 420 (define-primitive-expander caddr (x) (car (cdr (cdr x))))
 421 (define-primitive-expander cdaar (x) (cdr (car (car x))))
 422 (define-primitive-expander cdadr (x) (cdr (car (cdr x))))
 423 (define-primitive-expander cddar (x) (cdr (cdr (car x))))
 424 (define-primitive-expander cdddr (x) (cdr (cdr (cdr x))))
 425 (define-primitive-expander caaaar (x) (car (car (car (car x)))))
 426 (define-primitive-expander caaadr (x) (car (car (car (cdr x)))))
 427 (define-primitive-expander caadar (x) (car (car (cdr (car x)))))
 428 (define-primitive-expander caaddr (x) (car (car (cdr (cdr x)))))
 429 (define-primitive-expander cadaar (x) (car (cdr (car (car x)))))
 430 (define-primitive-expander cadadr (x) (car (cdr (car (cdr x)))))
 431 (define-primitive-expander caddar (x) (car (cdr (cdr (car x)))))
 432 (define-primitive-expander cadddr (x) (car (cdr (cdr (cdr x)))))
 433 (define-primitive-expander cdaaar (x) (cdr (car (car (car x)))))
 434 (define-primitive-expander cdaadr (x) (cdr (car (car (cdr x)))))
 435 (define-primitive-expander cdadar (x) (cdr (car (cdr (car x)))))
 436 (define-primitive-expander cdaddr (x) (cdr (car (cdr (cdr x)))))
 437 (define-primitive-expander cddaar (x) (cdr (cdr (car (car x)))))
 438 (define-primitive-expander cddadr (x) (cdr (cdr (car (cdr x)))))
 439 (define-primitive-expander cdddar (x) (cdr (cdr (cdr (car x)))))
 440 (define-primitive-expander cddddr (x) (cdr (cdr (cdr (cdr x)))))
 441
 442 (define-primitive-expander cons*
 443   (x) (values x)
 444   (x y) (cons x y)
 445   (x y . rest) (cons x (cons* y . rest)))
 446
 447 (define-primitive-expander acons (x y z)
 448   (cons (cons x y) z))
 449
 450 (define-primitive-expander call/cc (proc)
 451   (call-with-current-continuation proc))
 452
 453 (define-primitive-expander make-struct (vtable tail-size . args)
 454   (if (and (const? tail-size)
 455            (let ((n (const-exp tail-size)))
 456              (and (number? n) (exact? n) (zero? n))))
 457       (make-struct/no-tail vtable . args)
 458       #f))
 459
 460 (define-primitive-expander u8vector-ref (vec i)
 461   (bytevector-u8-ref vec i))
 462 (define-primitive-expander u8vector-set! (vec i x)
 463   (bytevector-u8-set! vec i x))
 464 (define-primitive-expander s8vector-ref (vec i)
 465   (bytevector-s8-ref vec i))
 466 (define-primitive-expander s8vector-set! (vec i x)
 467   (bytevector-s8-set! vec i x))
 468
 469 (define-primitive-expander u16vector-ref (vec i)
 470   (bytevector-u16-native-ref vec (* i 2)))
 471 (define-primitive-expander u16vector-set! (vec i x)
 472   (bytevector-u16-native-set! vec (* i 2) x))
 473 (define-primitive-expander s16vector-ref (vec i)
 474   (bytevector-s16-native-ref vec (* i 2)))
 475 (define-primitive-expander s16vector-set! (vec i x)
 476   (bytevector-s16-native-set! vec (* i 2) x))
 477
 478 (define-primitive-expander u32vector-ref (vec i)
 479   (bytevector-u32-native-ref vec (* i 4)))
 480 (define-primitive-expander u32vector-set! (vec i x)
 481   (bytevector-u32-native-set! vec (* i 4) x))
 482 (define-primitive-expander s32vector-ref (vec i)
 483   (bytevector-s32-native-ref vec (* i 4)))
 484 (define-primitive-expander s32vector-set! (vec i x)
 485   (bytevector-s32-native-set! vec (* i 4) x))
 486
 487 (define-primitive-expander u64vector-ref (vec i)
 488   (bytevector-u64-native-ref vec (* i 8)))
 489 (define-primitive-expander u64vector-set! (vec i x)
 490   (bytevector-u64-native-set! vec (* i 8) x))
 491 (define-primitive-expander s64vector-ref (vec i)
 492   (bytevector-s64-native-ref vec (* i 8)))
 493 (define-primitive-expander s64vector-set! (vec i x)
 494   (bytevector-s64-native-set! vec (* i 8) x))
 495
 496 (define-primitive-expander f32vector-ref (vec i)
 497   (bytevector-ieee-single-native-ref vec (* i 4)))
 498 (define-primitive-expander f32vector-set! (vec i x)
 499   (bytevector-ieee-single-native-set! vec (* i 4) x))
 500 (define-primitive-expander f32vector-ref (vec i)
 501   (bytevector-ieee-single-native-ref vec (* i 4)))
 502 (define-primitive-expander f32vector-set! (vec i x)
 503   (bytevector-ieee-single-native-set! vec (* i 4) x))
 504
 505 (define-primitive-expander f64vector-ref (vec i)
 506   (bytevector-ieee-double-native-ref vec (* i 8)))
 507 (define-primitive-expander f64vector-set! (vec i x)
 508   (bytevector-ieee-double-native-set! vec (* i 8) x))
 509 (define-primitive-expander f64vector-ref (vec i)
 510   (bytevector-ieee-double-native-ref vec (* i 8)))
 511 (define-primitive-expander f64vector-set! (vec i x)
 512   (bytevector-ieee-double-native-set! vec (* i 8) x))
 513
 514 ;; Appropriate for use with either 'eqv?' or 'equal?'.
 515 (define (maybe-simplify-to-eq prim)
 516   (case-lambda
 517     ((src) (make-const src #t))
 518     ((src a) (make-const src #t))
 519     ((src a b)
 520      ;; Simplify cases where either A or B is constant.
 521      (define (maybe-simplify a b)
 522        (and (const? a)
 523             (let ((v (const-exp a)))
 524               (and (or (memq v '(#f #t () #nil))
 525                        (symbol? v)
 526                        (and (integer? v)
 527                             (exact? v)
 528                             (<= v most-positive-fixnum)
 529                             (>= v most-negative-fixnum)))
 530                    (make-primcall src 'eq? (list a b))))))
 531      (or (maybe-simplify a b) (maybe-simplify b a)))
 532     ((src a b . rest)
 533      (make-conditional src (make-primcall src prim (list a b))
 534                        (make-primcall src prim (cons b rest))
 535                        (make-const src #f)))
 536     (else #f)))
 537
 538 (hashq-set! *primitive-expand-table* 'eqv?   (maybe-simplify-to-eq 'eqv?))
 539 (hashq-set! *primitive-expand-table* 'equal? (maybe-simplify-to-eq 'equal?))
 540
 541 (define (expand-chained-comparisons prim)
 542   (case-lambda
 543     ((src) (make-const src #t))
 544     ((src a) (make-const src #t))
 545     ((src a b) #f)
 546     ((src a b . rest)
 547      (make-conditional src (make-primcall src prim (list a b))
 548                        (make-primcall src prim (cons b rest))
 549                        (make-const src #f)))
 550     (else #f)))
 551
 552 (for-each (lambda (prim)
 553             (hashq-set! *primitive-expand-table* prim
 554                         (expand-chained-comparisons prim)))
 555  '(< <= = >= > eq?))
 556
 557 (hashq-set! *primitive-expand-table*
 558             'call-with-prompt
 559             (case-lambda
 560               ((src tag thunk handler)
 561                (make-prompt src #f tag thunk handler))
 562               (else #f)))
 563
 564 (hashq-set! *primitive-expand-table*
 565             'abort-to-prompt*
 566             (case-lambda
 567               ((src tag tail-args)
 568                (make-abort src tag '() tail-args))
 569               (else #f)))
 570 (hashq-set! *primitive-expand-table*
 571             'abort-to-prompt
 572             (case-lambda
 573               ((src tag . args)
 574                (make-abort src tag args (make-const #f '())))
 575               (else #f)))