configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 Boston, MA 02111-1307, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT(m4_esyscmd(. ./GUILE-VERSION && echo -n ${PACKAGE}),
  31         m4_esyscmd(. ./GUILE-VERSION && echo -n ${GUILE_VERSION}))
  32 AC_CONFIG_SRCDIR(GUILE-VERSION)
  33 AM_INIT_AUTOMAKE([no-define])
  34
  35 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  36 AC_CONFIG_SRCDIR([GUILE-VERSION])
  37
  38 . $srcdir/GUILE-VERSION
  39
  40 AM_MAINTAINER_MODE
  41 AM_CONFIG_HEADER([config.h])
  42 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  43
  44 #--------------------------------------------------------------------
  45 #
  46 # Independent Subdirectories
  47 #
  48 #--------------------------------------------------------------------
  49
  50 AC_CONFIG_SUBDIRS(guile-readline)
  51
  52 #--------------------------------------------------------------------
  53
  54 dnl Some more checks for Win32
  55 AC_CYGWIN
  56 AC_MINGW32
  57 AC_LIBTOOL_WIN32_DLL
  58
  59 AC_PROG_INSTALL
  60 AC_PROG_CC
  61 AC_PROG_CPP
  62 AC_PROG_AWK
  63
  64 AC_AIX
  65 AC_ISC_POSIX
  66 AC_MINIX
  67
  68 AM_PROG_CC_STDC
  69
  70 AC_LIBTOOL_DLOPEN
  71 AC_PROG_LIBTOOL
  72 AC_LIB_LTDL
  73
  74 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  75 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  76
  77 AM_PATH_LISPDIR
  78
  79 #--------------------------------------------------------------------
  80 #
  81 # User options (after above tests that may set default CFLAGS etc.)
  82 #
  83 #--------------------------------------------------------------------
  84
  85 GUILE_ERROR_ON_WARNING="yes"
  86
  87 AC_ARG_ENABLE(error-on-warning,
  88   [  --enable-error-on-warning    treat compile warnings as errors],
  89   [case "${enableval}" in
  90      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  91      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  92      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  93    esac])
  94
  95 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
  96 AC_ARG_ENABLE(debug-freelist,
  97   [  --enable-debug-freelist include garbage collector freelist debugging code],
  98   if test "$enable_debug_freelist" = y \
  99      || test "$enable_debug_freelist" = yes; then
 100     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 101   fi)
 102
 103 AC_ARG_ENABLE(debug-malloc,
 104   [  --enable-debug-malloc   include malloc debugging code],
 105   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 106     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 107       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 108   fi)
 109
 110 SCM_I_GSC_GUILE_DEBUG=0
 111 AC_ARG_ENABLE(guile-debug,
 112   [AC_HELP_STRING([--enable-guile-debug],
 113                   [include internal debugging functions])],
 114   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 115     SCM_I_GSC_GUILE_DEBUG=1
 116   fi)
 117
 118 AC_ARG_ENABLE(arrays,
 119   [AC_HELP_STRING([--disable-arrays],[omit array and uniform array support])],
 120   ,
 121   enable_arrays=yes)
 122
 123 AC_ARG_ENABLE(posix,
 124   [  --disable-posix         omit posix interfaces],,
 125   enable_posix=yes)
 126
 127 AC_ARG_ENABLE(networking,
 128   [  --disable-networking    omit networking interfaces],,
 129   enable_networking=yes)
 130
 131 AC_ARG_ENABLE(regex,
 132   [  --disable-regex         omit regular expression interfaces],,
 133   enable_regex=yes)
 134
 135 AC_ARG_ENABLE([discouraged],
 136   AC_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 137
 138 if test "$enable_discouraged" = no; then
 139   SCM_I_GSC_ENABLE_DISCOURAGED=0
 140 else
 141   SCM_I_GSC_ENABLE_DISCOURAGED=1
 142 fi
 143
 144 AC_ARG_ENABLE([deprecated],
 145   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 146
 147 if test "$enable_deprecated" = no; then
 148   SCM_I_GSC_ENABLE_DEPRECATED=0
 149 else
 150   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 151     warn_default=summary
 152   elif test "$enable_deprecated" = shutup; then
 153     warn_default=no
 154   else
 155     warn_default=$enable_deprecated
 156   fi
 157   SCM_I_GSC_ENABLE_DEPRECATED=1
 158   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 159   [Define this to control the default warning level for deprecated features.])
 160 fi
 161
 162 AC_ARG_ENABLE(elisp,
 163   [  --disable-elisp         omit Emacs Lisp support],,
 164   enable_elisp=yes)
 165
 166 #--------------------------------------------------------------------
 167
 168 dnl Check for dynamic linking
 169
 170 use_modules=yes
 171 AC_ARG_WITH(modules,
 172 [  --with-modules[=FILES]  Add support for dynamic modules],
 173 use_modules="$withval")
 174 test -z "$use_modules" && use_modules=yes
 175 DLPREOPEN=
 176 if test "$use_modules" != no; then
 177   if test "$use_modules" = yes; then
 178     DLPREOPEN="-dlpreopen force"
 179   else
 180     DLPREOPEN="-export-dynamic"
 181     for module in $use_modules; do
 182       DLPREOPEN="$DLPREOPEN -dlopen $module"
 183     done
 184   fi
 185 fi
 186
 187 dnl files which are destined for separate modules.
 188
 189 if test "$use_modules" != no; then
 190    AC_LIBOBJ([dynl])
 191 fi
 192
 193 SCM_I_GSC_HAVE_ARRAYS=0
 194 if test "$enable_arrays" = yes; then
 195    AC_LIBOBJ([ramap])
 196    AC_LIBOBJ([unif])
 197    SCM_I_GSC_HAVE_ARRAYS=1
 198 fi
 199
 200 if test "$enable_posix" = yes; then
 201    AC_LIBOBJ([filesys])
 202    AC_LIBOBJ([posix])
 203    AC_DEFINE(HAVE_POSIX, 1,
 204      [Define this if you want support for POSIX system calls in Guile.])
 205 fi
 206
 207 if test "$enable_networking" = yes; then
 208    AC_LIBOBJ([net_db])
 209    AC_LIBOBJ([socket])
 210    AC_DEFINE(HAVE_NETWORKING, 1,
 211      [Define this if you want support for networking in Guile.])
 212 fi
 213
 214 if test "$enable_debug_malloc" = yes; then
 215    AC_LIBOBJ([debug-malloc])
 216 fi
 217
 218 if test "$enable_elisp" = yes; then
 219   SCM_I_GSC_ENABLE_ELISP=1
 220 else
 221   SCM_I_GSC_ENABLE_ELISP=0
 222 fi
 223
 224 AC_C_CONST
 225
 226 AC_C_INLINE
 227 if test "$ac_cv_c_inline" != no; then
 228   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 229 else
 230   SCM_I_GSC_C_INLINE=NULL
 231 fi
 232
 233 AC_C_BIGENDIAN
 234
 235 AC_CHECK_SIZEOF(char)
 236 AC_CHECK_SIZEOF(unsigned char)
 237 AC_CHECK_SIZEOF(short)
 238 AC_CHECK_SIZEOF(unsigned short)
 239 AC_CHECK_SIZEOF(int)
 240 AC_CHECK_SIZEOF(unsigned int)
 241 AC_CHECK_SIZEOF(long)
 242 AC_CHECK_SIZEOF(unsigned long)
 243 AC_CHECK_SIZEOF(size_t)
 244 AC_CHECK_SIZEOF(long long)
 245 AC_CHECK_SIZEOF(unsigned long long)
 246 AC_CHECK_SIZEOF(__int64)
 247 AC_CHECK_SIZEOF(unsigned __int64)
 248 AC_CHECK_SIZEOF(void *)
 249 AC_CHECK_SIZEOF(intptr_t)
 250 AC_CHECK_SIZEOF(uintptr_t)
 251 AC_CHECK_SIZEOF(ptrdiff_t)
 252 AC_CHECK_SIZEOF(size_t)
 253
 254 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 255   AC_MSG_ERROR(sizes of long and void* are not identical)
 256 fi
 257
 258 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 259   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 260 else
 261   SCM_I_GSC_T_PTRDIFF='"long"'
 262 fi
 263 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 264
 265 AC_CHECK_HEADERS([stdint.h])
 266 AC_CHECK_HEADERS([inttypes.h])
 267
 268 AC_CHECK_SIZEOF(intmax_t)
 269
 270 SCM_I_GSC_NEEDS_STDINT_H=0
 271 SCM_I_GSC_NEEDS_INTTYPES_H=0
 272
 273 ### intptr and uintptr (try not to use inttypes if we don't have to)
 274 if test "$ac_cv_header_inttypes_h" = yes; then
 275   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 276     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 277 #include <stdio.h>])
 278     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 279       SCM_I_GSC_NEEDS_INTTYPES_H=1
 280     fi
 281   fi
 282   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 283     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 284 #include <stdio.h>])
 285     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 286       SCM_I_GSC_NEEDS_INTTYPES_H=1
 287     fi
 288   fi
 289 fi
 290
 291 ### See what's provided by stdint.h
 292 if test "$ac_cv_header_stdint_h" = yes; then
 293    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 294    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 295    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 296    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 297    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 298    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 299    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 300    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 301    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 302    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 303 fi
 304
 305 # so we don't get confused by the cache (wish there was a better way
 306 # to check particular headers for the same type...)
 307
 308 unset ac_cv_type_int8_t
 309 unset ac_cv_type_uint8_t
 310 unset ac_cv_type_int16_t
 311 unset ac_cv_type_uint16_t
 312 unset ac_cv_type_int32_t
 313 unset ac_cv_type_uint32_t
 314 unset ac_cv_type_int64_t
 315 unset ac_cv_type_uint64_t
 316 unset ac_cv_type_intmax_t
 317 unset ac_cv_type_uintmax_t
 318
 319 ### See what's provided by inttypes.h
 320 if test "$ac_cv_header_inttypes_h" = yes; then
 321   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 322   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 323   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 324   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 325   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 326   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 327   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 328   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 329   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 330   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 331 fi
 332
 333 # Try hard to find definitions for some required scm_t_*int* types.
 334
 335 ### Required type scm_t_int8
 336 if test "$scm_stdint_has_int8"; then
 337   SCM_I_GSC_T_INT8='"int8_t"'
 338   SCM_I_GSC_NEEDS_STDINT_H=1
 339 elif test "$scm_inttypes_has_int8"; then
 340   SCM_I_GSC_T_INT8='"int8_t"'
 341   SCM_I_GSC_NEEDS_INTTYPES_H=1
 342 elif test "$ac_cv_sizeof_char" -eq 1; then
 343   SCM_I_GSC_T_INT8='"signed char"'
 344 else
 345   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 346 fi
 347 AC_SUBST([SCM_I_GSC_T_INT8])
 348
 349 ### Required type scm_t_uint8
 350 if test "$scm_stdint_has_uint8"; then
 351   SCM_I_GSC_T_UINT8='"uint8_t"'
 352   SCM_I_GSC_NEEDS_STDINT_H=1
 353 elif test "$scm_inttypes_has_uint8"; then
 354   SCM_I_GSC_T_UINT8='"uint8_t"'
 355   SCM_I_GSC_NEEDS_INTTYPES_H=1
 356 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 357   SCM_I_GSC_T_UINT8='"unsigned char"'
 358 else
 359   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 360 fi
 361 AC_SUBST([SCM_I_GSC_T_UINT8])
 362
 363 ### Required type scm_t_int16 (ANSI C says int or short might work)
 364 if test "$scm_stdint_has_int16"; then
 365   SCM_I_GSC_T_INT16='"int16_t"'
 366   SCM_I_GSC_NEEDS_STDINT_H=1
 367 elif test "$scm_inttypes_has_int16"; then
 368   SCM_I_GSC_T_INT16='"int16_t"'
 369   SCM_I_GSC_NEEDS_INTTYPES_H=1
 370 elif test "$ac_cv_sizeof_int" -eq 2; then
 371   SCM_I_GSC_T_INT16='"int"'
 372 elif test "$ac_cv_sizeof_short" -eq 2; then
 373   SCM_I_GSC_T_INT16='"short"'
 374 else
 375   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 376 fi
 377 AC_SUBST([SCM_I_GSC_T_INT16])
 378
 379 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 380 if test "$scm_stdint_has_uint16"; then
 381   SCM_I_GSC_T_UINT16='"uint16_t"'
 382   SCM_I_GSC_NEEDS_STDINT_H=1
 383 elif test "$scm_inttypes_has_uint16"; then
 384   SCM_I_GSC_T_UINT16='"uint16_t"'
 385   SCM_I_GSC_NEEDS_INTTYPES_H=1
 386 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 387   SCM_I_GSC_T_UINT16='"unsigned int"'
 388 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 389   SCM_I_GSC_T_UINT16='"unsigned short"'
 390 else
 391   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 392 fi
 393 AC_SUBST([SCM_I_GSC_T_UINT16])
 394
 395
 396 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 397 if test "$scm_stdint_has_int32"; then
 398   SCM_I_GSC_T_INT32='"int32_t"'
 399   SCM_I_GSC_NEEDS_STDINT_H=1
 400 elif test "$scm_inttypes_has_int32"; then
 401   SCM_I_GSC_T_INT32='"int32_t"'
 402   SCM_I_GSC_NEEDS_INTTYPES_H=1
 403 elif test "$ac_cv_sizeof_int" -eq 4; then
 404   SCM_I_GSC_T_INT32='"int"'
 405 elif test "$ac_cv_sizeof_long" -eq 4; then
 406   SCM_I_GSC_T_INT32='"long"'
 407 elif test "$ac_cv_sizeof_short" -eq 4; then
 408   SCM_I_GSC_T_INT32='"short"'
 409 else
 410   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 411 fi
 412 AC_SUBST([SCM_I_GSC_T_INT32])
 413
 414 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 415 if test "$scm_stdint_has_uint32"; then
 416   SCM_I_GSC_T_UINT32='"uint32_t"'
 417   SCM_I_GSC_NEEDS_STDINT_H=1
 418 elif test "$scm_inttypes_has_uint32"; then
 419   SCM_I_GSC_T_UINT32='"uint32_t"'
 420   SCM_I_GSC_NEEDS_INTTYPES_H=1
 421 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 422   SCM_I_GSC_T_UINT32='"unsigned int"'
 423 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 424   SCM_I_GSC_T_UINT32='"unsigned long"'
 425 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 426   SCM_I_GSC_T_UINT32='"unsigned short"'
 427 else
 428   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 429 fi
 430 AC_SUBST([SCM_I_GSC_T_UINT32])
 431
 432 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 433 ### Also try 'long long' and '__int64' if we have it.
 434 SCM_I_GSC_T_INT64=0
 435 if test "$scm_stdint_has_int64"; then
 436   SCM_I_GSC_T_INT64='"int64_t"'
 437   SCM_I_GSC_NEEDS_STDINT_H=1
 438 elif test "$scm_inttypes_has_int64"; then
 439   SCM_I_GSC_T_INT64='"int64_t"'
 440   SCM_I_GSC_NEEDS_INTTYPES_H=1
 441 elif test "$ac_cv_sizeof_int" -eq 8; then
 442   SCM_I_GSC_T_INT64='"int"'
 443 elif test "$ac_cv_sizeof_long" -eq 8; then
 444   SCM_I_GSC_T_INT64='"long"'
 445 elif test "$ac_cv_sizeof_short" -eq 8; then
 446   SCM_I_GSC_T_INT64='"short"'
 447 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 448   SCM_I_GSC_T_INT64='"long long"'
 449 elif test "$ac_cv_sizeof___int64" -eq 8; then
 450   SCM_I_GSC_T_INT64='"__int64"'
 451 else
 452   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 453 fi
 454 AC_SUBST([SCM_I_GSC_T_INT64])
 455
 456
 457 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 458 ### Also try 'long long' and '__int64' if we have it.
 459 SCM_I_GSC_T_UINT64=0
 460 if test "$scm_stdint_has_uint64"; then
 461   SCM_I_GSC_T_UINT64='"uint64_t"'
 462   SCM_I_GSC_NEEDS_STDINT_H=1
 463 elif test "$scm_inttypes_has_uint64"; then
 464   SCM_I_GSC_T_UINT64='"uint64_t"'
 465   SCM_I_GSC_NEEDS_INTTYPES_H=1
 466 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 467   SCM_I_GSC_T_UINT64='"unsigned int"'
 468 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 469   SCM_I_GSC_T_UINT64='"unsigned long"'
 470 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 471   SCM_I_GSC_T_UINT64='"unsigned short"'
 472 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 473   SCM_I_GSC_T_UINT64='"unsigned long long"'
 474 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 475   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 476 else
 477   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 478 fi
 479 AC_SUBST([SCM_I_GSC_T_UINT64])
 480
 481 ### Required type scm_t_intmax
 482 ###
 483 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 484 ### none of them is available, we use 'long'.
 485 ###
 486 SCM_I_GSC_T_INTMAX=0
 487 if test "$scm_stdint_has_intmax"; then
 488   SCM_I_GSC_T_INTMAX='"intmax_t"'
 489   SCM_I_GSC_NEEDS_STDINT_H=1
 490 elif test "$scm_inttypes_has_intmax"; then
 491   SCM_I_GSC_T_INTMAX='"intmax_t"'
 492   SCM_I_GSC_NEEDS_INTTYPES_H=1
 493 elif test "$ac_cv_sizeof___int64" -ne 0; then
 494   SCM_I_GSC_T_INTMAX='"__int64"'
 495 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 496   SCM_I_GSC_T_INTMAX='"long long"'
 497 else
 498   SCM_I_GSC_T_INTMAX='"long"'
 499 fi
 500 AC_SUBST([SCM_I_GSC_T_INTMAX])
 501
 502 ### Required type scm_t_uintmax
 503 ###
 504 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 505 ### this order.  When none of them is available, we use 'unsigned long'.
 506 ###
 507 SCM_I_GSC_T_UINTMAX=0
 508 if test "$scm_stdint_has_uintmax"; then
 509   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 510   SCM_I_GSC_NEEDS_STDINT_H=1
 511 elif test "$scm_inttypes_has_uintmax"; then
 512   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 513   SCM_I_GSC_NEEDS_INTTYPES_H=1
 514 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 515   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 516 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 517   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 518 else
 519   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 520 fi
 521 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 522
 523
 524 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 525 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 526
 527 AC_HEADER_STDC
 528 AC_HEADER_DIRENT
 529 AC_HEADER_TIME
 530 AC_HEADER_SYS_WAIT
 531
 532 # Reasons for testing:
 533 #   fenv.h - available in C99, but not older systems
 534 #
 535 AC_CHECK_HEADERS([fenv.h io.h libc.h limits.h malloc.h memory.h string.h \
 536 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 537 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 538 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 539 direct.h])
 540
 541 GUILE_HEADER_LIBC_WITH_UNISTD
 542
 543 AC_TYPE_GETGROUPS
 544 AC_TYPE_SIGNAL
 545 AC_TYPE_MODE_T
 546
 547 if test $MINGW32 = no; then
 548         AC_CHECK_LIB(m, main)
 549 fi
 550 AC_CHECK_FUNCS(gethostbyname)
 551 if test $ac_cv_func_gethostbyname = no; then
 552     AC_CHECK_LIB(nsl, gethostbyname)
 553 fi
 554
 555 AC_CHECK_FUNCS(connect)
 556 if test $ac_cv_func_connect = no; then
 557     AC_CHECK_LIB(socket, connect)
 558 fi
 559
 560 dnl
 561 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 562 dnl
 563 EXTRA_DEFS=""
 564 if test "$MINGW32" = "yes" ; then
 565     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 566       [Define if you have the <winsock2.h> header file.])])
 567     AC_CHECK_LIB(ws2_32, main)
 568     AC_LIBOBJ([win32-uname])
 569     AC_LIBOBJ([win32-dirent])
 570     if test "$enable_networking" = yes ; then
 571       AC_LIBOBJ([win32-socket])
 572     fi
 573     if test "$enable_shared" = yes ; then
 574       EXTRA_DEFS="-DSCM_IMPORT"
 575       AC_DEFINE(USE_DLL_IMPORT, 1,
 576         [Define if you need additional CPP macros on Win32 platforms.])
 577     fi
 578     if test x"$enable_ltdl_install" = x"yes" ; then
 579       INCLTDL="-DLIBLTDL_DLL_IMPORT $INCLTDL"
 580     fi
 581 fi
 582 AC_SUBST(EXTRA_DEFS)
 583
 584 # FIXME: check to see if we still need these.
 585 #AC_SUBST(INCLTDL)
 586 #AC_SUBST(LIBLTDL)
 587
 588 AC_SUBST(DLPREOPEN)
 589
 590 # Reasons for testing:
 591 #   crt_externs.h - Darwin specific
 592 #
 593 AC_CHECK_HEADERS([assert.h crt_externs.h])
 594
 595 # Reasons for testing:
 596 #   DINFINITY - OSF specific
 597 #   DQNAN - OSF specific
 598 #       (DINFINITY and DQNAN are actually global variables, not functions)
 599 #   fesetround - available in C99, but not older systems
 600 #   gmtime_r - recent posix, not on old systems
 601 #   readdir_r - recent posix, not on old systems
 602 #   sysconf - not on old systems
 603 #   _NSGetEnviron - Darwin specific
 604 #
 605 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid fesetround ftime fchown getcwd geteuid gettimeofday gmtime_r lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv _NSGetEnviron])
 606
 607 # Reasons for testing:
 608 #   netdb.h - not in mingw
 609 #   sys/param.h - not in mingw
 610 #
 611 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 612 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 613
 614 # crypt() may or may not be available, for instance in some countries there
 615 # are restrictions on cryptography.
 616 #
 617 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 618 # -lcrypt library (eg. Debian GNU/Linux).
 619 #
 620 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 621 # be careful to avoid -lcrypt in this case, since libtool will see there's
 622 # only a static libcrypt and decide to build only a static libguile.
 623 #
 624 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 625 # libraries already in that list.
 626 #
 627 AC_SEARCH_LIBS(crypt, crypt,
 628   [AC_DEFINE(HAVE_CRYPT,1,
 629              [Define to 1 if you have the `crypt' function.])])
 630
 631 dnl GMP tests
 632 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 633   [AC_MSG_ERROR([GNU MP not found, see http://swox.com/gmp])])
 634
 635 # mpz_import is a macro so we need to include <gmp.h>
 636 AC_TRY_LINK([#include <gmp.h>],
 637             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 638   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see http://swox.com/gmp])])
 639
 640 ### Some systems don't declare some functions.  On such systems, we
 641 ### need to at least provide our own K&R-style declarations.
 642
 643 ### GUILE_FUNC_DECLARED(function, headerfile)
 644
 645 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 646 ### not there, #define MISSING_FUNCTION_DECL.
 647 AC_DEFUN([GUILE_FUNC_DECLARED], [
 648   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 649     AC_EGREP_HEADER($1, $2,
 650                     guile_cv_func_$1_declared=yes,
 651                     guile_cv_func_$1_declared=no))
 652   if test [x$guile_cv_func_]$1[_declared] = xno; then
 653     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 654       [Define if the operating system supplies $1 without declaring it.])
 655   fi
 656 ])
 657
 658 GUILE_FUNC_DECLARED(sleep, unistd.h)
 659 GUILE_FUNC_DECLARED(usleep, unistd.h)
 660
 661 AC_CHECK_DECLS([strptime],,,
 662 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 663 #include <time.h>])
 664
 665 ### On some systems usleep has no return value.  If it does have one,
 666 ### we'd like to return it; otherwise, we'll fake it.
 667 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 668   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 669                    unistd.h,
 670                    [guile_cv_func_usleep_return_type=void],
 671                    [guile_cv_func_usleep_return_type=int])])
 672 case "$guile_cv_func_usleep_return_type" in
 673   "void" )
 674     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 675       [Define if the system headers declare usleep to return void.])
 676   ;;
 677 esac
 678
 679 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 680 if test -n "$have_sys_un_h" ; then
 681   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 682     [Define if the system supports Unix-domain (file-domain) sockets.])
 683 fi
 684
 685 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 686
 687 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 688                setnetent    getnetent    endnetent    dnl
 689                setprotoent  getprotoent  endprotoent  dnl
 690                setservent   getservent   endservent   dnl
 691                getnetbyaddr getnetbyname dnl
 692                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 693                inet_pton inet_ntop)
 694
 695 # struct sockaddr field sin_len is only present on BSD systems.
 696 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 697 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 698 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 699 [#ifdef HAVE_SYS_TYPES_H
 700 #include <sys/types.h>
 701 #endif
 702 #include <netinet/in.h>])
 703
 704 AC_MSG_CHECKING(for __libc_stack_end)
 705 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 706 [AC_TRY_LINK([#include <stdio.h>
 707 extern char *__libc_stack_end;],
 708              [printf("%p", (char*) __libc_stack_end);],
 709              guile_cv_have_libc_stack_end=yes,
 710              guile_cv_have_libc_stack_end=no)])
 711 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 712
 713 if test $guile_cv_have_libc_stack_end = yes; then
 714   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 715            [Define if you have the __libc_stack_end variable.])
 716 fi
 717
 718 dnl Some systems do not declare this.  Some systems do declare it, as a
 719 dnl macro.  With cygwin it may be in a DLL.
 720
 721 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 722 AC_CACHE_VAL(guile_cv_have_h_errno,
 723 [AC_TRY_COMPILE([#include <netdb.h>],
 724 [int a = h_errno;],
 725 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 726 AC_MSG_RESULT($guile_cv_have_h_errno)
 727 if test $guile_cv_have_h_errno = yes; then
 728   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 729 fi
 730
 731 AC_MSG_CHECKING(whether uint32_t is defined)
 732 AC_CACHE_VAL(guile_cv_have_uint32_t,
 733   [AC_TRY_COMPILE([#include <sys/types.h>
 734                    #if HAVE_STDINT_H
 735                    #include <stdint.h>
 736                    #endif
 737                    #ifndef __MINGW32__
 738                    #include <netdb.h>
 739                    #endif],
 740                   [uint32_t a;],
 741                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 742 AC_MSG_RESULT($guile_cv_have_uint32_t)
 743 if test $guile_cv_have_uint32_t = yes; then
 744   AC_DEFINE(HAVE_UINT32_T, 1,
 745     [Define if uint32_t typedef is defined when netdb.h is include.])
 746 fi
 747
 748 AC_MSG_CHECKING(for working IPv6 support)
 749 AC_CACHE_VAL(guile_cv_have_ipv6,
 750 [AC_TRY_COMPILE([
 751 #ifdef HAVE_SYS_TYPES_H
 752 #include <sys/types.h>
 753 #endif
 754 #include <netinet/in.h>
 755 #include <sys/socket.h>],
 756 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 757 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 758 AC_MSG_RESULT($guile_cv_have_ipv6)
 759 if test $guile_cv_have_ipv6 = yes; then
 760   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 761 fi
 762
 763 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 764 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 765 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 766 [AC_TRY_COMPILE([
 767 #ifdef HAVE_SYS_TYPES_H
 768 #include <sys/types.h>
 769 #endif
 770 #include <netinet/in.h>],
 771 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 772 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 773 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 774 if test $guile_cv_have_sin6_scope_id = yes; then
 775   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 776     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 777 fi
 778
 779 # struct sockaddr_in6 field sin_len is only present on BSD systems
 780 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 781 [#ifdef HAVE_SYS_TYPES_H
 782 #include <sys/types.h>
 783 #endif
 784 #include <netinet/in.h>])
 785
 786 AC_MSG_CHECKING(whether localtime caches TZ)
 787 AC_CACHE_VAL(guile_cv_localtime_cache,
 788 [if test x$ac_cv_func_tzset = xyes; then
 789 AC_TRY_RUN([#include <time.h>
 790 #if STDC_HEADERS
 791 # include <stdlib.h>
 792 #endif
 793 extern char **environ;
 794 unset_TZ ()
 795 {
 796   char **from, **to;
 797   for (to = from = environ; (*to = *from); from++)
 798     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 799       to++;
 800 }
 801 char TZ_GMT0[] = "TZ=GMT0";
 802 char TZ_PST8[] = "TZ=PST8";
 803 main()
 804 {
 805   time_t now = time ((time_t *) 0);
 806   int hour_GMT0, hour_unset;
 807   if (putenv (TZ_GMT0) != 0)
 808     exit (1);
 809   hour_GMT0 = localtime (&now)->tm_hour;
 810   unset_TZ ();
 811   hour_unset = localtime (&now)->tm_hour;
 812   if (putenv (TZ_PST8) != 0)
 813     exit (1);
 814   if (localtime (&now)->tm_hour == hour_GMT0)
 815     exit (1);
 816   unset_TZ ();
 817   if (localtime (&now)->tm_hour != hour_unset)
 818     exit (1);
 819   exit (0);
 820 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 821 [# If we have tzset, assume the worst when cross-compiling.
 822 guile_cv_localtime_cache=yes])
 823 else
 824         # If we lack tzset, report that localtime does not cache TZ,
 825         # since we can't invalidate the cache if we don't have tzset.
 826         guile_cv_localtime_cache=no
 827 fi])dnl
 828 AC_MSG_RESULT($guile_cv_localtime_cache)
 829 if test $guile_cv_localtime_cache = yes; then
 830   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 831 fi
 832
 833 dnl Test whether system calls are restartable by default on the
 834 dnl current system.  If they are not, we put a loop around every system
 835 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 836 dnl change from the default behaviour.  On the other hand, if signals
 837 dnl are restartable then the loop is not installed and when libguile
 838 dnl initialises it also resets the behaviour of each signal to cause a
 839 dnl restart (in case a different runtime had a different default
 840 dnl behaviour for some reason: e.g., different versions of linux seem
 841 dnl to behave differently.)
 842
 843 AC_SYS_RESTARTABLE_SYSCALLS
 844
 845 if test "$enable_regex" = yes; then
 846    if test "$ac_cv_header_regex_h" = yes ||
 847       test "$ac_cv_header_rxposix_h" = yes ||
 848       test "$ac_cv_header_rx_rxposix_h" = yes; then
 849      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 850      [AC_CHECK_LIB(rx, main)
 851       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 852      [AC_CHECK_LIB(regex, main)
 853       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 854      )
 855      dnl The following should not be necessary, but for some reason
 856      dnl autoheader misses it if we don't include it!
 857      if test "$ac_cv_func_regcomp_norx" = yes ||
 858         test "$ac_cv_func_regcomp_regex" = yes ||
 859         test "$ac_cv_func_regcomp_rx" = yes; then
 860        AC_DEFINE(HAVE_REGCOMP, 1,
 861          [This is included as part of a workaround for a autoheader bug.])
 862      fi
 863    fi
 864 fi
 865
 866 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 867
 868 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 869
 870 # Reasons for testing:
 871 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 872 #                                older systems
 873 #   sincos - GLIBC extension
 874 #
 875 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
 876
 877 # C99 specifies isinf and isnan as macros.
 878 # HP-UX provides only macros, no functions.
 879 # glibc 2.3.2 provides both macros and functions.
 880 # IRIX 6.5 and Solaris 8 only provide functions.
 881 #
 882 # The following tests detect isinf and isnan either as functions or as
 883 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
 884 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
 885 #
 886 AC_MSG_CHECKING([for isinf])
 887 AC_LINK_IFELSE(
 888 [#include <math.h>
 889 int main () { return (isinf(0.0) != 0); }],
 890   [AC_MSG_RESULT([yes])
 891    AC_DEFINE(HAVE_ISINF, 1,
 892              [Define to 1 if you have the `isinf' macro or function.])],
 893   [AC_MSG_RESULT([no])])
 894 AC_MSG_CHECKING([for isnan])
 895 AC_LINK_IFELSE(
 896 [#include <math.h>
 897 #ifdef __MINGW32__
 898 #define isnan _isnan
 899 #endif
 900 int main () { return (isnan(0.0) != 0); }],
 901   [AC_MSG_RESULT([yes])
 902    AC_DEFINE(HAVE_ISNAN, 1,
 903              [Define to 1 if you have the `isnan' macro or function.])],
 904   [AC_MSG_RESULT([no])])
 905
 906 # We must have a proper stack-using alloca in order for stack-copying
 907 # continuations to work properly.  If we don't find a native one,
 908 # abort.
 909
 910 AC_FUNC_ALLOCA
 911 if test "$ALLOCA" = "alloca.o"
 912 then
 913   AC_ERROR([No native alloca found.])
 914 fi
 915
 916 AC_CHECK_MEMBERS([struct stat.st_rdev])
 917 AC_CHECK_MEMBERS([struct stat.st_blksize])
 918
 919 AC_STRUCT_ST_BLOCKS
 920
 921 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 922   [AC_TRY_CPP([#include <sys/stat.h>
 923                #ifndef S_ISLNK
 924                #error no S_ISLNK
 925                #endif],
 926                ac_cv_macro_S_ISLNK=yes,
 927                ac_cv_macro_S_ISLNK=no)])
 928 if test $ac_cv_macro_S_ISLNK = yes; then
 929   AC_DEFINE(HAVE_S_ISLNK, 1,
 930     [Define this if your system defines S_ISLNK in sys/stat.h.])
 931 fi
 932
 933 AC_STRUCT_TIMEZONE
 934 GUILE_STRUCT_UTIMBUF
 935
 936 #--------------------------------------------------------------------
 937 #
 938 # Which way does the stack grow?
 939 #
 940 #--------------------------------------------------------------------
 941
 942 SCM_I_GSC_STACK_GROWS_UP=0
 943 AC_TRY_RUN(aux (l) unsigned long l;
 944              { int x; exit (l >= ((unsigned long)&x)); }
 945            main () { int q; aux((unsigned long)&q); },
 946            [SCM_I_GSC_STACK_GROWS_UP=1],
 947            [],
 948            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
 949
 950 AC_CHECK_SIZEOF(float)
 951 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
 952     AC_DEFINE(SCM_SINGLES, 1,
 953               [Define this if floats are the same size as longs.])
 954 fi
 955
 956 AC_MSG_CHECKING(for struct linger)
 957 AC_CACHE_VAL(scm_cv_struct_linger,
 958         AC_TRY_COMPILE([
 959 #include <sys/types.h>
 960 #include <sys/socket.h>],
 961                         [struct linger lgr;  lgr.l_linger = 100],
 962                         scm_cv_struct_linger="yes",
 963                         scm_cv_struct_linger="no"))
 964 AC_MSG_RESULT($scm_cv_struct_linger)
 965 if test $scm_cv_struct_linger = yes; then
 966         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 967           [Define this if your system defines struct linger, for use with the
 968            getsockopt and setsockopt system calls.])
 969 fi
 970
 971
 972 AC_MSG_CHECKING(for struct timespec)
 973 AC_CACHE_VAL(scm_cv_struct_timespec,
 974         AC_TRY_COMPILE([
 975 #include <time.h>],
 976                         [struct timespec t;  t.tv_nsec = 100],
 977                         scm_cv_struct_timespec="yes",
 978                         scm_cv_struct_timespec="no"))
 979 AC_MSG_RESULT($scm_cv_struct_timespec)
 980 if test $scm_cv_struct_timespec = yes; then
 981   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 982     [Define this if your system defines struct timespec via <time.h>.])
 983 fi
 984
 985 #--------------------------------------------------------------------
 986 #
 987 # Flags for thread support
 988 #
 989 #--------------------------------------------------------------------
 990
 991 SCM_I_GSC_USE_PTHREAD_THREADS=0
 992 SCM_I_GSC_USE_NULL_THREADS=0
 993 SCM_I_GSC_USE_COOP_THREADS=0
 994 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
 995 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
 996 AC_SUBST([SCM_I_GSC_USE_COOP_THREADS])
 997
 998 ### What thread package has the user asked for?
 999 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1000             , with_threads=yes)
1001
1002 case "$with_threads" in
1003   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1004     AC_CHECK_LIB(pthread, main,
1005       LIBS="-lpthread $LIBS"
1006       SCM_I_GSC_USE_PTHREAD_THREADS=1
1007       with_threads="pthreads",
1008       with_threads="null")
1009
1010     if test $GCC = yes; then
1011     AC_DEFINE(_THREAD_SAFE, 1,
1012       [Use thread safe versions of GNU Libc functions.])
1013     fi
1014
1015     AC_MSG_CHECKING(if pthread_mutexattr_settype is declared)
1016     AC_CACHE_VAL(guile_cv_mutexattr_settype_declared,
1017       [AC_TRY_COMPILE([#include <pthread.h>],
1018           [int pthread_mutexattr_settype (int, int);],
1019           guile_cv_mutexattr_settype_declared=no,
1020           guile_cv_mutexattr_settype_declared=yes)])
1021     AC_MSG_RESULT($guile_cv_mutexattr_settype_declared)
1022     if test $guile_cv_mutexattr_settype_declared = yes; then
1023       AC_DEFINE(SCM_MUTEXATTR_SETTYPE_DECLARED, 1,
1024           [Define if pthread.h declares pthread_mutexattr_settype.])
1025     fi
1026
1027     AC_MSG_CHECKING(how to get a fast mutex)
1028     AC_CACHE_VAL(guile_cv_have_mutex_fast,
1029       [AC_TRY_COMPILE([#include <pthread.h>],
1030           [int a = PTHREAD_MUTEX_ADAPTIVE_NP;],
1031           guile_cv_have_mutex_fast=PTHREAD_MUTEX_ADAPTIVE_NP,
1032           guile_cv_have_mutex_fast=none)])
1033     AC_MSG_RESULT($guile_cv_have_mutex_fast)
1034     if test ! $guile_cv_have_mutex_fast = none; then
1035       AC_DEFINE_UNQUOTED(SCM_MUTEX_FAST, $guile_cv_have_mutex_fast,
1036           [The mutex kind enum for fast mutexes.])
1037     fi
1038
1039     AC_MSG_CHECKING(how to get a recursive mutex)
1040     AC_CACHE_VAL(guile_cv_have_mutex_recursive,
1041       [AC_TRY_COMPILE([#include <pthread.h>],
1042         [int a = PTHREAD_MUTEX_RECURSIVE_NP;],
1043          guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE_NP)
1044       if test -z "$guile_cv_have_mutex_recursive"; then
1045           AC_TRY_COMPILE([#include <pthread.h>],
1046             [int a = PTHREAD_MUTEX_RECURSIVE;],
1047             guile_cv_have_mutex_recursive=PTHREAD_MUTEX_RECURSIVE,
1048             guile_cv_have_mutex_recursive=none)
1049         fi])
1050     AC_MSG_RESULT($guile_cv_have_mutex_recursive)
1051     if test ! $guile_cv_have_mutex_recursive = none; then
1052       AC_DEFINE_UNQUOTED(SCM_MUTEX_RECURSIVE, $guile_cv_have_mutex_recursive,
1053          [The mutex kind enum for recursive mutexes.])
1054     fi
1055
1056     # On Solaris, sched_yield lives in -lrt.
1057     AC_SEARCH_LIBS(sched_yield, rt)
1058
1059   ;;
1060 esac
1061
1062 case "$with_threads" in
1063   "pthreads")
1064   ;;
1065   "no" | "null")
1066     SCM_I_GSC_USE_NULL_THREADS=1
1067     with_threads="null-threads"
1068   ;;
1069   * )
1070     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1071   ;;
1072 esac
1073
1074 AC_MSG_CHECKING(what kind of threads to support)
1075 AC_MSG_RESULT($with_threads)
1076
1077 ## Cross building
1078 if test "$cross_compiling" = "yes"; then
1079   AC_MSG_CHECKING(cc for build)
1080   ## /usr/bin/cc still uses wrong assembler
1081   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1082   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1083 else
1084   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1085 fi
1086
1087 ## AC_MSG_CHECKING("if we are cross compiling")
1088 ## AC_MSG_RESULT($cross_compiling)
1089 if test "$cross_compiling" = "yes"; then
1090    AC_MSG_RESULT($CC_FOR_BUILD)
1091 fi
1092
1093 ## No need as yet to be more elaborate
1094 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1095
1096 AC_SUBST(cross_compiling)
1097 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1098 AC_SUBST(CCLD_FOR_BUILD)
1099
1100 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1101 ## --HOST is the platform that PACKAGE is compiled for.
1102 HOST_CC="$CC_FOR_BUILD"
1103 AC_SUBST(HOST_CC)
1104
1105 if test "$cross_compiling" = "yes"; then
1106   AC_MSG_CHECKING(guile for build)
1107   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1108 else
1109   GUILE_FOR_BUILD='$(preinstguile)'
1110 fi
1111
1112 ## AC_MSG_CHECKING("if we are cross compiling")
1113 ## AC_MSG_RESULT($cross_compiling)
1114 if test "$cross_compiling" = "yes"; then
1115    AC_MSG_RESULT($GUILE_FOR_BUILD)
1116 fi
1117 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1118 AC_SUBST(GUILE_FOR_BUILD)
1119
1120 ## If we're using GCC, ask for aggressive warnings.
1121 case "$GCC" in
1122   yes )
1123     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1124     ## much stuff with generic function pointers for that to really be
1125     ## less than exasperating.
1126     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1127     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1128     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1129     # Do this here so we don't screw up any of the tests above that might
1130     # not be "warning free"
1131     if test "${GUILE_ERROR_ON_WARNING}" = yes
1132     then
1133         CFLAGS="${CFLAGS} -Werror"
1134         enable_compile_warnings=no
1135     fi
1136     ;;
1137 esac
1138
1139 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
1140 ## -- I'm disabling it for now in the hopes that the newer autoconf
1141 ## will DTRT -- if not, we need to fix up the sed command to match the
1142 ## others...
1143 ##
1144 ## Remove fileblocks.o from the object list.  This file gets added by
1145 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
1146 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
1147
1148 ## If we're creating a shared library (using libtool!), then we'll
1149 ## need to generate a list of .lo files corresponding to the .o files
1150 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1151 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1152
1153 ## We also need to create corresponding .doc and .x files
1154 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1155 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1156
1157 AC_SUBST(GUILE_MAJOR_VERSION)
1158 AC_SUBST(GUILE_MINOR_VERSION)
1159 AC_SUBST(GUILE_MICRO_VERSION)
1160 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1161 AC_SUBST(GUILE_VERSION)
1162
1163 #######################################################################
1164 # library versioning
1165
1166 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1167 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1168 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1169 AC_SUBST(LIBGUILE_INTERFACE)
1170
1171 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1172 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1173 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1174 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1175 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1176
1177 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1178 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1179 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1180 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1181 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1182
1183 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1184 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1185 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1186 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1187 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1188
1189 #######################################################################
1190
1191 dnl Tell guile-config what flags guile users should link against.
1192 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
1193 AC_SUBST(GUILE_LIBS)
1194
1195 AC_SUBST(AWK)
1196 AC_SUBST(LIBLOBJS)
1197 AC_SUBST(EXTRA_DOT_DOC_FILES)
1198 AC_SUBST(EXTRA_DOT_X_FILES)
1199
1200 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1201 top_builddir_absolute=`pwd`
1202 AC_SUBST(top_builddir_absolute)
1203 top_srcdir_absolute=`(cd $srcdir && pwd)`
1204 AC_SUBST(top_srcdir_absolute)
1205
1206 # Additional SCM_I_GSC definitions are above.
1207 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1208 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1209 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1210 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1211 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1212 AC_SUBST([SCM_I_GSC_HAVE_ARRAYS])
1213 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1214 AC_SUBST([SCM_I_GSC_C_INLINE])
1215 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1216
1217 AC_CONFIG_FILES([
1218   Makefile
1219   am/Makefile
1220   benchmark-suite/Makefile
1221   doc/Makefile
1222   doc/goops/Makefile
1223   doc/r5rs/Makefile
1224   doc/ref/Makefile
1225   doc/tutorial/Makefile
1226   emacs/Makefile
1227   examples/Makefile
1228   examples/box-dynamic-module/Makefile
1229   examples/box-dynamic/Makefile
1230   examples/box-module/Makefile
1231   examples/box/Makefile
1232   examples/modules/Makefile
1233   examples/safe/Makefile
1234   examples/scripts/Makefile
1235   guile-config/Makefile
1236   ice-9/Makefile
1237   ice-9/debugger/Makefile
1238   ice-9/debugger/breakpoints/Makefile
1239   lang/Makefile
1240   lang/elisp/Makefile
1241   lang/elisp/internals/Makefile
1242   lang/elisp/primitives/Makefile
1243   libguile-ltdl/Makefile
1244   libguile-ltdl/upstream/Makefile
1245   libguile/Makefile
1246   oop/Makefile
1247   oop/goops/Makefile
1248   scripts/Makefile
1249   srfi/Makefile
1250   test-suite/Makefile
1251   test-suite/standalone/Makefile
1252 ])
1253
1254 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1255 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1256 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1257 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1258 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1259 AC_CONFIG_FILES([libguile/guile-snarf],
1260                 [chmod +x libguile/guile-snarf])
1261 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1262                 [chmod +x libguile/guile-doc-snarf])
1263 AC_CONFIG_FILES([libguile/guile-func-name-check],
1264                 [chmod +x libguile/guile-func-name-check])
1265 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1266                 [chmod +x libguile/guile-snarf-docs])
1267
1268 AC_OUTPUT
1269
1270 dnl Local Variables:
1271 dnl comment-start: "dnl "
1272 dnl comment-end: ""
1273 dnl comment-start-skip: "\\bdnl\\b\\s *"
1274 dnl End: