module/oop/goops.scm

   1 ;;; installed-scm-file
   2
   3 ;;;; Copyright (C) 1998,1999,2000,2001,2002, 2003, 2006, 2009 Free Software Foundation, Inc.
   4 ;;;;
   5 ;;;; This library is free software; you can redistribute it and/or
   6 ;;;; modify it under the terms of the GNU Lesser General Public
   7 ;;;; License as published by the Free Software Foundation; either
   8 ;;;; version 3 of the License, or (at your option) any later version.
   9 ;;;;
  10 ;;;; This library is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 ;;;; Lesser General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU Lesser General Public
  16 ;;;; License along with this library; if not, write to the Free Software
  17 ;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
  18 ;;;;
  19 \f
  20
  21 ;;;; This software is a derivative work of other copyrighted softwares; the
  22 ;;;; copyright notices of these softwares are placed in the file COPYRIGHTS
  23 ;;;;
  24 ;;;; This file is based upon stklos.stk from the STk distribution by
  25 ;;;; Erick Gallesio <eg@unice.fr>.
  26 ;;;;
  27
  28 (define-module (oop goops)
  29   :use-module (srfi srfi-1)
  30   :export-syntax (define-class class standard-define-class
  31                   define-generic define-accessor define-method
  32                   define-extended-generic define-extended-generics
  33                   method)
  34   :export (goops-version is-a? class-of
  35            ensure-metaclass ensure-metaclass-with-supers
  36            make-class
  37            make-generic ensure-generic
  38            make-extended-generic
  39            make-accessor ensure-accessor
  40            add-method!
  41            class-slot-ref class-slot-set! slot-unbound slot-missing
  42            slot-definition-name  slot-definition-options
  43            slot-definition-allocation
  44            slot-definition-getter slot-definition-setter
  45            slot-definition-accessor
  46            slot-definition-init-value slot-definition-init-form
  47            slot-definition-init-thunk slot-definition-init-keyword
  48            slot-init-function class-slot-definition
  49            method-source
  50            compute-cpl compute-std-cpl compute-get-n-set compute-slots
  51            compute-getter-method compute-setter-method
  52            allocate-instance initialize make-instance make
  53            no-next-method  no-applicable-method no-method
  54            change-class update-instance-for-different-class
  55            shallow-clone deep-clone
  56            class-redefinition
  57            apply-generic apply-method apply-methods
  58            compute-applicable-methods %compute-applicable-methods
  59            method-more-specific? sort-applicable-methods
  60            class-subclasses class-methods
  61            goops-error
  62            min-fixnum max-fixnum
  63            ;;; *fixme* Should go into goops.c
  64            instance?  slot-ref-using-class
  65            slot-set-using-class! slot-bound-using-class?
  66            slot-exists-using-class? slot-ref slot-set! slot-bound?
  67            class-name class-direct-supers class-direct-subclasses
  68            class-direct-methods class-direct-slots class-precedence-list
  69            class-slots
  70            generic-function-name
  71            generic-function-methods method-generic-function
  72            method-specializers method-formals
  73            primitive-generic-generic enable-primitive-generic!
  74            method-procedure accessor-method-slot-definition
  75            slot-exists? make find-method get-keyword)
  76   :no-backtrace)
  77
  78 (define *goops-module* (current-module))
  79
  80 ;; First initialize the builtin part of GOOPS
  81 (eval-when (eval load compile)
  82   (%init-goops-builtins))
  83
  84 (eval-when (eval load compile)
  85   (use-modules ((language tree-il primitives) :select (add-interesting-primitive!)))
  86   (add-interesting-primitive! 'class-of)
  87   (define (@slot-ref o n)
  88     (struct-ref o n))
  89   (define (@slot-set! o n v)
  90     (struct-set! o n v))
  91   (add-interesting-primitive! '@slot-ref)
  92   (add-interesting-primitive! '@slot-set!))
  93
  94 ;; Then load the rest of GOOPS
  95 (use-modules (oop goops util)
  96              (oop goops dispatch)
  97              (oop goops compile))
  98
  99 \f
 100 (eval-when (eval load compile)
 101   (define min-fixnum (- (expt 2 29)))
 102   (define max-fixnum (- (expt 2 29) 1)))
 103
 104 ;;
 105 ;; goops-error
 106 ;;
 107 (define (goops-error format-string . args)
 108   (save-stack)
 109   (scm-error 'goops-error #f format-string args '()))
 110
 111 ;;
 112 ;; is-a?
 113 ;;
 114 (define (is-a? obj class)
 115   (and (memq class (class-precedence-list (class-of obj))) #t))
 116
 117
 118 ;;;
 119 ;;; {Meta classes}
 120 ;;;
 121
 122 (define ensure-metaclass-with-supers
 123   (let ((table-of-metas '()))
 124     (lambda (meta-supers)
 125       (let ((entry (assoc meta-supers table-of-metas)))
 126         (if entry
 127             ;; Found a previously created metaclass
 128             (cdr entry)
 129             ;; Create a new meta-class which inherit from "meta-supers"
 130             (let ((new (make <class> #:dsupers meta-supers
 131                                      #:slots   '()
 132                                      #:name   (gensym "metaclass"))))
 133               (set! table-of-metas (cons (cons meta-supers new) table-of-metas))
 134               new))))))
 135
 136 (define (ensure-metaclass supers)
 137   (if (null? supers)
 138       <class>
 139       (let* ((all-metas (map (lambda (x) (class-of x)) supers))
 140              (all-cpls  (append-map (lambda (m)
 141                                       (cdr (class-precedence-list m)))
 142                                     all-metas))
 143              (needed-metas '()))
 144         ;; Find the most specific metaclasses.  The new metaclass will be
 145         ;; a subclass of these.
 146         (for-each
 147          (lambda (meta)
 148            (if (and (not (member meta all-cpls))
 149                       (not (member meta needed-metas)))
 150              (set! needed-metas (append needed-metas (list meta)))))
 151          all-metas)
 152         ;; Now return a subclass of the metaclasses we found.
 153         (if (null? (cdr needed-metas))
 154             (car needed-metas)  ; If there's only one, just use it.
 155             (ensure-metaclass-with-supers needed-metas)))))
 156
 157 ;;;
 158 ;;; {Classes}
 159 ;;;
 160
 161 ;;; (define-class NAME (SUPER ...) SLOT-DEFINITION ... OPTION ...)
 162 ;;;
 163 ;;;   SLOT-DEFINITION ::= SLOT-NAME | (SLOT-NAME OPTION ...)
 164 ;;;   OPTION ::= KEYWORD VALUE
 165 ;;;
 166
 167 (define (kw-do-map mapper f kwargs)
 168   (define (keywords l)
 169     (cond
 170      ((null? l) '())
 171      ((or (null? (cdr l)) (not (keyword? (car l))))
 172       (goops-error "malformed keyword arguments: ~a" kwargs))
 173      (else (cons (car l) (keywords (cddr l))))))
 174   (define (args l)
 175     (if (null? l) '() (cons (cadr l) (args (cddr l)))))
 176   ;; let* to check keywords first
 177   (let* ((k (keywords kwargs))
 178          (a (args kwargs)))
 179     (mapper f k a)))
 180
 181 (define (make-class supers slots . options)
 182   (let* ((name (get-keyword #:name options (make-unbound)))
 183          (supers (if (not (or-map (lambda (class)
 184                                     (memq <object>
 185                                           (class-precedence-list class)))
 186                                   supers))
 187                      (append supers (list <object>))
 188                      supers))
 189          (metaclass (or (get-keyword #:metaclass options #f)
 190                         (ensure-metaclass supers))))
 191
 192     ;; Verify that all direct slots are different and that we don't inherit
 193     ;; several time from the same class
 194     (let ((tmp1 (find-duplicate supers))
 195           (tmp2 (find-duplicate (map slot-definition-name slots))))
 196       (if tmp1
 197           (goops-error "make-class: super class ~S is duplicate in class ~S"
 198                        tmp1 name))
 199       (if tmp2
 200           (goops-error "make-class: slot ~S is duplicate in class ~S"
 201                        tmp2 name)))
 202
 203     ;; Everything seems correct, build the class
 204     (apply make metaclass
 205            #:dsupers supers
 206            #:slots slots
 207            #:name name
 208            options)))
 209
 210 ;;; (class (SUPER ...) SLOT-DEFINITION ... OPTION ...)
 211 ;;;
 212 ;;;   SLOT-DEFINITION ::= SLOT-NAME | (SLOT-NAME OPTION ...)
 213 ;;;   OPTION ::= KEYWORD VALUE
 214 ;;;
 215 (define-macro (class supers . slots)
 216   (define (make-slot-definition-forms slots)
 217     (map
 218      (lambda (def)
 219        (cond
 220         ((pair? def)
 221          `(list ',(car def)
 222                 ,@(kw-do-map append-map
 223                              (lambda (kw arg)
 224                                (case kw
 225                                  ((#:init-form)
 226                                   `(#:init-form ',arg
 227                                     #:init-thunk (lambda () ,arg)))
 228                                  (else (list kw arg))))
 229                              (cdr def))))
 230         (else
 231          `(list ',def))))
 232      slots))
 233   (if (not (list? supers))
 234       (goops-error "malformed superclass list: ~S" supers))
 235   (let ((slots (take-while (lambda (x) (not (keyword? x))) slots))
 236         (options (or (find-tail keyword? slots) '())))
 237     `(make-class
 238       ;; evaluate super class variables
 239       (list ,@supers)
 240       ;; evaluate slot definitions, except the slot name!
 241       (list ,@(make-slot-definition-forms slots))
 242       ;; evaluate class options
 243       ,@options)))
 244
 245 (define-syntax define-class-pre-definition
 246   (lambda (x)
 247     (syntax-case x ()
 248       ((_ (k arg rest ...) out ...)
 249        (keyword? (syntax->datum (syntax k)))
 250        (case (syntax->datum (syntax k))
 251          ((#:getter #:setter)
 252           (syntax
 253            (define-class-pre-definition (rest ...)
 254              out ...
 255              (if (or (not (defined? 'arg))
 256                      (not (is-a? arg <generic>)))
 257                  (toplevel-define!
 258                   'arg
 259                   (ensure-generic (if (defined? 'arg) arg #f) 'arg))))))
 260          ((#:accessor)
 261           (syntax
 262            (define-class-pre-definition (rest ...)
 263              out ...
 264              (if (or (not (defined? 'arg))
 265                      (not (is-a? arg <accessor>)))
 266                  (toplevel-define!
 267                   'arg
 268                   (ensure-accessor (if (defined? 'arg) arg #f) 'arg))))))
 269          (else
 270           (syntax
 271            (define-class-pre-definition (rest ...) out ...)))))
 272       ((_ () out ...)
 273        (syntax (begin out ...))))))
 274
 275 ;; Some slot options require extra definitions to be made. In
 276 ;; particular, we want to make sure that the generic function objects
 277 ;; which represent accessors exist before `make-class' tries to add
 278 ;; methods to them.
 279 (define-syntax define-class-pre-definitions
 280   (lambda (x)
 281     (syntax-case x ()
 282       ((_ () out ...)
 283        (syntax (begin out ...)))
 284       ((_ (slot rest ...) out ...)
 285        (keyword? (syntax->datum (syntax slot)))
 286        (syntax (begin out ...)))
 287       ((_ (slot rest ...) out ...)
 288        (identifier? (syntax slot))
 289        (syntax (define-class-pre-definitions (rest ...)
 290                  out ...)))
 291       ((_ ((slotname slotopt ...) rest ...) out ...)
 292        (syntax (define-class-pre-definitions (rest ...)
 293                  out ... (define-class-pre-definition (slotopt ...))))))))
 294
 295 (define-syntax define-class
 296   (syntax-rules ()
 297     ((_ name supers slot ...)
 298      (begin
 299        (define-class-pre-definitions (slot ...))
 300        (if (and (defined? 'name)
 301                 (is-a? name <class>)
 302                 (memq <object> (class-precedence-list name)))
 303            (class-redefinition name
 304                                (class supers slot ... #:name 'name))
 305            (toplevel-define! 'name (class supers slot ... #:name 'name)))))))
 306
 307 (define-syntax standard-define-class
 308   (syntax-rules ()
 309     ((_ arg ...) (define-class arg ...))))
 310
 311 ;;;
 312 ;;; {Generic functions and accessors}
 313 ;;;
 314
 315 ;; Apparently the desired semantics are that we extend previous
 316 ;; procedural definitions, but that if `name' was already a generic, we
 317 ;; overwrite its definition.
 318 (define-macro (define-generic name)
 319   (if (not (symbol? name))
 320       (goops-error "bad generic function name: ~S" name))
 321   `(define ,name
 322      (if (and (defined? ',name) (is-a? ,name <generic>))
 323          (make <generic> #:name ',name)
 324          (ensure-generic (if (defined? ',name) ,name #f) ',name))))
 325
 326 (define-macro (define-extended-generic name val)
 327   (if (not (symbol? name))
 328       (goops-error "bad generic function name: ~S" name))
 329   `(define ,name (make-extended-generic ,val ',name)))
 330
 331 (define-macro (define-extended-generics names . args)
 332   (let ((prefixes (get-keyword #:prefix args #f)))
 333     (if prefixes
 334         `(begin
 335            ,@(map (lambda (name)
 336                     `(define-extended-generic ,name
 337                        (list ,@(map (lambda (prefix)
 338                                       (symbol-append prefix name))
 339                                     prefixes))))
 340                   names))
 341         (goops-error "no prefixes supplied"))))
 342
 343 (define (make-generic . name)
 344   (let ((name (and (pair? name) (car name))))
 345     (make <generic> #:name name)))
 346
 347 (define (make-extended-generic gfs . name)
 348   (let* ((name (and (pair? name) (car name)))
 349          (gfs (if (pair? gfs) gfs (list gfs)))
 350          (gws? (any (lambda (gf) (is-a? gf <generic-with-setter>)) gfs)))
 351     (let ((ans (if gws?
 352                    (let* ((sname (and name (make-setter-name name)))
 353                           (setters
 354                            (append-map (lambda (gf)
 355                                          (if (is-a? gf <generic-with-setter>)
 356                                              (list (ensure-generic (setter gf)
 357                                                                    sname))
 358                                              '()))
 359                                        gfs))
 360                           (es (make <extended-generic-with-setter>
 361                                 #:name name
 362                                 #:extends gfs
 363                                 #:setter (make <extended-generic>
 364                                            #:name sname
 365                                            #:extends setters))))
 366                      (extended-by! setters (setter es))
 367                      es)
 368                    (make <extended-generic>
 369                      #:name name
 370                      #:extends gfs))))
 371       (extended-by! gfs ans)
 372       ans)))
 373
 374 (define (extended-by! gfs eg)
 375   (for-each (lambda (gf)
 376               (slot-set! gf 'extended-by
 377                          (cons eg (slot-ref gf 'extended-by))))
 378             gfs))
 379
 380 (define (not-extended-by! gfs eg)
 381   (for-each (lambda (gf)
 382               (slot-set! gf 'extended-by
 383                          (delq! eg (slot-ref gf 'extended-by))))
 384             gfs))
 385
 386 (define (ensure-generic old-definition . name)
 387   (let ((name (and (pair? name) (car name))))
 388     (cond ((is-a? old-definition <generic>) old-definition)
 389           ((procedure-with-setter? old-definition)
 390            (make <generic-with-setter>
 391                  #:name name
 392                  #:default (procedure old-definition)
 393                  #:setter (setter old-definition)))
 394           ((procedure? old-definition)
 395            (make <generic> #:name name #:default old-definition))
 396           (else (make <generic> #:name name)))))
 397
 398 ;; same semantics as <generic>
 399 (define-syntax define-accessor
 400   (syntax-rules ()
 401     ((_ name)
 402      (define name
 403        (cond ((not (defined? 'name))  (ensure-accessor #f 'name))
 404              ((is-a? name <accessor>) (make <accessor> #:name 'name))
 405              (else                    (ensure-accessor name 'name)))))))
 406
 407 (define (make-setter-name name)
 408   (string->symbol (string-append "setter:" (symbol->string name))))
 409
 410 (define (make-accessor . name)
 411   (let ((name (and (pair? name) (car name))))
 412     (make <accessor>
 413           #:name name
 414           #:setter (make <generic>
 415                          #:name (and name (make-setter-name name))))))
 416
 417 (define (ensure-accessor proc . name)
 418   (let ((name (and (pair? name) (car name))))
 419     (cond ((and (is-a? proc <accessor>)
 420                 (is-a? (setter proc) <generic>))
 421            proc)
 422           ((is-a? proc <generic-with-setter>)
 423            (upgrade-accessor proc (setter proc)))
 424           ((is-a? proc <generic>)
 425            (upgrade-accessor proc (make-generic name)))
 426           ((procedure-with-setter? proc)
 427            (make <accessor>
 428                  #:name name
 429                  #:default (procedure proc)
 430                  #:setter (ensure-generic (setter proc) name)))
 431           ((procedure? proc)
 432            (ensure-accessor (ensure-generic proc name) name))
 433           (else
 434            (make-accessor name)))))
 435
 436 (define (upgrade-accessor generic setter)
 437   (let ((methods (slot-ref generic 'methods))
 438         (gws (make (if (is-a? generic <extended-generic>)
 439                        <extended-generic-with-setter>
 440                        <accessor>)
 441                    #:name (generic-function-name generic)
 442                    #:extended-by (slot-ref generic 'extended-by)
 443                    #:setter setter)))
 444     (if (is-a? generic <extended-generic>)
 445         (let ((gfs (slot-ref generic 'extends)))
 446           (not-extended-by! gfs generic)
 447           (slot-set! gws 'extends gfs)
 448           (extended-by! gfs gws)))
 449     ;; Steal old methods
 450     (for-each (lambda (method)
 451                 (slot-set! method 'generic-function gws))
 452               methods)
 453     (slot-set! gws 'methods methods)
 454     gws))
 455
 456 ;;;
 457 ;;; {Methods}
 458 ;;;
 459
 460 (define (toplevel-define! name val)
 461   (module-define! (current-module) name val))
 462
 463 (define-syntax define-method
 464   (syntax-rules (setter)
 465     ((_ ((setter name) . args) body ...)
 466      (begin
 467        (if (or (not (defined? 'name))
 468                (not (is-a? name <accessor>)))
 469            (toplevel-define! 'name
 470                              (ensure-accessor
 471                               (if (defined? 'name) name #f) 'name)))
 472        (add-method! (setter name) (method args body ...))))
 473     ((_ (name . args) body ...)
 474      (begin
 475        ;; FIXME: this code is how it always was, but it's quite cracky:
 476        ;; it will only define the generic function if it was undefined
 477        ;; before (ok), or *was defined to #f*. The latter is crack. But
 478        ;; there are bootstrap issues about fixing this -- change it to
 479        ;; (is-a? name <generic>) and see.
 480        (if (or (not (defined? 'name))
 481                (not name))
 482            (toplevel-define! 'name (make <generic> #:name 'name)))
 483        (add-method! name (method args body ...))))))
 484
 485 (define-syntax method
 486   (lambda (x)
 487     (define (parse-args args)
 488       (let lp ((ls args) (formals '()) (specializers '()))
 489         (syntax-case ls ()
 490           (((f s) . rest)
 491            (and (identifier? (syntax f)) (identifier? (syntax s)))
 492            (lp (syntax rest)
 493                (cons (syntax f) formals)
 494                (cons (syntax s) specializers)))
 495           ((f . rest)
 496            (identifier? (syntax f))
 497            (lp (syntax rest)
 498                (cons (syntax f) formals)
 499                (cons (syntax <top>) specializers)))
 500           (()
 501            (list (reverse formals)
 502                  (reverse (cons (syntax '()) specializers))))
 503           (tail
 504            (identifier? (syntax tail))
 505            (list (append (reverse formals) (syntax tail))
 506                  (reverse (cons (syntax <top>) specializers)))))))
 507
 508     (define (find-free-id exp referent)
 509       (syntax-case exp ()
 510         ((x . y)
 511          (or (find-free-id (syntax x) referent)
 512              (find-free-id (syntax y) referent)))
 513         (x
 514          (identifier? (syntax x))
 515          (let ((id (datum->syntax (syntax x) referent)))
 516            (and (free-identifier=? (syntax x) id) id)))
 517         (_ #f)))
 518
 519     (define (compute-procedure formals body)
 520       (syntax-case body ()
 521         ((body0 ...)
 522          (with-syntax ((formals formals))
 523            (syntax (lambda formals body0 ...))))))
 524
 525     (define (->proper args)
 526       (let lp ((ls args) (out '()))
 527         (syntax-case ls ()
 528           ((x . xs)        (lp (syntax xs) (cons (syntax x) out)))
 529           (()              (reverse out))
 530           (tail            (reverse (cons (syntax tail) out))))))
 531
 532     (define (compute-make-procedure formals body next-method)
 533       (syntax-case body ()
 534         ((body ...)
 535          (with-syntax ((next-method next-method))
 536            (syntax-case formals ()
 537              ((formal ...)
 538               (syntax
 539                (lambda (real-next-method)
 540                  (lambda (formal ...)
 541                    (let ((next-method (lambda args
 542                                         (if (null? args)
 543                                             (real-next-method formal ...)
 544                                             (apply real-next-method args)))))
 545                      body ...)))))
 546              (formals
 547               (with-syntax (((formal ...) (->proper (syntax formals))))
 548                 (syntax
 549                  (lambda (real-next-method)
 550                    (lambda formals
 551                      (let ((next-method (lambda args
 552                                           (if (null? args)
 553                                               (apply real-next-method formal ...)
 554                                               (apply real-next-method args)))))
 555                        body ...)))))))))))
 556
 557     (define (compute-procedures formals body)
 558       ;; So, our use of this is broken, because it operates on the
 559       ;; pre-expansion source code. It's equivalent to just searching
 560       ;; for referent in the datums. Ah well.
 561       (let ((id (find-free-id body 'next-method)))
 562         (if id
 563             ;; return a make-procedure
 564             (values (syntax #f)
 565                     (compute-make-procedure formals body id))
 566             (values (compute-procedure formals body)
 567                     (syntax #f)))))
 568
 569     (syntax-case x ()
 570       ((_ args) (syntax (method args (if #f #f))))
 571       ((_ args body0 body1 ...)
 572        (with-syntax (((formals (specializer ...)) (parse-args (syntax args))))
 573          (call-with-values
 574              (lambda ()
 575                (compute-procedures (syntax formals) (syntax (body0 body1 ...))))
 576            (lambda (procedure make-procedure)
 577              (with-syntax ((procedure procedure)
 578                            (make-procedure make-procedure))
 579                (syntax
 580                 (make <method>
 581                   #:specializers (cons* specializer ...)
 582                   #:formals 'formals
 583                   #:body '(body0 body1 ...)
 584                   #:make-procedure make-procedure
 585                   #:procedure procedure))))))))))
 586
 587 ;;;
 588 ;;; {add-method!}
 589 ;;;
 590
 591 (define (add-method-in-classes! m)
 592   ;; Add method in all the classes which appears in its specializers list
 593   (for-each* (lambda (x)
 594                (let ((dm (class-direct-methods x)))
 595                  (if (not (memq m dm))
 596                      (slot-set! x 'direct-methods (cons m dm)))))
 597              (method-specializers m)))
 598
 599 (define (remove-method-in-classes! m)
 600   ;; Remove method in all the classes which appears in its specializers list
 601   (for-each* (lambda (x)
 602                (slot-set! x
 603                           'direct-methods
 604                           (delv! m (class-direct-methods x))))
 605              (method-specializers m)))
 606
 607 (define (compute-new-list-of-methods gf new)
 608   (let ((new-spec (method-specializers new))
 609         (methods  (slot-ref gf 'methods)))
 610     (let loop ((l methods))
 611       (if (null? l)
 612           (cons new methods)
 613           (if (equal? (method-specializers (car l)) new-spec)
 614               (begin
 615                 ;; This spec. list already exists. Remove old method from dependents
 616                 (remove-method-in-classes! (car l))
 617                 (set-car! l new)
 618                 methods)
 619               (loop (cdr l)))))))
 620
 621 (define internal-add-method!
 622   (method ((gf <generic>) (m <method>))
 623     (slot-set! m  'generic-function gf)
 624     (slot-set! gf 'methods (compute-new-list-of-methods gf m))
 625     (let ((specializers (slot-ref m 'specializers)))
 626       (slot-set! gf 'n-specialized
 627                  (max (length* specializers)
 628                       (slot-ref gf 'n-specialized))))
 629     (%invalidate-method-cache! gf)
 630     (add-method-in-classes! m)
 631     *unspecified*))
 632
 633 (define-generic add-method!)
 634
 635 ((method-procedure internal-add-method!) add-method! internal-add-method!)
 636
 637 (define-method (add-method! (proc <procedure>) (m <method>))
 638   (if (generic-capability? proc)
 639       (begin
 640         (enable-primitive-generic! proc)
 641         (add-method! proc m))
 642       (next-method)))
 643
 644 (define-method (add-method! (pg <primitive-generic>) (m <method>))
 645   (add-method! (primitive-generic-generic pg) m))
 646
 647 (define-method (add-method! obj (m <method>))
 648   (goops-error "~S is not a valid generic function" obj))
 649
 650 ;;;
 651 ;;; {Access to meta objects}
 652 ;;;
 653
 654 ;;;
 655 ;;; Methods
 656 ;;;
 657 (define-method (method-source (m <method>))
 658   (let* ((spec (map* class-name (slot-ref m 'specializers)))
 659          (src (procedure-source (slot-ref m 'procedure))))
 660     (and src
 661          (let ((args (cadr src))
 662                (body (cddr src)))
 663            (cons 'method
 664                  (cons (map* list args spec)
 665                        body))))))
 666
 667 (define-method (method-formals (m <method>))
 668   (slot-ref m 'formals))
 669
 670 ;;;
 671 ;;; Slots
 672 ;;;
 673 (define slot-definition-name car)
 674
 675 (define slot-definition-options cdr)
 676
 677 (define (slot-definition-allocation s)
 678   (get-keyword #:allocation (cdr s) #:instance))
 679
 680 (define (slot-definition-getter s)
 681   (get-keyword #:getter (cdr s) #f))
 682
 683 (define (slot-definition-setter s)
 684   (get-keyword #:setter (cdr s) #f))
 685
 686 (define (slot-definition-accessor s)
 687   (get-keyword #:accessor (cdr s) #f))
 688
 689 (define (slot-definition-init-value s)
 690   ;; can be #f, so we can't use #f as non-value
 691   (get-keyword #:init-value (cdr s) (make-unbound)))
 692
 693 (define (slot-definition-init-form s)
 694   (get-keyword #:init-form (cdr s) (make-unbound)))
 695
 696 (define (slot-definition-init-thunk s)
 697   (get-keyword #:init-thunk (cdr s) #f))
 698
 699 (define (slot-definition-init-keyword s)
 700   (get-keyword #:init-keyword (cdr s) #f))
 701
 702 (define (class-slot-definition class slot-name)
 703   (assq slot-name (class-slots class)))
 704
 705 (define (slot-init-function class slot-name)
 706   (cadr (assq slot-name (slot-ref class 'getters-n-setters))))
 707
 708 (define (accessor-method-slot-definition obj)
 709   "Return the slot definition of the accessor @var{obj}."
 710   (slot-ref obj 'slot-definition))
 711
 712
 713 ;;;
 714 ;;; {Standard methods used by the C runtime}
 715 ;;;
 716
 717 ;;; Methods to compare objects
 718 ;;;
 719
 720 ;; Have to do this in a strange order because equal? is used in the
 721 ;; add-method! implementation; we need to make sure that when the
 722 ;; primitive is extended, that the generic has a method. =
 723 (define g-equal? (make-generic 'equal?))
 724 ;; When this generic gets called, we will have already checked eq? and
 725 ;; eqv? -- the purpose of this generic is to extend equality. So by
 726 ;; default, there is no extension, thus the #f return.
 727 (add-method! g-equal? (method (x y) #f))
 728 (set-primitive-generic! equal? g-equal?)
 729
 730 ;;;
 731 ;;; methods to display/write an object
 732 ;;;
 733
 734 ;     Code for writing objects must test that the slots they use are
 735 ;     bound. Otherwise a slot-unbound method will be called and will
 736 ;     conduct to an infinite loop.
 737
 738 ;; Write
 739 (define (display-address o file)
 740   (display (number->string (object-address o) 16) file))
 741
 742 (define-method (write o file)
 743   (display "#<instance " file)
 744   (display-address o file)
 745   (display #\> file))
 746
 747 (define write-object (primitive-generic-generic write))
 748
 749 (define-method (write (o <object>) file)
 750   (let ((class (class-of o)))
 751     (if (slot-bound? class 'name)
 752         (begin
 753           (display "#<" file)
 754           (display (class-name class) file)
 755           (display #\space file)
 756           (display-address o file)
 757           (display #\> file))
 758         (next-method))))
 759
 760 (define-method (write (class <class>) file)
 761   (let ((meta (class-of class)))
 762     (if (and (slot-bound? class 'name)
 763              (slot-bound? meta 'name))
 764         (begin
 765           (display "#<" file)
 766           (display (class-name meta) file)
 767           (display #\space file)
 768           (display (class-name class) file)
 769           (display #\space file)
 770           (display-address class file)
 771           (display #\> file))
 772         (next-method))))
 773
 774 (define-method (write (gf <generic>) file)
 775   (let ((meta (class-of gf)))
 776     (if (and (slot-bound? meta 'name)
 777              (slot-bound? gf 'methods))
 778         (begin
 779           (display "#<" file)
 780           (display (class-name meta) file)
 781           (let ((name (generic-function-name gf)))
 782             (if name
 783                 (begin
 784                   (display #\space file)
 785                   (display name file))))
 786           (display " (" file)
 787           (display (length (generic-function-methods gf)) file)
 788           (display ")>" file))
 789         (next-method))))
 790
 791 (define-method (write (o <method>) file)
 792   (let ((meta (class-of o)))
 793     (if (and (slot-bound? meta 'name)
 794              (slot-bound? o 'specializers))
 795         (begin
 796           (display "#<" file)
 797           (display (class-name meta) file)
 798           (display #\space file)
 799           (display (map* (lambda (spec)
 800                            (if (slot-bound? spec 'name)
 801                                (slot-ref spec 'name)
 802                                spec))
 803                          (method-specializers o))
 804                    file)
 805           (display #\space file)
 806           (display-address o file)
 807           (display #\> file))
 808         (next-method))))
 809
 810 ;; Display (do the same thing as write by default)
 811 (define-method (display o file)
 812   (write-object o file))
 813
 814 ;;;
 815 ;;; Handling of duplicate bindings in the module system
 816 ;;;
 817
 818 (define-method (merge-generics (module <module>)
 819                                (name <symbol>)
 820                                (int1 <module>)
 821                                (val1 <top>)
 822                                (int2 <module>)
 823                                (val2 <top>)
 824                                (var <top>)
 825                                (val <top>))
 826   #f)
 827
 828 (define-method (merge-generics (module <module>)
 829                                (name <symbol>)
 830                                (int1 <module>)
 831                                (val1 <generic>)
 832                                (int2 <module>)
 833                                (val2 <generic>)
 834                                (var <top>)
 835                                (val <boolean>))
 836   (and (not (eq? val1 val2))
 837        (make-variable (make-extended-generic (list val2 val1) name))))
 838
 839 (define-method (merge-generics (module <module>)
 840                                (name <symbol>)
 841                                (int1 <module>)
 842                                (val1 <generic>)
 843                                (int2 <module>)
 844                                (val2 <generic>)
 845                                (var <top>)
 846                                (gf <extended-generic>))
 847   (and (not (memq val2 (slot-ref gf 'extends)))
 848        (begin
 849          (slot-set! gf
 850                     'extends
 851                     (cons val2 (delq! val2 (slot-ref gf 'extends))))
 852          (slot-set! val2
 853                     'extended-by
 854                     (cons gf (delq! gf (slot-ref val2 'extended-by))))
 855          var)))
 856
 857 (module-define! duplicate-handlers 'merge-generics merge-generics)
 858
 859 (define-method (merge-accessors (module <module>)
 860                                 (name <symbol>)
 861                                 (int1 <module>)
 862                                 (val1 <top>)
 863                                 (int2 <module>)
 864                                 (val2 <top>)
 865                                 (var <top>)
 866                                 (val <top>))
 867   #f)
 868
 869 (define-method (merge-accessors (module <module>)
 870                                 (name <symbol>)
 871                                 (int1 <module>)
 872                                 (val1 <accessor>)
 873                                 (int2 <module>)
 874                                 (val2 <accessor>)
 875                                 (var <top>)
 876                                 (val <top>))
 877   (merge-generics module name int1 val1 int2 val2 var val))
 878
 879 (module-define! duplicate-handlers 'merge-accessors merge-accessors)
 880
 881 ;;;
 882 ;;; slot access
 883 ;;;
 884
 885 (define (class-slot-g-n-s class slot-name)
 886   (let* ((this-slot (assq slot-name (slot-ref class 'slots)))
 887          (g-n-s (cddr (or (assq slot-name (slot-ref class 'getters-n-setters))
 888                           (slot-missing class slot-name)))))
 889     (if (not (memq (slot-definition-allocation this-slot)
 890                    '(#:class #:each-subclass)))
 891         (slot-missing class slot-name))
 892     g-n-s))
 893
 894 (define (class-slot-ref class slot)
 895   (let ((x ((car (class-slot-g-n-s class slot)) #f)))
 896     (if (unbound? x)
 897         (slot-unbound class slot)
 898         x)))
 899
 900 (define (class-slot-set! class slot value)
 901   ((cadr (class-slot-g-n-s class slot)) #f value))
 902
 903 (define-method (slot-unbound (c <class>) (o <object>) s)
 904   (goops-error "Slot `~S' is unbound in object ~S" s o))
 905
 906 (define-method (slot-unbound (c <class>) s)
 907   (goops-error "Slot `~S' is unbound in class ~S" s c))
 908
 909 (define-method (slot-unbound (o <object>))
 910   (goops-error "Unbound slot in object ~S" o))
 911
 912 (define-method (slot-missing (c <class>) (o <object>) s)
 913   (goops-error "No slot with name `~S' in object ~S" s o))
 914
 915 (define-method (slot-missing (c <class>) s)
 916   (goops-error "No class slot with name `~S' in class ~S" s c))
 917
 918
 919 (define-method (slot-missing (c <class>) (o <object>) s value)
 920   (slot-missing c o s))
 921
 922 ;;; Methods for the possible error we can encounter when calling a gf
 923
 924 (define-method (no-next-method (gf <generic>) args)
 925   (goops-error "No next method when calling ~S\nwith arguments ~S" gf args))
 926
 927 (define-method (no-applicable-method (gf <generic>) args)
 928   (goops-error "No applicable method for ~S in call ~S"
 929                gf (cons (generic-function-name gf) args)))
 930
 931 (define-method (no-method (gf <generic>) args)
 932   (goops-error "No method defined for ~S"  gf))
 933
 934 ;;;
 935 ;;; {Cloning functions (from rdeline@CS.CMU.EDU)}
 936 ;;;
 937
 938 (define-method (shallow-clone (self <object>))
 939   (let ((clone (%allocate-instance (class-of self) '()))
 940         (slots (map slot-definition-name
 941                     (class-slots (class-of self)))))
 942     (for-each (lambda (slot)
 943                 (if (slot-bound? self slot)
 944                     (slot-set! clone slot (slot-ref self slot))))
 945               slots)
 946     clone))
 947
 948 (define-method (deep-clone  (self <object>))
 949   (let ((clone (%allocate-instance (class-of self) '()))
 950         (slots (map slot-definition-name
 951                     (class-slots (class-of self)))))
 952     (for-each (lambda (slot)
 953                 (if (slot-bound? self slot)
 954                     (slot-set! clone slot
 955                                (let ((value (slot-ref self slot)))
 956                                  (if (instance? value)
 957                                      (deep-clone value)
 958                                      value)))))
 959               slots)
 960     clone))
 961
 962 ;;;
 963 ;;; {Class redefinition utilities}
 964 ;;;
 965
 966 ;;; (class-redefinition OLD NEW)
 967 ;;;
 968
 969 ;;; Has correct the following conditions:
 970
 971 ;;; Methods
 972 ;;;
 973 ;;; 1. New accessor specializers refer to new header
 974 ;;;
 975 ;;; Classes
 976 ;;;
 977 ;;; 1. New class cpl refers to the new class header
 978 ;;; 2. Old class header exists on old super classes direct-subclass lists
 979 ;;; 3. New class header exists on new super classes direct-subclass lists
 980
 981 (define-method (class-redefinition (old <class>) (new <class>))
 982   ;; Work on direct methods:
 983   ;;            1. Remove accessor methods from the old class
 984   ;;            2. Patch the occurences of new in the specializers by old
 985   ;;            3. Displace the methods from old to new
 986   (remove-class-accessors! old)                                 ;; -1-
 987   (let ((methods (class-direct-methods new)))
 988     (for-each (lambda (m)
 989                  (update-direct-method! m new old))     ;; -2-
 990               methods)
 991     (slot-set! new
 992                'direct-methods
 993                (append methods (class-direct-methods old))))
 994
 995   ;; Substitute old for new in new cpl
 996   (set-car! (slot-ref new 'cpl) old)
 997
 998   ;; Remove the old class from the direct-subclasses list of its super classes
 999   (for-each (lambda (c) (slot-set! c 'direct-subclasses
1000                                    (delv! old (class-direct-subclasses c))))
1001             (class-direct-supers old))
1002
1003   ;; Replace the new class with the old in the direct-subclasses of the supers
1004   (for-each (lambda (c)
1005               (slot-set! c 'direct-subclasses
1006                          (cons old (delv! new (class-direct-subclasses c)))))
1007             (class-direct-supers new))
1008
1009   ;; Swap object headers
1010   (%modify-class old new)
1011
1012   ;; Now old is NEW!
1013
1014   ;; Redefine all the subclasses of old to take into account modification
1015   (for-each
1016        (lambda (c)
1017          (update-direct-subclass! c new old))
1018        (class-direct-subclasses new))
1019
1020   ;; Invalidate class so that subsequent instances slot accesses invoke
1021   ;; change-object-class
1022   (slot-set! new 'redefined old)
1023   (%invalidate-class new) ;must come after slot-set!
1024
1025   old)
1026
1027 ;;;
1028 ;;; remove-class-accessors!
1029 ;;;
1030
1031 (define-method (remove-class-accessors! (c <class>))
1032   (for-each (lambda (m)
1033               (if (is-a? m <accessor-method>)
1034                   (let ((gf (slot-ref m 'generic-function)))
1035                     ;; remove the method from its GF
1036                     (slot-set! gf 'methods
1037                                (delq1! m (slot-ref gf 'methods)))
1038                     (%invalidate-method-cache! gf)
1039                     ;; remove the method from its specializers
1040                     (remove-method-in-classes! m))))
1041             (class-direct-methods c)))
1042
1043 ;;;
1044 ;;; update-direct-method!
1045 ;;;
1046
1047 (define-method (update-direct-method! (m  <method>)
1048                                       (old <class>)
1049                                       (new <class>))
1050   (let loop ((l (method-specializers m)))
1051     ;; Note: the <top> in dotted list is never used.
1052     ;; So we can work as if we had only proper lists.
1053     (if (pair? l)
1054         (begin
1055           (if (eqv? (car l) old)
1056               (set-car! l new))
1057           (loop (cdr l))))))
1058
1059 ;;;
1060 ;;; update-direct-subclass!
1061 ;;;
1062
1063 (define-method (update-direct-subclass! (c <class>)
1064                                         (old <class>)
1065                                         (new <class>))
1066   (class-redefinition c
1067                       (make-class (class-direct-supers c)
1068                                   (class-direct-slots c)
1069                                   #:name (class-name c)
1070                                   #:metaclass (class-of c))))
1071
1072 ;;;
1073 ;;; {Utilities for INITIALIZE methods}
1074 ;;;
1075
1076 ;;; compute-slot-accessors
1077 ;;;
1078 (define (compute-slot-accessors class slots)
1079   (for-each
1080       (lambda (s g-n-s)
1081         (let ((getter-function (slot-definition-getter   s))
1082               (setter-function (slot-definition-setter   s))
1083               (accessor        (slot-definition-accessor s)))
1084           (if getter-function
1085               (add-method! getter-function
1086                            (compute-getter-method class g-n-s)))
1087           (if setter-function
1088               (add-method! setter-function
1089                            (compute-setter-method class g-n-s)))
1090           (if accessor
1091               (begin
1092                 (add-method! accessor
1093                              (compute-getter-method class g-n-s))
1094                 (add-method! (setter accessor)
1095                              (compute-setter-method class g-n-s))))))
1096       slots (slot-ref class 'getters-n-setters)))
1097
1098 (define-method (compute-getter-method (class <class>) slotdef)
1099   (let ((init-thunk (cadr slotdef))
1100         (g-n-s (cddr slotdef)))
1101     (make <accessor-method>
1102           #:specializers (list class)
1103           #:procedure (cond ((pair? g-n-s)
1104                              (make-generic-bound-check-getter (car g-n-s)))
1105                             (init-thunk
1106                              (standard-get g-n-s))
1107                             (else
1108                              (bound-check-get g-n-s)))
1109           #:slot-definition slotdef)))
1110
1111 (define-method (compute-setter-method (class <class>) slotdef)
1112   (let ((g-n-s (cddr slotdef)))
1113     (make <accessor-method>
1114           #:specializers (list class <top>)
1115           #:procedure (if (pair? g-n-s)
1116                           (cadr g-n-s)
1117                           (standard-set g-n-s))
1118           #:slot-definition slotdef)))
1119
1120 (define (make-generic-bound-check-getter proc)
1121   (lambda (o) (assert-bound (proc o) o)))
1122
1123 ;; the idea is to compile the index into the procedure, for fastest
1124 ;; lookup. Also, @slot-ref and @slot-set! have their own bytecodes.
1125
1126 (eval-when (eval load compile)
1127   (define num-standard-pre-cache 20))
1128
1129 (define-macro (define-standard-accessor-method form . body)
1130   (let ((name (caar form))
1131         (n-var (cadar form))
1132         (args (cdr form)))
1133     (define (make-one x)
1134       (define (body-trans form)
1135         (cond ((not (pair? form)) form)
1136               ((eq? (car form) '@slot-ref)
1137                `(,(car form) ,(cadr form) ,x))
1138               ((eq? (car form) '@slot-set!)
1139                `(,(car form) ,(cadr form) ,x ,(cadddr form)))
1140               (else
1141                (map body-trans form))))
1142       `(lambda ,args ,@(map body-trans body)))
1143     `(define ,name
1144        (let ((cache (vector ,@(map make-one (iota num-standard-pre-cache)))))
1145          (lambda (n)
1146            (if (< n ,num-standard-pre-cache)
1147                (vector-ref cache n)
1148                ((lambda (,n-var) (lambda ,args ,@body)) n)))))))
1149
1150 (define-standard-accessor-method ((bound-check-get n) o)
1151   (let ((x (@slot-ref o n)))
1152     (if (unbound? x)
1153         (slot-unbound o)
1154         x)))
1155
1156 (define-standard-accessor-method ((standard-get n) o)
1157   (@slot-ref o n))
1158
1159 (define-standard-accessor-method ((standard-set n) o v)
1160   (@slot-set! o n v))
1161
1162 ;;; compute-getters-n-setters
1163 ;;;
1164 (define (compute-getters-n-setters class slots)
1165
1166   (define (compute-slot-init-function name s)
1167     (or (let ((thunk (slot-definition-init-thunk s)))
1168           (and thunk
1169                (if (thunk? thunk)
1170                    thunk
1171                    (goops-error "Bad init-thunk for slot `~S' in ~S: ~S"
1172                                 name class thunk))))
1173         (let ((init (slot-definition-init-value s)))
1174           (and (not (unbound? init))
1175                (lambda () init)))))
1176
1177   (define (verify-accessors slot l)
1178     (cond ((integer? l))
1179           ((not (and (list? l) (= (length l) 2)))
1180            (goops-error "Bad getter and setter for slot `~S' in ~S: ~S"
1181                         slot class l))
1182           (else
1183            (let ((get (car l))
1184                  (set (cadr l)))
1185              (if (not (procedure? get))
1186                  (goops-error "Bad getter closure for slot `~S' in ~S: ~S"
1187                               slot class get))
1188              (if (not (procedure? set))
1189                  (goops-error "Bad setter closure for slot `~S' in ~S: ~S"
1190                               slot class set))))))
1191
1192   (map (lambda (s)
1193          ;; The strange treatment of nfields is due to backward compatibility.
1194          (let* ((index (slot-ref class 'nfields))
1195                 (g-n-s (compute-get-n-set class s))
1196                 (size (- (slot-ref class 'nfields) index))
1197                 (name  (slot-definition-name s)))
1198            ;; NOTE: The following is interdependent with C macros
1199            ;; defined above goops.c:scm_sys_prep_layout_x.
1200            ;;
1201            ;; For simple instance slots, we have the simplest form
1202            ;; '(name init-function . index)
1203            ;; For other slots we have
1204            ;; '(name init-function getter setter . alloc)
1205            ;; where alloc is:
1206            ;;   '(index size) for instance allocated slots
1207            ;;   '() for other slots
1208            (verify-accessors name g-n-s)
1209            (cons name
1210                  (cons (compute-slot-init-function name s)
1211                        (if (or (integer? g-n-s)
1212                                (zero? size))
1213                            g-n-s
1214                            (append g-n-s (list index size)))))))
1215        slots))
1216
1217 ;;; compute-cpl
1218 ;;;
1219 ;;; Correct behaviour:
1220 ;;;
1221 ;;; (define-class food ())
1222 ;;; (define-class fruit (food))
1223 ;;; (define-class spice (food))
1224 ;;; (define-class apple (fruit))
1225 ;;; (define-class cinnamon (spice))
1226 ;;; (define-class pie (apple cinnamon))
1227 ;;; => cpl (pie) = pie apple fruit cinnamon spice food object top
1228 ;;;
1229 ;;; (define-class d ())
1230 ;;; (define-class e ())
1231 ;;; (define-class f ())
1232 ;;; (define-class b (d e))
1233 ;;; (define-class c (e f))
1234 ;;; (define-class a (b c))
1235 ;;; => cpl (a) = a b d c e f object top
1236 ;;;
1237
1238 (define-method (compute-cpl (class <class>))
1239   (compute-std-cpl class class-direct-supers))
1240
1241 ;; Support
1242
1243 (define (only-non-null lst)
1244   (filter (lambda (l) (not (null? l))) lst))
1245
1246 (define (compute-std-cpl c get-direct-supers)
1247   (let ((c-direct-supers (get-direct-supers c)))
1248     (merge-lists (list c)
1249                  (only-non-null (append (map class-precedence-list
1250                                              c-direct-supers)
1251                                         (list c-direct-supers))))))
1252
1253 (define (merge-lists reversed-partial-result inputs)
1254   (cond
1255    ((every null? inputs)
1256     (reverse! reversed-partial-result))
1257    (else
1258     (let* ((candidate (lambda (c)
1259                         (and (not (any (lambda (l)
1260                                          (memq c (cdr l)))
1261                                        inputs))
1262                              c)))
1263            (candidate-car (lambda (l)
1264                             (and (not (null? l))
1265                                  (candidate (car l)))))
1266            (next (any candidate-car inputs)))
1267       (if (not next)
1268           (goops-error "merge-lists: Inconsistent precedence graph"))
1269       (let ((remove-next (lambda (l)
1270                            (if (eq? (car l) next)
1271                                (cdr l)
1272                              l))))
1273         (merge-lists (cons next reversed-partial-result)
1274                      (only-non-null (map remove-next inputs))))))))
1275
1276 ;; Modified from TinyClos:
1277 ;;
1278 ;; A simple topological sort.
1279 ;;
1280 ;; It's in this file so that both TinyClos and Objects can use it.
1281 ;;
1282 ;; This is a fairly modified version of code I originally got from Anurag
1283 ;; Mendhekar <anurag@moose.cs.indiana.edu>.
1284 ;;
1285
1286 (define (compute-clos-cpl c get-direct-supers)
1287   (top-sort ((build-transitive-closure get-direct-supers) c)
1288             ((build-constraints get-direct-supers) c)
1289             (std-tie-breaker get-direct-supers)))
1290
1291
1292 (define (top-sort elements constraints tie-breaker)
1293   (let loop ((elements    elements)
1294              (constraints constraints)
1295              (result      '()))
1296     (if (null? elements)
1297         result
1298         (let ((can-go-in-now
1299                (filter
1300                 (lambda (x)
1301                   (every (lambda (constraint)
1302                            (or (not (eq? (cadr constraint) x))
1303                                (memq (car constraint) result)))
1304                          constraints))
1305                 elements)))
1306           (if (null? can-go-in-now)
1307               (goops-error "top-sort: Invalid constraints")
1308               (let ((choice (if (null? (cdr can-go-in-now))
1309                                 (car can-go-in-now)
1310                                 (tie-breaker result
1311                                              can-go-in-now))))
1312                 (loop
1313                  (filter (lambda (x) (not (eq? x choice)))
1314                          elements)
1315                  constraints
1316                  (append result (list choice)))))))))
1317
1318 (define (std-tie-breaker get-supers)
1319   (lambda (partial-cpl min-elts)
1320     (let loop ((pcpl (reverse partial-cpl)))
1321       (let ((current-elt (car pcpl)))
1322         (let ((ds-of-ce (get-supers current-elt)))
1323           (let ((common (filter (lambda (x)
1324                                       (memq x ds-of-ce))
1325                                     min-elts)))
1326             (if (null? common)
1327                 (if (null? (cdr pcpl))
1328                     (goops-error "std-tie-breaker: Nothing valid")
1329                     (loop (cdr pcpl)))
1330                 (car common))))))))
1331
1332
1333 (define (build-transitive-closure get-follow-ons)
1334   (lambda (x)
1335     (let track ((result '())
1336                 (pending (list x)))
1337       (if (null? pending)
1338           result
1339           (let ((next (car pending)))
1340             (if (memq next result)
1341                 (track result (cdr pending))
1342                 (track (cons next result)
1343                        (append (get-follow-ons next)
1344                                (cdr pending)))))))))
1345
1346 (define (build-constraints get-follow-ons)
1347   (lambda (x)
1348     (let loop ((elements ((build-transitive-closure get-follow-ons) x))
1349                (this-one '())
1350                (result '()))
1351       (if (or (null? this-one) (null? (cdr this-one)))
1352           (if (null? elements)
1353               result
1354               (loop (cdr elements)
1355                     (cons (car elements)
1356                           (get-follow-ons (car elements)))
1357                     result))
1358           (loop elements
1359                 (cdr this-one)
1360                 (cons (list (car this-one) (cadr this-one))
1361                       result))))))
1362
1363 ;;; compute-get-n-set
1364 ;;;
1365 (define-method (compute-get-n-set (class <class>) s)
1366   (case (slot-definition-allocation s)
1367     ((#:instance) ;; Instance slot
1368      ;; get-n-set is just its offset
1369      (let ((already-allocated (slot-ref class 'nfields)))
1370        (slot-set! class 'nfields (+ already-allocated 1))
1371        already-allocated))
1372
1373     ((#:class)  ;; Class slot
1374      ;; Class-slots accessors are implemented as 2 closures around
1375      ;; a Scheme variable. As instance slots, class slots must be
1376      ;; unbound at init time.
1377      (let ((name (slot-definition-name s)))
1378        (if (memq name (map slot-definition-name (class-direct-slots class)))
1379            ;; This slot is direct; create a new shared variable
1380            (make-closure-variable class)
1381            ;; Slot is inherited. Find its definition in superclass
1382            (let loop ((l (cdr (class-precedence-list class))))
1383              (let ((r (assoc name (slot-ref (car l) 'getters-n-setters))))
1384                (if r
1385                    (cddr r)
1386                    (loop (cdr l))))))))
1387
1388     ((#:each-subclass) ;; slot shared by instances of direct subclass.
1389      ;; (Thomas Buerger, April 1998)
1390      (make-closure-variable class))
1391
1392     ((#:virtual) ;; No allocation
1393      ;; slot-ref and slot-set! function must be given by the user
1394      (let ((get (get-keyword #:slot-ref  (slot-definition-options s) #f))
1395            (set (get-keyword #:slot-set! (slot-definition-options s) #f)))
1396        (if (not (and get set))
1397            (goops-error "You must supply a #:slot-ref and a #:slot-set! in ~S"
1398                         s))
1399        (list get set)))
1400     (else    (next-method))))
1401
1402 (define (make-closure-variable class)
1403   (let ((shared-variable (make-unbound)))
1404     (list (lambda (o) shared-variable)
1405           (lambda (o v) (set! shared-variable v)))))
1406
1407 (define-method (compute-get-n-set (o <object>) s)
1408   (goops-error "Allocation \"~S\" is unknown" (slot-definition-allocation s)))
1409
1410 (define-method (compute-slots (class <class>))
1411   (%compute-slots class))
1412
1413 ;;;
1414 ;;; {Initialize}
1415 ;;;
1416
1417 (define-method (initialize (object <object>) initargs)
1418   (%initialize-object object initargs))
1419
1420 (define-method (initialize (class <class>) initargs)
1421   (next-method)
1422   (let ((dslots (get-keyword #:slots initargs '()))
1423         (supers (get-keyword #:dsupers    initargs '())))
1424     (slot-set! class 'name              (get-keyword #:name initargs '???))
1425     (slot-set! class 'direct-supers     supers)
1426     (slot-set! class 'direct-slots      dslots)
1427     (slot-set! class 'direct-subclasses '())
1428     (slot-set! class 'direct-methods    '())
1429     (slot-set! class 'cpl               (compute-cpl class))
1430     (slot-set! class 'redefined         #f)
1431     (let ((slots (compute-slots class)))
1432       (slot-set! class 'slots             slots)
1433       (slot-set! class 'nfields           0)
1434       (slot-set! class 'getters-n-setters (compute-getters-n-setters class
1435                                                                      slots))
1436       ;; Build getters - setters - accessors
1437       (compute-slot-accessors class slots))
1438
1439     ;; Update the "direct-subclasses" of each inherited classes
1440     (for-each (lambda (x)
1441                 (slot-set! x
1442                            'direct-subclasses
1443                            (cons class (slot-ref x 'direct-subclasses))))
1444               supers)
1445
1446     ;; Support for the underlying structs:
1447
1448     ;; Set the layout slot
1449     (%prep-layout! class)
1450     ;; Inherit class flags (invisible on scheme level) from supers
1451     (%inherit-magic! class supers)))
1452
1453 (define (initialize-object-procedure object initargs)
1454   (let ((proc (get-keyword #:procedure initargs #f)))
1455     (cond ((not proc))
1456           ((pair? proc)
1457            (apply set-object-procedure! object proc))
1458           (else
1459            (set-object-procedure! object proc)))))
1460
1461 (define-method (initialize (applicable-struct <applicable-struct>) initargs)
1462   (next-method)
1463   (initialize-object-procedure applicable-struct initargs))
1464
1465 (define-method (initialize (generic <generic>) initargs)
1466   (let ((previous-definition (get-keyword #:default initargs #f))
1467         (name (get-keyword #:name initargs #f)))
1468     (next-method)
1469     (slot-set! generic 'methods (if (is-a? previous-definition <procedure>)
1470                                     (list (method args
1471                                             (apply previous-definition args)))
1472                                     '()))
1473     (if name
1474         (set-procedure-property! generic 'name name))
1475     ))
1476
1477 (define-method (initialize (gws <generic-with-setter>) initargs)
1478   (next-method)
1479   (%set-object-setter! gws (get-keyword #:setter initargs #f)))
1480
1481 (define-method (initialize (eg <extended-generic>) initargs)
1482   (next-method)
1483   (slot-set! eg 'extends (get-keyword #:extends initargs '())))
1484
1485 (define dummy-procedure (lambda args *unspecified*))
1486
1487 (define-method (initialize (method <method>) initargs)
1488   (next-method)
1489   (slot-set! method 'generic-function (get-keyword #:generic-function initargs #f))
1490   (slot-set! method 'specializers (get-keyword #:specializers initargs '()))
1491   (slot-set! method 'procedure
1492              (get-keyword #:procedure initargs #f))
1493   (slot-set! method 'formals (get-keyword #:formals initargs '()))
1494   (slot-set! method 'body (get-keyword #:body initargs '()))
1495   (slot-set! method 'make-procedure (get-keyword #:make-procedure initargs #f)))
1496
1497
1498 ;;;
1499 ;;; {Change-class}
1500 ;;;
1501
1502 (define (change-object-class old-instance old-class new-class)
1503   (let ((new-instance (allocate-instance new-class '())))
1504     ;; Initialize the slots of the new instance
1505     (for-each (lambda (slot)
1506                 (if (and (slot-exists-using-class? old-class old-instance slot)
1507                          (eq? (slot-definition-allocation
1508                                (class-slot-definition old-class slot))
1509                               #:instance)
1510                          (slot-bound-using-class? old-class old-instance slot))
1511                     ;; Slot was present and allocated in old instance; copy it
1512                     (slot-set-using-class!
1513                      new-class
1514                      new-instance
1515                      slot
1516                      (slot-ref-using-class old-class old-instance slot))
1517                     ;; slot was absent; initialize it with its default value
1518                     (let ((init (slot-init-function new-class slot)))
1519                       (if init
1520                           (slot-set-using-class!
1521                                new-class
1522                                new-instance
1523                                slot
1524                                (apply init '()))))))
1525               (map slot-definition-name (class-slots new-class)))
1526     ;; Exchange old and new instance in place to keep pointers valid
1527     (%modify-instance old-instance new-instance)
1528     ;; Allow class specific updates of instances (which now are swapped)
1529     (update-instance-for-different-class new-instance old-instance)
1530     old-instance))
1531
1532
1533 (define-method (update-instance-for-different-class (old-instance <object>)
1534                                                     (new-instance
1535                                                      <object>))
1536   ;;not really important what we do, we just need a default method
1537   new-instance)
1538
1539 (define-method (change-class (old-instance <object>) (new-class <class>))
1540   (change-object-class old-instance (class-of old-instance) new-class))
1541
1542 ;;;
1543 ;;; {make}
1544 ;;;
1545 ;;; A new definition which overwrites the previous one which was built-in
1546 ;;;
1547
1548 (define-method (allocate-instance (class <class>) initargs)
1549   (%allocate-instance class initargs))
1550
1551 (define-method (make-instance (class <class>) . initargs)
1552   (let ((instance (allocate-instance class initargs)))
1553     (initialize instance initargs)
1554     instance))
1555
1556 (define make make-instance)
1557
1558 ;;;
1559 ;;; {apply-generic}
1560 ;;;
1561 ;;; Protocol for calling standard generic functions.  This protocol is
1562 ;;; not used for real <generic> functions (in this case we use a
1563 ;;; completely C hard-coded protocol).  Apply-generic is used by
1564 ;;; goops for calls to subclasses of <generic> and <generic-with-setter>.
1565 ;;; The code below is similar to the first MOP described in AMOP. In
1566 ;;; particular, it doesn't used the currified approach to gf
1567 ;;; call. There are 2 reasons for that:
1568 ;;;   - the protocol below is exposed to mimic completely the one written in C
1569 ;;;   - the currified protocol would be imho inefficient in C.
1570 ;;;
1571
1572 (define-method (apply-generic (gf <generic>) args)
1573   (if (null? (slot-ref gf 'methods))
1574       (no-method gf args))
1575   (let ((methods (compute-applicable-methods gf args)))
1576     (if methods
1577         (apply-methods gf (sort-applicable-methods gf methods args) args)
1578         (no-applicable-method gf args))))
1579
1580 ;; compute-applicable-methods is bound to %compute-applicable-methods.
1581 ;; *fixme* use let
1582 (define %%compute-applicable-methods
1583   (make <generic> #:name 'compute-applicable-methods))
1584
1585 (define-method (%%compute-applicable-methods (gf <generic>) args)
1586   (%compute-applicable-methods gf args))
1587
1588 (set! compute-applicable-methods %%compute-applicable-methods)
1589
1590 (define-method (sort-applicable-methods (gf <generic>) methods args)
1591   (let ((targs (map class-of args)))
1592     (sort methods (lambda (m1 m2) (method-more-specific? m1 m2 targs)))))
1593
1594 (define-method (method-more-specific? (m1 <method>) (m2 <method>) targs)
1595   (%method-more-specific? m1 m2 targs))
1596
1597 (define-method (apply-method (gf <generic>) methods build-next args)
1598   (apply (method-procedure (car methods))
1599          (build-next (cdr methods) args)
1600          args))
1601
1602 (define-method (apply-methods (gf <generic>) (l <list>) args)
1603   (letrec ((next (lambda (procs args)
1604                    (lambda new-args
1605                      (let ((a (if (null? new-args) args new-args)))
1606                        (if (null? procs)
1607                            (no-next-method gf a)
1608                            (apply-method gf procs next a)))))))
1609     (apply-method gf l next args)))
1610
1611 ;; We don't want the following procedure to turn up in backtraces:
1612 (for-each (lambda (proc)
1613             (set-procedure-property! proc 'system-procedure #t))
1614           (list slot-unbound
1615                 slot-missing
1616                 no-next-method
1617                 no-applicable-method
1618                 no-method
1619                 ))
1620
1621 ;;;
1622 ;;; {<composite-metaclass> and <active-metaclass>}
1623 ;;;
1624
1625 ;(autoload "active-slot"    <active-metaclass>)
1626 ;(autoload "composite-slot" <composite-metaclass>)
1627 ;(export <composite-metaclass> <active-metaclass>)
1628
1629 ;;;
1630 ;;; {Tools}
1631 ;;;
1632
1633 ;; list2set
1634 ;;
1635 ;; duplicate the standard list->set function but using eq instead of
1636 ;; eqv which really sucks a lot, uselessly here
1637 ;;
1638 (define (list2set l)
1639   (let loop ((l l)
1640              (res '()))
1641     (cond
1642      ((null? l) res)
1643      ((memq (car l) res) (loop (cdr l) res))
1644      (else (loop (cdr l) (cons (car l) res))))))
1645
1646 (define (class-subclasses c)
1647   (letrec ((allsubs (lambda (c)
1648                       (cons c (mapappend allsubs
1649                                          (class-direct-subclasses c))))))
1650     (list2set (cdr (allsubs c)))))
1651
1652 (define (class-methods c)
1653   (list2set (mapappend class-direct-methods
1654                        (cons c (class-subclasses c)))))
1655
1656 ;;;
1657 ;;; {Final initialization}
1658 ;;;
1659
1660 ;; Tell C code that the main bulk of Goops has been loaded
1661 (%goops-loaded)