configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4
   5 define(GUILE_CONFIGURE_COPYRIGHT,[[
   6
   7 Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   8
   9 This file is part of GUILE
  10
  11 GUILE is free software; you can redistribute it and/or modify it
  12 under the terms of the GNU General Public License as published by
  13 the Free Software Foundation; either version 2, or (at your
  14 option) any later version.
  15
  16 GUILE is distributed in the hope that it will be useful, but
  17 WITHOUT ANY WARRANTY; without even the implied warranty of
  18 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 General Public License for more details.
  20
  21 You should have received a copy of the GNU General Public License
  22 along with GUILE; see the file COPYING.  If not, write to the
  23 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 Boston, MA 02110-1301, USA.
  25
  26 ]])
  27
  28 AC_PREREQ(2.53)
  29
  30 AC_INIT(m4_esyscmd(. ./GUILE-VERSION && echo -n ${PACKAGE}),
  31         m4_esyscmd(. ./GUILE-VERSION && echo -n ${GUILE_VERSION}))
  32 AC_CONFIG_AUX_DIR([.])
  33 AC_CONFIG_SRCDIR(GUILE-VERSION)
  34 AM_INIT_AUTOMAKE([no-define])
  35
  36 AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT)
  37 AC_CONFIG_SRCDIR([GUILE-VERSION])
  38
  39 . $srcdir/GUILE-VERSION
  40
  41 AM_MAINTAINER_MODE
  42 AM_CONFIG_HEADER([config.h])
  43 AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/)
  44
  45 #--------------------------------------------------------------------
  46 #
  47 # Independent Subdirectories
  48 #
  49 #--------------------------------------------------------------------
  50
  51 AC_CONFIG_SUBDIRS(guile-readline)
  52
  53 #--------------------------------------------------------------------
  54
  55 dnl Some more checks for Win32
  56 AC_CYGWIN
  57 AC_MINGW32
  58 AC_LIBTOOL_WIN32_DLL
  59
  60 AC_PROG_INSTALL
  61 AC_PROG_CC
  62 AC_PROG_CPP
  63 AC_PROG_AWK
  64
  65 AC_AIX
  66 AC_ISC_POSIX
  67 AC_MINIX
  68
  69 AM_PROG_CC_STDC
  70
  71 AC_LIBTOOL_DLOPEN
  72 AC_PROG_LIBTOOL
  73 AC_CHECK_LIB([ltdl], [lt_dlinit], ,
  74   [AC_MSG_ERROR([libltdl not found.  See README.])])
  75
  76 AC_SUBST(DLPREOPEN)
  77
  78 AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no)
  79 AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes)
  80
  81 AM_PATH_LISPDIR
  82
  83 #--------------------------------------------------------------------
  84 #
  85 # User options (after above tests that may set default CFLAGS etc.)
  86 #
  87 #--------------------------------------------------------------------
  88
  89 GUILE_ERROR_ON_WARNING="yes"
  90
  91 AC_ARG_ENABLE(error-on-warning,
  92   [  --enable-error-on-warning    treat compile warnings as errors],
  93   [case "${enableval}" in
  94      yes | y) GUILE_ERROR_ON_WARNING="yes" ;;
  95      no | n)  GUILE_ERROR_ON_WARNING="no" ;;
  96      *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;;
  97    esac])
  98
  99 SCM_I_GSC_GUILE_DEBUG_FREELIST=0
 100 AC_ARG_ENABLE(debug-freelist,
 101   [  --enable-debug-freelist include garbage collector freelist debugging code],
 102   if test "$enable_debug_freelist" = y \
 103      || test "$enable_debug_freelist" = yes; then
 104     SCM_I_GSC_GUILE_DEBUG_FREELIST=1
 105   fi)
 106
 107 AC_ARG_ENABLE(debug-malloc,
 108   [  --enable-debug-malloc   include malloc debugging code],
 109   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
 110     AC_DEFINE(GUILE_DEBUG_MALLOC, 1,
 111       [Define this if you want to debug scm_must_malloc/realloc/free calls.])
 112   fi)
 113
 114 SCM_I_GSC_GUILE_DEBUG=0
 115 AC_ARG_ENABLE(guile-debug,
 116   [AC_HELP_STRING([--enable-guile-debug],
 117                   [include internal debugging functions])],
 118   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
 119     SCM_I_GSC_GUILE_DEBUG=1
 120   fi)
 121
 122 AC_ARG_ENABLE(posix,
 123   [  --disable-posix         omit posix interfaces],,
 124   enable_posix=yes)
 125
 126 AC_ARG_ENABLE(networking,
 127   [  --disable-networking    omit networking interfaces],,
 128   enable_networking=yes)
 129
 130 AC_ARG_ENABLE(regex,
 131   [  --disable-regex         omit regular expression interfaces],,
 132   enable_regex=yes)
 133
 134 AC_ARG_ENABLE([discouraged],
 135   AC_HELP_STRING([--disable-discouraged],[omit discouraged features]))
 136
 137 if test "$enable_discouraged" = no; then
 138   SCM_I_GSC_ENABLE_DISCOURAGED=0
 139 else
 140   SCM_I_GSC_ENABLE_DISCOURAGED=1
 141 fi
 142
 143 AC_ARG_ENABLE([deprecated],
 144   AC_HELP_STRING([--disable-deprecated],[omit deprecated features]))
 145
 146 if test "$enable_deprecated" = no; then
 147   SCM_I_GSC_ENABLE_DEPRECATED=0
 148 else
 149   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 150     warn_default=summary
 151   elif test "$enable_deprecated" = shutup; then
 152     warn_default=no
 153   else
 154     warn_default=$enable_deprecated
 155   fi
 156   SCM_I_GSC_ENABLE_DEPRECATED=1
 157   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default",
 158   [Define this to control the default warning level for deprecated features.])
 159 fi
 160
 161 AC_ARG_ENABLE(elisp,
 162   [  --disable-elisp         omit Emacs Lisp support],,
 163   enable_elisp=yes)
 164
 165 #--------------------------------------------------------------------
 166
 167 dnl Check for dynamic linking
 168
 169 use_modules=yes
 170 AC_ARG_WITH(modules,
 171 [  --with-modules[=FILES]  Add support for dynamic modules],
 172 use_modules="$withval")
 173 test -z "$use_modules" && use_modules=yes
 174 DLPREOPEN=
 175 if test "$use_modules" != no; then
 176   if test "$use_modules" = yes; then
 177     DLPREOPEN="-dlpreopen force"
 178   else
 179     DLPREOPEN="-export-dynamic"
 180     for module in $use_modules; do
 181       DLPREOPEN="$DLPREOPEN -dlopen $module"
 182     done
 183   fi
 184 fi
 185
 186 dnl files which are destined for separate modules.
 187
 188 if test "$use_modules" != no; then
 189    AC_LIBOBJ([dynl])
 190 fi
 191
 192 if test "$enable_posix" = yes; then
 193    AC_LIBOBJ([filesys])
 194    AC_LIBOBJ([posix])
 195    AC_DEFINE(HAVE_POSIX, 1,
 196      [Define this if you want support for POSIX system calls in Guile.])
 197 fi
 198
 199 if test "$enable_networking" = yes; then
 200    AC_LIBOBJ([net_db])
 201    AC_LIBOBJ([socket])
 202    AC_DEFINE(HAVE_NETWORKING, 1,
 203      [Define this if you want support for networking in Guile.])
 204 fi
 205
 206 if test "$enable_debug_malloc" = yes; then
 207    AC_LIBOBJ([debug-malloc])
 208 fi
 209
 210 if test "$enable_elisp" = yes; then
 211   SCM_I_GSC_ENABLE_ELISP=1
 212 else
 213   SCM_I_GSC_ENABLE_ELISP=0
 214 fi
 215
 216 AC_C_CONST
 217
 218 AC_C_INLINE
 219 if test "$ac_cv_c_inline" != no; then
 220   SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\""
 221 else
 222   SCM_I_GSC_C_INLINE=NULL
 223 fi
 224
 225 AC_C_BIGENDIAN
 226
 227 AC_CHECK_SIZEOF(char)
 228 AC_CHECK_SIZEOF(unsigned char)
 229 AC_CHECK_SIZEOF(short)
 230 AC_CHECK_SIZEOF(unsigned short)
 231 AC_CHECK_SIZEOF(int)
 232 AC_CHECK_SIZEOF(unsigned int)
 233 AC_CHECK_SIZEOF(long)
 234 AC_CHECK_SIZEOF(unsigned long)
 235 AC_CHECK_SIZEOF(size_t)
 236 AC_CHECK_SIZEOF(long long)
 237 AC_CHECK_SIZEOF(unsigned long long)
 238 AC_CHECK_SIZEOF(__int64)
 239 AC_CHECK_SIZEOF(unsigned __int64)
 240 AC_CHECK_SIZEOF(void *)
 241 AC_CHECK_SIZEOF(intptr_t)
 242 AC_CHECK_SIZEOF(uintptr_t)
 243 AC_CHECK_SIZEOF(ptrdiff_t)
 244 AC_CHECK_SIZEOF(size_t)
 245 AC_CHECK_SIZEOF(off_t)
 246
 247 if test "$ac_cv_sizeof_long" -ne "$ac_cv_sizeof_void_p"; then
 248   AC_MSG_ERROR(sizes of long and void* are not identical)
 249 fi
 250
 251 if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then
 252   SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"'
 253 else
 254   SCM_I_GSC_T_PTRDIFF='"long"'
 255 fi
 256 AC_SUBST([SCM_I_GSC_T_PTRDIFF])
 257
 258 AC_CHECK_HEADERS([stdint.h])
 259 AC_CHECK_HEADERS([inttypes.h])
 260
 261 AC_CHECK_SIZEOF(intmax_t)
 262
 263 SCM_I_GSC_NEEDS_STDINT_H=0
 264 SCM_I_GSC_NEEDS_INTTYPES_H=0
 265
 266 ### intptr and uintptr (try not to use inttypes if we don't have to)
 267 if test "$ac_cv_header_inttypes_h" = yes; then
 268   if test "$ac_cv_sizeof_intptr_t" -eq 0; then
 269     AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h>
 270 #include <stdio.h>])
 271     if test "$ac_cv_sizeof_intptr_t" -ne 0; then
 272       SCM_I_GSC_NEEDS_INTTYPES_H=1
 273     fi
 274   fi
 275   if test "$ac_cv_sizeof_uintptr_t" -eq 0; then
 276     AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h>
 277 #include <stdio.h>])
 278     if test "$ac_cv_sizeof_uintptr_t" -ne 0; then
 279       SCM_I_GSC_NEEDS_INTTYPES_H=1
 280     fi
 281   fi
 282 fi
 283
 284 ### See what's provided by stdint.h
 285 if test "$ac_cv_header_stdint_h" = yes; then
 286    AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>])
 287    AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>])
 288    AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>])
 289    AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>])
 290    AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>])
 291    AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>])
 292    AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>])
 293    AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>])
 294    AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>])
 295    AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>])
 296 fi
 297
 298 # so we don't get confused by the cache (wish there was a better way
 299 # to check particular headers for the same type...)
 300
 301 unset ac_cv_type_int8_t
 302 unset ac_cv_type_uint8_t
 303 unset ac_cv_type_int16_t
 304 unset ac_cv_type_uint16_t
 305 unset ac_cv_type_int32_t
 306 unset ac_cv_type_uint32_t
 307 unset ac_cv_type_int64_t
 308 unset ac_cv_type_uint64_t
 309 unset ac_cv_type_intmax_t
 310 unset ac_cv_type_uintmax_t
 311
 312 ### See what's provided by inttypes.h
 313 if test "$ac_cv_header_inttypes_h" = yes; then
 314   AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>])
 315   AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>])
 316   AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>])
 317   AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>])
 318   AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>])
 319   AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>])
 320   AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>])
 321   AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>])
 322   AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>])
 323   AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>])
 324 fi
 325
 326 # Try hard to find definitions for some required scm_t_*int* types.
 327
 328 ### Required type scm_t_int8
 329 if test "$scm_stdint_has_int8"; then
 330   SCM_I_GSC_T_INT8='"int8_t"'
 331   SCM_I_GSC_NEEDS_STDINT_H=1
 332 elif test "$scm_inttypes_has_int8"; then
 333   SCM_I_GSC_T_INT8='"int8_t"'
 334   SCM_I_GSC_NEEDS_INTTYPES_H=1
 335 elif test "$ac_cv_sizeof_char" -eq 1; then
 336   SCM_I_GSC_T_INT8='"signed char"'
 337 else
 338   AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.])
 339 fi
 340 AC_SUBST([SCM_I_GSC_T_INT8])
 341
 342 ### Required type scm_t_uint8
 343 if test "$scm_stdint_has_uint8"; then
 344   SCM_I_GSC_T_UINT8='"uint8_t"'
 345   SCM_I_GSC_NEEDS_STDINT_H=1
 346 elif test "$scm_inttypes_has_uint8"; then
 347   SCM_I_GSC_T_UINT8='"uint8_t"'
 348   SCM_I_GSC_NEEDS_INTTYPES_H=1
 349 elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then
 350   SCM_I_GSC_T_UINT8='"unsigned char"'
 351 else
 352   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.])
 353 fi
 354 AC_SUBST([SCM_I_GSC_T_UINT8])
 355
 356 ### Required type scm_t_int16 (ANSI C says int or short might work)
 357 if test "$scm_stdint_has_int16"; then
 358   SCM_I_GSC_T_INT16='"int16_t"'
 359   SCM_I_GSC_NEEDS_STDINT_H=1
 360 elif test "$scm_inttypes_has_int16"; then
 361   SCM_I_GSC_T_INT16='"int16_t"'
 362   SCM_I_GSC_NEEDS_INTTYPES_H=1
 363 elif test "$ac_cv_sizeof_int" -eq 2; then
 364   SCM_I_GSC_T_INT16='"int"'
 365 elif test "$ac_cv_sizeof_short" -eq 2; then
 366   SCM_I_GSC_T_INT16='"short"'
 367 else
 368   AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.])
 369 fi
 370 AC_SUBST([SCM_I_GSC_T_INT16])
 371
 372 ### Required type scm_t_uint16 (ANSI C says int or short might work)
 373 if test "$scm_stdint_has_uint16"; then
 374   SCM_I_GSC_T_UINT16='"uint16_t"'
 375   SCM_I_GSC_NEEDS_STDINT_H=1
 376 elif test "$scm_inttypes_has_uint16"; then
 377   SCM_I_GSC_T_UINT16='"uint16_t"'
 378   SCM_I_GSC_NEEDS_INTTYPES_H=1
 379 elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then
 380   SCM_I_GSC_T_UINT16='"unsigned int"'
 381 elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then
 382   SCM_I_GSC_T_UINT16='"unsigned short"'
 383 else
 384   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.])
 385 fi
 386 AC_SUBST([SCM_I_GSC_T_UINT16])
 387
 388
 389 ### Required type scm_t_int32 (ANSI C says int, short, or long might work)
 390 if test "$scm_stdint_has_int32"; then
 391   SCM_I_GSC_T_INT32='"int32_t"'
 392   SCM_I_GSC_NEEDS_STDINT_H=1
 393 elif test "$scm_inttypes_has_int32"; then
 394   SCM_I_GSC_T_INT32='"int32_t"'
 395   SCM_I_GSC_NEEDS_INTTYPES_H=1
 396 elif test "$ac_cv_sizeof_int" -eq 4; then
 397   SCM_I_GSC_T_INT32='"int"'
 398 elif test "$ac_cv_sizeof_long" -eq 4; then
 399   SCM_I_GSC_T_INT32='"long"'
 400 elif test "$ac_cv_sizeof_short" -eq 4; then
 401   SCM_I_GSC_T_INT32='"short"'
 402 else
 403   AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.])
 404 fi
 405 AC_SUBST([SCM_I_GSC_T_INT32])
 406
 407 ### Required type scm_t_uint32 (ANSI C says int, short, or long might work)
 408 if test "$scm_stdint_has_uint32"; then
 409   SCM_I_GSC_T_UINT32='"uint32_t"'
 410   SCM_I_GSC_NEEDS_STDINT_H=1
 411 elif test "$scm_inttypes_has_uint32"; then
 412   SCM_I_GSC_T_UINT32='"uint32_t"'
 413   SCM_I_GSC_NEEDS_INTTYPES_H=1
 414 elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then
 415   SCM_I_GSC_T_UINT32='"unsigned int"'
 416 elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then
 417   SCM_I_GSC_T_UINT32='"unsigned long"'
 418 elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then
 419   SCM_I_GSC_T_UINT32='"unsigned short"'
 420 else
 421   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.])
 422 fi
 423 AC_SUBST([SCM_I_GSC_T_UINT32])
 424
 425 ### Optional type scm_t_int64 (ANSI C says int, short, or long might work)
 426 ### Also try 'long long' and '__int64' if we have it.
 427 SCM_I_GSC_T_INT64=0
 428 if test "$scm_stdint_has_int64"; then
 429   SCM_I_GSC_T_INT64='"int64_t"'
 430   SCM_I_GSC_NEEDS_STDINT_H=1
 431 elif test "$scm_inttypes_has_int64"; then
 432   SCM_I_GSC_T_INT64='"int64_t"'
 433   SCM_I_GSC_NEEDS_INTTYPES_H=1
 434 elif test "$ac_cv_sizeof_int" -eq 8; then
 435   SCM_I_GSC_T_INT64='"int"'
 436 elif test "$ac_cv_sizeof_long" -eq 8; then
 437   SCM_I_GSC_T_INT64='"long"'
 438 elif test "$ac_cv_sizeof_short" -eq 8; then
 439   SCM_I_GSC_T_INT64='"short"'
 440 elif test "$ac_cv_sizeof_long_long" -eq 8; then
 441   SCM_I_GSC_T_INT64='"long long"'
 442 elif test "$ac_cv_sizeof___int64" -eq 8; then
 443   SCM_I_GSC_T_INT64='"__int64"'
 444 else
 445   AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.])
 446 fi
 447 AC_SUBST([SCM_I_GSC_T_INT64])
 448
 449
 450 ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work)
 451 ### Also try 'long long' and '__int64' if we have it.
 452 SCM_I_GSC_T_UINT64=0
 453 if test "$scm_stdint_has_uint64"; then
 454   SCM_I_GSC_T_UINT64='"uint64_t"'
 455   SCM_I_GSC_NEEDS_STDINT_H=1
 456 elif test "$scm_inttypes_has_uint64"; then
 457   SCM_I_GSC_T_UINT64='"uint64_t"'
 458   SCM_I_GSC_NEEDS_INTTYPES_H=1
 459 elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then
 460   SCM_I_GSC_T_UINT64='"unsigned int"'
 461 elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then
 462   SCM_I_GSC_T_UINT64='"unsigned long"'
 463 elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then
 464   SCM_I_GSC_T_UINT64='"unsigned short"'
 465 elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then
 466   SCM_I_GSC_T_UINT64='"unsigned long long"'
 467 elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then
 468   SCM_I_GSC_T_UINT64='"unsigned __int64"'
 469 else
 470   AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.])
 471 fi
 472 AC_SUBST([SCM_I_GSC_T_UINT64])
 473
 474 ### Required type scm_t_intmax
 475 ###
 476 ### We try 'intmax_t', '__int64', 'long long' in this order.  When
 477 ### none of them is available, we use 'long'.
 478 ###
 479 SCM_I_GSC_T_INTMAX=0
 480 if test "$scm_stdint_has_intmax"; then
 481   SCM_I_GSC_T_INTMAX='"intmax_t"'
 482   SCM_I_GSC_NEEDS_STDINT_H=1
 483 elif test "$scm_inttypes_has_intmax"; then
 484   SCM_I_GSC_T_INTMAX='"intmax_t"'
 485   SCM_I_GSC_NEEDS_INTTYPES_H=1
 486 elif test "$ac_cv_sizeof___int64" -ne 0; then
 487   SCM_I_GSC_T_INTMAX='"__int64"'
 488 elif test "$ac_cv_sizeof_long_long" -ne 0; then
 489   SCM_I_GSC_T_INTMAX='"long long"'
 490 else
 491   SCM_I_GSC_T_INTMAX='"long"'
 492 fi
 493 AC_SUBST([SCM_I_GSC_T_INTMAX])
 494
 495 ### Required type scm_t_uintmax
 496 ###
 497 ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in
 498 ### this order.  When none of them is available, we use 'unsigned long'.
 499 ###
 500 SCM_I_GSC_T_UINTMAX=0
 501 if test "$scm_stdint_has_uintmax"; then
 502   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 503   SCM_I_GSC_NEEDS_STDINT_H=1
 504 elif test "$scm_inttypes_has_uintmax"; then
 505   SCM_I_GSC_T_UINTMAX='"uintmax_t"'
 506   SCM_I_GSC_NEEDS_INTTYPES_H=1
 507 elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then
 508   SCM_I_GSC_T_UINTMAX='"unsigned __int64"'
 509 elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then
 510   SCM_I_GSC_T_UINTMAX='"unsigned long long"'
 511 else
 512   SCM_I_GSC_T_UINTMAX='"unsigned long"'
 513 fi
 514 AC_SUBST([SCM_I_GSC_T_UINTMAX])
 515
 516
 517 AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H])
 518 AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H])
 519
 520 AC_HEADER_STDC
 521 AC_HEADER_DIRENT
 522 AC_HEADER_TIME
 523 AC_HEADER_SYS_WAIT
 524
 525 # Reasons for testing:
 526 #   fenv.h - available in C99, but not older systems
 527 #
 528 AC_CHECK_HEADERS([fenv.h io.h libc.h limits.h malloc.h memory.h string.h \
 529 regex.h rxposix.h rx/rxposix.h sys/dir.h sys/ioctl.h sys/select.h \
 530 sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \
 531 sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \
 532 direct.h])
 533
 534 # On MacOS X <sys/socklen.h> contains socklen_t, so must include that
 535 # when testing.
 536 AC_CHECK_TYPE(socklen_t, ,
 537   [AC_DEFINE_UNQUOTED(socklen_t, int,
 538                       [Define to `int' if <sys/socket.h> does not define.])],
 539   [#if HAVE_SYS_TYPES_H
 540 #include <sys/types.h>
 541 #endif
 542 #include <sys/socket.h>
 543 ])
 544 AC_CHECK_TYPE(struct ip_mreq)
 545
 546 GUILE_HEADER_LIBC_WITH_UNISTD
 547
 548 AC_TYPE_GETGROUPS
 549 AC_TYPE_SIGNAL
 550 AC_TYPE_MODE_T
 551
 552 if test $MINGW32 = no; then
 553         AC_CHECK_LIB(m, main)
 554 fi
 555 AC_CHECK_FUNCS(gethostbyname)
 556 if test $ac_cv_func_gethostbyname = no; then
 557     AC_CHECK_LIB(nsl, gethostbyname)
 558 fi
 559
 560 AC_CHECK_FUNCS(connect)
 561 if test $ac_cv_func_connect = no; then
 562     AC_CHECK_LIB(socket, connect)
 563 fi
 564
 565 dnl
 566 dnl Check for Winsock and other functionality on Win32 (*not* CygWin)
 567 dnl
 568 EXTRA_DEFS=""
 569 if test "$MINGW32" = "yes" ; then
 570     AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1,
 571       [Define if you have the <winsock2.h> header file.])])
 572     AC_CHECK_LIB(ws2_32, main)
 573     AC_LIBOBJ([win32-uname])
 574     AC_LIBOBJ([win32-dirent])
 575     if test "$enable_networking" = yes ; then
 576       AC_LIBOBJ([win32-socket])
 577     fi
 578     if test "$enable_shared" = yes ; then
 579       EXTRA_DEFS="-DSCM_IMPORT"
 580       AC_DEFINE(USE_DLL_IMPORT, 1,
 581         [Define if you need additional CPP macros on Win32 platforms.])
 582     fi
 583 fi
 584 AC_SUBST(EXTRA_DEFS)
 585
 586 # Reasons for testing:
 587 #   crt_externs.h - Darwin specific
 588 #
 589 AC_CHECK_HEADERS([assert.h crt_externs.h])
 590
 591 # Reasons for testing:
 592 #   DINFINITY - OSF specific
 593 #   DQNAN - OSF specific
 594 #       (DINFINITY and DQNAN are actually global variables, not functions)
 595 #   fesetround - available in C99, but not older systems
 596 #   ioctl - not in mingw.
 597 #   gmtime_r - recent posix, not on old systems
 598 #   readdir_r - recent posix, not on old systems
 599 #   stat64 - SuS largefile stuff, not on old systems
 600 #   sysconf - not on old systems
 601 #   _NSGetEnviron - Darwin specific
 602 #
 603 AC_CHECK_FUNCS([DINFINITY DQNAN ctermid fesetround ftime fchown getcwd geteuid gettimeofday gmtime_r ioctl lstat mkdir mknod nice readdir_r readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt stat64 strftime strptime symlink sync sysconf tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit chown link fcntl ttyname getpwent getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp index bcopy memcpy rindex unsetenv _NSGetEnviron])
 604
 605 # Reasons for testing:
 606 #   netdb.h - not in mingw
 607 #   sys/param.h - not in mingw
 608 #
 609 AC_CHECK_HEADERS(crypt.h netdb.h sys/param.h sys/resource.h sys/file.h)
 610 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 611
 612 # crypt() may or may not be available, for instance in some countries there
 613 # are restrictions on cryptography.
 614 #
 615 # crypt() might be in libc (eg. OpenBSD), or it might be in a separate
 616 # -lcrypt library (eg. Debian GNU/Linux).
 617 #
 618 # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a.  We must
 619 # be careful to avoid -lcrypt in this case, since libtool will see there's
 620 # only a static libcrypt and decide to build only a static libguile.
 621 #
 622 # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the
 623 # libraries already in that list.
 624 #
 625 AC_SEARCH_LIBS(crypt, crypt,
 626   [AC_DEFINE(HAVE_CRYPT,1,
 627              [Define to 1 if you have the `crypt' function.])])
 628
 629 dnl GMP tests
 630 AC_CHECK_LIB([gmp], [__gmpz_init], ,
 631   [AC_MSG_ERROR([GNU MP not found, see README])])
 632
 633 # mpz_import is a macro so we need to include <gmp.h>
 634 AC_TRY_LINK([#include <gmp.h>],
 635             [mpz_import (0, 0, 0, 0, 0, 0, 0);] , ,
 636   [AC_MSG_ERROR([At least GNU MP 4.1 is required, see README])])
 637
 638 dnl i18n tests
 639 #AC_CHECK_HEADERS([libintl.h])
 640 #AC_CHECK_FUNCS(gettext)
 641 #if test $ac_cv_func_gettext = no; then
 642 #   AC_CHECK_LIB(intl, gettext)
 643 #fi
 644 #AC_CHECK_FUNCS([bindtextdomain textdomain])
 645 AM_GNU_GETTEXT([external], [need-ngettext])
 646
 647 ### Some systems don't declare some functions.  On such systems, we
 648 ### need to at least provide our own K&R-style declarations.
 649
 650 ### GUILE_FUNC_DECLARED(function, headerfile)
 651
 652 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 653 ### not there, #define MISSING_FUNCTION_DECL.
 654 AC_DEFUN([GUILE_FUNC_DECLARED], [
 655   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 656     AC_EGREP_HEADER($1, $2,
 657                     guile_cv_func_$1_declared=yes,
 658                     guile_cv_func_$1_declared=no))
 659   if test [x$guile_cv_func_]$1[_declared] = xno; then
 660     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1,
 661       [Define if the operating system supplies $1 without declaring it.])
 662   fi
 663 ])
 664
 665 GUILE_FUNC_DECLARED(sleep, unistd.h)
 666 GUILE_FUNC_DECLARED(usleep, unistd.h)
 667
 668 AC_CHECK_DECLS([strptime],,,
 669 [#define _GNU_SOURCE /* ask glibc to give strptime prototype */
 670 #include <time.h>])
 671
 672 ### On some systems usleep has no return value.  If it does have one,
 673 ### we'd like to return it; otherwise, we'll fake it.
 674 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 675   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 676                    unistd.h,
 677                    [guile_cv_func_usleep_return_type=void],
 678                    [guile_cv_func_usleep_return_type=int])])
 679 case "$guile_cv_func_usleep_return_type" in
 680   "void" )
 681     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
 682       [Define if the system headers declare usleep to return void.])
 683   ;;
 684 esac
 685
 686 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 687 if test -n "$have_sys_un_h" ; then
 688   AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS, 1,
 689     [Define if the system supports Unix-domain (file-domain) sockets.])
 690 fi
 691
 692 AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset)
 693
 694 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 695                setnetent    getnetent    endnetent    dnl
 696                setprotoent  getprotoent  endprotoent  dnl
 697                setservent   getservent   endservent   dnl
 698                getnetbyaddr getnetbyname dnl
 699                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 700                inet_pton inet_ntop)
 701
 702 # struct sockaddr field sin_len is only present on BSD systems.
 703 # On 4.4BSD apparently a #define SIN_LEN exists, but on other BSD systems
 704 # (eg. FreeBSD 4.9) it doesn't and we must use this configure check
 705 AC_CHECK_MEMBERS([struct sockaddr.sin_len],,,
 706 [#ifdef HAVE_SYS_TYPES_H
 707 #include <sys/types.h>
 708 #endif
 709 #include <netinet/in.h>])
 710
 711 AC_MSG_CHECKING(for __libc_stack_end)
 712 AC_CACHE_VAL(guile_cv_have_libc_stack_end,
 713 [AC_TRY_LINK([#include <stdio.h>
 714 extern char *__libc_stack_end;],
 715              [printf("%p", (char*) __libc_stack_end);],
 716              guile_cv_have_libc_stack_end=yes,
 717              guile_cv_have_libc_stack_end=no)])
 718 AC_MSG_RESULT($guile_cv_have_libc_stack_end)
 719
 720 if test $guile_cv_have_libc_stack_end = yes; then
 721   AC_DEFINE(HAVE_LIBC_STACK_END, 1,
 722            [Define if you have the __libc_stack_end variable.])
 723 fi
 724
 725 dnl Some systems do not declare this.  Some systems do declare it, as a
 726 dnl macro.  With cygwin it may be in a DLL.
 727
 728 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 729 AC_CACHE_VAL(guile_cv_have_h_errno,
 730 [AC_TRY_COMPILE([#include <netdb.h>],
 731 [int a = h_errno;],
 732 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 733 AC_MSG_RESULT($guile_cv_have_h_errno)
 734 if test $guile_cv_have_h_errno = yes; then
 735   AC_DEFINE(HAVE_H_ERRNO, 1, [Define if h_errno is declared in netdb.h.])
 736 fi
 737
 738 AC_MSG_CHECKING(whether uint32_t is defined)
 739 AC_CACHE_VAL(guile_cv_have_uint32_t,
 740   [AC_TRY_COMPILE([#include <sys/types.h>
 741                    #if HAVE_STDINT_H
 742                    #include <stdint.h>
 743                    #endif
 744                    #ifndef __MINGW32__
 745                    #include <netdb.h>
 746                    #endif],
 747                   [uint32_t a;],
 748                   guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 749 AC_MSG_RESULT($guile_cv_have_uint32_t)
 750 if test $guile_cv_have_uint32_t = yes; then
 751   AC_DEFINE(HAVE_UINT32_T, 1,
 752     [Define if uint32_t typedef is defined when netdb.h is include.])
 753 fi
 754
 755 AC_MSG_CHECKING(for working IPv6 support)
 756 AC_CACHE_VAL(guile_cv_have_ipv6,
 757 [AC_TRY_COMPILE([
 758 #ifdef HAVE_SYS_TYPES_H
 759 #include <sys/types.h>
 760 #endif
 761 #include <netinet/in.h>
 762 #include <sys/socket.h>],
 763 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 764 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 765 AC_MSG_RESULT($guile_cv_have_ipv6)
 766 if test $guile_cv_have_ipv6 = yes; then
 767   AC_DEFINE(HAVE_IPV6, 1, [Define if you want support for IPv6.])
 768 fi
 769
 770 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 771 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 772 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 773 [AC_TRY_COMPILE([
 774 #ifdef HAVE_SYS_TYPES_H
 775 #include <sys/types.h>
 776 #endif
 777 #include <netinet/in.h>],
 778 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 779 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 780 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 781 if test $guile_cv_have_sin6_scope_id = yes; then
 782   AC_DEFINE(HAVE_SIN6_SCOPE_ID, 1,
 783     [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.])
 784 fi
 785
 786 # struct sockaddr_in6 field sin_len is only present on BSD systems
 787 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,,
 788 [#ifdef HAVE_SYS_TYPES_H
 789 #include <sys/types.h>
 790 #endif
 791 #include <netinet/in.h>])
 792
 793 AC_MSG_CHECKING(whether localtime caches TZ)
 794 AC_CACHE_VAL(guile_cv_localtime_cache,
 795 [if test x$ac_cv_func_tzset = xyes; then
 796 AC_TRY_RUN([#include <time.h>
 797 #if STDC_HEADERS
 798 # include <stdlib.h>
 799 #endif
 800 extern char **environ;
 801 unset_TZ ()
 802 {
 803   char **from, **to;
 804   for (to = from = environ; (*to = *from); from++)
 805     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 806       to++;
 807 }
 808 char TZ_GMT0[] = "TZ=GMT0";
 809 char TZ_PST8[] = "TZ=PST8";
 810 main()
 811 {
 812   time_t now = time ((time_t *) 0);
 813   int hour_GMT0, hour_unset;
 814   if (putenv (TZ_GMT0) != 0)
 815     exit (1);
 816   hour_GMT0 = localtime (&now)->tm_hour;
 817   unset_TZ ();
 818   hour_unset = localtime (&now)->tm_hour;
 819   if (putenv (TZ_PST8) != 0)
 820     exit (1);
 821   if (localtime (&now)->tm_hour == hour_GMT0)
 822     exit (1);
 823   unset_TZ ();
 824   if (localtime (&now)->tm_hour != hour_unset)
 825     exit (1);
 826   exit (0);
 827 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 828 [# If we have tzset, assume the worst when cross-compiling.
 829 guile_cv_localtime_cache=yes])
 830 else
 831         # If we lack tzset, report that localtime does not cache TZ,
 832         # since we can't invalidate the cache if we don't have tzset.
 833         guile_cv_localtime_cache=no
 834 fi])dnl
 835 AC_MSG_RESULT($guile_cv_localtime_cache)
 836 if test $guile_cv_localtime_cache = yes; then
 837   AC_DEFINE(LOCALTIME_CACHE, 1, [Define if localtime caches the TZ setting.])
 838 fi
 839
 840 dnl Test whether system calls are restartable by default on the
 841 dnl current system.  If they are not, we put a loop around every system
 842 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 843 dnl change from the default behaviour.  On the other hand, if signals
 844 dnl are restartable then the loop is not installed and when libguile
 845 dnl initialises it also resets the behaviour of each signal to cause a
 846 dnl restart (in case a different runtime had a different default
 847 dnl behaviour for some reason: e.g., different versions of linux seem
 848 dnl to behave differently.)
 849
 850 AC_SYS_RESTARTABLE_SYSCALLS
 851
 852 if test "$enable_regex" = yes; then
 853    if test "$ac_cv_header_regex_h" = yes ||
 854       test "$ac_cv_header_rxposix_h" = yes ||
 855       test "$ac_cv_header_rx_rxposix_h" = yes; then
 856      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [AC_LIBOBJ([regex-posix])],
 857      [AC_CHECK_LIB(rx, main)
 858       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [AC_LIBOBJ([regex-posix])],
 859      [AC_CHECK_LIB(regex, main)
 860       GUILE_NAMED_CHECK_FUNC(regcomp, regex, [AC_LIBOBJ([regex-posix])])])]
 861      )
 862      dnl The following should not be necessary, but for some reason
 863      dnl autoheader misses it if we don't include it!
 864      if test "$ac_cv_func_regcomp_norx" = yes ||
 865         test "$ac_cv_func_regcomp_regex" = yes ||
 866         test "$ac_cv_func_regcomp_rx" = yes; then
 867        AC_DEFINE(HAVE_REGCOMP, 1,
 868          [This is included as part of a workaround for a autoheader bug.])
 869      fi
 870    fi
 871 fi
 872
 873 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove mkstemp)
 874
 875 AC_CHECK_HEADERS(floatingpoint.h ieeefp.h nan.h)
 876
 877 # Reasons for testing:
 878 #   asinh, acosh, atanh, trunc - C99 standard, generally not available on
 879 #                                older systems
 880 #   dirfd - mainly BSD derived, not in older systems
 881 #   sincos - GLIBC extension
 882 #
 883 AC_CHECK_FUNCS(asinh acosh atanh copysign dirfd finite sincos trunc)
 884
 885 # C99 specifies isinf and isnan as macros.
 886 # HP-UX provides only macros, no functions.
 887 # glibc 2.3.2 provides both macros and functions.
 888 # IRIX 6.5 and Solaris 8 only provide functions.
 889 #
 890 # The following tests detect isinf and isnan either as functions or as
 891 # macros from <math.h>.  Plain AC_CHECK_FUNCS is insufficient, it doesn't
 892 # use <math.h> so doesn't detect on macro-only systems like HP-UX.
 893 #
 894 AC_MSG_CHECKING([for isinf])
 895 AC_LINK_IFELSE(
 896 [#include <math.h>
 897 int main () { return (isinf(0.0) != 0); }],
 898   [AC_MSG_RESULT([yes])
 899    AC_DEFINE(HAVE_ISINF, 1,
 900              [Define to 1 if you have the `isinf' macro or function.])],
 901   [AC_MSG_RESULT([no])])
 902 AC_MSG_CHECKING([for isnan])
 903 AC_LINK_IFELSE(
 904 [#include <math.h>
 905 int main () { return (isnan(0.0) != 0); }],
 906   [AC_MSG_RESULT([yes])
 907    AC_DEFINE(HAVE_ISNAN, 1,
 908              [Define to 1 if you have the `isnan' macro or function.])],
 909   [AC_MSG_RESULT([no])])
 910
 911 # We must have a proper stack-using alloca in order for stack-copying
 912 # continuations to work properly.  If we don't find a native one,
 913 # abort.
 914
 915 AC_FUNC_ALLOCA
 916 if test "$ALLOCA" = "alloca.o"
 917 then
 918   AC_ERROR([No native alloca found.])
 919 fi
 920
 921 # Reasons for checking:
 922 #
 923 #     st_rdev
 924 #     st_blksize
 925 #     st_blocks   not in mingw
 926 #
 927 # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the
 928 # AC_LIBOBJ(fileblocks) replacement which that macro gives.
 929 #
 930 AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks])
 931
 932 AC_STRUCT_TIMEZONE
 933 GUILE_STRUCT_UTIMBUF
 934
 935 #--------------------------------------------------------------------
 936 #
 937 # Which way does the stack grow?
 938 #
 939 #--------------------------------------------------------------------
 940
 941 SCM_I_GSC_STACK_GROWS_UP=0
 942 AC_TRY_RUN(aux (l) unsigned long l;
 943              { int x; exit (l >= ((unsigned long)&x)); }
 944            main () { int q; aux((unsigned long)&q); },
 945            [SCM_I_GSC_STACK_GROWS_UP=1],
 946            [],
 947            [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)])
 948
 949 AC_CHECK_SIZEOF(float)
 950 if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then
 951     AC_DEFINE(SCM_SINGLES, 1,
 952               [Define this if floats are the same size as longs.])
 953 fi
 954
 955 AC_MSG_CHECKING(for struct linger)
 956 AC_CACHE_VAL(scm_cv_struct_linger,
 957         AC_TRY_COMPILE([
 958 #include <sys/types.h>
 959 #include <sys/socket.h>],
 960                         [struct linger lgr;  lgr.l_linger = 100],
 961                         scm_cv_struct_linger="yes",
 962                         scm_cv_struct_linger="no"))
 963 AC_MSG_RESULT($scm_cv_struct_linger)
 964 if test $scm_cv_struct_linger = yes; then
 965         AC_DEFINE(HAVE_STRUCT_LINGER, 1,
 966           [Define this if your system defines struct linger, for use with the
 967            getsockopt and setsockopt system calls.])
 968 fi
 969
 970
 971 AC_MSG_CHECKING(for struct timespec)
 972 AC_CACHE_VAL(scm_cv_struct_timespec,
 973         AC_TRY_COMPILE([
 974 #include <time.h>],
 975                         [struct timespec t;  t.tv_nsec = 100],
 976                         scm_cv_struct_timespec="yes",
 977                         scm_cv_struct_timespec="no"))
 978 AC_MSG_RESULT($scm_cv_struct_timespec)
 979 if test $scm_cv_struct_timespec = yes; then
 980   AC_DEFINE(HAVE_STRUCT_TIMESPEC, 1,
 981     [Define this if your system defines struct timespec via <time.h>.])
 982 fi
 983
 984 #--------------------------------------------------------------------
 985 #
 986 # Flags for thread support
 987 #
 988 #--------------------------------------------------------------------
 989
 990 SCM_I_GSC_USE_PTHREAD_THREADS=0
 991 SCM_I_GSC_USE_NULL_THREADS=0
 992 AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS])
 993 AC_SUBST([SCM_I_GSC_USE_NULL_THREADS])
 994
 995 ### What thread package has the user asked for?
 996 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 997             , with_threads=yes)
 998
 999 case "$with_threads" in
1000   "yes" | "pthread" | "pthreads" | "pthread-threads" | "")
1001     ACX_PTHREAD(CC="$PTHREAD_CC"
1002       LIBS="$PTHREAD_LIBS $LIBS"
1003       SCM_I_GSC_USE_PTHREAD_THREADS=1
1004       with_threads="pthreads",
1005       with_threads="null")
1006
1007     old_CFLAGS="$CFLAGS"
1008     CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1009     AC_CHECK_FUNCS(pthread_attr_getstack)
1010     CFLAGS="$old_CFLAGS"
1011
1012     # On Solaris, sched_yield lives in -lrt.
1013     AC_SEARCH_LIBS(sched_yield, rt)
1014
1015   ;;
1016 esac
1017
1018 case "$with_threads" in
1019   "pthreads")
1020   ;;
1021   "no" | "null")
1022     SCM_I_GSC_USE_NULL_THREADS=1
1023     with_threads="null-threads"
1024   ;;
1025   * )
1026     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
1027   ;;
1028 esac
1029
1030 AC_MSG_CHECKING(what kind of threads to support)
1031 AC_MSG_RESULT($with_threads)
1032
1033 ## Check whether pthread_attr_getstack works for the main thread
1034
1035 if test "$with_threads" = pthreads; then
1036
1037 AC_MSG_CHECKING(whether pthread_attr_getstack works for the main thread)
1038 old_CFLAGS="$CFLAGS"
1039 CFLAGS="$PTHREAD_CFLAGS $CFLAGS"
1040 AC_TRY_RUN(
1041 [
1042 #if HAVE_PTHREAD_ATTR_GETSTACK
1043 #include <pthread.h>
1044
1045 int main ()
1046 {
1047   pthread_attr_t attr;
1048   void *start, *end;
1049   size_t size;
1050
1051   pthread_getattr_np (pthread_self (), &attr);
1052   pthread_attr_getstack (&attr, &start, &size);
1053   end = (char *)start + size;
1054
1055   if ((void *)&attr < start || (void *)&attr >= end)
1056     return 1;
1057   else
1058     return 0;
1059 }
1060 #else
1061 int main ()
1062 {
1063   return 1;
1064 }
1065 #endif
1066 ],
1067 [works=yes
1068 AC_DEFINE(PTHREAD_ATTR_GETSTACK_WORKS, [1], [Define when pthread_att_get_stack works for the main thread])],
1069 [works=no])
1070 CFLAGS="$old_CFLAGS"
1071 AC_MSG_RESULT($works)
1072
1073 fi # with_threads=pthreads
1074
1075
1076 ## Cross building
1077 if test "$cross_compiling" = "yes"; then
1078   AC_MSG_CHECKING(cc for build)
1079   ## /usr/bin/cc still uses wrong assembler
1080   ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}"
1081   CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}"
1082 else
1083   CC_FOR_BUILD="${CC_FOR_BUILD-$CC}"
1084 fi
1085
1086 ## AC_MSG_CHECKING("if we are cross compiling")
1087 ## AC_MSG_RESULT($cross_compiling)
1088 if test "$cross_compiling" = "yes"; then
1089    AC_MSG_RESULT($CC_FOR_BUILD)
1090 fi
1091
1092 ## No need as yet to be more elaborate
1093 CCLD_FOR_BUILD="$CC_FOR_BUILD"
1094
1095 AC_SUBST(cross_compiling)
1096 AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler])
1097 AC_SUBST(CCLD_FOR_BUILD)
1098
1099 ## libtool erroneously calls CC_FOR_BUILD HOST_CC;
1100 ## --HOST is the platform that PACKAGE is compiled for.
1101 HOST_CC="$CC_FOR_BUILD"
1102 AC_SUBST(HOST_CC)
1103
1104 if test "$cross_compiling" = "yes"; then
1105   AC_MSG_CHECKING(guile for build)
1106   GUILE_FOR_BUILD="${GUILE_FOR_BUILD-guile}"
1107 else
1108   GUILE_FOR_BUILD='$(preinstguile)'
1109 fi
1110
1111 ## AC_MSG_CHECKING("if we are cross compiling")
1112 ## AC_MSG_RESULT($cross_compiling)
1113 if test "$cross_compiling" = "yes"; then
1114    AC_MSG_RESULT($GUILE_FOR_BUILD)
1115 fi
1116 AC_ARG_VAR(GUILE_FOR_BUILD,[guile for build system])
1117 AC_SUBST(GUILE_FOR_BUILD)
1118
1119 ## If we're using GCC, ask for aggressive warnings.
1120 case "$GCC" in
1121   yes )
1122     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
1123     ## much stuff with generic function pointers for that to really be
1124     ## less than exasperating.
1125     ## -Wpointer-arith was here too, but something changed in gcc/glibc
1126     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
1127     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes"
1128     # Do this here so we don't screw up any of the tests above that might
1129     # not be "warning free"
1130     if test "${GUILE_ERROR_ON_WARNING}" = yes
1131     then
1132         CFLAGS="${CFLAGS} -Werror"
1133         enable_compile_warnings=no
1134     fi
1135     ;;
1136 esac
1137
1138 ## If we're creating a shared library (using libtool!), then we'll
1139 ## need to generate a list of .lo files corresponding to the .o files
1140 ## given in LIBOBJS.  We'll call it LIBLOBJS.
1141 LIBLOBJS="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`"
1142
1143 ## We also need to create corresponding .doc and .x files
1144 EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`"
1145 EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`"
1146
1147 AC_SUBST(GUILE_MAJOR_VERSION)
1148 AC_SUBST(GUILE_MINOR_VERSION)
1149 AC_SUBST(GUILE_MICRO_VERSION)
1150 AC_SUBST(GUILE_EFFECTIVE_VERSION)
1151 AC_SUBST(GUILE_VERSION)
1152
1153 #######################################################################
1154 # library versioning
1155
1156 AC_SUBST(LIBGUILE_INTERFACE_CURRENT)
1157 AC_SUBST(LIBGUILE_INTERFACE_REVISION)
1158 AC_SUBST(LIBGUILE_INTERFACE_AGE)
1159 AC_SUBST(LIBGUILE_INTERFACE)
1160
1161 AC_SUBST(LIBGUILE_SRFI_SRFI_1_MAJOR)
1162 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_CURRENT)
1163 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_REVISION)
1164 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE_AGE)
1165 AC_SUBST(LIBGUILE_SRFI_SRFI_1_INTERFACE)
1166
1167 AC_SUBST(LIBGUILE_SRFI_SRFI_4_MAJOR)
1168 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_CURRENT)
1169 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_REVISION)
1170 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE_AGE)
1171 AC_SUBST(LIBGUILE_SRFI_SRFI_4_INTERFACE)
1172
1173 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_MAJOR)
1174 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_CURRENT)
1175 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_REVISION)
1176 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE_AGE)
1177 AC_SUBST(LIBGUILE_SRFI_SRFI_13_14_INTERFACE)
1178
1179 AC_SUBST(LIBGUILE_SRFI_SRFI_60_MAJOR)
1180 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_CURRENT)
1181 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_REVISION)
1182 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE_AGE)
1183 AC_SUBST(LIBGUILE_SRFI_SRFI_60_INTERFACE)
1184
1185 #######################################################################
1186
1187 dnl Tell guile-config what flags guile users should compile and link with.
1188 GUILE_LIBS="$LDFLAGS $LIBS"
1189 GUILE_CFLAGS="$PTHREAD_CFLAGS"
1190 AC_SUBST(GUILE_LIBS)
1191 AC_SUBST(GUILE_CFLAGS)
1192
1193 AC_SUBST(AWK)
1194 AC_SUBST(LIBLOBJS)
1195 AC_SUBST(EXTRA_DOT_DOC_FILES)
1196 AC_SUBST(EXTRA_DOT_X_FILES)
1197
1198 dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL
1199 top_builddir_absolute=`pwd`
1200 AC_SUBST(top_builddir_absolute)
1201 top_srcdir_absolute=`(cd $srcdir && pwd)`
1202 AC_SUBST(top_srcdir_absolute)
1203
1204 # Additional SCM_I_GSC definitions are above.
1205 AC_SUBST([SCM_I_GSC_GUILE_DEBUG])
1206 AC_SUBST([SCM_I_GSC_GUILE_DEBUG_FREELIST])
1207 AC_SUBST([SCM_I_GSC_ENABLE_DISCOURAGED])
1208 AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED])
1209 AC_SUBST([SCM_I_GSC_ENABLE_ELISP])
1210 AC_SUBST([SCM_I_GSC_STACK_GROWS_UP])
1211 AC_SUBST([SCM_I_GSC_C_INLINE])
1212 AC_CONFIG_FILES([libguile/gen-scmconfig.h])
1213
1214 AC_CONFIG_FILES([
1215   Makefile
1216   am/Makefile
1217   benchmark-suite/Makefile
1218   doc/Makefile
1219   doc/goops/Makefile
1220   doc/r5rs/Makefile
1221   doc/ref/Makefile
1222   doc/tutorial/Makefile
1223   emacs/Makefile
1224   examples/Makefile
1225   examples/box-dynamic-module/Makefile
1226   examples/box-dynamic/Makefile
1227   examples/box-module/Makefile
1228   examples/box/Makefile
1229   examples/modules/Makefile
1230   examples/safe/Makefile
1231   examples/scripts/Makefile
1232   guile-config/Makefile
1233   ice-9/Makefile
1234   ice-9/debugger/Makefile
1235   ice-9/debugging/Makefile
1236   lang/Makefile
1237   lang/elisp/Makefile
1238   lang/elisp/internals/Makefile
1239   lang/elisp/primitives/Makefile
1240   libguile/Makefile
1241   oop/Makefile
1242   oop/goops/Makefile
1243   scripts/Makefile
1244   srfi/Makefile
1245   test-suite/Makefile
1246   test-suite/standalone/Makefile
1247 ])
1248
1249 AC_CONFIG_FILES([check-guile], [chmod +x check-guile])
1250 AC_CONFIG_FILES([benchmark-guile], [chmod +x benchmark-guile])
1251 AC_CONFIG_FILES([guile-tools], [chmod +x guile-tools])
1252 AC_CONFIG_FILES([pre-inst-guile], [chmod +x pre-inst-guile])
1253 AC_CONFIG_FILES([pre-inst-guile-env], [chmod +x pre-inst-guile-env])
1254 AC_CONFIG_FILES([libguile/guile-snarf],
1255                 [chmod +x libguile/guile-snarf])
1256 AC_CONFIG_FILES([libguile/guile-doc-snarf],
1257                 [chmod +x libguile/guile-doc-snarf])
1258 AC_CONFIG_FILES([libguile/guile-func-name-check],
1259                 [chmod +x libguile/guile-func-name-check])
1260 AC_CONFIG_FILES([libguile/guile-snarf-docs],
1261                 [chmod +x libguile/guile-snarf-docs])
1262
1263 AC_OUTPUT
1264
1265 dnl Local Variables:
1266 dnl comment-start: "dnl "
1267 dnl comment-end: ""
1268 dnl comment-start-skip: "\\bdnl\\b\\s *"
1269 dnl End: