config.bat

   1 @echo off
   2 rem   ----------------------------------------------------------------------
   3 rem   Configuration script for MSDOS
   4 rem   Copyright (C) 1994, 1995, 1996, 1997, 1998, 1999, 2001
   5 rem   Free Software Foundation, Inc.
   6
   7 rem   This file is part of GNU Emacs.
   8
   9 rem   GNU Emacs is free software; you can redistribute it and/or modify
  10 rem   it under the terms of the GNU General Public License as published by
  11 rem   the Free Software Foundation; either version 2, or (at your option)
  12 rem   any later version.
  13
  14 rem   GNU Emacs is distributed in the hope that it will be useful,
  15 rem   but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 rem   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 rem   GNU General Public License for more details.
  18
  19 rem   You should have received a copy of the GNU General Public License
  20 rem   along with GNU Emacs; see the file COPYING.  If not, write to the
  21 rem   Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 rem   Boston, MA 02111-1307, USA.
  23 rem   ----------------------------------------------------------------------
  24 rem   YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:
  25 rem
  26 rem   + msdos version 3 or better.
  27 rem   + djgpp version 1.12maint1 or later (version 2.0 or later recommended).
  28 rem   + make utility that allows breaking of the 128 chars limit on
  29 rem     command lines.  ndmake (as of version 4.5) won't work due to a
  30 rem     line length limit.  The make that comes with djgpp does work.
  31 rem   + rm and mv (from GNU file utilities).
  32 rem   + sed (you can use the port that comes with DJGPP).
  33 rem
  34 rem   You should be able to get all the above utilities from any SimTel
  35 rem   repository, e.g. ftp.simtel.net, in the directory
  36 rem   "pub/simtelnet/gnu/djgpp/v2gnu".  As usual, please use your local
  37 rem   mirroring site to reduce trans-Atlantic traffic.
  38 rem   ----------------------------------------------------------------------
  39 set X11=
  40 set nodebug=
  41 set djgpp_ver=
  42 if "%1" == "" goto usage
  43 rem   ----------------------------------------------------------------------
  44 rem   See if their environment is large enough.  We need 28 bytes.
  45 set $foo$=789012345678901234567
  46 if not "%$foo$%" == "789012345678901234567" goto SmallEnv
  47 set $foo$=
  48 :again
  49 if "%1" == "" goto usage
  50 if "%1" == "--with-x" goto withx
  51 if "%1" == "--no-debug" goto nodebug
  52 if "%1" == "msdos" goto msdos
  53 :usage
  54 echo Usage: config [--with-x] [--no-debug] msdos
  55 echo [Read the script before you run it.]
  56 goto end
  57 rem   ----------------------------------------------------------------------
  58 :withx
  59 set X11=Y
  60 shift
  61 goto again
  62 rem   ----------------------------------------------------------------------
  63 :nodebug
  64 set nodebug=Y
  65 shift
  66 goto again
  67 rem   ----------------------------------------------------------------------
  68 :msdos
  69 Echo Checking whether 'sed' is available...
  70 sed -e "w junk.$$$" <Nul
  71 If Exist junk.$$$ Goto sedOk
  72 Echo To configure 'Emacs' you need to have 'sed'!
  73 Goto End
  74 :sedOk
  75 Echo Checking whether 'rm' is available...
  76 rm -f junk.$$$
  77 If Not Exist junk.$$$ Goto rmOk
  78 Echo To configure 'Emacs' you need to have 'rm'!
  79 Goto End
  80 :rmOk
  81 Echo Checking whether 'mv' is available...
  82 rm -f junk.1 junk.2
  83 echo foo >junk.1
  84 mv junk.1 ./junk.2
  85 If Exist junk.2 Goto mvOk
  86 Echo To configure 'Emacs' you need to have 'mv'!
  87 rm -f junk.1
  88 Goto End
  89 :mvOk
  90 rm -f junk.2
  91 Echo Checking whether 'gcc' is available...
  92 echo main(){} >junk.c
  93 gcc -c junk.c
  94 if exist junk.o goto gccOk
  95 Echo To configure 'Emacs' you need to have 'gcc'!
  96 rm -f junk.c
  97 Goto End
  98 :gccOk
  99 rm -f junk.c junk.o junk junk.exe
 100 Echo Checking what version of DJGPP is installed...
 101 If Not "%DJGPP%" == "" goto djgppOk
 102 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!
 103 Goto End
 104 :djgppOk
 105 echo int main()           >junk.c
 106 echo #ifdef __DJGPP__    >>junk.c
 107 echo {return (__DJGPP__)*10;} >>junk.c
 108 echo #else               >>junk.c
 109 echo #ifdef __GO32__     >>junk.c
 110 echo {return 10;}         >>junk.c
 111 echo #else               >>junk.c
 112 echo {return 0;}         >>junk.c
 113 echo #endif              >>junk.c
 114 echo #endif              >>junk.c
 115 gcc -o junk junk.c
 116 if not exist junk.exe coff2exe junk
 117 junk
 118 If ErrorLevel 10 Goto go32Ok
 119 rm -f junk.c junk junk.exe
 120 Echo To compile 'Emacs' under MS-DOS you MUST have DJGPP installed!
 121 Goto End
 122 :go32Ok
 123 set djgpp_ver=1
 124 If ErrorLevel 20 set djgpp_ver=2
 125 rm -f junk.c junk junk.exe
 126 rem DJECHO is used by the top-level Makefile
 127 Echo Checking whether 'djecho' is available...
 128 redir -o Nul -eo djecho -o junk.$$$ foo
 129 If Exist junk.$$$ Goto djechoOk
 130 Echo To build 'Emacs' you need the 'djecho.exe' program!
 131 Echo 'djecho.exe' is part of 'djdevNNN.zip' basic DJGPP development kit.
 132 Echo Versions of DJGPP before 2.02 called this program 'echo.exe'.
 133 Echo Either unpack 'djecho.exe' from the 'djdevNNN.zip' archive,
 134 Echo or, if you have 'echo.exe', copy it to 'djecho.exe'.
 135 Echo Then run CONFIG.BAT again with the same arguments you did now.
 136 Goto End
 137 :djechoOk
 138 rm -f junk.$$$
 139 Echo Configuring for DJGPP Version %DJGPP_VER% ...
 140 Rem   ----------------------------------------------------------------------
 141 Echo Configuring the source directory...
 142 cd src
 143
 144 rem   Create "epaths.h"
 145 sed -f ../msdos/sed4.inp <epaths.in >epaths.tmp
 146 update epaths.tmp epaths.h >nul
 147 rm -f epaths.tmp
 148
 149 rem   Create "config.h"
 150 rm -f config.h2 config.tmp
 151 sed -e '' config.in > config.tmp
 152 if "%X11%" == "" goto src4
 153 sed -f ../msdos/sed2x.inp <config.in >config.tmp
 154 :src4
 155 if "%DJGPP_VER%" == "2" Goto src41
 156 sed -f ../msdos/sed2.inp <config.tmp >config.h2
 157 goto src42
 158 :src41
 159 sed -f ../msdos/sed2v2.inp <config.tmp >config.h2
 160 :src42
 161 update config.h2 config.h >nul
 162 rm -f config.tmp config.h2
 163
 164 rem   On my system dir.h gets in the way.  It's a VMS file so who cares.
 165 if exist dir.h ren dir.h vmsdir.h
 166
 167 rem   Create "makefile" from "makefile.in".
 168 rm -f Makefile junk.c
 169 sed -e "1,/== start of cpp stuff ==/s@^# .*$@@" <Makefile.in >junk.c
 170 If "%DJGPP_VER%" == "1" Goto mfV1
 171 gcc -E -traditional junk.c | sed -f ../msdos/sed1v2.inp >Makefile
 172 goto mfDone
 173 :mfV1
 174 gcc -E -traditional junk.c | sed -f ../msdos/sed1.inp >Makefile
 175 :mfDone
 176 rm -f junk.c
 177
 178 if "%X11%" == "" goto src5
 179 mv Makefile makefile.tmp
 180 sed -f ../msdos/sed1x.inp <makefile.tmp >Makefile
 181 rm -f makefile.tmp
 182 :src5
 183
 184 if "%nodebug%" == "" goto src6
 185 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 186 sed -e "/^LDFLAGS *=/s/=/=-s/" <makefile.tmp >Makefile
 187 rm -f makefile.tmp
 188 :src6
 189 cd ..
 190 rem   ----------------------------------------------------------------------
 191 Echo Configuring the library source directory...
 192 cd lib-src
 193 rem   Create "makefile" from "makefile.in".
 194 sed -e "1,/== start of cpp stuff ==/s@^# .*$@@" <Makefile.in >junk.c
 195 gcc -E -traditional -I. -I../src junk.c | sed -e "s/^ / /" -e "/^#/d" -e "/^[   \f]*$/d" >makefile.new
 196 If "%DJGPP_VER%" == "2" goto libsrc-v2
 197 sed -f ../msdos/sed3.inp <makefile.new >Makefile
 198 Goto libsrc2
 199 :libsrc-v2
 200 sed -f ../msdos/sed3v2.inp <makefile.new >Makefile
 201 :libsrc2
 202 rm -f makefile.new junk.c
 203 if "%nodebug%" == "" goto libsrc3
 204 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 205 sed -e "/^ALL_CFLAGS *=/s/=/= -s/" <makefile.tmp >Makefile
 206 rm -f makefile.tmp
 207 :libsrc3
 208 cd ..
 209 rem   ----------------------------------------------------------------------
 210 if "%X11%" == "" goto oldx1
 211 Echo Configuring the oldxmenu directory...
 212 cd oldxmenu
 213 sed -f ../msdos/sed5x.inp <Makefile.in >Makefile
 214 if "%nodebug%" == "" goto oldx2
 215 sed -e "/^CFLAGS *=/s/ *-gcoff//" <Makefile >makefile.tmp
 216 mv -f makefile.tmp Makefile
 217 :oldx2
 218 cd ..
 219 :oldx1
 220 rem   ----------------------------------------------------------------------
 221 Echo Configuring the manual directory...
 222 cd man
 223 sed -f ../msdos/sed6.inp < Makefile.in > Makefile
 224 cd ..
 225 rem   ----------------------------------------------------------------------
 226 Echo Configuring the ELisp manual directory...
 227 cd lispref
 228 sed -f ../msdos/sed6.inp < Makefile.in > Makefile
 229 cd ..
 230 rem   ----------------------------------------------------------------------
 231 Echo Configuring the ELisp Introduction manual directory...
 232 cd lispintro
 233 sed -f ../msdos/sed6.inp < Makefile.in > Makefile
 234 cd ..
 235 rem   ----------------------------------------------------------------------
 236 Echo Configuring the lisp directory...
 237 cd lisp
 238 sed -f ../msdos/sedlisp.inp < Makefile.in > Makefile
 239 cd ..
 240 rem   ----------------------------------------------------------------------
 241 If not Exist leim\quail\latin-pre.el goto maindir
 242 Echo Configuring the leim directory...
 243 cd leim
 244 sed -f ../msdos/sedleim.inp < Makefile.in > Makefile
 245 cd ..
 246 rem   ----------------------------------------------------------------------
 247 :maindir
 248 Echo Configuring the main directory...
 249 If "%DJGPP_VER%" == "1" goto mainv1
 250 Echo Looking for the GDB init file...
 251 If Exist src\.gdbinit update src/.gdbinit src/_gdbinit
 252 If Exist src\_gdbinit goto gdbinitOk
 253 Echo ERROR:
 254 Echo I cannot find the GDB init file.  It was called ".gdbinit" in
 255 Echo the Emacs distribution, but was probably renamed to some other
 256 Echo name without the leading dot when you untarred the archive.
 257 Echo It should be in the "src/" subdirectory.  Please make sure this
 258 Echo file exists and is called "_gdbinit" with a leading underscore.
 259 Echo Then run CONFIG.BAT again with the same arguments you did now.
 260 goto End
 261 :gdbinitOk
 262 Echo Looking for the GDB init file...found
 263 copy msdos\mainmake.v2 Makefile >nul
 264 :mainv1
 265 If "%DJGPP_VER%" == "1" copy msdos\mainmake Makefile >nul
 266 rem   ----------------------------------------------------------------------
 267 goto End
 268 :SmallEnv
 269 echo Your environment size is too small.  Please enlarge it and run me again.
 270 echo For example, type "command.com /e:2048" to have 2048 bytes available.
 271 set $foo$=
 272 :end
 273 set X11=
 274 set nodebug=
 275 set djgpp_ver=