configure.in

   1 dnl   configuration script for Guile
   2 dnl   Process this file with autoconf to produce configure.
   3 dnl
   4 dnl  Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
   5 dnl
   6 dnl  This file is part of GUILE
   7 dnl
   8 dnl  GUILE is free software; you can redistribute it and/or modify it
   9 dnl  under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 2, or (at your
  11 dnl  option) any later version.
  12 dnl
  13 dnl  GUILE is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl  General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with GUILE; see the file COPYING.  If not, write to the
  20 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 dnl  Boston, MA 02111-1307, USA.
  22
  23 AC_INIT(Makefile.in)
  24 . $srcdir/GUILE-VERSION
  25 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  26 AM_MAINTAINER_MODE
  27 AM_CONFIG_HEADER(libguile/scmconfig.h)
  28
  29 #--------------------------------------------------------------------
  30 #
  31 # Independent Subdirectories
  32 #
  33 #--------------------------------------------------------------------
  34
  35 AC_CONFIG_SUBDIRS(guile-readline)
  36
  37 #--------------------------------------------------------------------
  38 #
  39 # User options
  40 #
  41 #--------------------------------------------------------------------
  42
  43 AC_ARG_ENABLE(debug-freelist,
  44   [  --enable-debug-freelist include garbage collector freelist debugging code],
  45   if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
  46     AC_DEFINE(GUILE_DEBUG_FREELIST)
  47   fi)
  48
  49 AC_ARG_ENABLE(debug-malloc,
  50   [  --enable-debug-malloc   include malloc debugging code],
  51   if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
  52     AC_DEFINE(GUILE_DEBUG_MALLOC)
  53   fi)
  54
  55 AC_ARG_ENABLE(guile-debug,
  56   [  --enable-guile-debug    include internal debugging functions],
  57   if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
  58     AC_DEFINE(GUILE_DEBUG)
  59   fi)
  60
  61 AC_ARG_ENABLE(arrays,
  62   [  --disable-arrays        omit array and uniform array support],,
  63   enable_arrays=yes)
  64
  65 AC_ARG_ENABLE(posix,
  66   [  --disable-posix         omit posix interfaces],,
  67   enable_posix=yes)
  68
  69 AC_ARG_ENABLE(networking,
  70   [  --disable-networking    omit networking interfaces],,
  71   enable_networking=yes)
  72
  73 AC_ARG_ENABLE(regex,
  74   [  --disable-regex         omit regular expression interfaces],,
  75   enable_regex=yes)
  76
  77 AC_ARG_ENABLE(htmldoc,
  78   [  --enable-htmldoc        build HTML documentation as well as Info],
  79   [if test "$enable_htmldoc" = "" || test "$enable_htmldoc" = y || test "$enable_htmldoc" = yes; then
  80      htmldoc_enabled=yes
  81      AC_PATH_PROG(TEXI2HTML, texi2html, not found)
  82      if test "$TEXI2HTML" = "not found"; then
  83        echo
  84        echo Building HTML documentation requires the \`texi2html\' program,
  85        echo which appears not to be present on your machine.
  86        echo
  87        echo \`texi2html\' is available from
  88        echo 'http://www.mathematik.uni-kl.de/~obachman/Texi2html/.'
  89        echo
  90        echo In the meantime, to build the guile-doc distribution
  91        echo without HTML enabled, please rerun \`./configure\' without
  92        echo the \`--enable-htmldoc\' option.
  93        exit -1
  94      fi
  95    fi])
  96
  97 AM_CONDITIONAL(HTMLDOC, test x$htmldoc_enabled = xyes)
  98
  99 AC_ARG_ENABLE(deprecated,
 100   [  --disable-deprecated    omit deprecated features [no]])
 101
 102 if test "$enable_deprecated" = no; then
 103   AC_DEFINE(SCM_DEBUG_DEPRECATED, 1)
 104 else
 105   if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then
 106     warn_default=summary
 107   elif test "$enable_deprecated" = shutup; then
 108     warn_default=no
 109   else
 110     warn_default=$enable_deprecated
 111   fi
 112   AC_DEFINE(SCM_DEBUG_DEPRECATED, 0)
 113   AC_DEFINE_UNQUOTED(SCM_WARN_DEPRECATED_DEFAULT, "$warn_default")
 114 fi
 115
 116 dnl The --disable-debug used to control these two.  But now they are
 117 dnl a required part of the distribution.
 118 AC_DEFINE(DEBUG_EXTENSIONS)
 119 AC_DEFINE(READER_EXTENSIONS)
 120
 121 dnl files which are destined for separate modules.
 122
 123 if test "$enable_arrays" = yes; then
 124    LIBOBJS="$LIBOBJS ramap.o unif.o"
 125    AC_DEFINE(HAVE_ARRAYS)
 126 fi
 127
 128 if test "$enable_posix" = yes; then
 129    LIBOBJS="$LIBOBJS filesys.o posix.o"
 130    AC_DEFINE(HAVE_POSIX)
 131 fi
 132
 133 if test "$enable_networking" = yes; then
 134    LIBOBJS="$LIBOBJS net_db.o socket.o"
 135    AC_DEFINE(HAVE_NETWORKING)
 136 fi
 137
 138 if test "$enable_debug_malloc" = yes; then
 139    LIBOBJS="$LIBOBJS debug-malloc.o"
 140 fi
 141
 142 #--------------------------------------------------------------------
 143
 144 AC_LIBLTDL_CONVENIENCE
 145 AC_CONFIG_SUBDIRS(libltdl)
 146
 147 AC_PROG_CC
 148 AC_PROG_CPP
 149 AC_LIBTOOL_DLOPEN
 150
 151 AC_AIX
 152 AC_ISC_POSIX
 153 AC_MINIX
 154
 155 AM_PROG_CC_STDC
 156 AM_PROG_LIBTOOL
 157
 158 AC_C_CONST
 159 AC_C_INLINE
 160 AC_C_BIGENDIAN
 161
 162 AC_CHECK_SIZEOF(int)
 163 AC_CHECK_SIZEOF(long)
 164
 165 dnl by the pre C9X ANSI C standards, size_t & ptrdiff_t have to be
 166 dnl representable by a standard integral type.  since the largest
 167 dnl integer type in the pre-C9X ANSI C standards is long...
 168 AC_CHECK_TYPE(ptrdiff_t, long)
 169
 170 AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
 171                AC_TRY_COMPILE(,
 172                               [long long a],
 173                               scm_cv_long_longs=yes,
 174                               scm_cv_long_longs=no))
 175 if test "$scm_cv_long_longs" = yes; then
 176   AC_DEFINE(HAVE_LONG_LONGS)
 177   AC_CHECK_SIZEOF(long long)
 178 fi
 179
 180 AC_CHECK_SIZEOF(void *)
 181
 182 if test "$ac_cv_sizeof_long" -eq "$ac_cv_sizeof_void_p"; then
 183   AC_DEFINE(SCM_BITS_T, long)
 184   AC_DEFINE(SCM_UBITS_T, unsigned long)
 185   AC_DEFINE(SCM_SIZEOF_BITS_T, SIZEOF_LONG)
 186 elif test \( "$scm_cv_long_longs" = yes \) -a \( "$ac_cv_sizeof_long_long" -eq "$ac_cv_sizeof_void_p" \); then
 187   AC_DEFINE(SCM_BITS_T, long long)
 188   AC_DEFINE(SCM_UBITS_T, unsigned long long)
 189   AC_DEFINE(SCM_SIZEOF_BITS_T, SIZEOF_LONG_LONG)
 190 elif test "$ac_cv_sizeof_int" -eq "$ac_cv_sizeof_void_p"; then
 191   AC_DEFINE(SCM_BITS_T, int)
 192   AC_DEFINE(SCM_UBITS_T, unsigned int)
 193   AC_DEFINE(SCM_SIZEOF_BITS_T, SIZEOF_INT)
 194 else
 195   AC_MSG_ERROR(cannot find an integral type capable of storing a pointer: "$ac_cv_sizeof_void_p" bytes)
 196 fi
 197
 198 AC_HEADER_STDC
 199 AC_HEADER_DIRENT
 200 AC_HEADER_TIME
 201 AC_HEADER_SYS_WAIT
 202 AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h sys/utime.h time.h unistd.h utime.h)
 203 GUILE_HEADER_LIBC_WITH_UNISTD
 204
 205 AC_TYPE_GETGROUPS
 206 AC_TYPE_SIGNAL
 207 AC_TYPE_MODE_T
 208
 209 AC_CHECK_LIB(m, main)
 210 AC_CHECK_FUNCS(gethostbyname)
 211 if test $ac_cv_func_gethostbyname = no; then
 212     AC_CHECK_LIB(nsl, gethostbyname)
 213 fi
 214 AC_CHECK_FUNCS(connect)
 215 if test $ac_cv_func_connect = no; then
 216     AC_CHECK_LIB(socket, connect)
 217 fi
 218
 219 # Check for dynamic linking
 220
 221 use_modules=yes
 222 AC_ARG_WITH(modules,
 223 [  --with-modules[=FILES]  Add support for dynamic modules],
 224 use_modules="$withval")
 225 test -z "$use_modules" && use_modules=yes
 226 DLPREOPEN=
 227 if test "$use_modules" != no; then
 228   AC_DEFINE(DYNAMIC_LINKING)
 229   if test "$use_modules" = yes; then
 230     DLPREOPEN="-dlpreopen force"
 231   else
 232     DLPREOPEN="-export-dynamic"
 233     for module in $use_modules; do
 234       DLPREOPEN="$DLPREOPEN -dlopen $module"
 235     done
 236   fi
 237 fi
 238 AC_SUBST(INCLTDL)
 239 AC_SUBST(LIBLTDL)
 240 AC_SUBST(DLPREOPEN)
 241
 242 AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid strdup system usleep atexit on_exit)
 243
 244 AC_CHECK_HEADERS(crypt.h sys/resource.h sys/file.h)
 245 AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname)
 246 AC_CHECK_LIB(crypt, crypt)
 247
 248 ### Some systems don't declare some functions.  On such systems, we
 249 ### need to at least provide our own K&R-style declarations.
 250
 251 ### GUILE_FUNC_DECLARED(function, headerfile)
 252
 253 ### Check for a declaration of FUNCTION in HEADERFILE; if it is
 254 ### not there, #define MISSING_FUNCTION_DECL.
 255 AC_DEFUN(GUILE_FUNC_DECLARED, [
 256   AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
 257     AC_EGREP_HEADER($1, $2,
 258                     guile_cv_func_$1_declared=yes,
 259                     guile_cv_func_$1_declared=no))
 260   if test [x$guile_cv_func_]$1[_declared] = xno; then
 261     AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
 262   fi
 263 ])
 264
 265 GUILE_FUNC_DECLARED(strptime, time.h)
 266 GUILE_FUNC_DECLARED(sleep, unistd.h)
 267 GUILE_FUNC_DECLARED(usleep, unistd.h)
 268
 269 ### On some systems usleep has no return value.  If it does have one,
 270 ### we'd like to return it; otherwise, we'll fake it.
 271 AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
 272   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
 273                    /usr/include/unistd.h,
 274                    [guile_cv_func_usleep_return_type=void],
 275                    [guile_cv_func_usleep_return_type=int])])
 276 case "$guile_cv_func_usleep_return_type" in
 277   "void" )
 278     AC_DEFINE(USLEEP_RETURNS_VOID)
 279   ;;
 280 esac
 281
 282 AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
 283 if test -n "$have_sys_un_h" ; then
 284 AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
 285 fi
 286
 287 AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
 288
 289 AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
 290                setnetent    getnetent    endnetent    dnl
 291                setprotoent  getprotoent  endprotoent  dnl
 292                setservent   getservent   endservent   dnl
 293                getnetbyaddr getnetbyname dnl
 294                inet_lnaof inet_makeaddr inet_netof hstrerror dnl
 295                inet_pton inet_ntop)
 296
 297 dnl Some systems do not declare this.  Some systems do declare it, as a
 298 dnl macro.  With cygwin it may be in a DLL.
 299
 300 AC_MSG_CHECKING(whether netdb.h declares h_errno)
 301 AC_CACHE_VAL(guile_cv_have_h_errno,
 302 [AC_TRY_COMPILE([#include <netdb.h>],
 303 [int a = h_errno;],
 304 guile_cv_have_h_errno=yes, guile_cv_have_h_errno=no)])
 305 AC_MSG_RESULT($guile_cv_have_h_errno)
 306 if test $guile_cv_have_h_errno = yes; then
 307   AC_DEFINE(HAVE_H_ERRNO)
 308 fi
 309
 310 AC_MSG_CHECKING(whether netdb.h defines uint32_t)
 311 AC_CACHE_VAL(guile_cv_have_uint32_t,
 312 [AC_TRY_COMPILE([#include <netdb.h>],
 313 [uint32_t a;],
 314 guile_cv_have_uint32_t=yes, guile_cv_have_uint32_t=no)])
 315 AC_MSG_RESULT($guile_cv_have_uint32_t)
 316 if test $guile_cv_have_uint32_t = yes; then
 317   AC_DEFINE(HAVE_UINT32_T)
 318 fi
 319
 320 AC_MSG_CHECKING(for working IPv6 support)
 321 AC_CACHE_VAL(guile_cv_have_ipv6,
 322 [AC_TRY_COMPILE([#include <netinet/in.h>
 323 #include <sys/socket.h>],
 324 [struct sockaddr_in6 a;  a.sin6_family = AF_INET6;],
 325 guile_cv_have_ipv6=yes, guile_cv_have_ipv6=no)])
 326 AC_MSG_RESULT($guile_cv_have_ipv6)
 327 if test $guile_cv_have_ipv6 = yes; then
 328   AC_DEFINE(HAVE_IPV6)
 329 fi
 330
 331 # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3.
 332 AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id)
 333 AC_CACHE_VAL(guile_cv_have_sin6_scope_id,
 334 [AC_TRY_COMPILE([#include <netinet/in.h>],
 335 [struct sockaddr_in6 sok;  sok.sin6_scope_id = 0;],
 336 guile_cv_have_sin6_scope_id=yes, guile_cv_have_sin6_scope_id=no)])
 337 AC_MSG_RESULT($guile_cv_have_sin6_scope_id)
 338 if test $guile_cv_have_sin6_scope_id = yes; then
 339   AC_DEFINE(HAVE_SIN6_SCOPE_ID)
 340 fi
 341
 342 AC_MSG_CHECKING(whether localtime caches TZ)
 343 AC_CACHE_VAL(guile_cv_localtime_cache,
 344 [if test x$ac_cv_func_tzset = xyes; then
 345 AC_TRY_RUN([#include <time.h>
 346 #if STDC_HEADERS
 347 # include <stdlib.h>
 348 #endif
 349 extern char **environ;
 350 unset_TZ ()
 351 {
 352   char **from, **to;
 353   for (to = from = environ; (*to = *from); from++)
 354     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 355       to++;
 356 }
 357 char TZ_GMT0[] = "TZ=GMT0";
 358 char TZ_PST8[] = "TZ=PST8";
 359 main()
 360 {
 361   time_t now = time ((time_t *) 0);
 362   int hour_GMT0, hour_unset;
 363   if (putenv (TZ_GMT0) != 0)
 364     exit (1);
 365   hour_GMT0 = localtime (&now)->tm_hour;
 366   unset_TZ ();
 367   hour_unset = localtime (&now)->tm_hour;
 368   if (putenv (TZ_PST8) != 0)
 369     exit (1);
 370   if (localtime (&now)->tm_hour == hour_GMT0)
 371     exit (1);
 372   unset_TZ ();
 373   if (localtime (&now)->tm_hour != hour_unset)
 374     exit (1);
 375   exit (0);
 376 }], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
 377 [# If we have tzset, assume the worst when cross-compiling.
 378 guile_cv_localtime_cache=yes])
 379 else
 380         # If we lack tzset, report that localtime does not cache TZ,
 381         # since we can't invalidate the cache if we don't have tzset.
 382         guile_cv_localtime_cache=no
 383 fi])dnl
 384 AC_MSG_RESULT($guile_cv_localtime_cache)
 385 if test $guile_cv_localtime_cache = yes; then
 386   AC_DEFINE(LOCALTIME_CACHE)
 387 fi
 388
 389 dnl Test whether system calls are restartable by default on the
 390 dnl current system.  If they are not, we put a loop around every system
 391 dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
 392 dnl change from the default behaviour.  On the other hand, if signals
 393 dnl are restartable then the loop is not installed and when libguile
 394 dnl initialises it also resets the behaviour of each signal to cause a
 395 dnl restart (in case a different runtime had a different default
 396 dnl behaviour for some reason: e.g., different versions of linux seem
 397 dnl to behave differently.)
 398
 399 AC_SYS_RESTARTABLE_SYSCALLS
 400
 401 if test "$enable_regex" = yes; then
 402    if test "$ac_cv_header_regex_h" = yes ||
 403       test "$ac_cv_header_rxposix_h" = yes ||
 404       test "$ac_cv_header_rx_rxposix_h" = yes; then
 405      GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
 406      [AC_CHECK_LIB(rx, main)
 407       GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
 408      )
 409      dnl The following should not be necessary, but for some reason
 410      dnl autoheader misses it if we don't include it!
 411      if test "$ac_cv_func_regcomp_norx" = yes ||
 412         test "$ac_cv_func_regcomp_rx" = yes; then
 413        AC_DEFINE(HAVE_REGCOMP)
 414      fi
 415    fi
 416 fi
 417
 418 AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
 419
 420 # When testing for the presence of alloca, we need to add alloca.o
 421 # explicitly to LIBOBJS to make sure that it is translated to
 422 # `alloca.lo' for libtool later on.  This can and should be done more cleanly.
 423 AC_FUNC_ALLOCA
 424 if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
 425
 426 AC_STRUCT_ST_RDEV
 427 AC_STRUCT_ST_BLKSIZE
 428
 429 # We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
 430 # LIBOBJS, which we don't need.  This seems more direct.
 431 AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
 432 [AC_TRY_COMPILE([#include <sys/types.h>
 433 #include <sys/stat.h>], [struct stat s; s.st_blocks;],
 434 ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
 435 if test $ac_cv_struct_st_blocks = yes; then
 436   AC_DEFINE(HAVE_ST_BLOCKS)
 437 fi
 438
 439 AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
 440   [AC_TRY_CPP([#include <sys/stat.h>
 441                #ifndef S_ISLNK
 442                #error no S_ISLNK
 443                #endif],
 444                ac_cv_macro_S_ISLNK=yes,
 445                ac_cv_macro_S_ISLNK=no)])
 446 if test $ac_cv_macro_S_ISLNK = yes; then
 447   AC_DEFINE(HAVE_S_ISLNK)
 448 fi
 449
 450 AC_STRUCT_TIMEZONE
 451 GUILE_STRUCT_UTIMBUF
 452
 453 #--------------------------------------------------------------------
 454 #
 455 # Which way does the stack grow?
 456 #
 457 #--------------------------------------------------------------------
 458
 459 AC_TRY_RUN(aux (l) unsigned long l;
 460              { int x; exit (l >= ((unsigned long)&x)); }
 461            main () { int q; aux((unsigned long)&q); },
 462            AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
 463
 464 AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
 465     [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
 466                 [guile_cv_type_float_fits_long=yes],
 467                 [guile_cv_type_float_fits_long=no],
 468                 [guile_cv_type_float_fits_long=guess-yes])])
 469 case $guile_cv_type_float_fits_long in
 470   "yes" )
 471     AC_DEFINE(SCM_SINGLES)
 472   ;;
 473   "guess-yes" )
 474     AC_DEFINE(SCM_SINGLES)
 475     AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
 476     AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
 477   ;;
 478 esac
 479
 480
 481 AC_MSG_CHECKING(for struct linger)
 482 AC_CACHE_VAL(scm_cv_struct_linger,
 483         AC_TRY_COMPILE([
 484 #include <sys/types.h>
 485 #include <sys/socket.h>],
 486                         [struct linger lgr;  lgr.l_linger = 100],
 487                         scm_cv_struct_linger="yes",
 488                         scm_cv_struct_linger="no"))
 489 AC_MSG_RESULT($scm_cv_struct_linger)
 490 if test $scm_cv_struct_linger = yes; then
 491         AC_DEFINE(HAVE_STRUCT_LINGER)
 492 fi
 493
 494
 495 AC_MSG_CHECKING(for struct timespec)
 496 AC_CACHE_VAL(scm_cv_struct_timespec,
 497         AC_TRY_COMPILE([
 498 #include <time.h>],
 499                         [struct timespec t;  t.tv_nsec = 100],
 500                         scm_cv_struct_timespec="yes",
 501                         scm_cv_struct_timespec="no"))
 502 AC_MSG_RESULT($scm_cv_struct_timespec)
 503 if test $scm_cv_struct_timespec = yes; then
 504         AC_DEFINE(HAVE_STRUCT_TIMESPEC)
 505 fi
 506
 507 #--------------------------------------------------------------------
 508 #
 509 # Flags for thread support
 510 #
 511 #--------------------------------------------------------------------
 512
 513 ### What thread package has the user asked for?
 514 AC_ARG_WITH(threads, [  --with-threads          thread interface],
 515             , with_threads=no)
 516
 517 ### Turn $with_threads into either the name of a threads package, like
 518 ### `qt', or `no', meaning that threads should not be supported.
 519 AC_MSG_CHECKING(whether to support threads)
 520 case "$with_threads" in
 521   "yes" | "qt" | "coop" | "")
 522     with_threads=qt
 523   ;;
 524   "no" )
 525   ;;
 526   * )
 527     AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
 528   ;;
 529 esac
 530 AC_MSG_RESULT($with_threads)
 531
 532 ## Make sure the threads package we've chosen is actually supported on
 533 ## the present platform.
 534 case "${with_threads}" in
 535   "qt" )
 536     ## This configures the QuickThreads package, and sets or clears
 537     ## the THREAD_PACKAGE variable if qthreads don't configure
 538     ## correctly.
 539     QTHREADS_CONFIGURE
 540    ;;
 541 esac
 542
 543 ## If we're using threads, bring in some other parts of Guile which
 544 ## work with them.
 545 if test "${THREAD_PACKAGE}" != "" ; then
 546   AC_DEFINE(USE_THREADS, 1)
 547
 548   ## Include the Guile thread interface in the library...
 549   LIBOBJS="$LIBOBJS threads.o"
 550
 551   ## ... and tell it which package to talk to.
 552   case "${THREAD_PACKAGE}" in
 553     "QT" )
 554       AC_DEFINE(USE_COOP_THREADS, 1)
 555     ;;
 556     * )
 557       AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
 558     ;;
 559   esac
 560
 561   ## Bring in scm_internal_select, if appropriate.
 562   if test $ac_cv_func_gettimeofday = yes &&
 563      test $ac_cv_func_select = yes; then
 564     AC_DEFINE(GUILE_ISELECT, 1)
 565   fi
 566
 567   ## Workaround for linuxthreads (currently disabled)
 568   if test $host_os = linux-gnu; then
 569     AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
 570     AC_CHECK_LIB(pthread, main)
 571   fi
 572 fi
 573 AC_SUBST(LIBGUILEQTHREADS_MAJOR_VERSION)
 574 AC_SUBST(LIBGUILEQTHREADS_MINOR_VERSION)
 575 AC_SUBST(LIBGUILEQTHREADS_REVISION_VERSION)
 576 AC_SUBST(LIBGUILEQTHREADS_VERSION)
 577
 578 ## If we're using GCC, ask for aggressive warnings.
 579 case "$GCC" in
 580   yes )
 581     ## We had -Wstrict-prototypes in here for a bit, but Guile does too
 582     ## much stuff with generic function pointers for that to really be
 583     ## less than exasperating.
 584     ## -Wpointer-arith was here too, but something changed in gcc/glibc
 585     ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
 586     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
 587 esac
 588
 589 AC_PROG_AWK
 590
 591 ## If we're creating a shared library (using libtool!), then we'll
 592 ## need to generate a list of .lo files corresponding to the .o files
 593 ## given in LIBOBJS.  We'll call it LIBLOBJS.
 594 LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"
 595
 596 ## We also need to create corresponding .doc and .x files
 597 EXTRA_DOT_DOC_FILES="`echo ${LIBOBJS} | sed 's/\.o/.doc/g'`"
 598 EXTRA_DOT_X_FILES="`echo ${LIBOBJS} | sed 's/\.o/.x/g'`"
 599
 600 AC_SUBST(GUILE_MAJOR_VERSION)
 601 AC_SUBST(GUILE_MINOR_VERSION)
 602 AC_SUBST(GUILE_MICRO_VERSION)
 603 AC_SUBST(GUILE_VERSION)
 604 AC_SUBST(LIBGUILE_MAJOR_VERSION)
 605 AC_SUBST(LIBGUILE_MINOR_VERSION)
 606 AC_SUBST(LIBGUILE_REVISION_VERSION)
 607 AC_SUBST(LIBGUILE_VERSION)
 608
 609 dnl Tell guile-config what flags guile users should link against.
 610 GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
 611 AC_SUBST(GUILE_LIBS)
 612
 613 AC_SUBST(AWK)
 614 AC_SUBST(LIBLOBJS)
 615 AC_SUBST(EXTRA_DOT_DOC_FILES)
 616 AC_SUBST(EXTRA_DOT_X_FILES)
 617
 618 AC_OUTPUT([Makefile
 619            libguile/Makefile
 620            libguile/guile-snarf
 621            libguile/guile-doc-snarf
 622            libguile/guile-func-name-check
 623            libguile/guile-snarf.awk
 624            libguile/versiondat.h
 625            ice-9/Makefile
 626            oop/Makefile
 627            oop/goops/Makefile
 628            scripts/Makefile
 629            srfi/Makefile
 630            qt/Makefile
 631            qt/qt.h
 632            qt/md/Makefile
 633            qt/time/Makefile
 634            guile-config/Makefile
 635            doc/Makefile
 636            check-guile
 637            guile-tools],
 638           [chmod +x libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check check-guile guile-tools])
 639
 640 dnl Local Variables:
 641 dnl comment-start: "dnl "
 642 dnl comment-end: ""
 643 dnl comment-start-skip: "\\bdnl\\b\\s *"
 644 dnl End: