configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT(m4_esyscmd(. ./GUILE-VERSION && echo -n ${PACKAGE}),
  31         m4_esyscmd(. ./GUILE-VERSION && echo -n ${GUILE_VERSION}))
  32 AC_CONFIG_SRCDIR(GUILE-VERSION)
  33 AM_INIT_AUTOMAKE([no-define])
  34
  35 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  36 AC_CONFIG_SRCDIR([GUILE-VERSION])
  37
  38 . $srcdir/GUILE-VERSION
  39
  40 AM_MAINTAINER_MODE
  41 AM_CONFIG_HEADER([config.h])
  42 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  43
  44 #--------------------------------------------------------------------
  45 #
  46 # Independent Subdirectories
  47 #
  48 #--------------------------------------------------------------------
  49
  50 AC_CONFIG_SUBDIRS(guile-readline)
  51
  52 #--------------------------------------------------------------------
  53
  54 dnl Some more checks for Win32
  55 AC_CYGWIN
  56 AC_MINGW32
  57 AC_LIBTOOL_WIN32_DLL
  58
  59 AC_PROG_INSTALL
  60 AC_PROG_CC
  61 AC_PROG_CPP
  62 AC_PROG_AWK
  63
  64 AC_AIX
  65 AC_ISC_POSIX
  66 AC_MINIX
  67
  68 AM_PROG_CC_STDC
  69
  70 AC_LIBTOOL_DLOPEN
  71 AC_PROG_LIBTOOL
  72 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  73   [AC_MSG_ERROR([libltdl not found.  See README.])])
  74
  75 AC_SUBST(DLPREOPEN)
  76
  77 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  78 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  79
  80 AM_PATH_LISPDIR
  81
  82 #--------------------------------------------------------------------
  83 #
  84 # User options (after above tests that may set default CFLAGS etc.)
  85 #
  86 #--------------------------------------------------------------------
  87
  88 GUILE_ERROR_ON_WARNING="yes"
  89
  90 AC_ARG_ENABLE(error-on-warning,
  91   [  --enable-error-on-warning    treat compile warnings as errors],
  92   [case "${enableval}" in
  93      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  94      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  95      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  96    esac])
  97
  98 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
  99 AC_ARG_ENABLE(debug-freelist,
 100   [  --enable-debug-freelist include garbage collector freelist debugging code],
 101   if test "$enable_debug_freelist" = y \
 102      || test "$enable_debug_freelist" = yes; then
 103     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 104   fi)
 105
 106 AC_ARG_ENABLE(debug-malloc,
 107   [  --enable-debug-malloc   include malloc debugging code],
 108   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 109     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 110       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 111   fi)
 112
 113 SCM_I_GSC_GUILE_DEBUG=0
 114 AC_ARG_ENABLE(guile-debug,
 115   [AC_HELP_STRING([--enable-guile-debug],
 116                   [include internal debugging functions])],
 117   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 118     SCM_I_GSC_GUILE_DEBUG=1
 119   fi)
 120
 121 AC_ARG_ENABLE(posix,
 122   [  --disable-posix         omit posix interfaces],,
 123   enable_posix=yes)
 124
 125 AC_ARG_ENABLE(networking,
 126   [  --disable-networking    omit networking interfaces],,
 127   enable_networking=yes)
 128
 129 AC_ARG_ENABLE(regex,
 130   [  --disable-regex         omit regular expression interfaces],,
 131   enable_regex=yes)
 132
 133 AC_ARG_ENABLE([discouraged],
 134   AC_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 135
 136 if test "$enable_discouraged" = no; then
 137   SCM_I_GSC_ENABLE_DISCOURAGED=0
 138 else
 139   SCM_I_GSC_ENABLE_DISCOURAGED=1
 140 fi
 141
 142 AC_ARG_ENABLE([deprecated],
 143   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 144
 145 if test "$enable_deprecated" = no; then
 146   SCM_I_GSC_ENABLE_DEPRECATED=0
 147 else
 148   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 149     warn_default=summary
 150   elif test "$enable_deprecated" = shutup; then
 151     warn_default=no
 152   else
 153     warn_default=$enable_deprecated
 154   fi
 155   SCM_I_GSC_ENABLE_DEPRECATED=1
 156   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 157   [Define this to control the default warning level for deprecated features.])
 158 fi
 159
 160 AC_ARG_ENABLE(elisp,
 161   [  --disable-elisp         omit Emacs Lisp support],,
 162   enable_elisp=yes)
 163
 164 #--------------------------------------------------------------------
 165
 166 dnl Check for dynamic linking
 167
 168 use_modules=yes
 169 AC_ARG_WITH(modules,
 170 [  --with-modules[=FILES]  Add support for dynamic modules],
 171 use_modules="$withval")
 172 test -z "$use_modules" && use_modules=yes
 173 DLPREOPEN=
 174 if test "$use_modules" != no; then
 175   if test "$use_modules" = yes; then
 176     DLPREOPEN="-dlpreopen force"
 177   else
 178     DLPREOPEN="-export-dynamic"
 179     for module in $use_modules; do
 180       DLPREOPEN="$DLPREOPEN -dlopen $module"
 181     done
 182   fi
 183 fi
 184
 185 dnl files which are destined for separate modules.
 186
 187 if test "$use_modules" != no; then
 188    AC_LIBOBJ([dynl])
 189 fi
 190
 191 if test "$enable_posix" = yes; then
 192    AC_LIBOBJ([filesys])
 193    AC_LIBOBJ([posix])
 194    AC_DEFINE(HAVE_POSIX, 1,
 195      [Define this if you want support for POSIX system calls in Guile.])
 196 fi
 197
 198 if test "$enable_networking" = yes; then
 199    AC_LIBOBJ([net_db])
 200    AC_LIBOBJ([socket])
 201    AC_DEFINE(HAVE_NETWORKING, 1,
 202      [Define this if you want support for networking in Guile.])
 203 fi
 204
 205 if test "$enable_debug_malloc" = yes; then
 206    AC_LIBOBJ([debug-malloc])
 207 fi
 208
 209 if test "$enable_elisp" = yes; then
 210   SCM_I_GSC_ENABLE_ELISP=1
 211 else
 212   SCM_I_GSC_ENABLE_ELISP=0
 213 fi
 214
 215 AC_C_CONST
 216
 217 AC_C_INLINE
 218 if test "$ac_cv_c_inline" != no; then
 219   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 220 else
 221   SCM_I_GSC_C_INLINE=NULL
 222 fi
 223
 224 AC_C_BIGENDIAN
 225
 226 AC_CHECK_SIZEOF(char)
 227 AC_CHECK_SIZEOF(unsigned char)
 228 AC_CHECK_SIZEOF(short)
 229 AC_CHECK_SIZEOF(unsigned short)
 230 AC_CHECK_SIZEOF(int)
 231 AC_CHECK_SIZEOF(unsigned int)
 232 AC_CHECK_SIZEOF(long)
 233 AC_CHECK_SIZEOF(unsigned long)
 234 AC_CHECK_SIZEOF(size_t)
 235 AC_CHECK_SIZEOF(long long)
 236 AC_CHECK_SIZEOF(unsigned long long)
 237 AC_CHECK_SIZEOF(__int64)
 238 AC_CHECK_SIZEOF(unsigned __int64)
 239 AC_CHECK_SIZEOF(void *)
 240 AC_CHECK_SIZEOF(intptr_t)
 241 AC_CHECK_SIZEOF(uintptr_t)
 242 AC_CHECK_SIZEOF(ptrdiff_t)
 243 AC_CHECK_SIZEOF(size_t)
 244
 245 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 246   AC_MSG_ERROR(sizes of long and void* are not identical)
 247 fi
 248
 249 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 250   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 251 else
 252   SCM_I_GSC_T_PTRDIFF='"long"'
 253 fi
 254 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 255
 256 AC_CHECK_HEADERS([stdint.h])
 257 AC_CHECK_HEADERS([inttypes.h])
 258
 259 AC_CHECK_SIZEOF(intmax_t)
 260
 261 SCM_I_GSC_NEEDS_STDINT_H=0
 262 SCM_I_GSC_NEEDS_INTTYPES_H=0
 263
 264 ### intptr and uintptr (try not to use inttypes if we don't have to)
 265 if test "$ac_cv_header_inttypes_h" = yes; then
 266   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 267     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 268 #include <stdio.h>])
 269     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 270       SCM_I_GSC_NEEDS_INTTYPES_H=1
 271     fi
 272   fi
 273   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 274     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 275 #include <stdio.h>])
 276     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 277       SCM_I_GSC_NEEDS_INTTYPES_H=1
 278     fi
 279   fi
 280 fi
 281
 282 ### See what's provided by stdint.h
 283 if test "$ac_cv_header_stdint_h" = yes; then
 284    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 285    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 286    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 287    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 288    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 289    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 290    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 291    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 292    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 293    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 294 fi
 295
 296 # so we don't get confused by the cache (wish there was a better way
 297 # to check particular headers for the same type...)
 298
 299 unset ac_cv_type_int8_t
 300 unset ac_cv_type_uint8_t
 301 unset ac_cv_type_int16_t
 302 unset ac_cv_type_uint16_t
 303 unset ac_cv_type_int32_t
 304 unset ac_cv_type_uint32_t
 305 unset ac_cv_type_int64_t
 306 unset ac_cv_type_uint64_t
 307 unset ac_cv_type_intmax_t
 308 unset ac_cv_type_uintmax_t
 309
 310 ### See what's provided by inttypes.h
 311 if test "$ac_cv_header_inttypes_h" = yes; then
 312   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 313   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 314   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 315   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 316   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 317   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 318   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 319   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 320   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 321   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 322 fi
 323
 324 # Try hard to find definitions for some required scm_t_*int* types.
 325
 326 ### Required type scm_t_int8
 327 if test "$scm_stdint_has_int8"; then
 328   SCM_I_GSC_T_INT8='"int8_t"'
 329   SCM_I_GSC_NEEDS_STDINT_H=1
 330 elif test "$scm_inttypes_has_int8"; then
 331   SCM_I_GSC_T_INT8='"int8_t"'
 332   SCM_I_GSC_NEEDS_INTTYPES_H=1
 333 elif test "$ac_cv_sizeof_char" -eq 1; then
 334   SCM_I_GSC_T_INT8='"signed char"'
 335 else
 336   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 337 fi
 338 AC_SUBST([SCM_I_GSC_T_INT8])
 339
 340 ### Required type scm_t_uint8
 341 if test "$scm_stdint_has_uint8"; then
 342   SCM_I_GSC_T_UINT8='"uint8_t"'
 343   SCM_I_GSC_NEEDS_STDINT_H=1
 344 elif test "$scm_inttypes_has_uint8"; then
 345   SCM_I_GSC_T_UINT8='"uint8_t"'
 346   SCM_I_GSC_NEEDS_INTTYPES_H=1
 347 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 348   SCM_I_GSC_T_UINT8='"unsigned char"'
 349 else
 350   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 351 fi
 352 AC_SUBST([SCM_I_GSC_T_UINT8])
 353
 354 ### Required type scm_t_int16 (ANSI C says int or short might work)
 355 if test "$scm_stdint_has_int16"; then
 356   SCM_I_GSC_T_INT16='"int16_t"'
 357   SCM_I_GSC_NEEDS_STDINT_H=1
 358 elif test "$scm_inttypes_has_int16"; then
 359   SCM_I_GSC_T_INT16='"int16_t"'
 360   SCM_I_GSC_NEEDS_INTTYPES_H=1
 361 elif test "$ac_cv_sizeof_int" -eq 2; then
 362   SCM_I_GSC_T_INT16='"int"'
 363 elif test "$ac_cv_sizeof_short" -eq 2; then
 364   SCM_I_GSC_T_INT16='"short"'
 365 else
 366   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 367 fi
 368 AC_SUBST([SCM_I_GSC_T_INT16])
 369
 370 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 371 if test "$scm_stdint_has_uint16"; then
 372   SCM_I_GSC_T_UINT16='"uint16_t"'
 373   SCM_I_GSC_NEEDS_STDINT_H=1
 374 elif test "$scm_inttypes_has_uint16"; then
 375   SCM_I_GSC_T_UINT16='"uint16_t"'
 376   SCM_I_GSC_NEEDS_INTTYPES_H=1
 377 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 378   SCM_I_GSC_T_UINT16='"unsigned int"'
 379 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 380   SCM_I_GSC_T_UINT16='"unsigned short"'
 381 else
 382   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 383 fi
 384 AC_SUBST([SCM_I_GSC_T_UINT16])
 385
 386
 387 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 388 if test "$scm_stdint_has_int32"; then
 389   SCM_I_GSC_T_INT32='"int32_t"'
 390   SCM_I_GSC_NEEDS_STDINT_H=1
 391 elif test "$scm_inttypes_has_int32"; then
 392   SCM_I_GSC_T_INT32='"int32_t"'
 393   SCM_I_GSC_NEEDS_INTTYPES_H=1
 394 elif test "$ac_cv_sizeof_int" -eq 4; then
 395   SCM_I_GSC_T_INT32='"int"'
 396 elif test "$ac_cv_sizeof_long" -eq 4; then
 397   SCM_I_GSC_T_INT32='"long"'
 398 elif test "$ac_cv_sizeof_short" -eq 4; then
 399   SCM_I_GSC_T_INT32='"short"'
 400 else
 401   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 402 fi
 403 AC_SUBST([SCM_I_GSC_T_INT32])
 404
 405 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 406 if test "$scm_stdint_has_uint32"; then
 407   SCM_I_GSC_T_UINT32='"uint32_t"'
 408   SCM_I_GSC_NEEDS_STDINT_H=1
 409 elif test "$scm_inttypes_has_uint32"; then
 410   SCM_I_GSC_T_UINT32='"uint32_t"'
 411   SCM_I_GSC_NEEDS_INTTYPES_H=1
 412 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 413   SCM_I_GSC_T_UINT32='"unsigned int"'
 414 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 415   SCM_I_GSC_T_UINT32='"unsigned long"'
 416 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 417   SCM_I_GSC_T_UINT32='"unsigned short"'
 418 else
 419   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 420 fi
 421 AC_SUBST([SCM_I_GSC_T_UINT32])
 422
 423 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 424 ### Also try 'long long' and '__int64' if we have it.
 425 SCM_I_GSC_T_INT64=0
 426 if test "$scm_stdint_has_int64"; then
 427   SCM_I_GSC_T_INT64='"int64_t"'
 428   SCM_I_GSC_NEEDS_STDINT_H=1
 429 elif test "$scm_inttypes_has_int64"; then
 430   SCM_I_GSC_T_INT64='"int64_t"'
 431   SCM_I_GSC_NEEDS_INTTYPES_H=1
 432 elif test "$ac_cv_sizeof_int" -eq 8; then
 433   SCM_I_GSC_T_INT64='"int"'
 434 elif test "$ac_cv_sizeof_long" -eq 8; then
 435   SCM_I_GSC_T_INT64='"long"'
 436 elif test "$ac_cv_sizeof_short" -eq 8; then
 437   SCM_I_GSC_T_INT64='"short"'
 438 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 439   SCM_I_GSC_T_INT64='"long long"'
 440 elif test "$ac_cv_sizeof___int64" -eq 8; then
 441   SCM_I_GSC_T_INT64='"__int64"'
 442 else
 443   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 444 fi
 445 AC_SUBST([SCM_I_GSC_T_INT64])
 446
 447
 448 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 449 ### Also try 'long long' and '__int64' if we have it.
 450 SCM_I_GSC_T_UINT64=0
 451 if test "$scm_stdint_has_uint64"; then
 452   SCM_I_GSC_T_UINT64='"uint64_t"'
 453   SCM_I_GSC_NEEDS_STDINT_H=1
 454 elif test "$scm_inttypes_has_uint64"; then
 455   SCM_I_GSC_T_UINT64='"uint64_t"'
 456   SCM_I_GSC_NEEDS_INTTYPES_H=1
 457 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 458   SCM_I_GSC_T_UINT64='"unsigned int"'
 459 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 460   SCM_I_GSC_T_UINT64='"unsigned long"'
 461 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 462   SCM_I_GSC_T_UINT64='"unsigned short"'
 463 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 464   SCM_I_GSC_T_UINT64='"unsigned long long"'
 465 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 466   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 467 else
 468   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 469 fi
 470 AC_SUBST([SCM_I_GSC_T_UINT64])
 471
 472 ### Required type scm_t_intmax
 473 ###
 474 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 475 ### none of them is available, we use 'long'.
 476 ###
 477 SCM_I_GSC_T_INTMAX=0
 478 if test "$scm_stdint_has_intmax"; then
 479   SCM_I_GSC_T_INTMAX='"intmax_t"'
 480   SCM_I_GSC_NEEDS_STDINT_H=1
 481 elif test "$scm_inttypes_has_intmax"; then
 482   SCM_I_GSC_T_INTMAX='"intmax_t"'
 483   SCM_I_GSC_NEEDS_INTTYPES_H=1
 484 elif test "$ac_cv_sizeof___int64" -ne 0; then
 485   SCM_I_GSC_T_INTMAX='"__int64"'
 486 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 487   SCM_I_GSC_T_INTMAX='"long long"'
 488 else
 489   SCM_I_GSC_T_INTMAX='"long"'
 490 fi
 491 AC_SUBST([SCM_I_GSC_T_INTMAX])
 492
 493 ### Required type scm_t_uintmax
 494 ###
 495 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 496 ### this order.  When none of them is available, we use 'unsigned long'.
 497 ###
 498 SCM_I_GSC_T_UINTMAX=0
 499 if test "$scm_stdint_has_uintmax"; then
 500   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 501   SCM_I_GSC_NEEDS_STDINT_H=1
 502 elif test "$scm_inttypes_has_uintmax"; then
 503   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 504   SCM_I_GSC_NEEDS_INTTYPES_H=1
 505 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 506   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 507 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 508   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 509 else
 510   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 511 fi
 512 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 513
 514
 515 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 516 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 517
 518 AC_CHECK_TYPE(socklen_t, int)
 519 AC_CHECK_TYPE(struct ip_mreq)
 520
 521 AC_HEADER_STDC
 522 AC_HEADER_DIRENT
 523 AC_HEADER_TIME
 524 AC_HEADER_SYS_WAIT
 525
 526 # Reasons for testing:
 527 #   fenv.h - available in C99, but not older systems
 528 #
 529 AC_CHECK_HEADERS([fenv.h io.h libc.h limits.h malloc.h memory.h string.h \
 530 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 531 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 532 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 533 direct.h])
 534
 535 GUILE_HEADER_LIBC_WITH_UNISTD
 536
 537 AC_TYPE_GETGROUPS
 538 AC_TYPE_SIGNAL
 539 AC_TYPE_MODE_T
 540
 541 if test $MINGW32 = no; then
 542         AC_CHECK_LIB(m, main)
 543 fi
 544 AC_CHECK_FUNCS(gethostbyname)
 545 if test $ac_cv_func_gethostbyname = no; then
 546     AC_CHECK_LIB(nsl, gethostbyname)
 547 fi
 548
 549 AC_CHECK_FUNCS(connect)
 550 if test $ac_cv_func_connect = no; then
 551     AC_CHECK_LIB(socket, connect)
 552 fi
 553
 554 dnl
 555 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 556 dnl
 557 EXTRA_DEFS=""
 558 if test "$MINGW32" = "yes" ; then
 559     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 560       [Define if you have the <winsock2.h> header file.])])
 561     AC_CHECK_LIB(ws2_32, main)
 562     AC_LIBOBJ([win32-uname])
 563     AC_LIBOBJ([win32-dirent])
 564     if test "$enable_networking" = yes ; then
 565       AC_LIBOBJ([win32-socket])
 566     fi
 567     if test "$enable_shared" = yes ; then
 568       EXTRA_DEFS="-DSCM_IMPORT"
 569       AC_DEFINE(USE_DLL_IMPORT, 1,
 570         [Define if you need additional CPP macros on Win32 platforms.])
 571     fi
 572 fi
 573 AC_SUBST(EXTRA_DEFS)
 574
 575 # Reasons for testing:
 576 #   crt_externs.h - Darwin specific
 577 #
 578 AC_CHECK_HEADERS([assert.h crt_externs.h])
 579
 580 # Reasons for testing:
 581 #   DINFINITY - OSF specific
 582 #   DQNAN - OSF specific
 583 #       (DINFINITY and DQNAN are actually global variables, not functions)
 584 #   fesetround - available in C99, but not older systems
 585 #   gmtime_r - recent posix, not on old systems
 586 #   readdir_r - recent posix, not on old systems
 587 #   sysconf - not on old systems
 588 #   _NSGetEnviron - Darwin specific
 589 #
 590 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid fesetround ftime fchown getcwd geteuid gettimeofday gmtime_r lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv _NSGetEnviron])
 591
 592 # Reasons for testing:
 593 #   netdb.h - not in mingw
 594 #   sys/param.h - not in mingw
 595 #
 596 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 597 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 598
 599 # crypt() may or may not be available, for instance in some countries there
 600 # are restrictions on cryptography.
 601 #
 602 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 603 # -lcrypt library (eg. Debian GNU/Linux).
 604 #
 605 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 606 # be careful to avoid -lcrypt in this case, since libtool will see there's
 607 # only a static libcrypt and decide to build only a static libguile.
 608 #
 609 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 610 # libraries already in that list.
 611 #
 612 AC_SEARCH_LIBS(crypt, crypt,
 613   [AC_DEFINE(HAVE_CRYPT,1,
 614              [Define to 1 if you have the `crypt' function.])])
 615
 616 dnl GMP tests
 617 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 618   [AC_MSG_ERROR([GNU MP not found, see README])])
 619
 620 # mpz_import is a macro so we need to include <gmp.h>
 621 AC_TRY_LINK([#include <gmp.h>],
 622             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 623   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see README])])
 624
 625 dnl i18n tests
 626 #AC_CHECK_HEADERS([libintl.h])
 627 #AC_CHECK_FUNCS(gettext)
 628 #if test $ac_cv_func_gettext = no; then
 629 #   AC_CHECK_LIB(intl, gettext)
 630 #fi
 631 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 632 AM_GNU_GETTEXT([external], [need-ngettext])
 633
 634 ### Some systems don't declare some functions.  On such systems, we
 635 ### need to at least provide our own K&R-style declarations.
 636
 637 ### GUILE_FUNC_DECLARED(function, headerfile)
 638
 639 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 640 ### not there, #define MISSING_FUNCTION_DECL.
 641 AC_DEFUN([GUILE_FUNC_DECLARED], [
 642   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 643     AC_EGREP_HEADER($1, $2,
 644                     guile_cv_func_$1_declared=yes,
 645                     guile_cv_func_$1_declared=no))
 646   if test [x$guile_cv_func_]$1[_declared] = xno; then
 647     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 648       [Define if the operating system supplies $1 without declaring it.])
 649   fi
 650 ])
 651
 652 GUILE_FUNC_DECLARED(sleep, unistd.h)
 653 GUILE_FUNC_DECLARED(usleep, unistd.h)
 654
 655 AC_CHECK_DECLS([strptime],,,
 656 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 657 #include <time.h>])
 658
 659 ### On some systems usleep has no return value.  If it does have one,
 660 ### we'd like to return it; otherwise, we'll fake it.
 661 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 662   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 663                    unistd.h,
 664                    [guile_cv_func_usleep_return_type=void],
 665                    [guile_cv_func_usleep_return_type=int])])
 666 case "$guile_cv_func_usleep_return_type" in
 667   "void" )
 668     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 669       [Define if the system headers declare usleep to return void.])
 670   ;;
 671 esac
 672
 673 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 674 if test -n "$have_sys_un_h" ; then
 675   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 676     [Define if the system supports Unix-domain (file-domain) sockets.])
 677 fi
 678
 679 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 680
 681 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 682                setnetent    getnetent    endnetent    dnl
 683                setprotoent  getprotoent  endprotoent  dnl
 684                setservent   getservent   endservent   dnl
 685                getnetbyaddr getnetbyname dnl
 686                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 687                inet_pton inet_ntop)
 688
 689 # struct sockaddr field sin_len is only present on BSD systems.
 690 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 691 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 692 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 693 [#ifdef HAVE_SYS_TYPES_H
 694 #include <sys/types.h>
 695 #endif
 696 #include <netinet/in.h>])
 697
 698 AC_MSG_CHECKING(for __libc_stack_end)
 699 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 700 [AC_TRY_LINK([#include <stdio.h>
 701 extern char *__libc_stack_end;],
 702              [printf("%p", (char*) __libc_stack_end);],
 703              guile_cv_have_libc_stack_end=yes,
 704              guile_cv_have_libc_stack_end=no)])
 705 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 706
 707 if test $guile_cv_have_libc_stack_end = yes; then
 708   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 709            [Define if you have the __libc_stack_end variable.])
 710 fi
 711
 712 dnl Some systems do not declare this.  Some systems do declare it, as a
 713 dnl macro.  With cygwin it may be in a DLL.
 714
 715 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 716 AC_CACHE_VAL(guile_cv_have_h_errno,
 717 [AC_TRY_COMPILE([#include <netdb.h>],
 718 [int a = h_errno;],
 719 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 720 AC_MSG_RESULT($guile_cv_have_h_errno)
 721 if test $guile_cv_have_h_errno = yes; then
 722   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 723 fi
 724
 725 AC_MSG_CHECKING(whether uint32_t is defined)
 726 AC_CACHE_VAL(guile_cv_have_uint32_t,
 727   [AC_TRY_COMPILE([#include <sys/types.h>
 728                    #if HAVE_STDINT_H
 729                    #include <stdint.h>
 730                    #endif
 731                    #ifndef __MINGW32__
 732                    #include <netdb.h>
 733                    #endif],
 734                   [uint32_t a;],
 735                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 736 AC_MSG_RESULT($guile_cv_have_uint32_t)
 737 if test $guile_cv_have_uint32_t = yes; then
 738   AC_DEFINE(HAVE_UINT32_T, 1,
 739     [Define if uint32_t typedef is defined when netdb.h is include.])
 740 fi
 741
 742 AC_MSG_CHECKING(for working IPv6 support)
 743 AC_CACHE_VAL(guile_cv_have_ipv6,
 744 [AC_TRY_COMPILE([
 745 #ifdef HAVE_SYS_TYPES_H
 746 #include <sys/types.h>
 747 #endif
 748 #include <netinet/in.h>
 749 #include <sys/socket.h>],
 750 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 751 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 752 AC_MSG_RESULT($guile_cv_have_ipv6)
 753 if test $guile_cv_have_ipv6 = yes; then
 754   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 755 fi
 756
 757 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 758 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 759 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 760 [AC_TRY_COMPILE([
 761 #ifdef HAVE_SYS_TYPES_H
 762 #include <sys/types.h>
 763 #endif
 764 #include <netinet/in.h>],
 765 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 766 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 767 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 768 if test $guile_cv_have_sin6_scope_id = yes; then
 769   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 770     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 771 fi
 772
 773 # struct sockaddr_in6 field sin_len is only present on BSD systems
 774 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 775 [#ifdef HAVE_SYS_TYPES_H
 776 #include <sys/types.h>
 777 #endif
 778 #include <netinet/in.h>])
 779
 780 AC_MSG_CHECKING(whether localtime caches TZ)
 781 AC_CACHE_VAL(guile_cv_localtime_cache,
 782 [if test x$ac_cv_func_tzset = xyes; then
 783 AC_TRY_RUN([#include <time.h>
 784 #if STDC_HEADERS
 785 # include <stdlib.h>
 786 #endif
 787 extern char **environ;
 788 unset_TZ ()
 789 {
 790   char **from, **to;
 791   for (to = from = environ; (*to = *from); from++)
 792     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 793       to++;
 794 }
 795 char TZ_GMT0[] = "TZ=GMT0";
 796 char TZ_PST8[] = "TZ=PST8";
 797 main()
 798 {
 799   time_t now = time ((time_t *) 0);
 800   int hour_GMT0, hour_unset;
 801   if (putenv (TZ_GMT0) != 0)
 802     exit (1);
 803   hour_GMT0 = localtime (&now)->tm_hour;
 804   unset_TZ ();
 805   hour_unset = localtime (&now)->tm_hour;
 806   if (putenv (TZ_PST8) != 0)
 807     exit (1);
 808   if (localtime (&now)->tm_hour == hour_GMT0)
 809     exit (1);
 810   unset_TZ ();
 811   if (localtime (&now)->tm_hour != hour_unset)
 812     exit (1);
 813   exit (0);
 814 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 815 [# If we have tzset, assume the worst when cross-compiling.
 816 guile_cv_localtime_cache=yes])
 817 else
 818         # If we lack tzset, report that localtime does not cache TZ,
 819         # since we can't invalidate the cache if we don't have tzset.
 820         guile_cv_localtime_cache=no
 821 fi])dnl
 822 AC_MSG_RESULT($guile_cv_localtime_cache)
 823 if test $guile_cv_localtime_cache = yes; then
 824   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 825 fi
 826
 827 dnl Test whether system calls are restartable by default on the
 828 dnl current system.  If they are not, we put a loop around every system
 829 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 830 dnl change from the default behaviour.  On the other hand, if signals
 831 dnl are restartable then the loop is not installed and when libguile
 832 dnl initialises it also resets the behaviour of each signal to cause a
 833 dnl restart (in case a different runtime had a different default
 834 dnl behaviour for some reason: e.g., different versions of linux seem
 835 dnl to behave differently.)
 836
 837 AC_SYS_RESTARTABLE_SYSCALLS
 838
 839 if test "$enable_regex" = yes; then
 840    if test "$ac_cv_header_regex_h" = yes ||
 841       test "$ac_cv_header_rxposix_h" = yes ||
 842       test "$ac_cv_header_rx_rxposix_h" = yes; then
 843      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 844      [AC_CHECK_LIB(rx, main)
 845       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 846      [AC_CHECK_LIB(regex, main)
 847       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 848      )
 849      dnl The following should not be necessary, but for some reason
 850      dnl autoheader misses it if we don't include it!
 851      if test "$ac_cv_func_regcomp_norx" = yes ||
 852         test "$ac_cv_func_regcomp_regex" = yes ||
 853         test "$ac_cv_func_regcomp_rx" = yes; then
 854        AC_DEFINE(HAVE_REGCOMP, 1,
 855          [This is included as part of a workaround for a autoheader bug.])
 856      fi
 857    fi
 858 fi
 859
 860 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 861
 862 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 863
 864 # Reasons for testing:
 865 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 866 #                                older systems
 867 #   sincos - GLIBC extension
 868 #
 869 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
 870
 871 # C99 specifies isinf and isnan as macros.
 872 # HP-UX provides only macros, no functions.
 873 # glibc 2.3.2 provides both macros and functions.
 874 # IRIX 6.5 and Solaris 8 only provide functions.
 875 #
 876 # The following tests detect isinf and isnan either as functions or as
 877 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
 878 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
 879 #
 880 AC_MSG_CHECKING([for isinf])
 881 AC_LINK_IFELSE(
 882 [#include <math.h>
 883 int main () { return (isinf(0.0) != 0); }],
 884   [AC_MSG_RESULT([yes])
 885    AC_DEFINE(HAVE_ISINF, 1,
 886              [Define to 1 if you have the `isinf' macro or function.])],
 887   [AC_MSG_RESULT([no])])
 888 AC_MSG_CHECKING([for isnan])
 889 AC_LINK_IFELSE(
 890 [#include <math.h>
 891 #ifdef __MINGW32__
 892 #define isnan _isnan
 893 #endif
 894 int main () { return (isnan(0.0) != 0); }],
 895   [AC_MSG_RESULT([yes])
 896    AC_DEFINE(HAVE_ISNAN, 1,
 897              [Define to 1 if you have the `isnan' macro or function.])],
 898   [AC_MSG_RESULT([no])])
 899
 900 # We must have a proper stack-using alloca in order for stack-copying
 901 # continuations to work properly.  If we don't find a native one,
 902 # abort.
 903
 904 AC_FUNC_ALLOCA
 905 if test "$ALLOCA" = "alloca.o"
 906 then
 907   AC_ERROR([No native alloca found.])
 908 fi
 909
 910 AC_CHECK_MEMBERS([struct stat.st_rdev])
 911 AC_CHECK_MEMBERS([struct stat.st_blksize])
 912
 913 AC_STRUCT_ST_BLOCKS
 914
 915 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 916   [AC_TRY_CPP([#include <sys/stat.h>
 917                #ifndef S_ISLNK
 918                #error no S_ISLNK
 919                #endif],
 920                ac_cv_macro_S_ISLNK=yes,
 921                ac_cv_macro_S_ISLNK=no)])
 922 if test $ac_cv_macro_S_ISLNK = yes; then
 923   AC_DEFINE(HAVE_S_ISLNK, 1,
 924     [Define this if your system defines S_ISLNK in sys/stat.h.])
 925 fi
 926
 927 AC_STRUCT_TIMEZONE
 928 GUILE_STRUCT_UTIMBUF
 929
 930 #--------------------------------------------------------------------
 931 #
 932 # Which way does the stack grow?
 933 #
 934 #--------------------------------------------------------------------
 935
 936 SCM_I_GSC_STACK_GROWS_UP=0
 937 AC_TRY_RUN(aux (l) unsigned long l;
 938              { int x; exit (l >= ((unsigned long)&x)); }
 939            main () { int q; aux((unsigned long)&q); },
 940            [SCM_I_GSC_STACK_GROWS_UP=1],
 941            [],
 942            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
 943
 944 AC_CHECK_SIZEOF(float)
 945 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
 946     AC_DEFINE(SCM_SINGLES, 1,
 947               [Define this if floats are the same size as longs.])
 948 fi
 949
 950 AC_MSG_CHECKING(for struct linger)
 951 AC_CACHE_VAL(scm_cv_struct_linger,
 952         AC_TRY_COMPILE([
 953 #include <sys/types.h>
 954 #include <sys/socket.h>],
 955                         [struct linger lgr;  lgr.l_linger = 100],
 956                         scm_cv_struct_linger="yes",
 957                         scm_cv_struct_linger="no"))
 958 AC_MSG_RESULT($scm_cv_struct_linger)
 959 if test $scm_cv_struct_linger = yes; then
 960         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 961           [Define this if your system defines struct linger, for use with the
 962            getsockopt and setsockopt system calls.])
 963 fi
 964
 965
 966 AC_MSG_CHECKING(for struct timespec)
 967 AC_CACHE_VAL(scm_cv_struct_timespec,
 968         AC_TRY_COMPILE([
 969 #include <time.h>],
 970                         [struct timespec t;  t.tv_nsec = 100],
 971                         scm_cv_struct_timespec="yes",
 972                         scm_cv_struct_timespec="no"))
 973 AC_MSG_RESULT($scm_cv_struct_timespec)
 974 if test $scm_cv_struct_timespec = yes; then
 975   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 976     [Define this if your system defines struct timespec via <time.h>.])
 977 fi
 978
 979 #--------------------------------------------------------------------
 980 #
 981 # Flags for thread support
 982 #
 983 #--------------------------------------------------------------------
 984
 985 SCM_I_GSC_USE_PTHREAD_THREADS=0
 986 SCM_I_GSC_USE_NULL_THREADS=0
 987 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
 988 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
 989
 990 ### What thread package has the user asked for?
 991 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 992             , with_threads=yes)
 993
 994 case "$with_threads" in
 995   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
 996     ACX_PTHREAD(CC="$PTHREAD_CC"
 997       LIBS="$PTHREAD_LIBS $LIBS"
 998       SCM_I_GSC_USE_PTHREAD_THREADS=1
 999       with_threads="pthreads",
1000       with_threads="null")
1001
1002     old_CFLAGS="$CFLAGS"
1003     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1004     AC_CHECK_FUNCS(pthread_attr_getstack)
1005     CFLAGS="$old_CFLAGS"
1006
1007     # On Solaris, sched_yield lives in -lrt.
1008     AC_SEARCH_LIBS(sched_yield, rt)
1009
1010   ;;
1011 esac
1012
1013 case "$with_threads" in
1014   "pthreads")
1015   ;;
1016   "no" | "null")
1017     SCM_I_GSC_USE_NULL_THREADS=1
1018     with_threads="null-threads"
1019   ;;
1020   * )
1021     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1022   ;;
1023 esac
1024
1025 AC_MSG_CHECKING(what kind of threads to support)
1026 AC_MSG_RESULT($with_threads)
1027
1028 ## Cross building
1029 if test "$cross_compiling" = "yes"; then
1030   AC_MSG_CHECKING(cc for build)
1031   ## /usr/bin/cc still uses wrong assembler
1032   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1033   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1034 else
1035   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1036 fi
1037
1038 ## AC_MSG_CHECKING("if we are cross compiling")
1039 ## AC_MSG_RESULT($cross_compiling)
1040 if test "$cross_compiling" = "yes"; then
1041    AC_MSG_RESULT($CC_FOR_BUILD)
1042 fi
1043
1044 ## No need as yet to be more elaborate
1045 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1046
1047 AC_SUBST(cross_compiling)
1048 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1049 AC_SUBST(CCLD_FOR_BUILD)
1050
1051 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1052 ## --HOST is the platform that PACKAGE is compiled for.
1053 HOST_CC="$CC_FOR_BUILD"
1054 AC_SUBST(HOST_CC)
1055
1056 if test "$cross_compiling" = "yes"; then
1057   AC_MSG_CHECKING(guile for build)
1058   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1059 else
1060   GUILE_FOR_BUILD='$(preinstguile)'
1061 fi
1062
1063 ## AC_MSG_CHECKING("if we are cross compiling")
1064 ## AC_MSG_RESULT($cross_compiling)
1065 if test "$cross_compiling" = "yes"; then
1066    AC_MSG_RESULT($GUILE_FOR_BUILD)
1067 fi
1068 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1069 AC_SUBST(GUILE_FOR_BUILD)
1070
1071 ## If we're using GCC, ask for aggressive warnings.
1072 case "$GCC" in
1073   yes )
1074     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1075     ## much stuff with generic function pointers for that to really be
1076     ## less than exasperating.
1077     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1078     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1079     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1080     # Do this here so we don't screw up any of the tests above that might
1081     # not be "warning free"
1082     if test "${GUILE_ERROR_ON_WARNING}" = yes
1083     then
1084         CFLAGS="${CFLAGS} -Werror"
1085         enable_compile_warnings=no
1086     fi
1087     ;;
1088 esac
1089
1090 ## NOTE the code below sets LIBOBJS directly and so is now forbidden
1091 ## -- I'm disabling it for now in the hopes that the newer autoconf
1092 ## will DTRT -- if not, we need to fix up the sed command to match the
1093 ## others...
1094 ##
1095 ## Remove fileblocks.o from the object list.  This file gets added by
1096 ## the Autoconf macro AC_STRUCT_ST_BLOCKS.  But there is no need.
1097 #LIBOBJS="`echo ${LIBOBJS} | sed 's/fileblocks\.o//g'`"
1098
1099 ## If we're creating a shared library (using libtool!), then we'll
1100 ## need to generate a list of .lo files corresponding to the .o files
1101 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1102 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1103
1104 ## We also need to create corresponding .doc and .x files
1105 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1106 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1107
1108 AC_SUBST(GUILE_MAJOR_VERSION)
1109 AC_SUBST(GUILE_MINOR_VERSION)
1110 AC_SUBST(GUILE_MICRO_VERSION)
1111 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1112 AC_SUBST(GUILE_VERSION)
1113
1114 #######################################################################
1115 # library versioning
1116
1117 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1118 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1119 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1120 AC_SUBST(LIBGUILE_INTERFACE)
1121
1122 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1123 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1124 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1125 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1126 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1127
1128 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1129 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1130 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1131 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1132 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1133
1134 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1135 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1136 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1137 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1138 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1139
1140 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1141 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1142 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1143 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1144 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1145
1146 #######################################################################
1147
1148 dnl Tell guile-config what flags guile users should compile and link with.
1149 GUILE_LIBS="$LDFLAGS $LIBS"
1150 GUILE_CFLAGS="$PTHREAD_CFLAGS"
1151 AC_SUBST(GUILE_LIBS)
1152 AC_SUBST(GUILE_CFLAGS)
1153
1154 AC_SUBST(AWK)
1155 AC_SUBST(LIBLOBJS)
1156 AC_SUBST(EXTRA_DOT_DOC_FILES)
1157 AC_SUBST(EXTRA_DOT_X_FILES)
1158
1159 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1160 top_builddir_absolute=`pwd`
1161 AC_SUBST(top_builddir_absolute)
1162 top_srcdir_absolute=`(cd $srcdir && pwd)`
1163 AC_SUBST(top_srcdir_absolute)
1164
1165 # Additional SCM_I_GSC definitions are above.
1166 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1167 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1168 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1169 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1170 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1171 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1172 AC_SUBST([SCM_I_GSC_C_INLINE])
1173 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1174
1175 AC_CONFIG_FILES([
1176   Makefile
1177   am/Makefile
1178   benchmark-suite/Makefile
1179   doc/Makefile
1180   doc/goops/Makefile
1181   doc/r5rs/Makefile
1182   doc/ref/Makefile
1183   doc/tutorial/Makefile
1184   examples/Makefile
1185   examples/box-dynamic-module/Makefile
1186   examples/box-dynamic/Makefile
1187   examples/box-module/Makefile
1188   examples/box/Makefile
1189   examples/modules/Makefile
1190   examples/safe/Makefile
1191   examples/scripts/Makefile
1192   guile-config/Makefile
1193   ice-9/Makefile
1194   ice-9/debugger/Makefile
1195   lang/Makefile
1196   lang/elisp/Makefile
1197   lang/elisp/internals/Makefile
1198   lang/elisp/primitives/Makefile
1199   libguile/Makefile
1200   oop/Makefile
1201   oop/goops/Makefile
1202   scripts/Makefile
1203   srfi/Makefile
1204   test-suite/Makefile
1205   test-suite/standalone/Makefile
1206 ])
1207
1208 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1209 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1210 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1211 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1212 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1213 AC_CONFIG_FILES([libguile/guile-snarf],
1214                 [chmod +x libguile/guile-snarf])
1215 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1216                 [chmod +x libguile/guile-doc-snarf])
1217 AC_CONFIG_FILES([libguile/guile-func-name-check],
1218                 [chmod +x libguile/guile-func-name-check])
1219 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1220                 [chmod +x libguile/guile-snarf-docs])
1221
1222 AC_OUTPUT
1223
1224 dnl Local Variables:
1225 dnl comment-start: "dnl "
1226 dnl comment-end: ""
1227 dnl comment-start-skip: "\\bdnl\\b\\s *"
1228 dnl End: