configure.ac

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
   8   2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   9
  10 This file is part of GUILE
  11
  12 GUILE is free software; you can redistribute it and/or modify it under
  13 the terms of the GNU Lesser General Public License as published by the
  14 Free Software Foundation; either version 3, or (at your option) any
  15 later version.
  16
  17 GUILE is distributed in the hope that it will be useful, but WITHOUT
  18 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  19 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  20 License for more details.
  21
  22 You should have received a copy of the GNU Lesser General Public
  23 License along with GUILE; see the file COPYING.LESSER.  If not, write
  24 to the Free Software Foundation, Inc., 51 Franklin Street, Fifth
  25 Floor, Boston, MA 02110-1301, USA.
  26
  27 ]])
  28
  29 AC_PREREQ(2.61)
  30
  31 AC_INIT([GNU Guile],
  32         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  33         [bug-guile@gnu.org])
  34 AC_CONFIG_AUX_DIR([build-aux])
  35 AC_CONFIG_MACRO_DIR([m4])
  36 AC_CONFIG_SRCDIR(GUILE-VERSION)
  37
  38 AM_INIT_AUTOMAKE([gnu no-define -Wall -Wno-override])
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)])
  40
  41 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  42 AC_CONFIG_SRCDIR([GUILE-VERSION])
  43
  44 . $srcdir/GUILE-VERSION
  45 GUILE_VERSION="$PACKAGE_VERSION"
  46
  47 AC_CONFIG_HEADERS([config.h])
  48 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  49
  50 #--------------------------------------------------------------------
  51
  52 AC_LANG([C])
  53
  54 dnl Some more checks for Win32
  55 AC_CANONICAL_HOST
  56
  57 AC_LIBTOOL_WIN32_DLL
  58
  59 AC_PROG_INSTALL
  60 AC_PROG_CC
  61 gl_EARLY
  62 AC_PROG_CPP
  63 AC_PROG_SED
  64 AC_PROG_AWK
  65
  66 dnl Gnulib.
  67 gl_INIT
  68
  69 AC_PROG_CC_C89
  70
  71 # for per-target cflags in the libguile subdir
  72 AM_PROG_CC_C_O
  73
  74 AC_LIBTOOL_DLOPEN
  75 AC_PROG_LIBTOOL
  76
  77 AM_CONDITIONAL([HAVE_SHARED_LIBRARIES], [test "x$enable_shared" = "xyes"])
  78
  79 AC_DEFINE_UNQUOTED([SHARED_LIBRARY_PATH_VARIABLE], ["$shlibpath_var"],
  80   [Name of the environment variable that tells the dynamic linker where
  81 to find shared libraries.])
  82
  83 dnl Check for libltdl.
  84 AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>],
  85   [lt_dlopenext ("foo");])
  86 if test "x$HAVE_LIBLTDL" != "xyes"; then
  87   AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.])
  88 fi
  89
  90 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  91 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  92
  93 AM_PATH_LISPDIR
  94
  95 AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"],
  96   [Define to the host's GNU triplet.])
  97
  98 #--------------------------------------------------------------------
  99 #
 100 # User options (after above tests that may set default CFLAGS etc.)
 101 #
 102 #--------------------------------------------------------------------
 103
 104 GUILE_ERROR_ON_WARNING="no"
 105
 106 AC_ARG_ENABLE(error-on-warning,
 107   [  --enable-error-on-warning    treat compile warnings as errors],
 108   [case "${enableval}" in
 109      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
 110      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
 111      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
 112    esac])
 113
 114 AC_ARG_ENABLE(debug-malloc,
 115   [  --enable-debug-malloc   include malloc debugging code],
 116   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 117     AC_DEFINE([GUILE_DEBUG_MALLOC], 1,
 118       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 119   fi)
 120
 121 SCM_I_GSC_GUILE_DEBUG=0
 122 AC_ARG_ENABLE(guile-debug,
 123   [AS_HELP_STRING([--enable-guile-debug],
 124                   [include internal debugging functions])],
 125   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 126     SCM_I_GSC_GUILE_DEBUG=1
 127   fi)
 128
 129 AC_ARG_ENABLE(posix,
 130   [  --disable-posix         omit posix interfaces],,
 131   enable_posix=yes)
 132
 133 AC_ARG_ENABLE(networking,
 134   [  --disable-networking    omit networking interfaces],,
 135   enable_networking=yes)
 136
 137 AC_ARG_ENABLE(regex,
 138   [  --disable-regex         omit regular expression interfaces],,
 139   enable_regex=yes)
 140
 141 AC_ARG_ENABLE([deprecated],
 142   AS_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 143
 144 if test "$enable_deprecated" = no; then
 145   SCM_I_GSC_ENABLE_DEPRECATED=0
 146   warn_default=no
 147 else
 148   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 149     warn_default=summary
 150   elif test "$enable_deprecated" = shutup; then
 151     warn_default=no
 152   else
 153     warn_default=$enable_deprecated
 154   fi
 155   SCM_I_GSC_ENABLE_DEPRECATED=1
 156 fi
 157 AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default",
 158 [Define this to control the default warning level for deprecated features.])
 159
 160 dnl  Added the following configure option in January 2008 following
 161 dnl  investigation of problems with "64" system and library calls on
 162 dnl  Darwin (MacOS X).  The libguile code (_scm.h) assumes that if a
 163 dnl  system has stat64, it will have all the other 64 APIs too; but on
 164 dnl  Darwin, stat64 is there but other APIs are missing.
 165 dnl
 166 dnl  It also appears, from the Darwin docs, that most system call APIs
 167 dnl  there (i.e. the traditional ones _without_ "64" in their names) have
 168 dnl  been 64-bit-capable for a long time now, so it isn't necessary to
 169 dnl  use "64" versions anyway.  For example, Darwin's off_t is 64-bit.
 170 dnl
 171 dnl  A similar problem has been reported for HP-UX:
 172 dnl  http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html
 173 dnl
 174 dnl  Therefore, and also because a Guile without LARGEFILE64 support is
 175 dnl  better than no Guile at all, we provide this option to suppress
 176 dnl  trying to use "64" calls.
 177 dnl
 178 dnl  It may be that for some 64-bit function on Darwin/HP-UX we do need
 179 dnl  to use a "64" call, and hence that by using --without-64-calls we're
 180 dnl  missing out on that.  If so, someone can work on that in the future.
 181 dnl  For now, --without-64-calls allows Guile to build on OSs where it
 182 dnl  wasn't building before.
 183 AC_MSG_CHECKING([whether to use system and library "64" calls])
 184 AC_ARG_WITH([64-calls],
 185   AS_HELP_STRING([--without-64-calls],
 186                  [don't attempt to use system and library calls with "64" in their names]),
 187   [use_64_calls=$withval],
 188   [use_64_calls=yes
 189    case $host in
 190      *-apple-darwin* )
 191        use_64_calls=no
 192        ;;
 193      powerpc-ibm-aix* )
 194        use_64_calls=no
 195        ;;
 196    esac])
 197 AC_MSG_RESULT($use_64_calls)
 198 case "$use_64_calls" in
 199   y* )
 200     AC_DEFINE([GUILE_USE_64_CALLS], 1,
 201       [Define to 1 in order to try to use "64" versions of system and library calls.])
 202     ;;
 203 esac
 204
 205 #--------------------------------------------------------------------
 206
 207 dnl Check for dynamic linking
 208
 209 use_modules=yes
 210 AC_ARG_WITH(modules,
 211 [  --with-modules[=FILES]  Add support for dynamic modules],
 212 use_modules="$withval")
 213 test -z "$use_modules" && use_modules=yes
 214 DLPREOPEN=
 215 if test "$use_modules" != no; then
 216   if test "$use_modules" = yes; then
 217     DLPREOPEN="-dlpreopen force"
 218   else
 219     DLPREOPEN="-export-dynamic"
 220     for module in $use_modules; do
 221       DLPREOPEN="$DLPREOPEN -dlopen $module"
 222     done
 223   fi
 224 fi
 225
 226 dnl files which are destined for separate modules.
 227
 228 if test "$use_modules" != no; then
 229    AC_LIBOBJ([dynl])
 230 fi
 231
 232 if test "$enable_posix" = yes; then
 233    AC_LIBOBJ([filesys])
 234    AC_LIBOBJ([posix])
 235    AC_DEFINE([HAVE_POSIX], 1,
 236      [Define this if you want support for POSIX system calls in Guile.])
 237 fi
 238
 239 if test "$enable_networking" = yes; then
 240    AC_LIBOBJ([net_db])
 241    AC_LIBOBJ([socket])
 242    AC_DEFINE([HAVE_NETWORKING], 1,
 243      [Define this if you want support for networking in Guile.])
 244 fi
 245
 246 if test "$enable_debug_malloc" = yes; then
 247    AC_LIBOBJ([debug-malloc])
 248 fi
 249
 250 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 251
 252 AC_C_CONST
 253
 254 # "volatile" is used in a couple of tests below.
 255 AC_C_VOLATILE
 256
 257 AC_C_INLINE
 258 if test "$ac_cv_c_inline" != no; then
 259   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 260 else
 261   SCM_I_GSC_C_INLINE=NULL
 262 fi
 263 AC_CHECK_LIB(uca, __uc_get_ar_bsp)
 264
 265 AC_C_BIGENDIAN
 266
 267 AC_C_LABELS_AS_VALUES
 268
 269 AC_CHECK_SIZEOF(char)
 270 AC_CHECK_SIZEOF(unsigned char)
 271 AC_CHECK_SIZEOF(short)
 272 AC_CHECK_SIZEOF(unsigned short)
 273 AC_CHECK_SIZEOF(int)
 274 AC_CHECK_SIZEOF(unsigned int)
 275 AC_CHECK_SIZEOF(long)
 276 AC_CHECK_SIZEOF(unsigned long)
 277 AC_CHECK_SIZEOF(size_t)
 278 AC_CHECK_SIZEOF(long long)
 279 AC_CHECK_SIZEOF(unsigned long long)
 280 AC_CHECK_SIZEOF(__int64)
 281 AC_CHECK_SIZEOF(unsigned __int64)
 282 AC_CHECK_SIZEOF(void *)
 283 AC_CHECK_SIZEOF(intptr_t)
 284 AC_CHECK_SIZEOF(uintptr_t)
 285 AC_CHECK_SIZEOF(ptrdiff_t)
 286 AC_CHECK_SIZEOF(size_t)
 287 AC_CHECK_SIZEOF(off_t)
 288
 289 if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then
 290   AC_MSG_ERROR(long does not fit into a void*)
 291 fi
 292
 293 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 294   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 295 else
 296   SCM_I_GSC_T_PTRDIFF='"long"'
 297 fi
 298 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 299
 300 AC_CHECK_HEADERS([stdint.h])
 301 AC_CHECK_HEADERS([inttypes.h])
 302
 303 AC_CHECK_SIZEOF(intmax_t)
 304
 305 SCM_I_GSC_NEEDS_STDINT_H=0
 306 SCM_I_GSC_NEEDS_INTTYPES_H=0
 307
 308 ### intptr and uintptr (try not to use inttypes if we don't have to)
 309 if test "$ac_cv_header_inttypes_h" = yes; then
 310   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 311     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 312 #include <stdio.h>])
 313     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 314       SCM_I_GSC_NEEDS_INTTYPES_H=1
 315     fi
 316   fi
 317   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 318     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 319 #include <stdio.h>])
 320     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 321       SCM_I_GSC_NEEDS_INTTYPES_H=1
 322     fi
 323   fi
 324 fi
 325
 326 ### See what's provided by stdint.h
 327 if test "$ac_cv_header_stdint_h" = yes; then
 328    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 329    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 330    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 331    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 332    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 333    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 334    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 335    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 336    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 337    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 338    AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>])
 339    AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>])
 340 fi
 341
 342 # so we don't get confused by the cache (wish there was a better way
 343 # to check particular headers for the same type...)
 344
 345 unset ac_cv_type_int8_t
 346 unset ac_cv_type_uint8_t
 347 unset ac_cv_type_int16_t
 348 unset ac_cv_type_uint16_t
 349 unset ac_cv_type_int32_t
 350 unset ac_cv_type_uint32_t
 351 unset ac_cv_type_int64_t
 352 unset ac_cv_type_uint64_t
 353 unset ac_cv_type_intmax_t
 354 unset ac_cv_type_uintmax_t
 355
 356 ### See what's provided by inttypes.h
 357 if test "$ac_cv_header_inttypes_h" = yes; then
 358   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 359   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 360   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 361   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 362   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 363   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 364   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 365   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 366   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 367   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 368   AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>])
 369   AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>])
 370 fi
 371
 372 # Try hard to find definitions for some required scm_t_*int* types.
 373
 374 ### Required type scm_t_int8
 375 if test "$scm_stdint_has_int8"; then
 376   SCM_I_GSC_T_INT8='"int8_t"'
 377   SCM_I_GSC_NEEDS_STDINT_H=1
 378 elif test "$scm_inttypes_has_int8"; then
 379   SCM_I_GSC_T_INT8='"int8_t"'
 380   SCM_I_GSC_NEEDS_INTTYPES_H=1
 381 elif test "$ac_cv_sizeof_char" -eq 1; then
 382   SCM_I_GSC_T_INT8='"signed char"'
 383 else
 384   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 385 fi
 386 AC_SUBST([SCM_I_GSC_T_INT8])
 387
 388 ### Required type scm_t_uint8
 389 if test "$scm_stdint_has_uint8"; then
 390   SCM_I_GSC_T_UINT8='"uint8_t"'
 391   SCM_I_GSC_NEEDS_STDINT_H=1
 392 elif test "$scm_inttypes_has_uint8"; then
 393   SCM_I_GSC_T_UINT8='"uint8_t"'
 394   SCM_I_GSC_NEEDS_INTTYPES_H=1
 395 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 396   SCM_I_GSC_T_UINT8='"unsigned char"'
 397 else
 398   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 399 fi
 400 AC_SUBST([SCM_I_GSC_T_UINT8])
 401
 402 ### Required type scm_t_int16 (ANSI C says int or short might work)
 403 if test "$scm_stdint_has_int16"; then
 404   SCM_I_GSC_T_INT16='"int16_t"'
 405   SCM_I_GSC_NEEDS_STDINT_H=1
 406 elif test "$scm_inttypes_has_int16"; then
 407   SCM_I_GSC_T_INT16='"int16_t"'
 408   SCM_I_GSC_NEEDS_INTTYPES_H=1
 409 elif test "$ac_cv_sizeof_int" -eq 2; then
 410   SCM_I_GSC_T_INT16='"int"'
 411 elif test "$ac_cv_sizeof_short" -eq 2; then
 412   SCM_I_GSC_T_INT16='"short"'
 413 else
 414   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 415 fi
 416 AC_SUBST([SCM_I_GSC_T_INT16])
 417
 418 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 419 if test "$scm_stdint_has_uint16"; then
 420   SCM_I_GSC_T_UINT16='"uint16_t"'
 421   SCM_I_GSC_NEEDS_STDINT_H=1
 422 elif test "$scm_inttypes_has_uint16"; then
 423   SCM_I_GSC_T_UINT16='"uint16_t"'
 424   SCM_I_GSC_NEEDS_INTTYPES_H=1
 425 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 426   SCM_I_GSC_T_UINT16='"unsigned int"'
 427 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 428   SCM_I_GSC_T_UINT16='"unsigned short"'
 429 else
 430   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 431 fi
 432 AC_SUBST([SCM_I_GSC_T_UINT16])
 433
 434
 435 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 436 if test "$scm_stdint_has_int32"; then
 437   SCM_I_GSC_T_INT32='"int32_t"'
 438   SCM_I_GSC_NEEDS_STDINT_H=1
 439 elif test "$scm_inttypes_has_int32"; then
 440   SCM_I_GSC_T_INT32='"int32_t"'
 441   SCM_I_GSC_NEEDS_INTTYPES_H=1
 442 elif test "$ac_cv_sizeof_int" -eq 4; then
 443   SCM_I_GSC_T_INT32='"int"'
 444 elif test "$ac_cv_sizeof_long" -eq 4; then
 445   SCM_I_GSC_T_INT32='"long"'
 446 elif test "$ac_cv_sizeof_short" -eq 4; then
 447   SCM_I_GSC_T_INT32='"short"'
 448 else
 449   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 450 fi
 451 AC_SUBST([SCM_I_GSC_T_INT32])
 452
 453 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 454 if test "$scm_stdint_has_uint32"; then
 455   SCM_I_GSC_T_UINT32='"uint32_t"'
 456   SCM_I_GSC_NEEDS_STDINT_H=1
 457 elif test "$scm_inttypes_has_uint32"; then
 458   SCM_I_GSC_T_UINT32='"uint32_t"'
 459   SCM_I_GSC_NEEDS_INTTYPES_H=1
 460 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 461   SCM_I_GSC_T_UINT32='"unsigned int"'
 462 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 463   SCM_I_GSC_T_UINT32='"unsigned long"'
 464 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 465   SCM_I_GSC_T_UINT32='"unsigned short"'
 466 else
 467   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 468 fi
 469 AC_SUBST([SCM_I_GSC_T_UINT32])
 470
 471 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 472 ### Also try 'long long' and '__int64' if we have it.
 473 SCM_I_GSC_T_INT64=0
 474 if test "$scm_stdint_has_int64"; then
 475   SCM_I_GSC_T_INT64='"int64_t"'
 476   SCM_I_GSC_NEEDS_STDINT_H=1
 477 elif test "$scm_inttypes_has_int64"; then
 478   SCM_I_GSC_T_INT64='"int64_t"'
 479   SCM_I_GSC_NEEDS_INTTYPES_H=1
 480 elif test "$ac_cv_sizeof_int" -eq 8; then
 481   SCM_I_GSC_T_INT64='"int"'
 482 elif test "$ac_cv_sizeof_long" -eq 8; then
 483   SCM_I_GSC_T_INT64='"long"'
 484 elif test "$ac_cv_sizeof_short" -eq 8; then
 485   SCM_I_GSC_T_INT64='"short"'
 486 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 487   SCM_I_GSC_T_INT64='"long long"'
 488 elif test "$ac_cv_sizeof___int64" -eq 8; then
 489   SCM_I_GSC_T_INT64='"__int64"'
 490 else
 491   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 492 fi
 493 AC_SUBST([SCM_I_GSC_T_INT64])
 494
 495
 496 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 497 ### Also try 'long long' and '__int64' if we have it.
 498 SCM_I_GSC_T_UINT64=0
 499 if test "$scm_stdint_has_uint64"; then
 500   SCM_I_GSC_T_UINT64='"uint64_t"'
 501   SCM_I_GSC_NEEDS_STDINT_H=1
 502 elif test "$scm_inttypes_has_uint64"; then
 503   SCM_I_GSC_T_UINT64='"uint64_t"'
 504   SCM_I_GSC_NEEDS_INTTYPES_H=1
 505 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 506   SCM_I_GSC_T_UINT64='"unsigned int"'
 507 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 508   SCM_I_GSC_T_UINT64='"unsigned long"'
 509 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 510   SCM_I_GSC_T_UINT64='"unsigned short"'
 511 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 512   SCM_I_GSC_T_UINT64='"unsigned long long"'
 513 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 514   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 515 else
 516   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 517 fi
 518 AC_SUBST([SCM_I_GSC_T_UINT64])
 519
 520 ### Required type scm_t_intmax
 521 ###
 522 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 523 ### none of them is available, we use 'long'.
 524 ###
 525 SCM_I_GSC_T_INTMAX=0
 526 if test "$scm_stdint_has_intmax"; then
 527   SCM_I_GSC_T_INTMAX='"intmax_t"'
 528   SCM_I_GSC_NEEDS_STDINT_H=1
 529 elif test "$scm_inttypes_has_intmax"; then
 530   SCM_I_GSC_T_INTMAX='"intmax_t"'
 531   SCM_I_GSC_NEEDS_INTTYPES_H=1
 532 elif test "$ac_cv_sizeof___int64" -ne 0; then
 533   SCM_I_GSC_T_INTMAX='"__int64"'
 534 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 535   SCM_I_GSC_T_INTMAX='"long long"'
 536 else
 537   SCM_I_GSC_T_INTMAX='"long"'
 538 fi
 539 AC_SUBST([SCM_I_GSC_T_INTMAX])
 540
 541 ### Required type scm_t_uintmax
 542 ###
 543 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 544 ### this order.  When none of them is available, we use 'unsigned long'.
 545 ###
 546 SCM_I_GSC_T_UINTMAX=0
 547 if test "$scm_stdint_has_uintmax"; then
 548   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 549   SCM_I_GSC_NEEDS_STDINT_H=1
 550 elif test "$scm_inttypes_has_uintmax"; then
 551   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 552   SCM_I_GSC_NEEDS_INTTYPES_H=1
 553 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 554   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 555 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 556   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 557 else
 558   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 559 fi
 560 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 561
 562 ### Required type scm_t_intptr
 563 ###
 564 SCM_I_GSC_T_INTPTR=0
 565 if test "$scm_stdint_has_intptr"; then
 566   SCM_I_GSC_T_INTPTR='"intptr_t"'
 567   SCM_I_GSC_NEEDS_STDINT_H=1
 568 elif test "$scm_inttypes_has_intptr"; then
 569   SCM_I_GSC_T_INTPTR='"intptr_t"'
 570   SCM_I_GSC_NEEDS_INTTYPES_H=1
 571 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 572   SCM_I_GSC_T_INTPTR='"int"'
 573 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 574   SCM_I_GSC_T_INTPTR='"long"'
 575 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 576   SCM_I_GSC_T_INTPTR='"long long"'
 577 else
 578   AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.])
 579 fi
 580 AC_SUBST([SCM_I_GSC_T_INTPTR])
 581
 582 ### Required type scm_t_uintptr
 583 ###
 584 SCM_I_GSC_T_UINTPTR=0
 585 if test "$scm_stdint_has_uintptr"; then
 586   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 587   SCM_I_GSC_NEEDS_STDINT_H=1
 588 elif test "$scm_inttypes_has_uintptr"; then
 589   SCM_I_GSC_T_UINTPTR='"uintptr_t"'
 590   SCM_I_GSC_NEEDS_INTTYPES_H=1
 591 elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then
 592   SCM_I_GSC_T_UINTPTR='"unsigned int"'
 593 elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then
 594   SCM_I_GSC_T_UINTPTR='"unsigned long"'
 595 elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then
 596   SCM_I_GSC_T_UINTPTR='"unsigned long long"'
 597 else
 598   AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.])
 599 fi
 600 AC_SUBST([SCM_I_GSC_T_UINTPTR])
 601
 602
 603 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 604 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 605
 606 AC_HEADER_STDC
 607 AC_HEADER_TIME
 608 AC_HEADER_SYS_WAIT
 609 AC_HEADER_DIRENT
 610
 611 # Reason for checking:
 612 #
 613 #   HP-UX 11.11 (at least) doesn't provide `struct dirent64', even
 614 #   with `_LARGEFILE64_SOURCE', so check whether it's available.
 615 #
 616 AC_CHECK_MEMBER([struct dirent64.d_name],
 617   [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0],
 618   [ #ifndef _LARGEFILE64_SOURCE
 619     # define _LARGEFILE64_SOURCE
 620     #endif
 621
 622     /* Per Autoconf manual.  */
 623     #include <sys/types.h>
 624     #ifdef HAVE_DIRENT_H
 625     # include <dirent.h>
 626     #else
 627     # define dirent direct
 628     # ifdef HAVE_SYS_NDIR_H
 629     #  include <sys/ndir.h>
 630     # endif
 631     # ifdef HAVE_SYS_DIR_H
 632     #  include <sys/dir.h>
 633     # endif
 634     # ifdef HAVE_NDIR_H
 635     #  include <ndir.h>
 636     # endif
 637     #endif ])
 638 AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64])
 639
 640 # Reasons for testing:
 641 #   complex.h - new in C99
 642 #   fenv.h - available in C99, but not older systems
 643 #   machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in
 644 #     this file instead of <fenv.h>
 645 #   process.h - mingw specific
 646 #   langinfo.h, nl_types.h - SuS v2
 647 #   sched.h - missing on MinGW
 648 #
 649 AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h malloc.h memory.h process.h string.h \
 650 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 651 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 652 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 653 direct.h langinfo.h nl_types.h machine/fpu.h poll.h sched.h])
 654
 655 # Reasons for testing:
 656 #   nl_item - lacking on Cygwin
 657 AC_CHECK_TYPES([nl_item], [], [],
 658   [[#ifdef HAVE_LANGINFO_H
 659     # include <langinfo.h>
 660     #endif
 661     #ifdef HAVE_NL_TYPES_H
 662     # include <nl_types.h>
 663     #endif]])
 664
 665 # "complex double" is new in C99, and "complex" is only a keyword if
 666 # <complex.h> is included
 667 AC_CHECK_TYPES(complex double,,,
 668 [#if HAVE_COMPLEX_H
 669 #include <complex.h>
 670 #endif])
 671
 672 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 673 # when testing.
 674 AC_CHECK_TYPE(socklen_t, ,
 675   [AC_DEFINE_UNQUOTED([socklen_t], int,
 676                       [Define to `int' if <sys/socket.h> does not define.])],
 677   [#if HAVE_SYS_TYPES_H
 678 #include <sys/types.h>
 679 #endif
 680 #include <sys/socket.h>
 681 ])
 682
 683 AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>])
 684
 685 GUILE_HEADER_LIBC_WITH_UNISTD
 686
 687 AC_TYPE_GETGROUPS
 688 AC_TYPE_SIGNAL
 689 AC_TYPE_MODE_T
 690
 691 # On mingw -lm is empty, so this test is unnecessary, but it's
 692 # harmless so we don't hard-code to suppress it.
 693 #
 694 AC_CHECK_LIB(m, cos)
 695
 696 AC_CHECK_FUNCS(gethostbyname)
 697 if test $ac_cv_func_gethostbyname = no; then
 698     AC_CHECK_LIB(nsl, gethostbyname)
 699 fi
 700
 701 AC_CHECK_FUNCS(connect)
 702 if test $ac_cv_func_connect = no; then
 703     AC_CHECK_LIB(socket, connect)
 704 fi
 705
 706 dnl
 707 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 708 dnl
 709 EXTRA_DEFS=""
 710 case $host in
 711   *-*-mingw*)
 712     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 713       [Define if you have the <winsock2.h> header file.])])
 714     AC_CHECK_LIB(ws2_32, main)
 715     AC_LIBOBJ([win32-uname])
 716     AC_LIBOBJ([win32-dirent])
 717     if test "$enable_networking" = yes ; then
 718       AC_LIBOBJ([win32-socket])
 719     fi
 720     if test "$enable_shared" = yes ; then
 721       EXTRA_DEFS="-DSCM_IMPORT"
 722       AC_DEFINE([USE_DLL_IMPORT], 1,
 723         [Define if you need additional CPP macros on Win32 platforms.])
 724     fi
 725     ;;
 726 esac
 727 AC_SUBST(EXTRA_DEFS)
 728
 729 # Reasons for testing:
 730 #   crt_externs.h - Darwin specific
 731 #
 732 AC_CHECK_HEADERS([assert.h crt_externs.h])
 733
 734 # Reasons for testing:
 735 #   DINFINITY - OSF specific
 736 #   DQNAN - OSF specific
 737 #       (DINFINITY and DQNAN are actually global variables, not functions)
 738 #   chsize - an MS-DOS-ism, found in mingw
 739 #   cexp, clog - not in various pre-c99 systems, and note that it's possible
 740 #       for gcc to provide the "complex double" type but the system to not
 741 #       have functions like cexp and clog
 742 #   clog10 - not in mingw (though others like clog and csqrt are)
 743 #   fesetround - available in C99, but not older systems
 744 #   ftruncate - posix, but probably not older systems (current mingw
 745 #               has it as an inline for chsize)
 746 #   ioctl - not in mingw.
 747 #   gmtime_r - recent posix, not on old systems
 748 #   pipe - not in mingw
 749 #   _pipe - specific to mingw, taking 3 args
 750 #   poll - since posix 2001
 751 #   readdir_r - recent posix, not on old systems
 752 #   readdir64_r - not available on HP-UX 11.11
 753 #   stat64 - SuS largefile stuff, not on old systems
 754 #   sysconf - not on old systems
 755 #   truncate - not in mingw
 756 #   isblank - available as a GNU extension or in C99
 757 #   _NSGetEnviron - Darwin specific
 758 #   strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin
 759 #   nl_langinfo - X/Open, not available on Windows.
 760 #   utimensat: posix.1-2008
 761 #   sched_getaffinity, sched_setaffinity: GNU extensions (glibc)
 762 #
 763 AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid fesetround ftime ftruncate fchown getcwd geteuid getsid gettimeofday gmtime_r ioctl lstat mkdir mknod nice pipe _pipe poll readdir_r readdir64_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron strcoll strcoll_l newlocale nl_langinfo utimensat sched_getaffinity sched_setaffinity])
 764
 765 # Reasons for testing:
 766 #   netdb.h - not in mingw
 767 #   sys/param.h - not in mingw
 768 #   pthread.h - only available with pthreads.  ACX_PTHREAD doesn't
 769 #       check this specifically, we need it for the timespec test below.
 770 #   sethostname - the function itself check because it's not in mingw,
 771 #       the DECL is checked because Solaris 10 doens't have in any header
 772 #   hstrerror - on Tru64 5.1b the symbol is available in libc but the
 773 #       declaration isn't anywhere.
 774 #   cuserid - on Tru64 5.1b the declaration is documented to be available
 775 #       only with `_XOPEN_SOURCE' or some such.
 776 #
 777 AC_CHECK_HEADERS([crypt.h netdb.h pthread.h sys/param.h sys/resource.h sys/file.h sys/mman.h])
 778 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 779 AC_CHECK_DECLS([sethostname, hstrerror, cuserid])
 780
 781 # crypt() may or may not be available, for instance in some countries there
 782 # are restrictions on cryptography.
 783 #
 784 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 785 # -lcrypt library (eg. Debian GNU/Linux).
 786 #
 787 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 788 # be careful to avoid -lcrypt in this case, since libtool will see there's
 789 # only a static libcrypt and decide to build only a static libguile.
 790 #
 791 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 792 # libraries already in that list.
 793 #
 794 AC_SEARCH_LIBS(crypt, crypt,
 795   [AC_DEFINE([HAVE_CRYPT],1,
 796              [Define to 1 if you have the `crypt' function.])])
 797
 798 # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't
 799 # work; in the reported cases so far, 1.0fi works well instead.  According
 800 # to the C99 spec, the complex.h header must provide a working definition
 801 # of _Complex_I, so we always try _Complex_I first.  The 1.0fi fallback
 802 # is a workaround for the failure of some systems to conform to C99.
 803 if test "$ac_cv_type_complex_double" = yes; then
 804   AC_MSG_CHECKING([for i])
 805   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 806 #if HAVE_COMPLEX_H
 807 #include <complex.h>
 808 #endif
 809 complex double z;
 810 ]], [[
 811 z = _Complex_I;
 812 ]])],
 813     [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).])
 814      AC_MSG_RESULT([_Complex_I])],
 815     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 816 #if HAVE_COMPLEX_H
 817 #include <complex.h>
 818 #endif
 819 complex double z;
 820 ]],[[
 821 z = 1.0fi;
 822 ]])],
 823   [AC_DEFINE([GUILE_I],1.0fi)
 824    AC_MSG_RESULT([1.0fi])],
 825   [ac_cv_type_complex_double=no
 826    AC_MSG_RESULT([not available])])])
 827 fi
 828
 829 # glibc 2.3.6 (circa 2006) and various prior versions had a bug where
 830 # csqrt(-i) returned a negative real part, when it should be positive
 831 # for the principal root.
 832 #
 833 if test "$ac_cv_type_complex_double" = yes; then
 834
 835   AC_CACHE_CHECK([whether csqrt is usable],
 836     guile_cv_use_csqrt,
 837     [AC_RUN_IFELSE([AC_LANG_SOURCE([[
 838 #include <complex.h>
 839 /* "volatile" is meant to prevent gcc from calculating the sqrt as a
 840    constant, we want to test libc. */
 841 volatile complex double z = - _Complex_I;
 842 int
 843 main (void)
 844 {
 845   z = csqrt (z);
 846   if (creal (z) > 0.0)
 847     return 0;  /* good */
 848   else
 849     return 1;  /* bad */
 850 }]])],
 851     [guile_cv_use_csqrt=yes],
 852     [guile_cv_use_csqrt="no, glibc 2.3 bug"],
 853     [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])])
 854   case $guile_cv_use_csqrt in
 855     yes*)
 856       AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free])
 857       ;;
 858   esac
 859 fi
 860
 861 AC_CACHE_SAVE
 862
 863 dnl GMP tests
 864 AC_LIB_HAVE_LINKFLAGS([gmp],
 865   [],
 866   [#include <gmp.h>],
 867   [mpz_import (0, 0, 0, 0, 0, 0, 0);])
 868
 869 if test "x$HAVE_LIBGMP" != "xyes"; then
 870   AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README])
 871 fi
 872
 873 dnl GNU libunistring is checked for by Gnulib's `libunistring' module.
 874 if test "x$LTLIBUNISTRING" = "x"; then
 875   AC_MSG_ERROR([GNU libunistring is required, please install it.])
 876 fi
 877
 878 dnl Libffi is needed to compile Guile's foreign function interface, but its
 879 dnl interface isn't exposed in Guile's API.
 880 PKG_CHECK_MODULES(LIBFFI, libffi)
 881 AC_SUBST(LIBFFI_CFLAGS)
 882 AC_SUBST(LIBFFI_LIBS)
 883
 884 dnl figure out approriate ffi type for size_t
 885 AC_CHECK_SIZEOF(size_t)
 886 AC_CHECK_SIZEOF(ssize_t)
 887 ffi_size_type=uint$(($ac_cv_sizeof_size_t*8))
 888 ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8))
 889 AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type},
 890                    [ffi type for size_t])
 891 AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type},
 892                    [ffi type for ssize_t])
 893
 894 dnl i18n tests
 895 #AC_CHECK_HEADERS([libintl.h])
 896 #AC_CHECK_FUNCS(gettext)
 897 #if test $ac_cv_func_gettext = no; then
 898 #   AC_CHECK_LIB(intl, gettext)
 899 #fi
 900 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 901 AM_GNU_GETTEXT([external], [need-ngettext])
 902
 903 ### Some systems don't declare some functions.  On such systems, we
 904 ### need to at least provide our own K&R-style declarations.
 905
 906 ### GUILE_FUNC_DECLARED(function, headerfile)
 907
 908 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 909 ### not there, #define MISSING_FUNCTION_DECL.
 910 AC_DEFUN([GUILE_FUNC_DECLARED], [
 911   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 912     AC_EGREP_HEADER($1, $2,
 913                     guile_cv_func_$1_declared=yes,
 914                     guile_cv_func_$1_declared=no))
 915   if test [x$guile_cv_func_]$1[_declared] = xno; then
 916     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 917       [Define if the operating system supplies $1 without declaring it.])
 918   fi
 919 ])
 920
 921 GUILE_FUNC_DECLARED(sleep, unistd.h)
 922 GUILE_FUNC_DECLARED(usleep, unistd.h)
 923
 924 AC_CHECK_DECLS([strptime],,,
 925 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 926 #include <time.h>])
 927
 928 ### On some systems usleep has no return value.  If it does have one,
 929 ### we'd like to return it; otherwise, we'll fake it.
 930 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 931   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 932                    unistd.h,
 933                    [guile_cv_func_usleep_return_type=void],
 934                    [guile_cv_func_usleep_return_type=int])])
 935 case "$guile_cv_func_usleep_return_type" in
 936   "void" )
 937     AC_DEFINE([USLEEP_RETURNS_VOID], 1,
 938       [Define if the system headers declare usleep to return void.])
 939   ;;
 940 esac
 941
 942 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 943 if test -n "$have_sys_un_h" ; then
 944   AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1,
 945     [Define if the system supports Unix-domain (file-domain) sockets.])
 946 fi
 947
 948 AC_CHECK_FUNCS(getrlimit setrlimit)
 949
 950 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 951
 952 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 953                setnetent    getnetent    endnetent    dnl
 954                setprotoent  getprotoent  endprotoent  dnl
 955                setservent   getservent   endservent   dnl
 956                getnetbyaddr getnetbyname dnl
 957                inet_lnaof inet_makeaddr inet_netof hstrerror)
 958
 959 AC_CHECK_MEMBERS([struct sockaddr_in.sin_len],,,
 960 [#ifdef HAVE_SYS_TYPES_H
 961 #include <sys/types.h>
 962 #endif
 963 #include <netinet/in.h>])
 964
 965 AC_MSG_CHECKING(for __libc_stack_end)
 966 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 967 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h>
 968 extern char *__libc_stack_end;]],
 969    [[printf("%p", (char*) __libc_stack_end);]])],
 970    [guile_cv_have_libc_stack_end=yes],
 971    [guile_cv_have_libc_stack_end=no])])
 972 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 973
 974 if test $guile_cv_have_libc_stack_end = yes; then
 975   AC_DEFINE([HAVE_LIBC_STACK_END], 1,
 976            [Define if you have the __libc_stack_end variable.])
 977 fi
 978
 979 dnl Some systems do not declare this.  Some systems do declare it, as a
 980 dnl macro.  With cygwin it may be in a DLL.
 981
 982 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 983 AC_CACHE_VAL(guile_cv_have_h_errno,
 984   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 985                                       [[int a = h_errno;]])],
 986   [guile_cv_have_h_errno=yes],
 987   [guile_cv_have_h_errno=no])])
 988 AC_MSG_RESULT($guile_cv_have_h_errno)
 989 if test $guile_cv_have_h_errno = yes; then
 990   AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.])
 991 fi
 992
 993 AC_MSG_CHECKING(whether uint32_t is defined)
 994 AC_CACHE_VAL(guile_cv_have_uint32_t,
 995   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 996                    #if HAVE_STDINT_H
 997                    #include <stdint.h>
 998                    #endif
 999                    #ifndef HAVE_NETDB_H
1000                    #include <netdb.h>
1001                    #endif]],
1002                    [[uint32_t a;]])],
1003                    [guile_cv_have_uint32_t=yes],
1004                    [guile_cv_have_uint32_t=no])])
1005 AC_MSG_RESULT($guile_cv_have_uint32_t)
1006 if test $guile_cv_have_uint32_t = yes; then
1007   AC_DEFINE([HAVE_UINT32_T], 1,
1008     [Define if uint32_t typedef is defined when netdb.h is include.])
1009 fi
1010
1011 AC_MSG_CHECKING(for working IPv6 support)
1012 AC_CACHE_VAL(guile_cv_have_ipv6,
1013 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1014 #ifdef HAVE_SYS_TYPES_H
1015 #include <sys/types.h>
1016 #endif
1017 #include <netinet/in.h>
1018 #include <sys/socket.h>]],
1019 [[struct sockaddr_in6 a;  a.sin6_family = AF_INET6;]])],
1020 [guile_cv_have_ipv6=yes],
1021 [guile_cv_have_ipv6=no])])
1022 AC_MSG_RESULT($guile_cv_have_ipv6)
1023 if test $guile_cv_have_ipv6 = yes; then
1024   AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.])
1025 fi
1026
1027 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
1028 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
1029 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
1030 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1031 #ifdef HAVE_SYS_TYPES_H
1032 #include <sys/types.h>
1033 #endif
1034 #include <netinet/in.h>]],
1035 [[struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;]])],
1036 [guile_cv_have_sin6_scope_id=yes],
1037 [guile_cv_have_sin6_scope_id=no])])
1038 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
1039 if test $guile_cv_have_sin6_scope_id = yes; then
1040   AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1,
1041     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
1042 fi
1043
1044 # struct sockaddr_in6 field sin_len is only present on BSD systems
1045 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
1046 [#ifdef HAVE_SYS_TYPES_H
1047 #include <sys/types.h>
1048 #endif
1049 #include <netinet/in.h>])
1050
1051 AC_MSG_CHECKING(whether localtime caches TZ)
1052 AC_CACHE_VAL(guile_cv_localtime_cache,
1053 [if test x$ac_cv_func_tzset = xyes; then
1054 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
1055 #if STDC_HEADERS
1056 # include <stdlib.h>
1057 #endif
1058 extern char **environ;
1059 unset_TZ ()
1060 {
1061   char **from, **to;
1062   for (to = from = environ; (*to = *from); from++)
1063     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1064       to++;
1065 }
1066 char TZ_GMT0[] = "TZ=GMT0";
1067 char TZ_PST8[] = "TZ=PST8";
1068 main()
1069 {
1070   time_t now = time ((time_t *) 0);
1071   int hour_GMT0, hour_unset;
1072   if (putenv (TZ_GMT0) != 0)
1073     exit (1);
1074   hour_GMT0 = localtime (&now)->tm_hour;
1075   unset_TZ ();
1076   hour_unset = localtime (&now)->tm_hour;
1077   if (putenv (TZ_PST8) != 0)
1078     exit (1);
1079   if (localtime (&now)->tm_hour == hour_GMT0)
1080     exit (1);
1081   unset_TZ ();
1082   if (localtime (&now)->tm_hour != hour_unset)
1083     exit (1);
1084   exit (0);
1085 }]])],
1086 [guile_cv_localtime_cache=no],
1087 [guile_cv_localtime_cache=yes],
1088 [# If we have tzset, assume the worst when cross-compiling.
1089 guile_cv_localtime_cache=yes])
1090 else
1091         # If we lack tzset, report that localtime does not cache TZ,
1092         # since we can't invalidate the cache if we don't have tzset.
1093         guile_cv_localtime_cache=no
1094 fi])dnl
1095 AC_MSG_RESULT($guile_cv_localtime_cache)
1096 if test $guile_cv_localtime_cache = yes; then
1097   AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.])
1098 fi
1099
1100 if test "$enable_regex" = yes; then
1101    if test "$ac_cv_header_regex_h" = yes ||
1102       test "$ac_cv_header_rxposix_h" = yes ||
1103       test "$ac_cv_header_rx_rxposix_h" = yes; then
1104      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
1105      [AC_CHECK_LIB(rx, main)
1106       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
1107      [AC_CHECK_LIB(regex, main)
1108       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
1109      )
1110      dnl The following should not be necessary, but for some reason
1111      dnl autoheader misses it if we don't include it!
1112      if test "$ac_cv_func_regcomp_norx" = yes ||
1113         test "$ac_cv_func_regcomp_regex" = yes ||
1114         test "$ac_cv_func_regcomp_rx" = yes; then
1115        AC_DEFINE([HAVE_REGCOMP], 1,
1116          [This is included as part of a workaround for a autoheader bug.])
1117      fi
1118    fi
1119 fi
1120
1121 AC_REPLACE_FUNCS([strerror memmove mkstemp])
1122
1123 # Reasons for testing:
1124 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
1125 #                                older systems
1126 #   sincos - GLIBC extension
1127 #
1128 AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc)
1129
1130 # C99 specifies isinf and isnan as macros.
1131 # HP-UX provides only macros, no functions.
1132 # glibc 2.3.2 provides both macros and functions.
1133 # IRIX 6.5 and Solaris 8 only provide functions.
1134 #
1135 # The following tests detect isinf and isnan either as functions or as
1136 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
1137 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
1138 #
1139 AC_MSG_CHECKING([for isinf])
1140 AC_LINK_IFELSE(AC_LANG_SOURCE(
1141 [[#include <math.h>
1142 volatile double x = 0.0;
1143 int main () { return (isinf(x) != 0); }]]),
1144   [AC_MSG_RESULT([yes])
1145    AC_DEFINE([HAVE_ISINF], 1,
1146              [Define to 1 if you have the `isinf' macro or function.])],
1147   [AC_MSG_RESULT([no])])
1148 AC_MSG_CHECKING([for isnan])
1149 AC_LINK_IFELSE(AC_LANG_SOURCE(
1150 [[#include <math.h>
1151 volatile double x = 0.0;
1152 int main () { return (isnan(x) != 0); }]]),
1153   [AC_MSG_RESULT([yes])
1154    AC_DEFINE([HAVE_ISNAN], 1,
1155              [Define to 1 if you have the `isnan' macro or function.])],
1156   [AC_MSG_RESULT([no])])
1157
1158 # Reasons for checking:
1159 #
1160 #     st_rdev
1161 #     st_blksize
1162 #     st_blocks   not in mingw
1163 #     tm_gmtoff   BSD+GNU, not in C99
1164 #
1165 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
1166 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
1167 #
1168 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,,
1169                  [#define _GNU_SOURCE
1170 AC_INCLUDES_DEFAULT
1171 ])
1172
1173 AC_STRUCT_TIMEZONE
1174 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,
1175 [#include <time.h>
1176 #ifdef TIME_WITH_SYS_TIME
1177 # include <sys/time.h>
1178 # include <time.h>
1179 #else
1180 # if HAVE_SYS_TIME_H
1181 #  include <sys/time.h>
1182 # else
1183 #  include <time.h>
1184 # endif
1185 #endif
1186 ])
1187 GUILE_STRUCT_UTIMBUF
1188
1189
1190 #--------------------------------------------------------------------
1191 #
1192 # Which way does the stack grow?
1193 #
1194 # Following code comes from Autoconf 2.61's internal _AC_LIBOBJ_ALLOCA
1195 # macro (/usr/share/autoconf/autoconf/functions.m4).  Gnulib has
1196 # very similar code, so in future we could look at using that.
1197 #
1198 # An important detail is that the code involves find_stack_direction
1199 # calling _itself_ - which means that find_stack_direction (or at
1200 # least the second find_stack_direction() call) cannot be inlined.
1201 # If the code could be inlined, that might cause the test to give
1202 # an incorrect answer.
1203 #--------------------------------------------------------------------
1204
1205 SCM_I_GSC_STACK_GROWS_UP=0
1206 AC_RUN_IFELSE([AC_LANG_SOURCE(
1207 [AC_INCLUDES_DEFAULT
1208 int
1209 find_stack_direction ()
1210 {
1211   static char *addr = 0;
1212   auto char dummy;
1213   if (addr == 0)
1214     {
1215       addr = &dummy;
1216       return find_stack_direction ();
1217     }
1218   else
1219     return (&dummy > addr) ? 1 : -1;
1220 }
1221
1222 int
1223 main ()
1224 {
1225   return find_stack_direction () < 0;
1226 }])],
1227                [SCM_I_GSC_STACK_GROWS_UP=1],
1228                [],
1229                [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
1230
1231 #--------------------------------------------------------------------
1232 #
1233 # Boehm's GC library
1234 #
1235 #--------------------------------------------------------------------
1236 PKG_CHECK_MODULES([BDW_GC], [bdw-gc])
1237
1238 save_LIBS="$LIBS"
1239 LIBS="$BDW_GC_LIBS $LIBS"
1240 CFLAGS="$BDW_GC_CFLAGS $CFLAGS"
1241
1242 AC_CHECK_FUNCS([GC_do_blocking GC_call_with_gc_active GC_pthread_exit GC_pthread_cancel GC_allow_register_threads GC_pthread_sigmask])
1243
1244 # Though the `GC_do_blocking ()' symbol is present in GC 7.1, it is not
1245 # declared, and has a different type (returning void instead of
1246 # void*).
1247 AC_CHECK_DECL([GC_do_blocking],
1248   [AC_DEFINE([HAVE_DECL_GC_DO_BLOCKING], [1],
1249     [Define this if the `GC_do_blocking ()' function is declared])],
1250   [],
1251   [#include <gc/gc.h>])
1252
1253 # `GC_fn_type' is not available in GC 7.1 and earlier.
1254 AC_CHECK_TYPE([GC_fn_type],
1255   [AC_DEFINE([HAVE_GC_FN_TYPE], [1],
1256     [Define this if the `GC_fn_type' type is available.])],
1257   [],
1258   [#include <gc/gc.h>])
1259
1260 # `GC_stack_base' is not available in GC 7.1 and earlier.
1261 AC_CHECK_TYPE([struct GC_stack_base],
1262   [AC_DEFINE([HAVE_GC_STACK_BASE], [1],
1263     [Define this if the `GC_stack_base' type is available.])],
1264   [],
1265   [#include <gc/gc.h>])
1266
1267 LIBS="$save_LIBS"
1268
1269
1270 AC_CHECK_SIZEOF(float)
1271 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
1272     AC_DEFINE([SCM_SINGLES], 1,
1273               [Define this if floats are the same size as longs.])
1274 fi
1275
1276 AC_MSG_CHECKING(for struct linger)
1277 AC_CACHE_VAL(scm_cv_struct_linger,
1278         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1279 #include <sys/types.h>
1280 #include <sys/socket.h>]],
1281                           [[struct linger lgr;  lgr.l_linger = 100]])],
1282                           [scm_cv_struct_linger="yes"],
1283                           [scm_cv_struct_linger="no"]))
1284 AC_MSG_RESULT($scm_cv_struct_linger)
1285 if test $scm_cv_struct_linger = yes; then
1286         AC_DEFINE([HAVE_STRUCT_LINGER], 1,
1287           [Define this if your system defines struct linger, for use with the
1288            getsockopt and setsockopt system calls.])
1289 fi
1290
1291
1292 # On mingw, struct timespec is in <pthread.h>.
1293 #
1294 AC_MSG_CHECKING(for struct timespec)
1295 AC_CACHE_VAL(scm_cv_struct_timespec,
1296         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1297 #include <time.h>
1298 #if HAVE_PTHREAD_H
1299 #include <pthread.h>
1300 #endif]], [[struct timespec t;  t.tv_nsec = 100]])],
1301           [scm_cv_struct_timespec="yes"],
1302           [scm_cv_struct_timespec="no"]))
1303 AC_MSG_RESULT($scm_cv_struct_timespec)
1304 if test $scm_cv_struct_timespec = yes; then
1305   AC_DEFINE([HAVE_STRUCT_TIMESPEC], 1,
1306     [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.])
1307 fi
1308
1309 #--------------------------------------------------------------------
1310 #
1311 # Flags for thread support
1312 #
1313 #--------------------------------------------------------------------
1314
1315 SCM_I_GSC_USE_PTHREAD_THREADS=0
1316 SCM_I_GSC_USE_NULL_THREADS=0
1317 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
1318 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
1319
1320 ### What thread package has the user asked for?
1321 AC_ARG_WITH(threads, [  --with-threads          thread interface],
1322             , with_threads=yes)
1323
1324 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0)
1325 AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0)
1326
1327 case "$with_threads" in
1328   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1329
1330     build_pthread_support="yes"
1331
1332     ACX_PTHREAD([CC="$PTHREAD_CC"
1333        LIBS="$PTHREAD_LIBS $LIBS"
1334        SCM_I_GSC_USE_PTHREAD_THREADS=1
1335        with_threads="pthreads"],
1336       [with_threads="null"
1337        build_pthread_support="no"])
1338
1339     old_CFLAGS="$CFLAGS"
1340     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1341
1342     # Reasons for testing:
1343     #     pthread_getattr_np - "np" meaning "non portable" says it
1344     #         all; not present on MacOS X or Solaris 10
1345     #     pthread_get_stackaddr_np - "np" meaning "non portable" says it
1346     #         all; specific to MacOS X
1347     #     pthread_sigmask - not available on mingw
1348     #
1349     AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_sigmask)
1350
1351     # On past versions of Solaris, believe 8 through 10 at least, you
1352     # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };".
1353     # This is contrary to POSIX:
1354     # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html
1355     # Check here if this style is required.
1356     #
1357     # glibc (2.3.6 at least) works both with or without braces, so the
1358     # test checks whether it works without.
1359     #
1360
1361     if test "$GCC" = "yes"; then
1362       # Since GCC only issues a warning for missing braces, so we need
1363       # `-Werror' to catch it.
1364       CFLAGS="-Werror -Wmissing-braces $CFLAGS"
1365     fi
1366
1367     AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces],
1368       guile_cv_need_braces_on_pthread_once_init,
1369       [AC_COMPILE_IFELSE([#include <pthread.h>
1370          pthread_once_t foo = PTHREAD_ONCE_INIT;],
1371         [guile_cv_need_braces_on_pthread_once_init=no],
1372         [guile_cv_need_braces_on_pthread_once_init=yes])])
1373     if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then
1374       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1
1375     fi
1376
1377     # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX
1378     # 6.5.30m with GCC 3.3.
1379     AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces],
1380       guile_cv_need_braces_on_pthread_mutex_initializer,
1381       [AC_COMPILE_IFELSE([#include <pthread.h>
1382          pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;],
1383         [guile_cv_need_braces_on_pthread_mutex_initializer=no],
1384         [guile_cv_need_braces_on_pthread_mutex_initializer=yes])])
1385     if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then
1386       SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1
1387     fi
1388
1389     CFLAGS="$old_CFLAGS"
1390
1391     # On Solaris, sched_yield lives in -lrt.
1392     AC_SEARCH_LIBS(sched_yield, rt)
1393
1394   ;;
1395 esac
1396
1397 case "$with_threads" in
1398   "pthreads")
1399   ;;
1400   "no" | "null")
1401     SCM_I_GSC_USE_NULL_THREADS=1
1402     SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
1403     with_threads="null-threads"
1404   ;;
1405   * )
1406     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1407   ;;
1408 esac
1409
1410 AC_MSG_CHECKING(what kind of threads to support)
1411 AC_MSG_RESULT($with_threads)
1412
1413 AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT],
1414   [test "x$build_pthread_support" = "xyes"])
1415
1416
1417 ## Check whether pthread_attr_getstack works for the main thread
1418
1419 if test "$with_threads" = pthreads; then
1420
1421 AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread])
1422 old_CFLAGS="$CFLAGS"
1423 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1424 if test "$cross_compiling" = "no"; then
1425   AC_RUN_IFELSE([AC_LANG_SOURCE([[
1426   #if HAVE_PTHREAD_ATTR_GETSTACK
1427   #include <pthread.h>
1428
1429   int main ()
1430   {
1431     pthread_attr_t attr;
1432     void *start, *end;
1433     size_t size;
1434
1435     pthread_getattr_np (pthread_self (), &attr);
1436     pthread_attr_getstack (&attr, &start, &size);
1437     end = (char *)start + size;
1438
1439     if ((void *)&attr < start || (void *)&attr >= end)
1440       return 1;
1441     else
1442       return 0;
1443   }
1444   #else
1445   int main ()
1446   {
1447     return 1;
1448   }
1449   #endif
1450   ]])],
1451   [works=yes
1452    AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])],
1453   [works=no],
1454   [])
1455 else
1456   works="assuming it doesn't"
1457 fi
1458 CFLAGS="$old_CFLAGS"
1459 AC_MSG_RESULT($works)
1460
1461 GUILE_THREAD_LOCAL_STORAGE
1462
1463 fi # with_threads=pthreads
1464
1465
1466 ## Cross building
1467 if test "$cross_compiling" = "yes"; then
1468   AC_MSG_CHECKING(cc for build)
1469   ## /usr/bin/cc still uses wrong assembler
1470   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1471   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1472 else
1473   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1474 fi
1475
1476 ## AC_MSG_CHECKING("if we are cross compiling")
1477 ## AC_MSG_RESULT($cross_compiling)
1478 if test "$cross_compiling" = "yes"; then
1479    AC_MSG_RESULT($CC_FOR_BUILD)
1480 fi
1481
1482 ## No need as yet to be more elaborate
1483 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1484
1485 AC_SUBST(cross_compiling)
1486 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1487 AC_SUBST(CCLD_FOR_BUILD)
1488
1489 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1490 ## --HOST is the platform that PACKAGE is compiled for.
1491 HOST_CC="$CC_FOR_BUILD"
1492 AC_SUBST(HOST_CC)
1493
1494 if test "$cross_compiling" = "yes"; then
1495   AC_MSG_CHECKING(guile for build)
1496   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1497 else
1498   GUILE_FOR_BUILD='this-value-will-never-be-used'
1499 fi
1500
1501 ## AC_MSG_CHECKING("if we are cross compiling")
1502 ## AC_MSG_RESULT($cross_compiling)
1503 if test "$cross_compiling" = "yes"; then
1504    AC_MSG_RESULT($GUILE_FOR_BUILD)
1505 fi
1506 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1507 AM_SUBST_NOTMAKE(GUILE_FOR_BUILD)
1508
1509 ## If we're using GCC, ask for aggressive warnings.
1510 GCC_CFLAGS=""
1511 case "$GCC" in
1512   yes )
1513     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1514     ## much stuff with generic function pointers for that to really be
1515     ## less than exasperating.
1516     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1517     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1518     POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \
1519       -Wdeclaration-after-statement -Wundef \
1520       -Wswitch-enum"
1521     # Do this here so we don't screw up any of the tests above that might
1522     # not be "warning free"
1523     if test "${GUILE_ERROR_ON_WARNING}" = yes
1524     then
1525         POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror"
1526         enable_compile_warnings=no
1527     fi
1528
1529     for flag in $POTENTIAL_GCC_CFLAGS
1530     do
1531         gl_WARN_ADD([$flag], [GCC_CFLAGS])
1532     done
1533     ;;
1534 esac
1535
1536 AC_SUBST(GCC_CFLAGS)
1537
1538 # Check for GNU ld's "-z relro".
1539 GUILE_GNU_LD_RELRO
1540
1541
1542 ## If we're creating a shared library (using libtool!), then we'll
1543 ## need to generate a list of .lo files corresponding to the .o files
1544 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1545 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1546
1547 ## We also need to create corresponding .doc and .x files
1548 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1549 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1550
1551 # GNU Readline bindings.
1552 GUILE_READLINE
1553
1554 AC_SUBST(GUILE_MAJOR_VERSION)
1555 AC_SUBST(GUILE_MINOR_VERSION)
1556 AC_SUBST(GUILE_MICRO_VERSION)
1557 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1558 AC_SUBST(GUILE_VERSION)
1559
1560 #######################################################################
1561 # library versioning
1562
1563 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1564 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1565 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1566 AC_SUBST(LIBGUILE_INTERFACE)
1567
1568 AC_SUBST(LIBGUILE_I18N_MAJOR)
1569 AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT)
1570 AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION)
1571 AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE)
1572 AC_SUBST(LIBGUILE_I18N_INTERFACE)
1573
1574
1575 #######################################################################
1576
1577 dnl Tell guile-config what flags guile users should compile and link
1578 dnl with, keeping only `-I' flags from $CPPFLAGS.
1579 GUILE_CFLAGS=""
1580 next_is_includedir=false
1581 for flag in $CPPFLAGS
1582 do
1583   if $next_is_includedir; then
1584     GUILE_CFLAGS="$GUILE_CFLAGS -I $flag"
1585     next_is_includedir=false
1586   else
1587     case "$flag" in
1588       -I)  next_is_includedir=true;;
1589       -I*) GUILE_CFLAGS="$GUILE_CFLAGS $flag";;
1590       *)   ;;
1591     esac
1592   fi
1593 done
1594
1595 GUILE_CFLAGS="$GUILE_CFLAGS $PTHREAD_CFLAGS"
1596 GUILE_LIBS="$LDFLAGS $LIBS"
1597
1598 AC_SUBST(GUILE_LIBS)
1599 AC_SUBST(GUILE_CFLAGS)
1600
1601 AC_SUBST(AWK)
1602 AC_SUBST(LIBLOBJS)
1603 AC_SUBST(EXTRA_DOT_DOC_FILES)
1604 AC_SUBST(EXTRA_DOT_X_FILES)
1605
1606 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1607 top_builddir_absolute=`pwd`
1608 AC_SUBST(top_builddir_absolute)
1609 top_srcdir_absolute=`(cd $srcdir && pwd)`
1610 AC_SUBST(top_srcdir_absolute)
1611
1612 dnl `sitedir' goes into libpath.h and the pkg-config file.
1613 pkgdatadir="$datadir/$PACKAGE_TARNAME"
1614 sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION"
1615 AC_SUBST([sitedir])
1616
1617 # Additional SCM_I_GSC definitions are above.
1618 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1619 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1620 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1621 AC_SUBST([SCM_I_GSC_C_INLINE])
1622 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1623
1624 AC_CONFIG_FILES([
1625   Makefile
1626   am/Makefile
1627   lib/Makefile
1628   benchmark-suite/Makefile
1629   gc-benchmarks/Makefile
1630   doc/Makefile
1631   doc/r5rs/Makefile
1632   doc/ref/Makefile
1633   emacs/Makefile
1634   examples/Makefile
1635   libguile/Makefile
1636   libguile/version.h
1637   guile-readline/Makefile
1638   test-suite/Makefile
1639   test-suite/standalone/Makefile
1640   test-suite/vm/Makefile
1641   meta/Makefile
1642   module/Makefile
1643 ])
1644
1645 AC_CONFIG_FILES([meta/guile-2.0.pc])
1646 AC_CONFIG_FILES([meta/guile-2.0-uninstalled.pc])
1647 AC_CONFIG_FILES([doc/ref/effective-version.texi])
1648
1649 GUILE_CONFIG_SCRIPT([check-guile])
1650 GUILE_CONFIG_SCRIPT([benchmark-guile])
1651 GUILE_CONFIG_SCRIPT([meta/guile])
1652 GUILE_CONFIG_SCRIPT([meta/uninstalled-env])
1653 GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile])
1654 GUILE_CONFIG_SCRIPT([meta/guile-tools])
1655 GUILE_CONFIG_SCRIPT([libguile/guile-snarf])
1656 GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs])
1657 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi])
1658 GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref])
1659
1660 AC_OUTPUT
1661
1662 dnl Local Variables:
1663 dnl comment-start: "dnl "
1664 dnl comment-end: ""
1665 dnl comment-start-skip: "\\bdnl\\b\\s *"
1666 dnl End: