configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 AC_INIT(Makefile.in)
   4 . $srcdir/GUILE-VERSION
   5 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
   6 AM_MAINTAINER_MODE
   7 AM_CONFIG_HEADER(libguile/scmconfig.h)
   8
   9 #--------------------------------------------------------------------
  10 #
  11 # User options
  12 #
  13 #--------------------------------------------------------------------
  14
  15 AC_ARG_ENABLE(dynamic-linking,
  16   [  --enable-dynamic-linking  Include support for dynamic linking],,
  17   enable_dynamic_linking=yes)
  18
  19 AC_ARG_ENABLE(guile-debug,
  20 [  --enable-guile-debug    Include internal debugging functions])
  21 if test "$enableval" = y || test "$enableval" = yes; then
  22   AC_DEFINE(GUILE_DEBUG)
  23 fi
  24
  25 dnl The --disable-debug used to control these two.  But now they are
  26 dnl a required part of the distribution.
  27 AC_DEFINE(DEBUG_EXTENSIONS)
  28 AC_DEFINE(READER_EXTENSIONS)
  29
  30 #--------------------------------------------------------------------
  31
  32 AC_PROG_CC
  33 AC_PROG_CPP
  34 AM_PROG_LIBTOOL
  35
  36 AC_AIX
  37 AC_ISC_POSIX
  38 AC_MINIX
  39
  40 AC_C_CONST
  41 AC_C_INLINE
  42
  43 AC_HEADER_STDC
  44 AC_HEADER_DIRENT
  45 AC_HEADER_TIME
  46 AC_HEADER_SYS_WAIT
  47 AC_CHECK_HEADERS(libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
  48 GUILE_HEADER_LIBC_WITH_UNISTD
  49
  50 AC_TYPE_GETGROUPS
  51 AC_TYPE_SIGNAL
  52 AC_TYPE_MODE_T
  53
  54 AC_CHECK_LIB(m, main)
  55 AC_CHECK_FUNCS(gethostbyname)
  56 if test $ac_cv_func_gethostbyname = no; then
  57     AC_CHECK_LIB(nsl, gethostbyname)
  58 fi
  59 AC_CHECK_FUNCS(connect)
  60 if test $ac_cv_func_connect = no; then
  61     AC_CHECK_LIB(socket, connect)
  62 fi
  63 AC_CHECK_LIB(termcap, tgoto)
  64 AC_CHECK_LIB(readline, readline)
  65 AC_CHECK_FUNCS(rl_clear_signals rl_cleanup_after_signal)
  66
  67 AC_CACHE_CHECK([for rl_getc_function pointer in readline],
  68                ac_cv_var_rl_getc_function,
  69                [AC_TRY_LINK([
  70 #include <stdio.h>
  71 #include <readline/readline.h>],
  72                             [rl_getc_function;],
  73                             [ac_cv_var_rl_getc_function=yes],
  74                             [ac_cv_var_rl_getc_function=no])])
  75 if test "$ac_cv_var_rl_getc_function" = "yes"; then
  76   AC_DEFINE(HAVE_RL_GETC_FUNCTION)
  77 fi
  78
  79 if test $ac_cv_lib_readline_readline = yes -a $ac_cv_var_rl_getc_function = no; then
  80   echo 'Warning: libreadline is too old on your system.  Need >= 2.1.'
  81 fi
  82
  83 # Checks for dynamic linking
  84
  85 if test "$enable_dynamic_linking" = "yes"; then
  86
  87 AC_CHECK_LIB(dl,dlopen)
  88 if test "$ac_cv_lib_dl_dlopen" = "yes"; then
  89   AC_CHECK_FUNCS(dlopen)
  90   AC_DEFINE(DYNAMIC_LINKING)
  91 else
  92 AC_CHECK_LIB(dld,dld_link)
  93 if test "$ac_cv_lib_dld_dld_link" = "yes"; then
  94   AC_DEFINE(DYNAMIC_LINKING)
  95 else
  96 AC_CHECK_FUNCS(shl_load)
  97 if test "$ac_cv_func_shl_load" = "yes"; then
  98   AC_DEFINE(DYNAMIC_LINKING)
  99 else
 100 AC_CHECK_FUNCS(dlopen)
 101 if test "$ac_cv_func_dlopen" = "yes"; then
 102   AC_DEFINE(DYNAMIC_LINKING)
 103 fi
 104 fi
 105 fi
 106 fi
 107
 108 fi
 109
 110 GUILE_DLSYM_USCORE
 111
 112 AC_CHECK_FUNCS(ctermid ftime getcwd geteuid gethostent gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep)
 113
 114 ### Some systems don't declare some functions.  On such systems, we
 115 ### need to at least provide our own K&R-style declarations.
 116
 117 ### GUILE_FUNC_DECLARED(function, headerfile)
 118
 119 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 120 ### not there, #define MISSING_FUNCTION_DECL.
 121 AC_DEFUN(GUILE_FUNC_DECLARED, [
 122   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 123     AC_EGREP_HEADER($1, $2,
 124                     guile_cv_func_$1_declared=yes,
 125                     guile_cv_func_$1_declared=no))
 126   if test [x$guile_cv_func_]$1[_declared] = xno; then
 127     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 128   fi
 129 ])
 130
 131 GUILE_FUNC_DECLARED(strptime, time.h)
 132 GUILE_FUNC_DECLARED(bzero, string.h)
 133 GUILE_FUNC_DECLARED(sleep, unistd.h)
 134 GUILE_FUNC_DECLARED(usleep, unistd.h)
 135
 136 ### On some systems usleep has no return value.  If it does have one,
 137 ### we'd like to return it; otherwise, we'll fake it.
 138 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 139   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 140                    /usr/include/unistd.h,
 141                    [guile_cv_func_usleep_return_type=void],
 142                    [guile_cv_func_usleep_return_type=int])])
 143 case "$guile_cv_func_usleep_return_type" in
 144   "void" )
 145     AC_DEFINE(USLEEP_RETURNS_VOID)
 146   ;;
 147 esac
 148
 149 dnl <GNU-WIN32 hacks>
 150
 151 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 152 if test -n "$have_sys_un_h" ; then
 153 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 154 fi
 155
 156 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 157
 158 dnl I don't know what this prefixing of cygwin32_ is for.
 159 dnl scmconfig.h wasn't updated with the test results.
 160 dnl so use AC_CHECK_FUNCS for now.
 161
 162 dnl how about:
 163 dnl save confdefs.h
 164 dnl if test $ac_cv_cigwin = yes; then
 165 dnl   modify confdefs.h
 166 dnl fi
 167 dnl AC_CHECK_FUNCS...
 168 dnl restore confdefs.h
 169
 170 dnl cp confdefs.h confdefs.h.bak
 171 dnl for func in sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof ; do
 172 dnl cp confdefs.h.bak confdefs.h
 173 dnl cat >> confdefs.h << EOF
 174 dnl #ifdef __CYGWIN32__
 175 dnl #define $func cygwin32_$func
 176 dnl #endif
 177 dnl EOF
 178 dnl AC_CHECK_FUNC($func)
 179 dnl done
 180 dnl cp confdefs.h.bak confdefs.h
 181
 182 AC_CHECK_FUNCS(sethostent endhostent getnetent setnetent endnetent getprotoent endprotoent getservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof)
 183
 184 dnl </GNU-WIN32 hacks>
 185
 186 AC_CACHE_CHECK([for restartable system calls], scm_cv_restarts,
 187         if test $ac_cv_func_sigaction = yes; then
 188                 [AC_TRY_COMPILE([#include <signal.h>],
 189                                 [int a = SA_RESTART],
 190                                 scm_cv_restarts=yes,
 191                                 scm_cv_restarts=no)]
 192         else
 193                 scm_cv_restarts=no
 194         fi)
 195 if test $scm_cv_restarts = yes; then
 196         AC_DEFINE(HAVE_RESTARTS)
 197 fi
 198
 199 if test "$ac_cv_header_regex_h" = yes ||
 200    test "$ac_cv_header_rxposix_h" = yes ||
 201    test "$ac_cv_header_rx_rxposix_h" = yes; then
 202   GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 203   [AC_CHECK_LIB(rx, main)
 204    GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 205   )
 206   dnl The following should not be necessary, but for some reason
 207   dnl autoheader misses it if we don't include it!
 208   if test "$ac_cv_func_regcomp_norx" = yes ||
 209      test "$ac_cv_func_regcomp_rx" = yes; then
 210     AC_DEFINE(HAVE_REGCOMP)
 211   fi
 212 fi
 213
 214 AC_REPLACE_FUNCS(inet_aton putenv strerror)
 215
 216 # When testing for the presence of alloca, we need to add alloca.o
 217 # explicitly to LIBOBJS to make sure that it is translated to
 218 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 219 AC_FUNC_ALLOCA
 220 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 221
 222 AC_STRUCT_ST_RDEV
 223 AC_STRUCT_ST_BLKSIZE
 224
 225 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 226 # LIBOBJS, which we don't need.  This seems more direct.
 227 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 228 [AC_TRY_COMPILE([#include <sys/types.h>
 229 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 230 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 231 if test $ac_cv_struct_st_blocks = yes; then
 232   AC_DEFINE(HAVE_ST_BLOCKS)
 233 fi
 234
 235 AC_STRUCT_TIMEZONE
 236 GUILE_STRUCT_UTIMBUF
 237
 238 #--------------------------------------------------------------------
 239 #
 240 # Which way does the stack grow?
 241 #
 242 #--------------------------------------------------------------------
 243
 244 AC_TRY_RUN(aux (l) unsigned long l;
 245              { int x; exit (l >= ((unsigned long)&x)); }
 246            main () { int q; aux((unsigned long)&q); },
 247            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 248
 249
 250 AC_TRY_RUN(main () { exit (sizeof(float) != sizeof(long)); },
 251            AC_DEFINE(SCM_SINGLES),,AC_DEFINE(SCM_SINGLES)
 252            AC_MSG_WARN(Guessing that sizeof(long) == sizeof(float) -- see scmconfig.h.in))
 253
 254 AC_MSG_CHECKING(for struct linger)
 255 AC_CACHE_VAL(scm_cv_struct_linger,
 256         AC_TRY_COMPILE([
 257 #include <sys/types.h>
 258 #include <sys/socket.h>],
 259                         [struct linger lgr;  lgr.l_linger = 100],
 260                         scm_cv_struct_linger="yes",
 261                         scm_cv_struct_linger="no"))
 262 AC_MSG_RESULT($scm_cv_struct_linger)
 263 if test $scm_cv_struct_linger = yes; then
 264         AC_DEFINE(HAVE_STRUCT_LINGER)
 265 fi
 266
 267 #--------------------------------------------------------------------
 268 #
 269 # How can you violate a stdio abstraction by setting a stream's fd?
 270 #
 271 #--------------------------------------------------------------------
 272
 273 AC_MSG_CHECKING(how to set a stream file descriptor)
 274 AC_CACHE_VAL(scm_cv_fd_setter,
 275         AC_TRY_COMPILE([#include <stdio.h>],
 276                         [stdout->_file = 1],
 277                         scm_cv_fd_setter="_file",
 278         AC_TRY_COMPILE([#include <stdio.h>],
 279                         [stdout->__file = 1],
 280                         scm_cv_fd_setter="__file",
 281         AC_TRY_COMPILE([#include <stdio.h>],
 282                         [stdout->_fileno = 1],
 283                         scm_cv_fd_setter="_fileno",
 284                         scm_cv_fd_setter=""))))
 285
 286 if test "$scm_cv_fd_setter"; then
 287         AC_MSG_RESULT($scm_cv_fd_setter)
 288         AC_DEFINE_UNQUOTED(FD_SETTER, $scm_cv_fd_setter)
 289 else
 290         AC_MSG_RESULT(we couldn't do it!)
 291 fi
 292
 293 #--------------------------------------------------------------------
 294 # How to find out whether a FILE structure contains buffered data.
 295 # From Tk we have the following list:
 296 #               _cnt:           Most UNIX systems
 297 #               __cnt:          HPUX and SCO
 298 #               _r:             BSD
 299 #               readCount:      Sprite
 300 #       Or, in GNU libc there are two fields, _gptr and _egptr, which
 301 #       have to be compared.
 302 #       These can also be known as _IO_read_ptr and _IO_read_end.
 303 #--------------------------------------------------------------------
 304
 305 AC_MSG_CHECKING(how to get buffer char count from FILE structure)
 306 AC_CACHE_VAL(scm_cv_struct_file_count,
 307         AC_TRY_COMPILE([#include <stdio.h>],
 308                         [FILE *f = stdin; f->_cnt = 0],
 309                         scm_cv_struct_file_count="_cnt",
 310         AC_TRY_COMPILE([#include <stdio.h>],
 311                         [FILE *f = stdin; f->__cnt = 0],
 312                         scm_cv_struct_file_count="__cnt",
 313         AC_TRY_COMPILE([#include <stdio.h>],
 314                         [FILE *f = stdin; f->_r = 0],
 315                         scm_cv_struct_file_count="_r",
 316         AC_TRY_COMPILE([#include <stdio.h>],
 317                         [FILE *f = stdin; f->readCount = 0],
 318                         scm_cv_struct_file_count="readCount",
 319         scm_cv_struct_file_count="")))))
 320 if test "$scm_cv_struct_file_count"; then
 321         AC_MSG_RESULT($scm_cv_struct_file_count)
 322         AC_DEFINE_UNQUOTED(FILE_CNT_FIELD, $scm_cv_struct_file_count)
 323 else
 324 AC_CACHE_VAL(scm_cv_struct_file_gptr,
 325         AC_TRY_COMPILE([#include <stdio.h>],
 326                         [FILE *f = stdin; f->_gptr = f->egptr;],
 327                         scm_cv_struct_file_gptr=1,
 328         scm_cv_struct_file_gptr=""))
 329 if test "$scm_cv_struct_gptr"; then
 330         AC_MSG_RESULT(gptr)
 331         AC_DEFINE_UNQUOTED(FILE_CNT_GPTR, $scm_cv_struct_file_gptr)
 332 else
 333 AC_CACHE_VAL(scm_cv_struct_file_readptr,
 334         AC_TRY_COMPILE([#include <stdio.h>],
 335                         [FILE *f = stdin; f->_IO_read_ptr = f->_IO_read_end;],
 336                         scm_cv_struct_file_readptr=1))
 337 if test "$scm_cv_struct_file_readptr"; then
 338         AC_MSG_RESULT(read_ptr)
 339         AC_DEFINE_UNQUOTED(FILE_CNT_READPTR, $scm_cv_struct_file_readptr)
 340 else
 341         AC_MSG_RESULT(we couldn't do it!)
 342 fi
 343 fi
 344 fi
 345
 346 #--------------------------------------------------------------------
 347 #
 348 # Flags for thread support
 349 #
 350 #--------------------------------------------------------------------
 351
 352 ### What thread package has the user asked for?
 353 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 354             , with_threads=no)
 355
 356 ### Turn $with_threads into either the name of a threads package, like
 357 ### `qt', or `no', meaning that threads should not be supported.
 358 AC_MSG_CHECKING(whether to support threads)
 359 case "$with_threads" in
 360   "yes" | "qt" | "coop" | "")
 361     with_threads=qt
 362   ;;
 363   "no" )
 364   ;;
 365   * )
 366     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 367   ;;
 368 esac
 369 AC_MSG_RESULT($with_threads)
 370
 371 ## Make sure the threads package we've chosen is actually supported on
 372 ## the present platform.
 373 case "${with_threads}" in
 374   "qt" )
 375     ## This configures the QuickThreads package, and sets or clears
 376     ## the THREAD_PACKAGE variable if qthreads don't configure
 377     ## correctly.
 378     QTHREADS_CONFIGURE
 379    ;;
 380 esac
 381
 382 ## If we're using threads, bring in some other parts of Guile which
 383 ## work with them.
 384 if test "${THREAD_PACKAGE}" != "" ; then
 385   AC_DEFINE(USE_THREADS, 1)
 386
 387   ## Include the Guile thread interface in the library...
 388   LIBOBJS="$LIBOBJS threads.o"
 389
 390   ## ... and tell it which package to talk to.
 391   case "${THREAD_PACKAGE}" in
 392     "QT" )
 393       AC_DEFINE(USE_COOP_THREADS, 1)
 394     ;;
 395     * )
 396       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 397     ;;
 398   esac
 399
 400   ## Bring in scm_internal_select, if appropriate.
 401   if test $ac_cv_func_gettimeofday = yes &&
 402      test $ac_cv_func_select = yes; then
 403     LIBOBJS="$LIBOBJS iselect.o"
 404     AC_DEFINE(GUILE_ISELECT, 1)
 405   fi
 406 fi
 407
 408 ## If we're using GCC, ask for aggressive warnings.
 409 case "$GCC" in
 410   yes )
 411     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 412     ## much stuff with generic function pointers for that to really be
 413     ## less than exasperating.
 414     CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wmissing-prototypes" ;;
 415 esac
 416
 417 AC_PROG_AWK
 418
 419 ## If we're creating a shared library (using libtool!), then we'll
 420 ## need to generate a list of .lo files corresponding to the .o files
 421 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 422 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 423
 424 AC_SUBST(GUILE_MAJOR_VERSION)
 425 AC_SUBST(GUILE_MINOR_VERSION)
 426 AC_SUBST(GUILE_VERSION)
 427
 428 dnl Tell guile-config what flags guile users should link against.
 429 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 430 AC_SUBST(GUILE_LIBS)
 431
 432 dnl timestamping the interpreter and scheme libraries:
 433 dnl
 434 dnl Help us notice when we're running one version of the Guile
 435 dnl interpreter against a different version of the ice-9 Scheme code.
 436 dnl This will definitely detect version skew due to differing
 437 dnl snapshots and releases, but may not catch skew for the developers.
 438 dnl Hopefully it will not detect skew when there is none; if that
 439 dnl happens, the warnings will be useless, and we should remove this.
 440 GUILE_STAMP="`date`"
 441 AC_SUBST(GUILE_STAMP)
 442
 443 AC_SUBST(AWK)
 444 AC_SUBST(LIBLOBJS)
 445
 446 AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/versiondat.h ice-9/Makefile ice-9/version.scm qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf])
 447
 448 dnl Local Variables:
 449 dnl comment-start: "dnl "
 450 dnl comment-end: ""
 451 dnl comment-start-skip: "\\bdnl\\b\\s *"
 452 dnl End: