configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # User options
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_ARG_ENABLE(dynamic-linking,
  36   [  --enable-dynamic-linking  Include support for dynamic linking],,
  37   enable_dynamic_linking=yes)
  38
  39 AC_ARG_ENABLE(guile-debug,
  40 [  --enable-guile-debug    Include internal debugging functions])
  41 if test "$enableval" = y || test "$enableval" = yes; then
  42   AC_DEFINE(GUILE_DEBUG)
  43 fi
  44
  45 dnl The --disable-debug used to control these two.  But now they are
  46 dnl a required part of the distribution.
  47 AC_DEFINE(DEBUG_EXTENSIONS)
  48 AC_DEFINE(READER_EXTENSIONS)
  49
  50 #--------------------------------------------------------------------
  51
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AM_PROG_LIBTOOL
  55
  56 AC_AIX
  57 AC_ISC_POSIX
  58 AC_MINIX
  59
  60 AM_PROG_CC_STDC
  61
  62 AC_C_CONST
  63 AC_C_INLINE
  64 AC_CHECK_SIZEOF(int)
  65 AC_CHECK_SIZEOF(long)
  66 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
  67                AC_TRY_COMPILE(,
  68                               [long long a],
  69                               scm_cv_long_longs=yes,
  70                               scm_cv_long_longs=no))
  71 if test "$scm_cv_long_longs" = yes; then
  72   AC_DEFINE(HAVE_LONG_LONGS)
  73 fi
  74
  75 AC_HEADER_STDC
  76 AC_HEADER_DIRENT
  77 AC_HEADER_TIME
  78 AC_HEADER_SYS_WAIT
  79 AC_CHECK_HEADERS(libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
  80 GUILE_HEADER_LIBC_WITH_UNISTD
  81
  82 AC_TYPE_GETGROUPS
  83 AC_TYPE_SIGNAL
  84 AC_TYPE_MODE_T
  85
  86 AC_CHECK_LIB(m, main)
  87 AC_CHECK_FUNCS(gethostbyname)
  88 if test $ac_cv_func_gethostbyname = no; then
  89     AC_CHECK_LIB(nsl, gethostbyname)
  90 fi
  91 AC_CHECK_FUNCS(connect)
  92 if test $ac_cv_func_connect = no; then
  93     AC_CHECK_LIB(socket, connect)
  94 fi
  95
  96 dnl Should we check for curses, terminfo, and termlib, too?
  97 for termlib in ncurses termcap ; do
  98    AC_CHECK_LIB(${termlib}, tgoto,
  99                 [LIBS="-l${termlib} $LIBS"; break])
 100 done
 101 AC_CHECK_LIB(readline, main)
 102 AC_CHECK_FUNCS(rl_clear_signals rl_cleanup_after_signal)
 103
 104 AC_CACHE_CHECK([for rl_getc_function pointer in readline],
 105                ac_cv_var_rl_getc_function,
 106                [AC_TRY_LINK([
 107 #include <stdio.h>
 108 #include <readline/readline.h>],
 109                             [rl_getc_function;],
 110                             [ac_cv_var_rl_getc_function=yes],
 111                             [ac_cv_var_rl_getc_function=no])])
 112 if test "$ac_cv_var_rl_getc_function" = "yes"; then
 113   AC_DEFINE(HAVE_RL_GETC_FUNCTION)
 114 fi
 115
 116 if test $ac_cv_lib_readline_main = yes -a $ac_cv_var_rl_getc_function = no; then
 117   echo 'Warning: libreadline is too old on your system.  Need >= 2.1.'
 118 fi
 119
 120 # Checks for dynamic linking
 121
 122 if test "$enable_dynamic_linking" = "yes"; then
 123
 124 AC_CHECK_LIB(dl,dlopen)
 125 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
 126   AC_CHECK_FUNCS(dlopen)
 127   AC_DEFINE(DYNAMIC_LINKING)
 128 else
 129 AC_CHECK_LIB(dld,dld_link)
 130 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
 131   AC_DEFINE(DYNAMIC_LINKING)
 132 else
 133 AC_CHECK_FUNCS(shl_load)
 134 if test "$ac_cv_func_shl_load" = "yes"; then
 135   AC_DEFINE(DYNAMIC_LINKING)
 136 else
 137 AC_CHECK_FUNCS(dlopen)
 138 if test "$ac_cv_func_dlopen" = "yes"; then
 139   AC_DEFINE(DYNAMIC_LINKING)
 140 fi
 141 fi
 142 fi
 143 fi
 144
 145 fi
 146
 147 GUILE_DLSYM_USCORE
 148
 149 AC_CHECK_FUNCS(ctermid ftime getcwd geteuid gethostent gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep)
 150
 151 ### Some systems don't declare some functions.  On such systems, we
 152 ### need to at least provide our own K&R-style declarations.
 153
 154 ### GUILE_FUNC_DECLARED(function, headerfile)
 155
 156 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 157 ### not there, #define MISSING_FUNCTION_DECL.
 158 AC_DEFUN(GUILE_FUNC_DECLARED, [
 159   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 160     AC_EGREP_HEADER($1, $2,
 161                     guile_cv_func_$1_declared=yes,
 162                     guile_cv_func_$1_declared=no))
 163   if test [x$guile_cv_func_]$1[_declared] = xno; then
 164     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 165   fi
 166 ])
 167
 168 GUILE_FUNC_DECLARED(strptime, time.h)
 169 GUILE_FUNC_DECLARED(bzero, string.h)
 170 GUILE_FUNC_DECLARED(sleep, unistd.h)
 171 GUILE_FUNC_DECLARED(usleep, unistd.h)
 172
 173 ### On some systems usleep has no return value.  If it does have one,
 174 ### we'd like to return it; otherwise, we'll fake it.
 175 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 176   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 177                    /usr/include/unistd.h,
 178                    [guile_cv_func_usleep_return_type=void],
 179                    [guile_cv_func_usleep_return_type=int])])
 180 case "$guile_cv_func_usleep_return_type" in
 181   "void" )
 182     AC_DEFINE(USLEEP_RETURNS_VOID)
 183   ;;
 184 esac
 185
 186 dnl <GNU-WIN32 hacks>
 187
 188 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 189 if test -n "$have_sys_un_h" ; then
 190 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 191 fi
 192
 193 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 194
 195 dnl I don't know what this prefixing of cygwin32_ is for.
 196 dnl scmconfig.h wasn't updated with the test results.
 197 dnl so use AC_CHECK_FUNCS for now.
 198
 199 dnl how about:
 200 dnl save confdefs.h
 201 dnl if test $ac_cv_cigwin = yes; then
 202 dnl   modify confdefs.h
 203 dnl fi
 204 dnl AC_CHECK_FUNCS...
 205 dnl restore confdefs.h
 206
 207 dnl cp confdefs.h confdefs.h.bak
 208 dnl for func in sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof ; do
 209 dnl cp confdefs.h.bak confdefs.h
 210 dnl cat >> confdefs.h << EOF
 211 dnl #ifdef __CYGWIN32__
 212 dnl #define $func cygwin32_$func
 213 dnl #endif
 214 dnl EOF
 215 dnl AC_CHECK_FUNC($func)
 216 dnl done
 217 dnl cp confdefs.h.bak confdefs.h
 218
 219 AC_CHECK_FUNCS(sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof)
 220
 221 dnl </GNU-WIN32 hacks>
 222
 223 AC_CACHE_CHECK([for restartable system calls], scm_cv_restarts,
 224         if test $ac_cv_func_sigaction = yes; then
 225                 [AC_TRY_COMPILE([#include <signal.h>],
 226                                 [int a = SA_RESTART],
 227                                 scm_cv_restarts=yes,
 228                                 scm_cv_restarts=no)]
 229         else
 230                 scm_cv_restarts=no
 231         fi)
 232 if test $scm_cv_restarts = yes; then
 233         AC_DEFINE(HAVE_RESTARTS)
 234 fi
 235
 236 if test "$ac_cv_header_regex_h" = yes ||
 237    test "$ac_cv_header_rxposix_h" = yes ||
 238    test "$ac_cv_header_rx_rxposix_h" = yes; then
 239   GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 240   [AC_CHECK_LIB(rx, main)
 241    GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 242   )
 243   dnl The following should not be necessary, but for some reason
 244   dnl autoheader misses it if we don't include it!
 245   if test "$ac_cv_func_regcomp_norx" = yes ||
 246      test "$ac_cv_func_regcomp_rx" = yes; then
 247     AC_DEFINE(HAVE_REGCOMP)
 248   fi
 249 fi
 250
 251 AC_REPLACE_FUNCS(inet_aton putenv strerror)
 252
 253 # When testing for the presence of alloca, we need to add alloca.o
 254 # explicitly to LIBOBJS to make sure that it is translated to
 255 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 256 AC_FUNC_ALLOCA
 257 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 258
 259 AC_STRUCT_ST_RDEV
 260 AC_STRUCT_ST_BLKSIZE
 261
 262 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 263 # LIBOBJS, which we don't need.  This seems more direct.
 264 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 265 [AC_TRY_COMPILE([#include <sys/types.h>
 266 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 267 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 268 if test $ac_cv_struct_st_blocks = yes; then
 269   AC_DEFINE(HAVE_ST_BLOCKS)
 270 fi
 271
 272 AC_STRUCT_TIMEZONE
 273 GUILE_STRUCT_UTIMBUF
 274
 275 #--------------------------------------------------------------------
 276 #
 277 # Which way does the stack grow?
 278 #
 279 #--------------------------------------------------------------------
 280
 281 AC_TRY_RUN(aux (l) unsigned long l;
 282              { int x; exit (l >= ((unsigned long)&x)); }
 283            main () { int q; aux((unsigned long)&q); },
 284            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 285
 286 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 287     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 288                 [guile_cv_type_float_fits_long=yes],
 289                 [guile_cv_type_float_fits_long=no],
 290                 [guile_cv_type_float_fits_long=guess-yes])])
 291 case $guile_cv_type_float_fits_long in
 292   "yes" )
 293     AC_DEFINE(SCM_SINGLES)
 294   ;;
 295   "guess-yes" )
 296     AC_DEFINE(SCM_SINGLES)
 297     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 298     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 299   ;;
 300 esac
 301
 302
 303 AC_MSG_CHECKING(for struct linger)
 304 AC_CACHE_VAL(scm_cv_struct_linger,
 305         AC_TRY_COMPILE([
 306 #include <sys/types.h>
 307 #include <sys/socket.h>],
 308                         [struct linger lgr;  lgr.l_linger = 100],
 309                         scm_cv_struct_linger="yes",
 310                         scm_cv_struct_linger="no"))
 311 AC_MSG_RESULT($scm_cv_struct_linger)
 312 if test $scm_cv_struct_linger = yes; then
 313         AC_DEFINE(HAVE_STRUCT_LINGER)
 314 fi
 315
 316 #--------------------------------------------------------------------
 317 #
 318 # How can you violate a stdio abstraction by setting a stream's fd?
 319 #
 320 #--------------------------------------------------------------------
 321
 322 AC_MSG_CHECKING(how to set a stream file descriptor)
 323 AC_CACHE_VAL(scm_cv_fd_setter,
 324         AC_TRY_COMPILE([#include <stdio.h>],
 325                         [stdout->_file = 1],
 326                         scm_cv_fd_setter="_file",
 327         AC_TRY_COMPILE([#include <stdio.h>],
 328                         [stdout->__file = 1],
 329                         scm_cv_fd_setter="__file",
 330         AC_TRY_COMPILE([#include <stdio.h>],
 331                         [stdout->_fileno = 1],
 332                         scm_cv_fd_setter="_fileno",
 333                         scm_cv_fd_setter=""))))
 334
 335 if test "$scm_cv_fd_setter"; then
 336         AC_MSG_RESULT($scm_cv_fd_setter)
 337         AC_DEFINE_UNQUOTED(FD_SETTER, $scm_cv_fd_setter)
 338 else
 339         AC_MSG_RESULT(we couldn't do it!)
 340 fi
 341
 342 #--------------------------------------------------------------------
 343 # How to find out whether a FILE structure contains buffered data.
 344 # From Tk we have the following list:
 345 #               _cnt:           Most UNIX systems
 346 #               __cnt:          HPUX and SCO
 347 #               _r:             BSD
 348 #               readCount:      Sprite
 349 #       Or, in GNU libc there are two fields, _gptr and _egptr, which
 350 #       have to be compared.
 351 #       These can also be known as _IO_read_ptr and _IO_read_end.
 352 #--------------------------------------------------------------------
 353
 354 AC_MSG_CHECKING(how to get buffer char count from FILE structure)
 355 AC_CACHE_VAL(scm_cv_struct_file_count,
 356         AC_TRY_COMPILE([#include <stdio.h>],
 357                         [FILE *f = stdin; f->_cnt = 0],
 358                         scm_cv_struct_file_count="_cnt",
 359         AC_TRY_COMPILE([#include <stdio.h>],
 360                         [FILE *f = stdin; f->__cnt = 0],
 361                         scm_cv_struct_file_count="__cnt",
 362         AC_TRY_COMPILE([#include <stdio.h>],
 363                         [FILE *f = stdin; f->_r = 0],
 364                         scm_cv_struct_file_count="_r",
 365         AC_TRY_COMPILE([#include <stdio.h>],
 366                         [FILE *f = stdin; f->readCount = 0],
 367                         scm_cv_struct_file_count="readCount",
 368         scm_cv_struct_file_count="")))))
 369 if test "$scm_cv_struct_file_count"; then
 370         AC_MSG_RESULT($scm_cv_struct_file_count)
 371         AC_DEFINE_UNQUOTED(FILE_CNT_FIELD, $scm_cv_struct_file_count)
 372 else
 373 AC_CACHE_VAL(scm_cv_struct_file_gptr,
 374         AC_TRY_COMPILE([#include <stdio.h>],
 375                         [FILE *f = stdin; f->_gptr = f->egptr;],
 376                         scm_cv_struct_file_gptr=1,
 377         scm_cv_struct_file_gptr=""))
 378 if test "$scm_cv_struct_gptr"; then
 379         AC_MSG_RESULT(gptr)
 380         AC_DEFINE_UNQUOTED(FILE_CNT_GPTR, $scm_cv_struct_file_gptr)
 381 else
 382 AC_CACHE_VAL(scm_cv_struct_file_readptr,
 383         AC_TRY_COMPILE([#include <stdio.h>],
 384                         [FILE *f = stdin; f->_IO_read_ptr = f->_IO_read_end;],
 385                         scm_cv_struct_file_readptr=1))
 386 if test "$scm_cv_struct_file_readptr"; then
 387         AC_MSG_RESULT(read_ptr)
 388         AC_DEFINE_UNQUOTED(FILE_CNT_READPTR, $scm_cv_struct_file_readptr)
 389 else
 390         AC_MSG_RESULT(we couldn't do it!)
 391 fi
 392 fi
 393 fi
 394
 395 #--------------------------------------------------------------------
 396 #
 397 # Flags for thread support
 398 #
 399 #--------------------------------------------------------------------
 400
 401 ### What thread package has the user asked for?
 402 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 403             , with_threads=no)
 404
 405 ### Turn $with_threads into either the name of a threads package, like
 406 ### `qt', or `no', meaning that threads should not be supported.
 407 AC_MSG_CHECKING(whether to support threads)
 408 case "$with_threads" in
 409   "yes" | "qt" | "coop" | "")
 410     with_threads=qt
 411   ;;
 412   "no" )
 413   ;;
 414   * )
 415     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 416   ;;
 417 esac
 418 AC_MSG_RESULT($with_threads)
 419
 420 ## Make sure the threads package we've chosen is actually supported on
 421 ## the present platform.
 422 case "${with_threads}" in
 423   "qt" )
 424     ## This configures the QuickThreads package, and sets or clears
 425     ## the THREAD_PACKAGE variable if qthreads don't configure
 426     ## correctly.
 427     QTHREADS_CONFIGURE
 428    ;;
 429 esac
 430
 431 ## If we're using threads, bring in some other parts of Guile which
 432 ## work with them.
 433 if test "${THREAD_PACKAGE}" != "" ; then
 434   AC_DEFINE(USE_THREADS, 1)
 435
 436   ## Include the Guile thread interface in the library...
 437   LIBOBJS="$LIBOBJS threads.o"
 438
 439   ## ... and tell it which package to talk to.
 440   case "${THREAD_PACKAGE}" in
 441     "QT" )
 442       AC_DEFINE(USE_COOP_THREADS, 1)
 443     ;;
 444     * )
 445       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 446     ;;
 447   esac
 448
 449   ## Bring in scm_internal_select, if appropriate.
 450   if test $ac_cv_func_gettimeofday = yes &&
 451      test $ac_cv_func_select = yes; then
 452     LIBOBJS="$LIBOBJS iselect.o"
 453     AC_DEFINE(GUILE_ISELECT, 1)
 454   fi
 455 fi
 456
 457 ## If we're using GCC, ask for aggressive warnings.
 458 case "$GCC" in
 459   yes )
 460     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 461     ## much stuff with generic function pointers for that to really be
 462     ## less than exasperating.
 463     CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wmissing-prototypes" ;;
 464 esac
 465
 466 AC_PROG_AWK
 467
 468 ## If we're creating a shared library (using libtool!), then we'll
 469 ## need to generate a list of .lo files corresponding to the .o files
 470 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 471 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 472
 473 AC_SUBST(GUILE_MAJOR_VERSION)
 474 AC_SUBST(GUILE_MINOR_VERSION)
 475 AC_SUBST(GUILE_VERSION)
 476
 477 dnl Tell guile-config what flags guile users should link against.
 478 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 479 AC_SUBST(GUILE_LIBS)
 480
 481 dnl timestamping the interpreter and scheme libraries:
 482 dnl
 483 dnl Help us notice when we're running one version of the Guile
 484 dnl interpreter against a different version of the ice-9 Scheme code.
 485 dnl This will definitely detect version skew due to differing
 486 dnl snapshots and releases, but may not catch skew for the developers.
 487 dnl Hopefully it will not detect skew when there is none; if that
 488 dnl happens, the warnings will be useless, and we should remove this.
 489 GUILE_STAMP="`date`"
 490 AC_SUBST(GUILE_STAMP)
 491
 492 AC_SUBST(AWK)
 493 AC_SUBST(LIBLOBJS)
 494
 495 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/versiondat.h ice-9/Makefile ice-9/version.scm qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf])
 496
 497 dnl Local Variables:
 498 dnl comment-start: "dnl "
 499 dnl comment-end: ""
 500 dnl comment-start-skip: "\\bdnl\\b\\s *"
 501 dnl End: